qcsrc/server/w_minelayer.qc

   1 #ifdef REGISTER_WEAPON
   2 REGISTER_WEAPON(MINE_LAYER, w_minelayer, IT_ROCKETS, 4, WEP_TYPE_SPLASH, BOT_PICKUP_RATING_HIGH, "minelayer", "minelayer", _("Mine Layer"))
   3 #else
   4 #ifdef SVQC
   5 void W_Mine_Think (void);
   6 .float minelayer_detonate, minelayer_mines;
   7 .float mine_time;
   8
   9 // weapon load persistence, for weapons that support reloading
  10 .float minelayer_load;
  11
  12 void W_MineLayer_SetAmmoCounter()
  13 {
  14         // set clip_load to the weapon we have switched to, if the gun uses reloading
  15         if(!autocvar_g_balance_minelayer_reload_ammo)
  16                 self.clip_load = 0; // also keeps crosshair ammo from displaying
  17         else
  18         {
  19                 self.clip_load = self.minelayer_load;
  20                 self.clip_size = autocvar_g_balance_minelayer_reload_ammo; // for the crosshair ammo display
  21         }
  22 }
  23
  24 void W_MineLayer_ReloadedAndReady()
  25 {
  26         float t;
  27
  28         // now do the ammo transfer
  29         self.clip_load = self.old_clip_load; // restore the ammo counter, in case we still had ammo in the weapon before reloading
  30         while(self.clip_load < autocvar_g_balance_minelayer_reload_ammo && self.ammo_rockets) // make sure we don't add more ammo than we have
  31         {
  32                 self.clip_load += 1;
  33                 self.ammo_rockets -= 1;
  34         }
  35         self.minelayer_load = self.clip_load;
  36
  37         t = ATTACK_FINISHED(self) - autocvar_g_balance_minelayer_reload_time - 1;
  38         ATTACK_FINISHED(self) = t;
  39         w_ready();
  40 }
  41
  42 void W_MineLayer_Reload()
  43 {
  44         // return if reloading is disabled for this weapon
  45         if(!autocvar_g_balance_minelayer_reload_ammo)
  46                 return;
  47
  48         if(!W_ReloadCheck(self.ammo_rockets, autocvar_g_balance_minelayer_ammo))
  49                 return;
  50
  51         float t;
  52
  53         sound (self, CHAN_WEAPON2, "weapons/reload.wav", VOL_BASE, ATTN_NORM);
  54
  55         t = max(time, ATTACK_FINISHED(self)) + autocvar_g_balance_minelayer_reload_time + 1;
  56         ATTACK_FINISHED(self) = t;
  57
  58         weapon_thinkf(WFRAME_RELOAD, autocvar_g_balance_minelayer_reload_time, W_MineLayer_ReloadedAndReady);
  59
  60         self.old_clip_load = self.clip_load;
  61         self.clip_load = -1;
  62 }
  63
  64 void spawnfunc_weapon_minelayer (void)
  65 {
  66         weapon_defaultspawnfunc(WEP_MINE_LAYER);
  67 }
  68
  69 void W_Mine_Stick ()
  70 {
  71         spamsound (self, CHAN_PROJECTILE, "weapons/mine_stick.wav", VOL_BASE, ATTN_NORM);
  72
  73         // in order for mines to face properly when sticking to the ground, they must be a server side entity rather than a csqc projectile
  74
  75         entity newmine;
  76         newmine = spawn();
  77         newmine.classname = self.classname;
  78
  79         newmine.bot_dodge = self.bot_dodge;
  80         newmine.bot_dodgerating = self.bot_dodgerating;
  81
  82         newmine.owner = self.owner;
  83         setsize(newmine, '-4 -4 -4', '4 4 4');
  84         setorigin(newmine, self.origin);
  85         setmodel(newmine, "models/mine.md3");
  86         newmine.angles = vectoangles(-trace_plane_normal); // face against the surface
  87
  88         newmine.takedamage = self.takedamage;
  89         newmine.damageforcescale = self.damageforcescale;
  90         newmine.health = self.health;
  91         newmine.event_damage = self.event_damage;
  92         newmine.spawnshieldtime = self.spawnshieldtime;
  93
  94         newmine.movetype = MOVETYPE_NONE; // lock the mine in place
  95         newmine.projectiledeathtype = self.projectiledeathtype;
  96
  97         newmine.mine_time = self.mine_time;
  98
  99         newmine.touch = SUB_Null;
 100         newmine.think = W_Mine_Think;
 101         newmine.nextthink = time;
 102         newmine.cnt = self.cnt;
 103         newmine.flags = self.flags;
 104
 105         remove(self);
 106         self = newmine;
 107 }
 108
 109 void W_Mine_Explode ()
 110 {
 111         if(other.takedamage == DAMAGE_AIM)
 112                 if(other.classname == "player")
 113                         if(IsDifferentTeam(self.owner, other))
 114                                 if(IsFlying(other))
 115                                         AnnounceTo(self.owner, "airshot");
 116
 117         self.event_damage = SUB_Null;
 118         self.takedamage = DAMAGE_NO;
 119
 120         RadiusDamage (self, self.owner, autocvar_g_balance_minelayer_damage, autocvar_g_balance_minelayer_edgedamage, autocvar_g_balance_minelayer_radius, world, autocvar_g_balance_minelayer_force, self.projectiledeathtype, other);
 121
 122         if (self.owner.weapon == WEP_MINE_LAYER)
 123         {
 124                 if(self.owner.ammo_rockets < autocvar_g_balance_minelayer_ammo)
 125                 {
 126                         self.owner.cnt = WEP_MINE_LAYER;
 127                         ATTACK_FINISHED(self.owner) = time;
 128                         self.owner.switchweapon = w_getbestweapon(self.owner);
 129                 }
 130         }
 131         remove (self);
 132 }
 133
 134 void W_Mine_DoRemoteExplode ()
 135 {
 136         self.event_damage = SUB_Null;
 137         self.takedamage = DAMAGE_NO;
 138
 139         RadiusDamage (self, self.owner, autocvar_g_balance_minelayer_remote_damage, autocvar_g_balance_minelayer_remote_edgedamage, autocvar_g_balance_minelayer_remote_radius, world, autocvar_g_balance_minelayer_remote_force, self.projectiledeathtype | HITTYPE_BOUNCE, world);
 140
 141         if (self.owner.weapon == WEP_MINE_LAYER)
 142         {
 143                 if(self.owner.ammo_rockets < autocvar_g_balance_minelayer_ammo)
 144                 {
 145                         self.owner.cnt = WEP_MINE_LAYER;
 146                         ATTACK_FINISHED(self.owner) = time;
 147                         self.owner.switchweapon = w_getbestweapon(self.owner);
 148                 }
 149         }
 150         remove (self);
 151 }
 152
 153 void W_Mine_RemoteExplode ()
 154 {
 155         if(self.owner.deadflag == DEAD_NO)
 156                 if((self.spawnshieldtime >= 0)
 157                         ? (time >= self.spawnshieldtime) // timer
 158                         : (vlen(NearestPointOnBox(self.owner, self.origin) - self.origin) > autocvar_g_balance_minelayer_remote_radius) // safety device
 159                 )
 160                 {
 161                         W_Mine_DoRemoteExplode();
 162                 }
 163 }
 164
 165 void W_Mine_ProximityExplode ()
 166 {
 167         // make sure no friend is in the mine's radius. If there is any, explosion is delayed until he's at a safe distance
 168         if(autocvar_g_balance_minelayer_protection)
 169         {
 170                 entity head;
 171                 head = findradius(self.origin, autocvar_g_balance_minelayer_radius);
 172                 while(head)
 173                 {
 174                         if(head == self.owner || !IsDifferentTeam(head, self.owner))
 175                                 return;
 176                         head = head.chain;
 177                 }
 178         }
 179
 180         self.mine_time = 0;
 181         W_Mine_Explode();
 182 }
 183
 184 void W_Mine_Think (void)
 185 {
 186         entity head;
 187
 188         self.nextthink = time;
 189         if (time > self.cnt)
 190         {
 191                 other = world;
 192                 self.projectiledeathtype |= HITTYPE_BOUNCE;
 193                 W_Mine_Explode();
 194                 return;
 195         }
 196
 197         // a player's mines shall explode if he disconnects or dies
 198         // TODO: Do this on team change too
 199         if(self.owner.classname != "player" || self.owner.deadflag != DEAD_NO)
 200         {
 201                 other = world;
 202                 self.projectiledeathtype |= HITTYPE_BOUNCE;
 203                 W_Mine_Explode();
 204                 return;
 205         }
 206
 207         // set the mine for detonation when a foe gets close enough
 208         head = findradius(self.origin, autocvar_g_balance_minelayer_proximityradius);
 209         while(head)
 210         {
 211                 if(head.classname == "player" && head.deadflag == DEAD_NO)
 212                 if(head != self.owner && IsDifferentTeam(head, self.owner)) // don't trigger for team mates
 213                 if(!self.mine_time)
 214                 {
 215                         spamsound (self, CHAN_PROJECTILE, "weapons/mine_trigger.wav", VOL_BASE, ATTN_NORM);
 216                         self.mine_time = time + autocvar_g_balance_minelayer_time;
 217                 }
 218                 head = head.chain;
 219         }
 220
 221         // explode if it's time to
 222         if(self.mine_time && time >= self.mine_time)
 223                 W_Mine_ProximityExplode();
 224
 225         // remote detonation
 226         if (self.owner.weapon == WEP_MINE_LAYER)
 227         if (self.owner.deadflag == DEAD_NO)
 228         if (self.minelayer_detonate)
 229                 W_Mine_RemoteExplode();
 230 }
 231
 232 void W_Mine_Touch (void)
 233 {
 234         PROJECTILE_TOUCH;
 235         if(!other || (other.takedamage != DAMAGE_AIM && other.movetype == MOVETYPE_NONE))
 236                 W_Mine_Stick();
 237         else if(self.movetype != MOVETYPE_NONE) // don't unstick a locked mine when someone touches it
 238                 self.velocity = '0 0 0';
 239 }
 240
 241 void W_Mine_Damage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 242 {
 243         if (self.health <= 0)
 244                 return;
 245         self.health = self.health - damage;
 246         self.angles = vectoangles(self.velocity);
 247         if (self.health <= 0)
 248                 W_PrepareExplosionByDamage(attacker, W_Mine_Explode);
 249 }
 250
 251 void W_Mine_Attack (void)
 252 {
 253         entity mine;
 254         entity flash;
 255
 256         // scan how many mines we placed, and return if we reached our limit
 257         if(autocvar_g_balance_minelayer_limit)
 258         {
 259                 self.minelayer_mines = 0;
 260                 for(mine = world; (mine = find(mine, classname, "mine")); ) if(mine.owner == self)
 261                         self.minelayer_mines += 1;
 262
 263                 if(self.minelayer_mines >= autocvar_g_balance_minelayer_limit)
 264                 {
 265                         // the refire delay keeps this message from being spammed
 266                         sprint(self, strcat("You cannot place more than ^2", ftos(autocvar_g_balance_minelayer_limit), " ^7mines at a time\n") );
 267                         play2(self, "weapons/unavailable.wav");
 268                         return;
 269                 }
 270         }
 271
 272         // if this weapon is reloadable, decrease its load. Else decrease the player's ammo
 273         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
 274         {
 275                 if(autocvar_g_balance_minelayer_reload_ammo)
 276                 {
 277                         self.clip_load -= autocvar_g_balance_minelayer_ammo;
 278                         self.minelayer_load = self.clip_load;
 279                 }
 280                 else
 281                         self.ammo_rockets -= autocvar_g_balance_minelayer_ammo;
 282         }
 283
 284         W_SetupShot_ProjectileSize (self, '-4 -4 -4', '4 4 4', FALSE, 5, "weapons/mine_fire.wav", CHAN_WEAPON, autocvar_g_balance_minelayer_damage);
 285         pointparticles(particleeffectnum("rocketlauncher_muzzleflash"), w_shotorg, w_shotdir * 1000, 1);
 286
 287         mine = WarpZone_RefSys_SpawnSameRefSys(self);
 288         mine.owner = self;
 289         if(autocvar_g_balance_minelayer_detonatedelay >= 0)
 290                 mine.spawnshieldtime = time + autocvar_g_balance_minelayer_detonatedelay;
 291         else
 292                 mine.spawnshieldtime = -1;
 293         mine.classname = "mine";
 294         mine.bot_dodge = TRUE;
 295         mine.bot_dodgerating = autocvar_g_balance_minelayer_damage * 2; // * 2 because it can detonate inflight which makes it even more dangerous
 296
 297         mine.takedamage = DAMAGE_YES;
 298         mine.damageforcescale = autocvar_g_balance_minelayer_damageforcescale;
 299         mine.health = autocvar_g_balance_minelayer_health;
 300         mine.event_damage = W_Mine_Damage;
 301
 302         mine.movetype = MOVETYPE_TOSS;
 303         PROJECTILE_MAKETRIGGER(mine);
 304         mine.projectiledeathtype = WEP_MINE_LAYER;
 305         setsize (mine, '-4 -4 -4', '4 4 4'); // give it some size so it can be shot
 306
 307         setorigin (mine, w_shotorg - v_forward * 4); // move it back so it hits the wall at the right point
 308         W_SetupProjectileVelocity(mine, autocvar_g_balance_minelayer_speed, 0);
 309         mine.angles = vectoangles (mine.velocity);
 310
 311         mine.touch = W_Mine_Touch;
 312         mine.think = W_Mine_Think;
 313         mine.nextthink = time;
 314         mine.cnt = time + autocvar_g_balance_minelayer_lifetime;
 315         mine.flags = FL_PROJECTILE;
 316
 317         CSQCProjectile(mine, TRUE, PROJECTILE_MINE, TRUE);
 318
 319         // muzzle flash for 1st person view
 320         flash = spawn ();
 321         setmodel (flash, "models/flash.md3"); // precision set below
 322         SUB_SetFade (flash, time, 0.1);
 323         flash.effects = EF_ADDITIVE | EF_FULLBRIGHT | EF_LOWPRECISION;
 324         W_AttachToShotorg(flash, '5 0 0');
 325
 326         // common properties
 327
 328         other = mine; MUTATOR_CALLHOOK(EditProjectile);
 329 }
 330
 331 void spawnfunc_weapon_minelayer (void); // defined in t_items.qc
 332
 333 float w_minelayer(float req)
 334 {
 335         entity mine;
 336         float minfound;
 337         float ammo_amount;
 338
 339         if (req == WR_AIM)
 340         {
 341                 // aim and decide to fire if appropriate
 342                 self.BUTTON_ATCK = bot_aim(autocvar_g_balance_minelayer_speed, 0, autocvar_g_balance_minelayer_lifetime, FALSE);
 343                 if(skill >= 2) // skill 0 and 1 bots won't detonate mines!
 344                 {
 345                         // decide whether to detonate mines
 346                         entity targetlist, targ;
 347                         float edgedamage, coredamage, edgeradius, recipricoledgeradius, d;
 348                         float selfdamage, teamdamage, enemydamage;
 349                         edgedamage = autocvar_g_balance_minelayer_edgedamage;
 350                         coredamage = autocvar_g_balance_minelayer_damage;
 351                         edgeradius = autocvar_g_balance_minelayer_radius;
 352                         recipricoledgeradius = 1 / edgeradius;
 353                         selfdamage = 0;
 354                         teamdamage = 0;
 355                         enemydamage = 0;
 356                         targetlist = findchainfloat(bot_attack, TRUE);
 357                         mine = find(world, classname, "mine");
 358                         while (mine)
 359                         {
 360                                 if (mine.owner != self)
 361                                 {
 362                                         mine = find(mine, classname, "mine");
 363                                         continue;
 364                                 }
 365                                 targ = targetlist;
 366                                 while (targ)
 367                                 {
 368                                         d = vlen(targ.origin + (targ.mins + targ.maxs) * 0.5 - mine.origin);
 369                                         d = bound(0, edgedamage + (coredamage - edgedamage) * sqrt(1 - d * recipricoledgeradius), 10000);
 370                                         // count potential damage according to type of target
 371                                         if (targ == self)
 372                                                 selfdamage = selfdamage + d;
 373                                         else if (targ.team == self.team && teams_matter)
 374                                                 teamdamage = teamdamage + d;
 375                                         else if (bot_shouldattack(targ))
 376                                                 enemydamage = enemydamage + d;
 377                                         targ = targ.chain;
 378                                 }
 379                                 mine = find(mine, classname, "mine");
 380                         }
 381                         float desirabledamage;
 382                         desirabledamage = enemydamage;
 383                         if (time > self.invincible_finished && time > self.spawnshieldtime)
 384                                 desirabledamage = desirabledamage - selfdamage * autocvar_g_balance_selfdamagepercent;
 385                         if (teams_matter && self.team)
 386                                 desirabledamage = desirabledamage - teamdamage;
 387
 388                         mine = find(world, classname, "mine");
 389                         while (mine)
 390                         {
 391                                 if (mine.owner != self)
 392                                 {
 393                                         mine = find(mine, classname, "mine");
 394                                         continue;
 395                                 }
 396                                 makevectors(mine.v_angle);
 397                                 targ = targetlist;
 398                                 if (skill > 9) // normal players only do this for the target they are tracking
 399                                 {
 400                                         targ = targetlist;
 401                                         while (targ)
 402                                         {
 403                                                 if (
 404                                                         (v_forward * normalize(mine.origin - targ.origin)< 0.1)
 405                                                         && desirabledamage > 0.1*coredamage
 406                                                 )self.BUTTON_ATCK2 = TRUE;
 407                                                 targ = targ.chain;
 408                                         }
 409                                 }else{
 410                                         float distance; distance= bound(300,vlen(self.origin-self.enemy.origin),30000);
 411                                         //As the distance gets larger, a correct detonation gets near imposible
 412                                         //Bots are assumed to use the mine spawnfunc_light to see if the mine gets near a player
 413                                         if(v_forward * normalize(mine.origin - self.enemy.origin)< 0.1)
 414                                                 if(self.enemy.classname == "player")
 415                                                         if(desirabledamage >= 0.1*coredamage)
 416                                                                 if(random()/distance*300 > frametime*bound(0,(10-skill)*0.2,1))
 417                                                                         self.BUTTON_ATCK2 = TRUE;
 418                                 //      dprint(ftos(random()/distance*300),">");dprint(ftos(frametime*bound(0,(10-skill)*0.2,1)),"\n");
 419                                 }
 420
 421                                 mine = find(mine, classname, "mine");
 422                         }
 423                         // if we would be doing at X percent of the core damage, detonate it
 424                         // but don't fire a new shot at the same time!
 425                         if (desirabledamage >= 0.75 * coredamage) //this should do group damage in rare fortunate events
 426                                 self.BUTTON_ATCK2 = TRUE;
 427                         if ((skill > 6.5) && (selfdamage > self.health))
 428                                 self.BUTTON_ATCK2 = FALSE;
 429                         //if(self.BUTTON_ATCK2 == TRUE)
 430                         //      dprint(ftos(desirabledamage),"\n");
 431                         if (self.BUTTON_ATCK2 == TRUE) self.BUTTON_ATCK = FALSE;
 432                 }
 433         }
 434         else if (req == WR_THINK)
 435         {
 436                 if(autocvar_g_balance_minelayer_reload_ammo && self.clip_load < autocvar_g_balance_minelayer_ammo) // forced reload
 437                         W_MineLayer_Reload();
 438                 else if (self.BUTTON_ATCK)
 439                 {
 440                         if(weapon_prepareattack(0, autocvar_g_balance_minelayer_refire))
 441                         {
 442                                 W_Mine_Attack();
 443                                 weapon_thinkf(WFRAME_FIRE1, autocvar_g_balance_minelayer_animtime, w_ready);
 444                         }
 445                 }
 446
 447                 else if (self.BUTTON_ATCK2)
 448                 {
 449                         minfound = 0;
 450                         for(mine = world; (mine = find(mine, classname, "mine")); ) if(mine.owner == self)
 451                         {
 452                                 if(!mine.minelayer_detonate)
 453                                 {
 454                                         mine.minelayer_detonate = TRUE;
 455                                         minfound = 1;
 456                                 }
 457                         }
 458                         if(minfound)
 459                                 sound (self, CHAN_WEAPON2, "weapons/mine_det.wav", VOL_BASE, ATTN_NORM);
 460                 }
 461         }
 462         else if (req == WR_PRECACHE)
 463         {
 464                 precache_model ("models/flash.md3");
 465                 precache_model ("models/mine.md3");
 466                 precache_model ("models/weapons/g_minelayer.md3");
 467                 precache_model ("models/weapons/v_minelayer.md3");
 468                 precache_model ("models/weapons/h_minelayer.iqm");
 469                 precache_sound ("weapons/mine_det.wav");
 470                 precache_sound ("weapons/mine_fire.wav");
 471                 precache_sound ("weapons/mine_stick.wav");
 472                 precache_sound ("weapons/mine_trigger.wav");
 473                 precache_sound ("weapons/reload.wav");
 474         }
 475         else if (req == WR_SETUP)
 476         {
 477                 weapon_setup(WEP_MINE_LAYER);
 478                 W_MineLayer_SetAmmoCounter();
 479         }
 480         else if (req == WR_CHECKAMMO1)
 481         {
 482                 // don't switch while placing a mine
 483                 if (ATTACK_FINISHED(self) <= time || self.weapon != WEP_MINE_LAYER)
 484                 {
 485                         if(self.ammo_rockets < autocvar_g_balance_minelayer_ammo)
 486                                 ammo_amount = FALSE;
 487                         if(autocvar_g_balance_electro_reload_ammo && self.minelayer_load < autocvar_g_balance_minelayer_ammo)
 488                                 ammo_amount = FALSE;
 489                 }
 490                 return ammo_amount;
 491         }
 492         else if (req == WR_CHECKAMMO2)
 493         {
 494                 return FALSE;
 495         }
 496         else if (req == WR_RESETPLAYER)
 497         {
 498                 // all weapons must be fully loaded when we spawn
 499                 self.minelayer_load = autocvar_g_balance_minelayer_reload_ammo;
 500         }
 501         else if (req == WR_RELOAD)
 502         {
 503                 W_MineLayer_Reload();
 504         }
 505         return TRUE;
 506 };
 507 #endif
 508 #ifdef CSQC
 509 float w_minelayer(float req)
 510 {
 511         if(req == WR_IMPACTEFFECT)
 512         {
 513                 vector org2;
 514                 org2 = w_org + w_backoff * 12;
 515                 pointparticles(particleeffectnum("rocket_explode"), org2, '0 0 0', 1);
 516                 if(!w_issilent)
 517                         sound(self, CHAN_PROJECTILE, "weapons/mine_exp.wav", VOL_BASE, ATTN_NORM);
 518         }
 519         else if(req == WR_PRECACHE)
 520         {
 521                 precache_sound("weapons/mine_exp.wav");
 522         }
 523         else if (req == WR_SUICIDEMESSAGE)
 524                 w_deathtypestring = _("%s exploded");
 525         else if (req == WR_KILLMESSAGE)
 526         {
 527                 if(w_deathtype & HITTYPE_BOUNCE) // (remote detonation)
 528                         w_deathtypestring = _("%s got too close to %s's mine");
 529                 else if(w_deathtype & HITTYPE_SPLASH)
 530                         w_deathtypestring = _("%s almost dodged %s's mine");
 531                 else
 532                         w_deathtypestring = _("%s stepped on %s's mine");
 533         }
 534         return TRUE;
 535 }
 536 #endif
 537 #endif