qcsrc/server/w_minelayer.qc

   1 #ifdef REGISTER_WEAPON
   2 REGISTER_WEAPON(MINE_LAYER, w_minelayer, IT_ROCKETS, 4, WEP_FLAG_NORMAL | WEP_TYPE_SPLASH, BOT_PICKUP_RATING_HIGH, "minelayer", "minelayer", _("Mine Layer"))
   3 #else
   4 #ifdef SVQC
   5 void W_Mine_Think (void);
   6 .float minelayer_detonate, minelayer_mines;
   7 .float mine_time;
   8
   9 void spawnfunc_weapon_minelayer (void)
  10 {
  11         weapon_defaultspawnfunc(WEP_MINE_LAYER);
  12 }
  13
  14 void W_Mine_Stick ()
  15 {
  16         spamsound (self, CHAN_PROJECTILE, "weapons/mine_stick.wav", VOL_BASE, ATTN_NORM);
  17
  18         // in order for mines to face properly when sticking to the ground, they must be a server side entity rather than a csqc projectile
  19
  20         entity newmine;
  21         newmine = spawn();
  22         newmine.classname = self.classname;
  23
  24         newmine.bot_dodge = self.bot_dodge;
  25         newmine.bot_dodgerating = self.bot_dodgerating;
  26
  27         newmine.owner = self.owner;
  28         setsize(newmine, '-4 -4 -4', '4 4 4');
  29         setorigin(newmine, self.origin);
  30         setmodel(newmine, "models/mine.md3");
  31         newmine.angles = vectoangles(-trace_plane_normal); // face against the surface
  32
  33         newmine.takedamage = self.takedamage;
  34         newmine.damageforcescale = self.damageforcescale;
  35         newmine.health = self.health;
  36         newmine.event_damage = self.event_damage;
  37         newmine.spawnshieldtime = self.spawnshieldtime;
  38
  39         newmine.movetype = MOVETYPE_NONE; // lock the mine in place
  40         newmine.projectiledeathtype = self.projectiledeathtype;
  41
  42         newmine.mine_time = self.mine_time;
  43
  44         newmine.touch = SUB_Null;
  45         newmine.think = W_Mine_Think;
  46         newmine.nextthink = time;
  47         newmine.cnt = self.cnt;
  48         newmine.flags = self.flags;
  49
  50         remove(self);
  51         self = newmine;
  52 }
  53
  54 void W_Mine_Explode ()
  55 {
  56         if(other.takedamage == DAMAGE_AIM)
  57                 if(other.classname == "player")
  58                         if(IsDifferentTeam(self.owner, other))
  59                                 if(IsFlying(other))
  60                                         AnnounceTo(self.owner, "airshot");
  61
  62         self.event_damage = SUB_Null;
  63         self.takedamage = DAMAGE_NO;
  64
  65         RadiusDamage (self, self.owner, autocvar_g_balance_minelayer_damage, autocvar_g_balance_minelayer_edgedamage, autocvar_g_balance_minelayer_radius, world, autocvar_g_balance_minelayer_force, self.projectiledeathtype, other);
  66
  67         if (self.owner.weapon == WEP_MINE_LAYER)
  68         {
  69                 if(self.owner.ammo_rockets < autocvar_g_balance_minelayer_ammo)
  70                 {
  71                         self.owner.cnt = WEP_MINE_LAYER;
  72                         ATTACK_FINISHED(self.owner) = time;
  73                         self.owner.switchweapon = w_getbestweapon(self.owner);
  74                 }
  75         }
  76         remove (self);
  77 }
  78
  79 void W_Mine_DoRemoteExplode ()
  80 {
  81         self.event_damage = SUB_Null;
  82         self.takedamage = DAMAGE_NO;
  83
  84         RadiusDamage (self, self.owner, autocvar_g_balance_minelayer_remote_damage, autocvar_g_balance_minelayer_remote_edgedamage, autocvar_g_balance_minelayer_remote_radius, world, autocvar_g_balance_minelayer_remote_force, self.projectiledeathtype | HITTYPE_BOUNCE, world);
  85
  86         if (self.owner.weapon == WEP_MINE_LAYER)
  87         {
  88                 if(self.owner.ammo_rockets < autocvar_g_balance_minelayer_ammo)
  89                 {
  90                         self.owner.cnt = WEP_MINE_LAYER;
  91                         ATTACK_FINISHED(self.owner) = time;
  92                         self.owner.switchweapon = w_getbestweapon(self.owner);
  93                 }
  94         }
  95         remove (self);
  96 }
  97
  98 void W_Mine_RemoteExplode ()
  99 {
 100         if(self.owner.deadflag == DEAD_NO)
 101                 if((self.spawnshieldtime >= 0)
 102                         ? (time >= self.spawnshieldtime) // timer
 103                         : (vlen(NearestPointOnBox(self.owner, self.origin) - self.origin) > autocvar_g_balance_minelayer_remote_radius) // safety device
 104                 )
 105                 {
 106                         W_Mine_DoRemoteExplode();
 107                 }
 108 }
 109
 110 void W_Mine_ProximityExplode ()
 111 {
 112         // make sure no friend is in the mine's radius. If there is any, explosion is delayed until he's at a safe distance
 113         if(autocvar_g_balance_minelayer_protection && self.minelayer_mines == 0)
 114         {
 115                 entity head;
 116                 head = findradius(self.origin, autocvar_g_balance_minelayer_radius);
 117                 while(head)
 118                 {
 119                         if(head == self.owner || !IsDifferentTeam(head, self.owner))
 120                                 return;
 121                         head = head.chain;
 122                 }
 123         }
 124
 125         self.mine_time = 0;
 126         W_Mine_Explode();
 127 }
 128
 129 void W_Mine_Think (void)
 130 {
 131         entity head;
 132
 133         self.nextthink = time;
 134
 135         // our lifetime has expired, it's time to die - mine_time just allows us to play a sound for this
 136         // TODO: replace this mine_trigger.wav sound with a real countdown
 137         if ((time > self.cnt) && (!self.mine_time))
 138         {
 139                 if(autocvar_g_balance_minelayer_lifetime_countdown > 0)
 140                         spamsound (self, CHAN_PROJECTILE, "weapons/mine_trigger.wav", VOL_BASE, ATTN_NORM);
 141                 self.mine_time = time + autocvar_g_balance_minelayer_lifetime_countdown;
 142                 self.minelayer_mines = 1; // make the mine super aggressive
 143         }
 144
 145         // a player's mines shall explode if he disconnects or dies
 146         // TODO: Do this on team change too -- Samual: But isn't a player killed when they switch teams?
 147         if(self.owner.classname != "player" || self.owner.deadflag != DEAD_NO)
 148         {
 149                 other = world;
 150                 self.projectiledeathtype |= HITTYPE_BOUNCE;
 151                 W_Mine_Explode();
 152                 return;
 153         }
 154
 155         // set the mine for detonation when a foe gets close enough
 156         head = findradius(self.origin, autocvar_g_balance_minelayer_proximityradius);
 157         while(head)
 158         {
 159                 if(head.classname == "player" && head.deadflag == DEAD_NO)
 160                 if(head != self.owner && IsDifferentTeam(head, self.owner)) // don't trigger for team mates
 161                 if(!self.mine_time)
 162                 {
 163                         spamsound (self, CHAN_PROJECTILE, "weapons/mine_trigger.wav", VOL_BASE, ATTN_NORM);
 164                         self.mine_time = time + autocvar_g_balance_minelayer_time;
 165                 }
 166                 head = head.chain;
 167         }
 168
 169         // explode if it's time to
 170         if(self.mine_time && time >= self.mine_time)
 171         {
 172                 W_Mine_ProximityExplode();
 173                 return;
 174         }
 175
 176         // remote detonation
 177         if (self.owner.weapon == WEP_MINE_LAYER)
 178         if (self.owner.deadflag == DEAD_NO)
 179         if (self.minelayer_detonate)
 180                 W_Mine_RemoteExplode();
 181 }
 182
 183 void W_Mine_Touch (void)
 184 {
 185         PROJECTILE_TOUCH;
 186         if(!other || (other.takedamage != DAMAGE_AIM && other.movetype == MOVETYPE_NONE))
 187                 W_Mine_Stick();
 188         else if(self.movetype != MOVETYPE_NONE) // don't unstick a locked mine when someone touches it
 189                 self.velocity = '0 0 0';
 190 }
 191
 192 void W_Mine_Damage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 193 {
 194         if (self.health <= 0)
 195                 return;
 196         self.health = self.health - damage;
 197         self.angles = vectoangles(self.velocity);
 198         if (self.health <= 0)
 199                 W_PrepareExplosionByDamage(attacker, W_Mine_Explode);
 200 }
 201
 202 void W_Mine_Attack (void)
 203 {
 204         entity mine;
 205         entity flash;
 206
 207         // scan how many mines we placed, and return if we reached our limit
 208         if(autocvar_g_balance_minelayer_limit)
 209         {
 210                 self.minelayer_mines = 0;
 211                 for(mine = world; (mine = find(mine, classname, "mine")); ) if(mine.owner == self)
 212                         self.minelayer_mines += 1;
 213
 214                 if(self.minelayer_mines >= autocvar_g_balance_minelayer_limit)
 215                 {
 216                         // the refire delay keeps this message from being spammed
 217                         sprint(self, strcat("You cannot place more than ^2", ftos(autocvar_g_balance_minelayer_limit), " ^7mines at a time\n") );
 218                         play2(self, "weapons/unavailable.wav");
 219                         return;
 220                 }
 221         }
 222
 223         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
 224                 self.ammo_rockets = self.ammo_rockets - autocvar_g_balance_minelayer_ammo;
 225
 226         W_SetupShot_ProjectileSize (self, '-4 -4 -4', '4 4 4', FALSE, 5, "weapons/mine_fire.wav", CHAN_WEAPON, autocvar_g_balance_minelayer_damage);
 227         pointparticles(particleeffectnum("rocketlauncher_muzzleflash"), w_shotorg, w_shotdir * 1000, 1);
 228
 229         mine = WarpZone_RefSys_SpawnSameRefSys(self);
 230         mine.owner = self;
 231         if(autocvar_g_balance_minelayer_detonatedelay >= 0)
 232                 mine.spawnshieldtime = time + autocvar_g_balance_minelayer_detonatedelay;
 233         else
 234                 mine.spawnshieldtime = -1;
 235         mine.classname = "mine";
 236         mine.bot_dodge = TRUE;
 237         mine.bot_dodgerating = autocvar_g_balance_minelayer_damage * 2; // * 2 because it can detonate inflight which makes it even more dangerous
 238
 239         mine.takedamage = DAMAGE_YES;
 240         mine.damageforcescale = autocvar_g_balance_minelayer_damageforcescale;
 241         mine.health = autocvar_g_balance_minelayer_health;
 242         mine.event_damage = W_Mine_Damage;
 243
 244         mine.movetype = MOVETYPE_TOSS;
 245         PROJECTILE_MAKETRIGGER(mine);
 246         mine.projectiledeathtype = WEP_MINE_LAYER;
 247         setsize (mine, '-4 -4 -4', '4 4 4'); // give it some size so it can be shot
 248
 249         setorigin (mine, w_shotorg - v_forward * 4); // move it back so it hits the wall at the right point
 250         W_SetupProjectileVelocity(mine, autocvar_g_balance_minelayer_speed, 0);
 251         mine.angles = vectoangles (mine.velocity);
 252
 253         mine.touch = W_Mine_Touch;
 254         mine.think = W_Mine_Think;
 255         mine.nextthink = time;
 256         mine.cnt = time + (autocvar_g_balance_minelayer_lifetime - autocvar_g_balance_minelayer_lifetime_countdown);
 257         mine.flags = FL_PROJECTILE;
 258
 259         CSQCProjectile(mine, TRUE, PROJECTILE_MINE, TRUE);
 260
 261         // muzzle flash for 1st person view
 262         flash = spawn ();
 263         setmodel (flash, "models/flash.md3"); // precision set below
 264         SUB_SetFade (flash, time, 0.1);
 265         flash.effects = EF_ADDITIVE | EF_FULLBRIGHT | EF_LOWPRECISION;
 266         W_AttachToShotorg(flash, '5 0 0');
 267
 268         // common properties
 269
 270         other = mine; MUTATOR_CALLHOOK(EditProjectile);
 271 }
 272
 273 void spawnfunc_weapon_minelayer (void); // defined in t_items.qc
 274
 275 float w_minelayer(float req)
 276 {
 277         entity mine;
 278         float minfound;
 279         if (req == WR_AIM)
 280         {
 281                 // aim and decide to fire if appropriate
 282                 self.BUTTON_ATCK = bot_aim(autocvar_g_balance_minelayer_speed, 0, autocvar_g_balance_minelayer_lifetime, FALSE);
 283                 if(skill >= 2) // skill 0 and 1 bots won't detonate mines!
 284                 {
 285                         // decide whether to detonate mines
 286                         entity targetlist, targ;
 287                         float edgedamage, coredamage, edgeradius, recipricoledgeradius, d;
 288                         float selfdamage, teamdamage, enemydamage;
 289                         edgedamage = autocvar_g_balance_minelayer_edgedamage;
 290                         coredamage = autocvar_g_balance_minelayer_damage;
 291                         edgeradius = autocvar_g_balance_minelayer_radius;
 292                         recipricoledgeradius = 1 / edgeradius;
 293                         selfdamage = 0;
 294                         teamdamage = 0;
 295                         enemydamage = 0;
 296                         targetlist = findchainfloat(bot_attack, TRUE);
 297                         mine = find(world, classname, "mine");
 298                         while (mine)
 299                         {
 300                                 if (mine.owner != self)
 301                                 {
 302                                         mine = find(mine, classname, "mine");
 303                                         continue;
 304                                 }
 305                                 targ = targetlist;
 306                                 while (targ)
 307                                 {
 308                                         d = vlen(targ.origin + (targ.mins + targ.maxs) * 0.5 - mine.origin);
 309                                         d = bound(0, edgedamage + (coredamage - edgedamage) * sqrt(1 - d * recipricoledgeradius), 10000);
 310                                         // count potential damage according to type of target
 311                                         if (targ == self)
 312                                                 selfdamage = selfdamage + d;
 313                                         else if (targ.team == self.team && teams_matter)
 314                                                 teamdamage = teamdamage + d;
 315                                         else if (bot_shouldattack(targ))
 316                                                 enemydamage = enemydamage + d;
 317                                         targ = targ.chain;
 318                                 }
 319                                 mine = find(mine, classname, "mine");
 320                         }
 321                         float desirabledamage;
 322                         desirabledamage = enemydamage;
 323                         if (time > self.invincible_finished && time > self.spawnshieldtime)
 324                                 desirabledamage = desirabledamage - selfdamage * autocvar_g_balance_selfdamagepercent;
 325                         if (teams_matter && self.team)
 326                                 desirabledamage = desirabledamage - teamdamage;
 327
 328                         mine = find(world, classname, "mine");
 329                         while (mine)
 330                         {
 331                                 if (mine.owner != self)
 332                                 {
 333                                         mine = find(mine, classname, "mine");
 334                                         continue;
 335                                 }
 336                                 makevectors(mine.v_angle);
 337                                 targ = targetlist;
 338                                 if (skill > 9) // normal players only do this for the target they are tracking
 339                                 {
 340                                         targ = targetlist;
 341                                         while (targ)
 342                                         {
 343                                                 if (
 344                                                         (v_forward * normalize(mine.origin - targ.origin)< 0.1)
 345                                                         && desirabledamage > 0.1*coredamage
 346                                                 )self.BUTTON_ATCK2 = TRUE;
 347                                                 targ = targ.chain;
 348                                         }
 349                                 }else{
 350                                         float distance; distance= bound(300,vlen(self.origin-self.enemy.origin),30000);
 351                                         //As the distance gets larger, a correct detonation gets near imposible
 352                                         //Bots are assumed to use the mine spawnfunc_light to see if the mine gets near a player
 353                                         if(v_forward * normalize(mine.origin - self.enemy.origin)< 0.1)
 354                                                 if(self.enemy.classname == "player")
 355                                                         if(desirabledamage >= 0.1*coredamage)
 356                                                                 if(random()/distance*300 > frametime*bound(0,(10-skill)*0.2,1))
 357                                                                         self.BUTTON_ATCK2 = TRUE;
 358                                 //      dprint(ftos(random()/distance*300),">");dprint(ftos(frametime*bound(0,(10-skill)*0.2,1)),"\n");
 359                                 }
 360
 361                                 mine = find(mine, classname, "mine");
 362                         }
 363                         // if we would be doing at X percent of the core damage, detonate it
 364                         // but don't fire a new shot at the same time!
 365                         if (desirabledamage >= 0.75 * coredamage) //this should do group damage in rare fortunate events
 366                                 self.BUTTON_ATCK2 = TRUE;
 367                         if ((skill > 6.5) && (selfdamage > self.health))
 368                                 self.BUTTON_ATCK2 = FALSE;
 369                         //if(self.BUTTON_ATCK2 == TRUE)
 370                         //      dprint(ftos(desirabledamage),"\n");
 371                         if (self.BUTTON_ATCK2 == TRUE) self.BUTTON_ATCK = FALSE;
 372                 }
 373         }
 374         else if (req == WR_THINK)
 375         {
 376                 if (self.BUTTON_ATCK)
 377                 {
 378                         if(weapon_prepareattack(0, autocvar_g_balance_minelayer_refire))
 379                         {
 380                                 W_Mine_Attack();
 381                                 weapon_thinkf(WFRAME_FIRE1, autocvar_g_balance_minelayer_animtime, w_ready);
 382                         }
 383                 }
 384
 385                 if (self.BUTTON_ATCK2)
 386                 {
 387                         minfound = 0;
 388                         for(mine = world; (mine = find(mine, classname, "mine")); ) if(mine.owner == self)
 389                         {
 390                                 if(!mine.minelayer_detonate)
 391                                 {
 392                                         mine.minelayer_detonate = TRUE;
 393                                         minfound = 1;
 394                                 }
 395                         }
 396                         if(minfound)
 397                                 sound (self, CHAN_WEAPON2, "weapons/mine_det.wav", VOL_BASE, ATTN_NORM);
 398                 }
 399         }
 400         else if (req == WR_PRECACHE)
 401         {
 402                 precache_model ("models/flash.md3");
 403                 precache_model ("models/mine.md3");
 404                 precache_model ("models/weapons/g_minelayer.md3");
 405                 precache_model ("models/weapons/v_minelayer.md3");
 406                 precache_model ("models/weapons/h_minelayer.iqm");
 407                 precache_sound ("weapons/mine_det.wav");
 408                 precache_sound ("weapons/mine_fire.wav");
 409                 precache_sound ("weapons/mine_stick.wav");
 410                 precache_sound ("weapons/mine_trigger.wav");
 411         }
 412         else if (req == WR_SETUP)
 413         {
 414                 weapon_setup(WEP_MINE_LAYER);
 415         }
 416         else if (req == WR_CHECKAMMO1)
 417         {
 418                 // don't switch while placing a mine
 419                 if ((ATTACK_FINISHED(self) <= time || self.weapon != WEP_MINE_LAYER)
 420                         && self.ammo_rockets < autocvar_g_balance_minelayer_ammo)
 421                         return FALSE;
 422         }
 423         else if (req == WR_CHECKAMMO2)
 424                 return FALSE;
 425         return TRUE;
 426 };
 427 #endif
 428 #ifdef CSQC
 429 float w_minelayer(float req)
 430 {
 431         if(req == WR_IMPACTEFFECT)
 432         {
 433                 vector org2;
 434                 org2 = w_org + w_backoff * 12;
 435                 pointparticles(particleeffectnum("rocket_explode"), org2, '0 0 0', 1);
 436                 if(!w_issilent)
 437                         sound(self, CHAN_PROJECTILE, "weapons/mine_exp.wav", VOL_BASE, ATTN_NORM);
 438         }
 439         else if(req == WR_PRECACHE)
 440         {
 441                 precache_sound("weapons/mine_exp.wav");
 442         }
 443         else if (req == WR_SUICIDEMESSAGE)
 444                 w_deathtypestring = _("%s exploded");
 445         else if (req == WR_KILLMESSAGE)
 446         {
 447                 if(w_deathtype & HITTYPE_BOUNCE) // (remote detonation)
 448                         w_deathtypestring = _("%s got too close to %s's mine");
 449                 else if(w_deathtype & HITTYPE_SPLASH)
 450                         w_deathtypestring = _("%s almost dodged %s's mine");
 451                 else
 452                         w_deathtypestring = _("%s stepped on %s's mine");
 453         }
 454         return TRUE;
 455 }
 456 #endif
 457 #endif