qcsrc/server/w_minelayer.qc

   1 #ifdef REGISTER_WEAPON
   2 REGISTER_WEAPON(MINE_LAYER, w_minelayer, IT_ROCKETS, 4, WEP_TYPE_SPLASH, BOT_PICKUP_RATING_HIGH, "minelayer", "minelayer", _("Mine Layer"))
   3 #else
   4 #ifdef SVQC
   5 void W_Mine_Think (void);
   6 .float minelayer_detonate, minelayer_mines;
   7 .float mine_time;
   8
   9 void W_MineLayer_SetAmmoCounter()
  10 {
  11         // set clip_load to the weapon we have switched to, if the gun uses reloading
  12         if(!autocvar_g_balance_minelayer_reload_ammo)
  13                 self.clip_load = 0; // also keeps crosshair ammo from displaying
  14         else
  15         {
  16                 self.clip_load = self.weapon_load[WEP_MINE_LAYER];
  17                 self.clip_size = autocvar_g_balance_minelayer_reload_ammo; // for the crosshair ammo display
  18         }
  19 }
  20
  21 void W_MineLayer_Reload()
  22 {
  23         self.reload_ammo_player = ammo_rockets;
  24         self.reload_ammo_min = autocvar_g_balance_minelayer_ammo;
  25         self.reload_ammo_amount = autocvar_g_balance_minelayer_reload_ammo;
  26         self.reload_time = autocvar_g_balance_minelayer_reload_time;
  27         self.reload_sound = "weapons/reload.wav";
  28
  29         W_Reload();
  30 }
  31
  32 void spawnfunc_weapon_minelayer (void)
  33 {
  34         weapon_defaultspawnfunc(WEP_MINE_LAYER);
  35 }
  36
  37 void W_Mine_Stick ()
  38 {
  39         spamsound (self, CHAN_PROJECTILE, "weapons/mine_stick.wav", VOL_BASE, ATTN_NORM);
  40
  41         // in order for mines to face properly when sticking to the ground, they must be a server side entity rather than a csqc projectile
  42
  43         entity newmine;
  44         newmine = spawn();
  45         newmine.classname = self.classname;
  46
  47         newmine.bot_dodge = self.bot_dodge;
  48         newmine.bot_dodgerating = self.bot_dodgerating;
  49
  50         newmine.owner = self.owner;
  51         setsize(newmine, '-4 -4 -4', '4 4 4');
  52         setorigin(newmine, self.origin);
  53         setmodel(newmine, "models/mine.md3");
  54         newmine.angles = vectoangles(-trace_plane_normal); // face against the surface
  55
  56         newmine.takedamage = self.takedamage;
  57         newmine.damageforcescale = self.damageforcescale;
  58         newmine.health = self.health;
  59         newmine.event_damage = self.event_damage;
  60         newmine.spawnshieldtime = self.spawnshieldtime;
  61
  62         newmine.movetype = MOVETYPE_NONE; // lock the mine in place
  63         newmine.projectiledeathtype = self.projectiledeathtype;
  64
  65         newmine.mine_time = self.mine_time;
  66
  67         newmine.touch = SUB_Null;
  68         newmine.think = W_Mine_Think;
  69         newmine.nextthink = time;
  70         newmine.cnt = self.cnt;
  71         newmine.flags = self.flags;
  72
  73         remove(self);
  74         self = newmine;
  75 }
  76
  77 void W_Mine_Explode ()
  78 {
  79         if(other.takedamage == DAMAGE_AIM)
  80                 if(other.classname == "player")
  81                         if(IsDifferentTeam(self.owner, other))
  82                                 if(IsFlying(other))
  83                                         AnnounceTo(self.owner, "airshot");
  84
  85         self.event_damage = SUB_Null;
  86         self.takedamage = DAMAGE_NO;
  87
  88         RadiusDamage (self, self.owner, autocvar_g_balance_minelayer_damage, autocvar_g_balance_minelayer_edgedamage, autocvar_g_balance_minelayer_radius, world, autocvar_g_balance_minelayer_force, self.projectiledeathtype, other);
  89
  90         if (self.owner.weapon == WEP_MINE_LAYER)
  91         {
  92                 if(self.owner.ammo_rockets < autocvar_g_balance_minelayer_ammo)
  93                 {
  94                         self.owner.cnt = WEP_MINE_LAYER;
  95                         ATTACK_FINISHED(self.owner) = time;
  96                         self.owner.switchweapon = w_getbestweapon(self.owner);
  97                 }
  98         }
  99         remove (self);
 100 }
 101
 102 void W_Mine_DoRemoteExplode ()
 103 {
 104         self.event_damage = SUB_Null;
 105         self.takedamage = DAMAGE_NO;
 106
 107         RadiusDamage (self, self.owner, autocvar_g_balance_minelayer_remote_damage, autocvar_g_balance_minelayer_remote_edgedamage, autocvar_g_balance_minelayer_remote_radius, world, autocvar_g_balance_minelayer_remote_force, self.projectiledeathtype | HITTYPE_BOUNCE, world);
 108
 109         if (self.owner.weapon == WEP_MINE_LAYER)
 110         {
 111                 if(self.owner.ammo_rockets < autocvar_g_balance_minelayer_ammo)
 112                 {
 113                         self.owner.cnt = WEP_MINE_LAYER;
 114                         ATTACK_FINISHED(self.owner) = time;
 115                         self.owner.switchweapon = w_getbestweapon(self.owner);
 116                 }
 117         }
 118         remove (self);
 119 }
 120
 121 void W_Mine_RemoteExplode ()
 122 {
 123         if(self.owner.deadflag == DEAD_NO)
 124                 if((self.spawnshieldtime >= 0)
 125                         ? (time >= self.spawnshieldtime) // timer
 126                         : (vlen(NearestPointOnBox(self.owner, self.origin) - self.origin) > autocvar_g_balance_minelayer_remote_radius) // safety device
 127                 )
 128                 {
 129                         W_Mine_DoRemoteExplode();
 130                 }
 131 }
 132
 133 void W_Mine_ProximityExplode ()
 134 {
 135         // make sure no friend is in the mine's radius. If there is any, explosion is delayed until he's at a safe distance
 136         if(autocvar_g_balance_minelayer_protection)
 137         {
 138                 entity head;
 139                 head = findradius(self.origin, autocvar_g_balance_minelayer_radius);
 140                 while(head)
 141                 {
 142                         if(head == self.owner || !IsDifferentTeam(head, self.owner))
 143                                 return;
 144                         head = head.chain;
 145                 }
 146         }
 147
 148         self.mine_time = 0;
 149         W_Mine_Explode();
 150 }
 151
 152 void W_Mine_Think (void)
 153 {
 154         entity head;
 155
 156         self.nextthink = time;
 157         if (time > self.cnt)
 158         {
 159                 other = world;
 160                 self.projectiledeathtype |= HITTYPE_BOUNCE;
 161                 W_Mine_Explode();
 162                 return;
 163         }
 164
 165         // a player's mines shall explode if he disconnects or dies
 166         // TODO: Do this on team change too
 167         if(self.owner.classname != "player" || self.owner.deadflag != DEAD_NO)
 168         {
 169                 other = world;
 170                 self.projectiledeathtype |= HITTYPE_BOUNCE;
 171                 W_Mine_Explode();
 172                 return;
 173         }
 174
 175         // set the mine for detonation when a foe gets close enough
 176         head = findradius(self.origin, autocvar_g_balance_minelayer_proximityradius);
 177         while(head)
 178         {
 179                 if(head.classname == "player" && head.deadflag == DEAD_NO)
 180                 if(head != self.owner && IsDifferentTeam(head, self.owner)) // don't trigger for team mates
 181                 if(!self.mine_time)
 182                 {
 183                         spamsound (self, CHAN_PROJECTILE, "weapons/mine_trigger.wav", VOL_BASE, ATTN_NORM);
 184                         self.mine_time = time + autocvar_g_balance_minelayer_time;
 185                 }
 186                 head = head.chain;
 187         }
 188
 189         // explode if it's time to
 190         if(self.mine_time && time >= self.mine_time)
 191                 W_Mine_ProximityExplode();
 192
 193         // remote detonation
 194         if (self.owner.weapon == WEP_MINE_LAYER)
 195         if (self.owner.deadflag == DEAD_NO)
 196         if (self.minelayer_detonate)
 197                 W_Mine_RemoteExplode();
 198 }
 199
 200 void W_Mine_Touch (void)
 201 {
 202         PROJECTILE_TOUCH;
 203         if(!other || (other.takedamage != DAMAGE_AIM && other.movetype == MOVETYPE_NONE))
 204                 W_Mine_Stick();
 205         else if(self.movetype != MOVETYPE_NONE) // don't unstick a locked mine when someone touches it
 206                 self.velocity = '0 0 0';
 207 }
 208
 209 void W_Mine_Damage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 210 {
 211         if (self.health <= 0)
 212                 return;
 213         self.health = self.health - damage;
 214         self.angles = vectoangles(self.velocity);
 215         if (self.health <= 0)
 216                 W_PrepareExplosionByDamage(attacker, W_Mine_Explode);
 217 }
 218
 219 void W_Mine_Attack (void)
 220 {
 221         entity mine;
 222         entity flash;
 223
 224         // scan how many mines we placed, and return if we reached our limit
 225         if(autocvar_g_balance_minelayer_limit)
 226         {
 227                 self.minelayer_mines = 0;
 228                 for(mine = world; (mine = find(mine, classname, "mine")); ) if(mine.owner == self)
 229                         self.minelayer_mines += 1;
 230
 231                 if(self.minelayer_mines >= autocvar_g_balance_minelayer_limit)
 232                 {
 233                         // the refire delay keeps this message from being spammed
 234                         sprint(self, strcat("You cannot place more than ^2", ftos(autocvar_g_balance_minelayer_limit), " ^7mines at a time\n") );
 235                         play2(self, "weapons/unavailable.wav");
 236                         return;
 237                 }
 238         }
 239
 240         // if this weapon is reloadable, decrease its load. Else decrease the player's ammo
 241         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
 242         {
 243                 if(autocvar_g_balance_minelayer_reload_ammo)
 244                 {
 245                         self.clip_load -= autocvar_g_balance_minelayer_ammo;
 246                         self.weapon_load[WEP_MINE_LAYER] = self.clip_load;
 247                 }
 248                 else
 249                         self.ammo_rockets -= autocvar_g_balance_minelayer_ammo;
 250         }
 251
 252         W_SetupShot_ProjectileSize (self, '-4 -4 -4', '4 4 4', FALSE, 5, "weapons/mine_fire.wav", CHAN_WEAPON, autocvar_g_balance_minelayer_damage);
 253         pointparticles(particleeffectnum("rocketlauncher_muzzleflash"), w_shotorg, w_shotdir * 1000, 1);
 254
 255         mine = WarpZone_RefSys_SpawnSameRefSys(self);
 256         mine.owner = self;
 257         if(autocvar_g_balance_minelayer_detonatedelay >= 0)
 258                 mine.spawnshieldtime = time + autocvar_g_balance_minelayer_detonatedelay;
 259         else
 260                 mine.spawnshieldtime = -1;
 261         mine.classname = "mine";
 262         mine.bot_dodge = TRUE;
 263         mine.bot_dodgerating = autocvar_g_balance_minelayer_damage * 2; // * 2 because it can detonate inflight which makes it even more dangerous
 264
 265         mine.takedamage = DAMAGE_YES;
 266         mine.damageforcescale = autocvar_g_balance_minelayer_damageforcescale;
 267         mine.health = autocvar_g_balance_minelayer_health;
 268         mine.event_damage = W_Mine_Damage;
 269
 270         mine.movetype = MOVETYPE_TOSS;
 271         PROJECTILE_MAKETRIGGER(mine);
 272         mine.projectiledeathtype = WEP_MINE_LAYER;
 273         setsize (mine, '-4 -4 -4', '4 4 4'); // give it some size so it can be shot
 274
 275         setorigin (mine, w_shotorg - v_forward * 4); // move it back so it hits the wall at the right point
 276         W_SetupProjectileVelocity(mine, autocvar_g_balance_minelayer_speed, 0);
 277         mine.angles = vectoangles (mine.velocity);
 278
 279         mine.touch = W_Mine_Touch;
 280         mine.think = W_Mine_Think;
 281         mine.nextthink = time;
 282         mine.cnt = time + autocvar_g_balance_minelayer_lifetime;
 283         mine.flags = FL_PROJECTILE;
 284
 285         CSQCProjectile(mine, TRUE, PROJECTILE_MINE, TRUE);
 286
 287         // muzzle flash for 1st person view
 288         flash = spawn ();
 289         setmodel (flash, "models/flash.md3"); // precision set below
 290         SUB_SetFade (flash, time, 0.1);
 291         flash.effects = EF_ADDITIVE | EF_FULLBRIGHT | EF_LOWPRECISION;
 292         W_AttachToShotorg(flash, '5 0 0');
 293
 294         // common properties
 295
 296         other = mine; MUTATOR_CALLHOOK(EditProjectile);
 297 }
 298
 299 void spawnfunc_weapon_minelayer (void); // defined in t_items.qc
 300
 301 float w_minelayer(float req)
 302 {
 303         entity mine;
 304         float minfound;
 305         float ammo_amount;
 306
 307         if (req == WR_AIM)
 308         {
 309                 // aim and decide to fire if appropriate
 310                 self.BUTTON_ATCK = bot_aim(autocvar_g_balance_minelayer_speed, 0, autocvar_g_balance_minelayer_lifetime, FALSE);
 311                 if(skill >= 2) // skill 0 and 1 bots won't detonate mines!
 312                 {
 313                         // decide whether to detonate mines
 314                         entity targetlist, targ;
 315                         float edgedamage, coredamage, edgeradius, recipricoledgeradius, d;
 316                         float selfdamage, teamdamage, enemydamage;
 317                         edgedamage = autocvar_g_balance_minelayer_edgedamage;
 318                         coredamage = autocvar_g_balance_minelayer_damage;
 319                         edgeradius = autocvar_g_balance_minelayer_radius;
 320                         recipricoledgeradius = 1 / edgeradius;
 321                         selfdamage = 0;
 322                         teamdamage = 0;
 323                         enemydamage = 0;
 324                         targetlist = findchainfloat(bot_attack, TRUE);
 325                         mine = find(world, classname, "mine");
 326                         while (mine)
 327                         {
 328                                 if (mine.owner != self)
 329                                 {
 330                                         mine = find(mine, classname, "mine");
 331                                         continue;
 332                                 }
 333                                 targ = targetlist;
 334                                 while (targ)
 335                                 {
 336                                         d = vlen(targ.origin + (targ.mins + targ.maxs) * 0.5 - mine.origin);
 337                                         d = bound(0, edgedamage + (coredamage - edgedamage) * sqrt(1 - d * recipricoledgeradius), 10000);
 338                                         // count potential damage according to type of target
 339                                         if (targ == self)
 340                                                 selfdamage = selfdamage + d;
 341                                         else if (targ.team == self.team && teams_matter)
 342                                                 teamdamage = teamdamage + d;
 343                                         else if (bot_shouldattack(targ))
 344                                                 enemydamage = enemydamage + d;
 345                                         targ = targ.chain;
 346                                 }
 347                                 mine = find(mine, classname, "mine");
 348                         }
 349                         float desirabledamage;
 350                         desirabledamage = enemydamage;
 351                         if (time > self.invincible_finished && time > self.spawnshieldtime)
 352                                 desirabledamage = desirabledamage - selfdamage * autocvar_g_balance_selfdamagepercent;
 353                         if (teams_matter && self.team)
 354                                 desirabledamage = desirabledamage - teamdamage;
 355
 356                         mine = find(world, classname, "mine");
 357                         while (mine)
 358                         {
 359                                 if (mine.owner != self)
 360                                 {
 361                                         mine = find(mine, classname, "mine");
 362                                         continue;
 363                                 }
 364                                 makevectors(mine.v_angle);
 365                                 targ = targetlist;
 366                                 if (skill > 9) // normal players only do this for the target they are tracking
 367                                 {
 368                                         targ = targetlist;
 369                                         while (targ)
 370                                         {
 371                                                 if (
 372                                                         (v_forward * normalize(mine.origin - targ.origin)< 0.1)
 373                                                         && desirabledamage > 0.1*coredamage
 374                                                 )self.BUTTON_ATCK2 = TRUE;
 375                                                 targ = targ.chain;
 376                                         }
 377                                 }else{
 378                                         float distance; distance= bound(300,vlen(self.origin-self.enemy.origin),30000);
 379                                         //As the distance gets larger, a correct detonation gets near imposible
 380                                         //Bots are assumed to use the mine spawnfunc_light to see if the mine gets near a player
 381                                         if(v_forward * normalize(mine.origin - self.enemy.origin)< 0.1)
 382                                                 if(self.enemy.classname == "player")
 383                                                         if(desirabledamage >= 0.1*coredamage)
 384                                                                 if(random()/distance*300 > frametime*bound(0,(10-skill)*0.2,1))
 385                                                                         self.BUTTON_ATCK2 = TRUE;
 386                                 //      dprint(ftos(random()/distance*300),">");dprint(ftos(frametime*bound(0,(10-skill)*0.2,1)),"\n");
 387                                 }
 388
 389                                 mine = find(mine, classname, "mine");
 390                         }
 391                         // if we would be doing at X percent of the core damage, detonate it
 392                         // but don't fire a new shot at the same time!
 393                         if (desirabledamage >= 0.75 * coredamage) //this should do group damage in rare fortunate events
 394                                 self.BUTTON_ATCK2 = TRUE;
 395                         if ((skill > 6.5) && (selfdamage > self.health))
 396                                 self.BUTTON_ATCK2 = FALSE;
 397                         //if(self.BUTTON_ATCK2 == TRUE)
 398                         //      dprint(ftos(desirabledamage),"\n");
 399                         if (self.BUTTON_ATCK2 == TRUE) self.BUTTON_ATCK = FALSE;
 400                 }
 401         }
 402         else if (req == WR_THINK)
 403         {
 404                 if(autocvar_g_balance_minelayer_reload_ammo && self.clip_load < autocvar_g_balance_minelayer_ammo) // forced reload
 405                         W_MineLayer_Reload();
 406                 else if (self.BUTTON_ATCK)
 407                 {
 408                         if(weapon_prepareattack(0, autocvar_g_balance_minelayer_refire))
 409                         {
 410                                 W_Mine_Attack();
 411                                 weapon_thinkf(WFRAME_FIRE1, autocvar_g_balance_minelayer_animtime, w_ready);
 412                         }
 413                 }
 414
 415                 else if (self.BUTTON_ATCK2)
 416                 {
 417                         minfound = 0;
 418                         for(mine = world; (mine = find(mine, classname, "mine")); ) if(mine.owner == self)
 419                         {
 420                                 if(!mine.minelayer_detonate)
 421                                 {
 422                                         mine.minelayer_detonate = TRUE;
 423                                         minfound = 1;
 424                                 }
 425                         }
 426                         if(minfound)
 427                                 sound (self, CHAN_WEAPON2, "weapons/mine_det.wav", VOL_BASE, ATTN_NORM);
 428                 }
 429         }
 430         else if (req == WR_PRECACHE)
 431         {
 432                 precache_model ("models/flash.md3");
 433                 precache_model ("models/mine.md3");
 434                 precache_model ("models/weapons/g_minelayer.md3");
 435                 precache_model ("models/weapons/v_minelayer.md3");
 436                 precache_model ("models/weapons/h_minelayer.iqm");
 437                 precache_sound ("weapons/mine_det.wav");
 438                 precache_sound ("weapons/mine_fire.wav");
 439                 precache_sound ("weapons/mine_stick.wav");
 440                 precache_sound ("weapons/mine_trigger.wav");
 441                 precache_sound ("weapons/reload.wav");
 442         }
 443         else if (req == WR_SETUP)
 444         {
 445                 weapon_setup(WEP_MINE_LAYER);
 446                 W_MineLayer_SetAmmoCounter();
 447         }
 448         else if (req == WR_CHECKAMMO1)
 449         {
 450                 // don't switch while placing a mine
 451                 if (ATTACK_FINISHED(self) <= time || self.weapon != WEP_MINE_LAYER)
 452                 {
 453                         if(autocvar_g_balance_minelayer_reload_ammo)
 454                         {
 455                                 if(self.ammo_rockets < autocvar_g_balance_minelayer_ammo && self.weapon_load[WEP_MINE_LAYER] < autocvar_g_balance_minelayer_ammo)
 456                                         ammo_amount = TRUE;
 457                         }
 458                         else if(self.ammo_rockets < autocvar_g_balance_minelayer_ammo)
 459                                 ammo_amount = TRUE;
 460                         return !ammo_amount;
 461                 }
 462         }
 463         else if (req == WR_CHECKAMMO2)
 464         {
 465                 return FALSE;
 466         }
 467         else if (req == WR_RESETPLAYER)
 468         {
 469                 // all weapons must be fully loaded when we spawn
 470                 self.weapon_load[WEP_MINE_LAYER] = autocvar_g_balance_minelayer_reload_ammo;
 471         }
 472         else if (req == WR_RELOAD)
 473         {
 474                 W_MineLayer_Reload();
 475         }
 476         return TRUE;
 477 };
 478 #endif
 479 #ifdef CSQC
 480 float w_minelayer(float req)
 481 {
 482         if(req == WR_IMPACTEFFECT)
 483         {
 484                 vector org2;
 485                 org2 = w_org + w_backoff * 12;
 486                 pointparticles(particleeffectnum("rocket_explode"), org2, '0 0 0', 1);
 487                 if(!w_issilent)
 488                         sound(self, CHAN_PROJECTILE, "weapons/mine_exp.wav", VOL_BASE, ATTN_NORM);
 489         }
 490         else if(req == WR_PRECACHE)
 491         {
 492                 precache_sound("weapons/mine_exp.wav");
 493         }
 494         else if (req == WR_SUICIDEMESSAGE)
 495                 w_deathtypestring = _("%s exploded");
 496         else if (req == WR_KILLMESSAGE)
 497         {
 498                 if(w_deathtype & HITTYPE_BOUNCE) // (remote detonation)
 499                         w_deathtypestring = _("%s got too close to %s's mine");
 500                 else if(w_deathtype & HITTYPE_SPLASH)
 501                         w_deathtypestring = _("%s almost dodged %s's mine");
 502                 else
 503                         w_deathtypestring = _("%s stepped on %s's mine");
 504         }
 505         return TRUE;
 506 }
 507 #endif
 508 #endif