qcsrc/server/w_minelayer.qc

   1 #ifdef REGISTER_WEAPON
   2 REGISTER_WEAPON(MINE_LAYER, w_minelayer, IT_ROCKETS, 9, WEP_FLAG_NORMAL | WEP_TYPE_SPLASH, BOT_PICKUP_RATING_HIGH, "minelayer", "minelayer", "Mine Layer");
   3 #else
   4 #ifdef SVQC
   5 .float minelayer_detonate;
   6 .float mine_number;
   7
   8 void spawnfunc_weapon_minelayer (void)
   9 {
  10         weapon_defaultspawnfunc(WEP_MINE_LAYER);
  11 }
  12
  13 void W_Mine_Unregister()
  14 {
  15         if(self.owner && self.owner.lastmine == self)
  16                 self.owner.lastmine = world;
  17 }
  18
  19 void W_Mine_Explode ()
  20 {
  21         W_Mine_Unregister();
  22
  23         if(other.takedamage == DAMAGE_AIM)
  24                 if(other.classname == "player")
  25                         if(IsDifferentTeam(self.owner, other))
  26                                 if(IsFlying(other))
  27                                         AnnounceTo(self.owner, "airshot");
  28
  29         self.event_damage = SUB_Null;
  30         self.takedamage = DAMAGE_NO;
  31
  32         RadiusDamage (self, self.owner, cvar("g_balance_minelayer_damage"), cvar("g_balance_minelayer_edgedamage"), cvar("g_balance_minelayer_radius"), world, cvar("g_balance_minelayer_force"), self.projectiledeathtype, other);
  33
  34         if (self.owner.weapon == WEP_MINE_LAYER)
  35         {
  36                 if(self.owner.ammo_rockets < cvar("g_balance_minelayer_ammo"))
  37                 {
  38                         self.owner.cnt = WEP_MINE_LAYER;
  39                         ATTACK_FINISHED(self.owner) = time;
  40                         self.owner.switchweapon = w_getbestweapon(self.owner);
  41                 }
  42         }
  43         remove (self);
  44 }
  45
  46 void W_Mine_DoRemoteExplode ()
  47 {
  48         W_Mine_Unregister();
  49
  50         self.event_damage = SUB_Null;
  51         self.takedamage = DAMAGE_NO;
  52
  53         RadiusDamage (self, self.owner, cvar("g_balance_minelayer_remote_damage"), cvar("g_balance_minelayer_remote_edgedamage"), cvar("g_balance_minelayer_remote_radius"), world, cvar("g_balance_minelayer_remote_force"), self.projectiledeathtype | HITTYPE_BOUNCE, world);
  54
  55         if (self.owner.weapon == WEP_MINE_LAYER)
  56         {
  57                 if(self.owner.ammo_rockets < cvar("g_balance_minelayer_ammo"))
  58                 {
  59                         self.owner.cnt = WEP_MINE_LAYER;
  60                         ATTACK_FINISHED(self.owner) = time;
  61                         self.owner.switchweapon = w_getbestweapon(self.owner);
  62                 }
  63         }
  64         remove (self);
  65 }
  66
  67 void W_Mine_RemoteExplode()
  68 {
  69         if(self.owner.deadflag == DEAD_NO)
  70         if(self.owner.lastmine)
  71         {
  72                 if((self.spawnshieldtime >= 0)
  73                         ? (time >= self.spawnshieldtime) // timer
  74                         : (vlen(NearestPointOnBox(self.owner, self.origin) - self.origin) > cvar("g_balance_minelayer_radius")) // safety device
  75                 )
  76                 {
  77                         W_Mine_DoRemoteExplode();
  78                 }
  79         }
  80 }
  81
  82 void W_Mine_Think (void)
  83 {
  84         self.nextthink = time;
  85         if (time > self.cnt)
  86         {
  87                 other = world;
  88                 self.projectiledeathtype |= HITTYPE_BOUNCE;
  89                 W_Mine_Explode ();
  90                 return;
  91         }
  92
  93         // detect players around the mine and explode if the player should detonate it
  94         entity head;
  95         head = findradius(self.origin, cvar("g_balance_minelayer_detectionradius"));
  96
  97         while(head)
  98         {
  99                 if(head.classname == "player" && head.deadflag == DEAD_NO)
 100                 if(head != self.owner)
 101                 if not(teams_matter && head.team == self.owner.team) // don't detonate for team mates
 102                 {
 103                         W_Mine_Unregister();
 104                         W_Mine_Explode();
 105                 }
 106                 head = head.chain;
 107         }
 108
 109         // remote detonation
 110         if (self.owner.weapon == WEP_MINE_LAYER)
 111         if (self.owner.deadflag == DEAD_NO)
 112         if (self.minelayer_detonate)
 113                 W_Mine_RemoteExplode();
 114
 115         if(self.csqcprojectile_clientanimate == 0)
 116                 UpdateCSQCProjectile(self);
 117 }
 118
 119 void W_Mine_Touch (void)
 120 {
 121         PROJECTILE_TOUCH;
 122         spamsound (self, CHAN_PROJECTILE, "weapons/mine_stick.wav", VOL_BASE, ATTN_NORM);
 123         self.movetype = MOVETYPE_NONE; // lock the mine in place
 124         // TODO: make sure this doesn't cause the mine to get stuck in the air if it falls over a team mate (doesn't explode) and the team mate leaves
 125 }
 126
 127 void W_Mine_Damage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 128 {
 129         if (self.health <= 0)
 130                 return;
 131         self.health = self.health - damage;
 132         self.angles = vectoangles(self.velocity);
 133         if (self.health <= 0)
 134                 W_PrepareExplosionByDamage(attacker, W_Mine_Explode);
 135 }
 136
 137 void W_Mine_Attack (void)
 138 {
 139         local entity mine;
 140         local entity flash;
 141
 142         // scan how many mines we placed, and return if we reached our limit
 143         if(cvar("g_balance_minelayer_limit"))
 144         {
 145                 entity min;
 146                 self.mine_number = 0;
 147                 for(min = world; (min = find(min, classname, "mine")); )
 148                         if(min.owner == self)
 149                                 self.mine_number += 1;
 150
 151                 if(self.mine_number >= cvar("g_balance_minelayer_limit"))
 152                         return;
 153         }
 154
 155         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
 156                 self.ammo_rockets = self.ammo_rockets - cvar("g_balance_minelayer_ammo");
 157
 158         W_SetupShot_ProjectileSize (self, '-3 -3 -3', '3 3 3', FALSE, 5, "weapons/mine_fire.wav", cvar("g_balance_minelayer_damage"));
 159         pointparticles(particleeffectnum("rocketlauncher_muzzleflash"), w_shotorg, w_shotdir * 1000, 1);
 160
 161         mine = WarpZone_RefSys_SpawnSameRefSys(self);
 162         mine.owner = self;
 163         self.lastmine = mine;
 164         if(cvar("g_balance_minelayer_detonatedelay") >= 0)
 165                 mine.spawnshieldtime = time + cvar("g_balance_minelayer_detonatedelay");
 166         else
 167                 mine.spawnshieldtime = -1;
 168         mine.classname = "mine";
 169         mine.bot_dodge = TRUE;
 170         mine.bot_dodgerating = cvar("g_balance_minelayer_damage") * 2; // * 2 because it can be detonated inflight which makes it even more dangerous
 171
 172         mine.takedamage = DAMAGE_YES;
 173         mine.damageforcescale = cvar("g_balance_minelayer_damageforcescale");
 174         mine.health = cvar("g_balance_minelayer_health");
 175         mine.event_damage = W_Mine_Damage;
 176
 177         mine.movetype = MOVETYPE_TOSS;
 178         PROJECTILE_MAKETRIGGER(mine);
 179         mine.projectiledeathtype = WEP_MINE_LAYER;
 180         setsize (mine, '-6 -6 -6', '6 6 6'); // give it some size so it can be shot
 181
 182         setorigin (mine, w_shotorg - v_forward * 6); // move it back so it hits the wall at the right point
 183         W_SetupProjectileVelocity(mine, cvar("g_balance_minelayer_speedstart"), 0);
 184         mine.angles = vectoangles (mine.velocity);
 185
 186         mine.touch = W_Mine_Touch;
 187         mine.think = W_Mine_Think;
 188         mine.nextthink = time;
 189         mine.cnt = time + cvar("g_balance_minelayer_lifetime");
 190         mine.flags = FL_PROJECTILE;
 191
 192         CSQCProjectile(mine, FALSE, PROJECTILE_MINE, FALSE);
 193
 194         // muzzle flash for 1st person view
 195         flash = spawn ();
 196         setmodel (flash, "models/flash.md3"); // precision set below
 197         SUB_SetFade (flash, time, 0.1);
 198         flash.effects = EF_ADDITIVE | EF_FULLBRIGHT | EF_LOWPRECISION;
 199         W_AttachToShotorg(flash, '5 0 0');
 200
 201         // common properties
 202 }
 203
 204 void spawnfunc_weapon_minelayer (void); // defined in t_items.qc
 205
 206 float w_minelayer(float req)
 207 {
 208         entity min;
 209         float minfound;
 210         if (req == WR_AIM)
 211         {
 212                 // aim and decide to fire if appropriate
 213                 self.BUTTON_ATCK = bot_aim(cvar("g_balance_minelayer_speed"), 0, cvar("g_balance_minelayer_lifetime"), FALSE);
 214                 if(skill >= 2) // skill 0 and 1 bots won't detonate mines!
 215                 {
 216                         // decide whether to detonate mines
 217                         local entity mine, targetlist, targ;
 218                         local float edgedamage, coredamage, edgeradius, recipricoledgeradius, d;
 219                         local float selfdamage, teamdamage, enemydamage;
 220                         edgedamage = cvar("g_balance_minelayer_edgedamage");
 221                         coredamage = cvar("g_balance_minelayer_damage");
 222                         edgeradius = cvar("g_balance_minelayer_radius");
 223                         recipricoledgeradius = 1 / edgeradius;
 224                         selfdamage = 0;
 225                         teamdamage = 0;
 226                         enemydamage = 0;
 227                         targetlist = findchainfloat(bot_attack, TRUE);
 228                         mine = find(world, classname, "mine");
 229                         while (mine)
 230                         {
 231                                 if (mine.owner != self)
 232                                 {
 233                                         mine = find(mine, classname, "mine");
 234                                         continue;
 235                                 }
 236                                 targ = targetlist;
 237                                 while (targ)
 238                                 {
 239                                         d = vlen(targ.origin + (targ.mins + targ.maxs) * 0.5 - mine.origin);
 240                                         d = bound(0, edgedamage + (coredamage - edgedamage) * sqrt(1 - d * recipricoledgeradius), 10000);
 241                                         // count potential damage according to type of target
 242                                         if (targ == self)
 243                                                 selfdamage = selfdamage + d;
 244                                         else if (targ.team == self.team && teams_matter)
 245                                                 teamdamage = teamdamage + d;
 246                                         else if (bot_shouldattack(targ))
 247                                                 enemydamage = enemydamage + d;
 248                                         targ = targ.chain;
 249                                 }
 250                                 mine = find(mine, classname, "mine");
 251                         }
 252                         local float desirabledamage;
 253                         desirabledamage = enemydamage;
 254                         if (teamplay != 1 && time > self.invincible_finished && time > self.spawnshieldtime)
 255                                 desirabledamage = desirabledamage - selfdamage * cvar("g_balance_selfdamagepercent");
 256                         if (self.team && teamplay != 1)
 257                                 desirabledamage = desirabledamage - teamdamage;
 258
 259                         mine = find(world, classname, "mine");
 260                         while (mine)
 261                         {
 262                                 if (mine.owner != self)
 263                                 {
 264                                         mine = find(mine, classname, "mine");
 265                                         continue;
 266                                 }
 267                                 makevectors(mine.v_angle);
 268                                 targ = targetlist;
 269                                 if (skill > 9) // normal players only do this for the target they are tracking
 270                                 {
 271                                         targ = targetlist;
 272                                         while (targ)
 273                                         {
 274                                                 if (
 275                                                         (v_forward * normalize(mine.origin - targ.origin)< 0.1)
 276                                                         && desirabledamage > 0.1*coredamage
 277                                                 )self.BUTTON_ATCK2 = TRUE;
 278                                                 targ = targ.chain;
 279                                         }
 280                                 }else{
 281                                         local float distance; distance= bound(300,vlen(self.origin-self.enemy.origin),30000);
 282                                         //As the distance gets larger, a correct detonation gets near imposible
 283                                         //Bots are assumed to use the rocket spawnfunc_light to see if the rocket gets near a player
 284                                         if(v_forward * normalize(mine.origin - self.enemy.origin)< 0.1)
 285                                                 if(self.enemy.classname == "player")
 286                                                         if(desirabledamage >= 0.1*coredamage)
 287                                                                 if(random()/distance*300 > frametime*bound(0,(10-skill)*0.2,1))
 288                                                                         self.BUTTON_ATCK2 = TRUE;
 289                                 //      dprint(ftos(random()/distance*300),">");dprint(ftos(frametime*bound(0,(10-skill)*0.2,1)),"\n");
 290                                 }
 291
 292                                 mine = find(mine, classname, "mine");
 293                         }
 294                         // if we would be doing at X percent of the core damage, detonate it
 295                         // but don't fire a new shot at the same time!
 296                         if (desirabledamage >= 0.75 * coredamage) //this should do group damage in rare fortunate events
 297                                 self.BUTTON_ATCK2 = TRUE;
 298                         if ((skill > 6.5) && (selfdamage > self.health))
 299                                 self.BUTTON_ATCK2 = FALSE;
 300                         //if(self.BUTTON_ATCK2 == TRUE)
 301                         //      dprint(ftos(desirabledamage),"\n");
 302                         if (self.BUTTON_ATCK2 == TRUE) self.BUTTON_ATCK = FALSE;
 303                 }
 304         }
 305         else if (req == WR_THINK)
 306         {
 307                 if (self.BUTTON_ATCK)
 308                 {
 309                         if(weapon_prepareattack(0, cvar("g_balance_minelayer_refire")))
 310                         {
 311                                 W_Mine_Attack();
 312                                 weapon_thinkf(WFRAME_FIRE1, cvar("g_balance_minelayer_animtime"), w_ready);
 313                         }
 314                 }
 315
 316                 if (self.BUTTON_ATCK2)
 317                 {
 318                         minfound = 0;
 319                         for(min = world; (min = find(min, classname, "mine")); ) if(min.owner == self)
 320                         {
 321                                 if(!min.minelayer_detonate)
 322                                 {
 323                                         min.minelayer_detonate = TRUE;
 324                                         minfound = 1;
 325                                 }
 326                         }
 327                         if(minfound)
 328                                 sound (self, CHAN_WEAPON2, "weapons/mine_det.wav", VOL_BASE, ATTN_NORM);
 329                 }
 330         }
 331         else if (req == WR_PRECACHE)
 332         {
 333                 precache_model ("models/flash.md3");
 334                 precache_model ("models/weapons/g_minelayer.md3");
 335                 precache_model ("models/weapons/v_minelayer.md3");
 336                 precache_model ("models/weapons/h_minelayer.iqm");
 337                 precache_sound ("weapons/mine_det.wav");
 338                 precache_sound ("weapons/mine_fire.wav");
 339                 precache_sound ("weapons/mine_stick.wav");
 340         }
 341         else if (req == WR_SETUP)
 342         {
 343                 weapon_setup(WEP_MINE_LAYER);
 344         }
 345         else if (req == WR_CHECKAMMO1)
 346         {
 347                 // don't switch while placing a mine
 348                 if ((ATTACK_FINISHED(self) <= time || self.weapon != WEP_MINE_LAYER)
 349                         && self.ammo_rockets < cvar("g_balance_minelayer_ammo"))
 350                         return FALSE;
 351         }
 352         else if (req == WR_CHECKAMMO2)
 353                 return FALSE;
 354         return TRUE;
 355 };
 356 #endif
 357 #ifdef CSQC
 358 float w_minelayer(float req)
 359 {
 360         if(req == WR_IMPACTEFFECT)
 361         {
 362                 vector org2;
 363                 org2 = w_org + w_backoff * 12;
 364                 pointparticles(particleeffectnum("rocket_explode"), org2, '0 0 0', 1);
 365                 if(!w_issilent)
 366                         sound(self, CHAN_PROJECTILE, "weapons/rocket_impact.wav", VOL_BASE, ATTN_NORM);
 367         }
 368         else if(req == WR_PRECACHE)
 369         {
 370                 precache_sound("weapons/rocket_impact.wav");
 371         }
 372         else if (req == WR_SUICIDEMESSAGE)
 373                 w_deathtypestring = "%s exploded";
 374         else if (req == WR_KILLMESSAGE)
 375         {
 376                 if(w_deathtype & HITTYPE_BOUNCE) // (remote detonation)
 377                         w_deathtypestring = "%s got too close to %s's mine";
 378                 else if(w_deathtype & HITTYPE_SPLASH)
 379                         w_deathtypestring = "%s almost dodged %s's mine";
 380                 else
 381                         w_deathtypestring = "%s ate %s's mine";
 382         }
 383         return TRUE;
 384 }
 385 #endif
 386 #endif