qcsrc/server/w_hagar.qc

   1 #ifdef REGISTER_WEAPON
   2 REGISTER_WEAPON(HAGAR, w_hagar, IT_ROCKETS, 8, WEP_FLAG_NORMAL | WEP_FLAG_RELOADABLE | WEP_FLAG_CANCLIMB | WEP_TYPE_SPLASH, BOT_PICKUP_RATING_MID, "hagar", "hagar", _("Hagar"))
   3 #else
   4 #ifdef SVQC
   5 // NO bounce protection, as bounces are limited!
   6
   7 void W_Hagar_Explode (void)
   8 {
   9         self.event_damage = SUB_Null;
  10         RadiusDamage (self, self.realowner, autocvar_g_balance_hagar_primary_damage, autocvar_g_balance_hagar_primary_edgedamage, autocvar_g_balance_hagar_primary_radius, world, autocvar_g_balance_hagar_primary_force, self.projectiledeathtype, other);
  11
  12         remove (self);
  13 }
  14
  15 void W_Hagar_Explode2 (void)
  16 {
  17         self.event_damage = SUB_Null;
  18         RadiusDamage (self, self.realowner, autocvar_g_balance_hagar_secondary_damage, autocvar_g_balance_hagar_secondary_edgedamage, autocvar_g_balance_hagar_secondary_radius, world, autocvar_g_balance_hagar_secondary_force, self.projectiledeathtype, other);
  19
  20         remove (self);
  21 }
  22
  23 void W_Hagar_Touch (void)
  24 {
  25         PROJECTILE_TOUCH;
  26         self.use ();
  27 }
  28
  29 void W_Hagar_Touch2 (void)
  30 {
  31         PROJECTILE_TOUCH;
  32
  33         if(self.cnt > 0 || other.takedamage == DAMAGE_AIM) {
  34                 self.use();
  35         } else {
  36                 self.cnt++;
  37                 pointparticles(particleeffectnum("hagar_bounce"), self.origin, self.velocity, 1);
  38                 self.angles = vectoangles (self.velocity);
  39                 self.owner = world;
  40                 self.projectiledeathtype |= HITTYPE_BOUNCE;
  41         }
  42 }
  43
  44 void W_Hagar_Attack (void)
  45 {
  46         local entity missile;
  47
  48         W_DecreaseAmmo(ammo_rockets, autocvar_g_balance_hagar_primary_ammo, autocvar_g_balance_hagar_reload_ammo);
  49
  50         W_SetupShot (self, FALSE, 2, "weapons/hagar_fire.wav", CH_WEAPON_A, autocvar_g_balance_hagar_primary_damage);
  51
  52         pointparticles(particleeffectnum("hagar_muzzleflash"), w_shotorg, w_shotdir * 1000, 1);
  53
  54         missile = spawn ();
  55         missile.owner = missile.realowner = self;
  56         missile.classname = "missile";
  57         missile.bot_dodge = TRUE;
  58         missile.bot_dodgerating = autocvar_g_balance_hagar_primary_damage;
  59         missile.touch = W_Hagar_Touch;
  60         missile.use = W_Hagar_Explode;
  61         missile.think = adaptor_think2use_hittype_splash;
  62         missile.nextthink = time + autocvar_g_balance_hagar_primary_lifetime;
  63         PROJECTILE_MAKETRIGGER(missile);
  64         missile.projectiledeathtype = WEP_HAGAR;
  65         setorigin (missile, w_shotorg);
  66         setsize(missile, '0 0 0', '0 0 0');
  67
  68         missile.movetype = MOVETYPE_FLY;
  69         W_SETUPPROJECTILEVELOCITY(missile, g_balance_hagar_primary);
  70
  71         missile.angles = vectoangles (missile.velocity);
  72         missile.flags = FL_PROJECTILE;
  73
  74         CSQCProjectile(missile, TRUE, PROJECTILE_HAGAR, TRUE);
  75
  76         other = missile; MUTATOR_CALLHOOK(EditProjectile);
  77 }
  78
  79 void W_Hagar_Attack2 (void)
  80 {
  81         local entity missile;
  82
  83         W_DecreaseAmmo(ammo_rockets, autocvar_g_balance_hagar_secondary_ammo, autocvar_g_balance_hagar_reload_ammo);
  84
  85         W_SetupShot (self, FALSE, 2, "weapons/hagar_fire.wav", CH_WEAPON_A, autocvar_g_balance_hagar_secondary_damage);
  86
  87         pointparticles(particleeffectnum("hagar_muzzleflash"), w_shotorg, w_shotdir * 1000, 1);
  88
  89         missile = spawn ();
  90         missile.owner = missile.realowner = self;
  91         missile.classname = "missile";
  92         missile.bot_dodge = TRUE;
  93         missile.bot_dodgerating = autocvar_g_balance_hagar_secondary_damage;
  94         missile.touch = W_Hagar_Touch2;
  95         missile.cnt = 0;
  96         missile.use = W_Hagar_Explode2;
  97         missile.think = adaptor_think2use_hittype_splash;
  98         missile.nextthink = time + autocvar_g_balance_hagar_secondary_lifetime_min + random() * autocvar_g_balance_hagar_secondary_lifetime_rand;
  99         PROJECTILE_MAKETRIGGER(missile);
 100         missile.projectiledeathtype = WEP_HAGAR | HITTYPE_SECONDARY;
 101         setorigin (missile, w_shotorg);
 102         setsize(missile, '0 0 0', '0 0 0');
 103
 104         missile.movetype = MOVETYPE_BOUNCEMISSILE;
 105         W_SETUPPROJECTILEVELOCITY(missile, g_balance_hagar_secondary);
 106
 107         missile.angles = vectoangles (missile.velocity);
 108         missile.flags = FL_PROJECTILE;
 109
 110         CSQCProjectile(missile, TRUE, PROJECTILE_HAGAR_BOUNCING, TRUE);
 111
 112         other = missile; MUTATOR_CALLHOOK(EditProjectile);
 113 }
 114
 115 .float hagar_loadstep, hagar_loadblock, hagar_loadbeep;
 116 void W_Hagar_Attack2_Load_Release (void)
 117 {
 118         // time to release the rockets we've loaded
 119
 120         local entity missile;
 121         local float counter, shots, spread_pershot;
 122         local vector s;
 123         vector forward, right, up;
 124
 125         if(!self.hagar_load)
 126                 return;
 127
 128         weapon_prepareattack_do(1, autocvar_g_balance_hagar_secondary_refire);
 129
 130         W_SetupShot (self, FALSE, 2, "weapons/hagar_fire.wav", CH_WEAPON_A, autocvar_g_balance_hagar_secondary_damage);
 131         pointparticles(particleeffectnum("hagar_muzzleflash"), w_shotorg, w_shotdir * 1000, 1);
 132
 133         forward = v_forward;
 134         right = v_right;
 135         up = v_up;
 136
 137         shots = self.hagar_load;
 138         missile = world;
 139         while (counter < shots)
 140         {
 141                 missile = spawn ();
 142                 missile.owner = missile.realowner = self;
 143                 missile.classname = "missile";
 144                 missile.bot_dodge = TRUE;
 145                 missile.bot_dodgerating = autocvar_g_balance_hagar_secondary_damage;
 146
 147                 missile.touch = W_Hagar_Touch; // not bouncy
 148                 missile.use = W_Hagar_Explode2;
 149                 missile.think = adaptor_think2use_hittype_splash;
 150                 missile.nextthink = time + autocvar_g_balance_hagar_secondary_lifetime_min + random() * autocvar_g_balance_hagar_secondary_lifetime_rand;
 151                 PROJECTILE_MAKETRIGGER(missile);
 152                 missile.projectiledeathtype = WEP_HAGAR;
 153                 setorigin (missile, w_shotorg);
 154                 setsize(missile, '0 0 0', '0 0 0');
 155                 missile.movetype = MOVETYPE_FLY;
 156
 157                 // handle the calculation for the shot pattern and its spread
 158                 spread_pershot = (autocvar_g_balance_hagar_secondary_spread * ((counter + 1) / shots));
 159
 160                 s = '0 0 0';
 161                 if (counter == 0)
 162                         s = '0 0 0';
 163                 else
 164                 {
 165                         makevectors('0 360 0' * (0.75 + (counter - 0.5) / (shots - 1)));
 166                         s_y = v_forward_x;
 167                         s_z = v_forward_y;
 168                 }
 169                 s = s * autocvar_g_balance_hagar_secondary_load_spread * g_weaponspreadfactor;
 170
 171                 W_SetupProjectileVelocityEx(missile, w_shotdir + right * s_y + up * s_z, v_up, autocvar_g_balance_hagar_secondary_speed, 0, 0, spread_pershot, FALSE);
 172
 173                 missile.angles = vectoangles (missile.velocity);
 174                 missile.flags = FL_PROJECTILE;
 175
 176                 CSQCProjectile(missile, TRUE, PROJECTILE_HAGAR, TRUE);
 177
 178                 other = missile; MUTATOR_CALLHOOK(EditProjectile);
 179
 180                 counter = counter + 1;
 181         }
 182
 183         weapon_thinkf(WFRAME_FIRE2, autocvar_g_balance_hagar_secondary_refire, w_ready);
 184         self.hagar_loadstep = time + autocvar_g_balance_hagar_secondary_refire * W_WeaponRateFactor();
 185         self.hagar_load = 0;
 186 }
 187
 188 void W_Hagar_Attack2_Load (void)
 189 {
 190         // loadable hagar secondary attack, must always run each frame
 191
 192         local float loaded, enough_ammo;
 193         loaded = self.hagar_load >= autocvar_g_balance_hagar_secondary_load_max;
 194
 195         // this is different than WR_CHECKAMMO when it comes to reloading
 196         if(autocvar_g_balance_hagar_reload_ammo)
 197                 enough_ammo = self.weapon_load[WEP_HAGAR] >= autocvar_g_balance_hagar_secondary_ammo;
 198         else
 199                 enough_ammo = self.ammo_rockets >= autocvar_g_balance_hagar_secondary_ammo;
 200
 201         if(self.BUTTON_ATCK2)
 202         {
 203                 if(self.BUTTON_ATCK && autocvar_g_balance_hagar_secondary_load_abort)
 204                 {
 205                         if(self.hagar_load)
 206                         {
 207                                 // if we pressed primary fire while loading, unload all rockets and abort
 208                                 self.weaponentity.state = WS_READY;
 209                                 W_DecreaseAmmo(ammo_rockets, autocvar_g_balance_hagar_secondary_ammo * self.hagar_load * -1, autocvar_g_balance_hagar_reload_ammo); // give back ammo
 210                                 self.hagar_load = 0;
 211                                 sound(self, CH_WEAPON_A, "weapons/hagar_beep.wav", VOL_BASE, ATTN_NORM);
 212
 213                                 // pause until we can load rockets again, once we re-press the alt fire button
 214                                 self.hagar_loadstep = time + autocvar_g_balance_hagar_secondary_load_speed * W_WeaponRateFactor();
 215
 216                                 // require letting go of the alt fire button before we can load again
 217                                 self.hagar_loadblock = TRUE;
 218                         }
 219                 }
 220                 else
 221                 {
 222                         // check if we can attempt to load another rocket
 223                         if(!loaded && enough_ammo)
 224                         {
 225                                 if(!self.hagar_loadblock && self.hagar_loadstep < time)
 226                                 {
 227                                         W_DecreaseAmmo(ammo_rockets, autocvar_g_balance_hagar_secondary_ammo, autocvar_g_balance_hagar_reload_ammo);
 228                                         self.weaponentity.state = WS_INUSE;
 229                                         self.hagar_load += 1;
 230                                         sound(self, CH_WEAPON_B, "weapons/hagar_load.wav", VOL_BASE, ATTN_NORM);
 231
 232                                         self.hagar_loadstep = time + autocvar_g_balance_hagar_secondary_load_speed * W_WeaponRateFactor();
 233                                 }
 234                         }
 235                         else if(!self.hagar_loadbeep && self.hagar_load) // prevents the beep from playing each frame
 236                         {
 237                                 // if this is the last rocket we can load, play a beep sound to notify the player
 238                                 sound(self, CH_WEAPON_A, "weapons/hagar_beep.wav", VOL_BASE, ATTN_NORM);
 239                                 self.hagar_loadbeep = TRUE;
 240                         }
 241                 }
 242         }
 243         else if(self.hagar_loadblock)
 244         {
 245                 // the alt fire button has been released, so re-enable loading if blocked
 246                 self.hagar_loadblock = FALSE;
 247         }
 248
 249         if(self.hagar_load)
 250         {
 251                 if(!self.BUTTON_ATCK2 || ((loaded || !enough_ammo) && self.hagar_loadstep < time && !autocvar_g_balance_hagar_secondary_load_hold))
 252                 {
 253                         self.weaponentity.state = WS_READY;
 254                         W_Hagar_Attack2_Load_Release();
 255                 }
 256         }
 257         else
 258         {
 259                 self.hagar_loadbeep = FALSE;
 260         }
 261
 262         // we aren't checking ammo during an attack, so we must do it here
 263         if not(weapon_action(self.weapon, WR_CHECKAMMO1) + weapon_action(self.weapon, WR_CHECKAMMO2))
 264         {
 265                 // note: this doesn't force the switch
 266                 W_SwitchToOtherWeapon(self);
 267                 return;
 268         }
 269 }
 270
 271 void spawnfunc_weapon_hagar (void)
 272 {
 273         weapon_defaultspawnfunc(WEP_HAGAR);
 274 }
 275
 276 float w_hagar(float req)
 277 {
 278         float ammo_amount;
 279         if (req == WR_AIM)
 280                 if (random()>0.15)
 281                         self.BUTTON_ATCK = bot_aim(autocvar_g_balance_hagar_primary_speed, 0, autocvar_g_balance_hagar_primary_lifetime, FALSE);
 282                 else
 283                 {
 284                         // not using secondary_speed since these are only 15% and should cause some ricochets without re-aiming
 285                         self.BUTTON_ATCK2 = bot_aim(autocvar_g_balance_hagar_primary_speed, 0, autocvar_g_balance_hagar_primary_lifetime, FALSE);
 286                 }
 287         else if (req == WR_THINK)
 288         {
 289                 local float loadable_secondary;
 290                 loadable_secondary = autocvar_g_balance_hagar_secondary_load && autocvar_g_balance_hagar_secondary;
 291
 292                 if (loadable_secondary)
 293                         W_Hagar_Attack2_Load(); // must always run each frame
 294                 if(autocvar_g_balance_hagar_reload_ammo && self.clip_load < min(autocvar_g_balance_hagar_primary_ammo, autocvar_g_balance_hagar_secondary_ammo)) // forced reload
 295                         weapon_action(self.weapon, WR_RELOAD);
 296                 else if (self.BUTTON_ATCK && !self.hagar_load && !self.hagar_loadblock) // not while secondary is loaded or awaiting reset
 297                 {
 298                         if (weapon_prepareattack(0, autocvar_g_balance_hagar_primary_refire))
 299                         {
 300                                 W_Hagar_Attack();
 301                                 weapon_thinkf(WFRAME_FIRE1, autocvar_g_balance_hagar_primary_refire, w_ready);
 302                         }
 303                 }
 304                 else if (self.BUTTON_ATCK2 && !loadable_secondary && autocvar_g_balance_hagar_secondary)
 305                 {
 306                         if (weapon_prepareattack(1, autocvar_g_balance_hagar_secondary_refire))
 307                         {
 308                                 W_Hagar_Attack2();
 309                                 weapon_thinkf(WFRAME_FIRE2, autocvar_g_balance_hagar_secondary_refire, w_ready);
 310                         }
 311                 }
 312         }
 313         else if (req == WR_GONETHINK)
 314         {
 315                 // we lost the weapon and want to prepare switching away
 316                 if(self.hagar_load)
 317                 {
 318                         self.weaponentity.state = WS_READY;
 319                         W_Hagar_Attack2_Load_Release();
 320                 }
 321         }
 322         else if (req == WR_PRECACHE)
 323         {
 324                 precache_model ("models/weapons/g_hagar.md3");
 325                 precache_model ("models/weapons/v_hagar.md3");
 326                 precache_model ("models/weapons/h_hagar.iqm");
 327                 precache_sound ("weapons/hagar_fire.wav");
 328                 precache_sound ("weapons/hagar_load.wav");
 329                 precache_sound ("weapons/hagar_beep.wav");
 330                 //precache_sound ("weapons/reload.wav"); // until weapons have individual reload sounds, precache the reload sound somewhere else
 331         }
 332         else if (req == WR_SETUP)
 333         {
 334                 weapon_setup(WEP_HAGAR);
 335                 self.current_ammo = ammo_rockets;
 336                 self.hagar_loadblock = FALSE;
 337
 338                 if(self.hagar_load)
 339                 {
 340                         W_DecreaseAmmo(ammo_rockets, autocvar_g_balance_hagar_secondary_ammo * self.hagar_load * -1, autocvar_g_balance_hagar_reload_ammo); // give back ammo if necessary
 341                         self.hagar_load = 0;
 342                 }
 343         }
 344         else if (req == WR_CHECKAMMO1)
 345         {
 346                 ammo_amount = self.ammo_rockets >= autocvar_g_balance_hagar_primary_ammo;
 347                 ammo_amount += self.weapon_load[WEP_HAGAR] >= autocvar_g_balance_hagar_primary_ammo;
 348                 return ammo_amount;
 349         }
 350         else if (req == WR_CHECKAMMO2)
 351         {
 352                 ammo_amount = self.ammo_rockets >= autocvar_g_balance_hagar_secondary_ammo;
 353                 ammo_amount += self.weapon_load[WEP_HAGAR] >= autocvar_g_balance_hagar_secondary_ammo;
 354                 return ammo_amount;
 355         }
 356         else if (req == WR_RESETPLAYER)
 357         {
 358                 self.hagar_load = 0;
 359         }
 360         else if (req == WR_PLAYERDEATH)
 361         {
 362                 // if we have any rockets loaded when we die, release them
 363                 if(self.hagar_load && autocvar_g_balance_hagar_secondary_load_releasedeath)
 364                         W_Hagar_Attack2_Load_Release();
 365         }
 366         else if (req == WR_RELOAD)
 367         {
 368                 if not(self.hagar_load) // require releasing loaded rockets first
 369                         W_Reload(min(autocvar_g_balance_hagar_primary_ammo, autocvar_g_balance_hagar_secondary_ammo), autocvar_g_balance_hagar_reload_ammo, autocvar_g_balance_hagar_reload_time, "weapons/reload.wav");
 370         }
 371         return TRUE;
 372 };
 373 #endif
 374 #ifdef CSQC
 375 float w_hagar(float req)
 376 {
 377         if(req == WR_IMPACTEFFECT)
 378         {
 379                 vector org2;
 380                 org2 = w_org + w_backoff * 6;
 381                 pointparticles(particleeffectnum("hagar_explode"), org2, '0 0 0', 1);
 382                 if(!w_issilent)
 383                 {
 384                         if (w_random<0.15)
 385                                 sound(self, CH_SHOTS, "weapons/hagexp1.wav", VOL_BASE, ATTN_NORM);
 386                         else if (w_random<0.7)
 387                                 sound(self, CH_SHOTS, "weapons/hagexp2.wav", VOL_BASE, ATTN_NORM);
 388                         else
 389                                 sound(self, CH_SHOTS, "weapons/hagexp3.wav", VOL_BASE, ATTN_NORM);
 390                 }
 391         }
 392         else if(req == WR_PRECACHE)
 393         {
 394                 precache_sound("weapons/hagexp1.wav");
 395                 precache_sound("weapons/hagexp2.wav");
 396                 precache_sound("weapons/hagexp3.wav");
 397         }
 398         else if (req == WR_SUICIDEMESSAGE)
 399                 w_deathtypestring = _("%s played with tiny rockets");
 400         else if (req == WR_KILLMESSAGE)
 401         {
 402                 if(w_deathtype & HITTYPE_BOUNCE) // must be secondary; unchecked: SPLASH
 403                         w_deathtypestring = _("%s hoped %s's missiles wouldn't bounce");
 404                 else // unchecked: SPLASH, SECONDARY
 405                         w_deathtypestring = _("%s was pummeled by %s");
 406         }
 407         return TRUE;
 408 }
 409 #endif
 410 #endif