qcsrc/server/w_minelayer.qc

   1 #ifdef REGISTER_WEAPON
   2 REGISTER_WEAPON(MINE_LAYER, w_minelayer, IT_ROCKETS, 4, WEP_FLAG_NORMAL | WEP_TYPE_SPLASH, BOT_PICKUP_RATING_HIGH, "minelayer", "minelayer", _("Mine Layer"))
   3 #else
   4 #ifdef SVQC
   5 void W_Mine_Think (void);
   6 .float minelayer_detonate, minelayer_mines;
   7 .float mine_time;
   8
   9 void spawnfunc_weapon_minelayer (void)
  10 {
  11         weapon_defaultspawnfunc(WEP_MINE_LAYER);
  12 }
  13
  14 void W_Mine_Stick ()
  15 {
  16         spamsound (self, CHAN_PROJECTILE, "weapons/mine_stick.wav", VOL_BASE, ATTN_NORM);
  17
  18         // in order for mines to face properly when sticking to the ground, they must be a server side entity rather than a csqc projectile
  19
  20         entity newmine;
  21         newmine = spawn();
  22         newmine.classname = self.classname;
  23
  24         newmine.bot_dodge = self.bot_dodge;
  25         newmine.bot_dodgerating = self.bot_dodgerating;
  26
  27         newmine.owner = self.owner;
  28         setsize(newmine, '-4 -4 -4', '4 4 4');
  29         setorigin(newmine, self.origin);
  30         setmodel(newmine, "models/mine.md3");
  31         newmine.angles = vectoangles(-trace_plane_normal); // face against the surface
  32
  33         newmine.takedamage = self.takedamage;
  34         newmine.damageforcescale = self.damageforcescale;
  35         newmine.health = self.health;
  36         newmine.event_damage = self.event_damage;
  37         newmine.spawnshieldtime = self.spawnshieldtime;
  38
  39         newmine.movetype = MOVETYPE_NONE; // lock the mine in place
  40         newmine.projectiledeathtype = self.projectiledeathtype;
  41
  42         newmine.mine_time = self.mine_time;
  43
  44         newmine.touch = SUB_Null;
  45         newmine.think = W_Mine_Think;
  46         newmine.nextthink = time;
  47         newmine.cnt = self.cnt;
  48         newmine.flags = self.flags;
  49
  50         remove(self);
  51         self = newmine;
  52 }
  53
  54 void W_Mine_Explode ()
  55 {
  56         if(other.takedamage == DAMAGE_AIM)
  57                 if(other.classname == "player")
  58                         if(IsDifferentTeam(self.owner, other))
  59                                 if(IsFlying(other))
  60                                         AnnounceTo(self.owner, "airshot");
  61
  62         self.event_damage = SUB_Null;
  63         self.takedamage = DAMAGE_NO;
  64
  65         RadiusDamage (self, self.owner, autocvar_g_balance_minelayer_damage, autocvar_g_balance_minelayer_edgedamage, autocvar_g_balance_minelayer_radius, world, autocvar_g_balance_minelayer_force, self.projectiledeathtype, other);
  66
  67         if (self.owner.weapon == WEP_MINE_LAYER)
  68         {
  69                 if(self.owner.ammo_rockets < autocvar_g_balance_minelayer_ammo)
  70                 {
  71                         self.owner.cnt = WEP_MINE_LAYER;
  72                         ATTACK_FINISHED(self.owner) = time;
  73                         self.owner.switchweapon = w_getbestweapon(self.owner);
  74                 }
  75         }
  76         remove (self);
  77 }
  78
  79 void W_Mine_DoRemoteExplode ()
  80 {
  81         self.event_damage = SUB_Null;
  82         self.takedamage = DAMAGE_NO;
  83
  84         RadiusDamage (self, self.owner, autocvar_g_balance_minelayer_remote_damage, autocvar_g_balance_minelayer_remote_edgedamage, autocvar_g_balance_minelayer_remote_radius, world, autocvar_g_balance_minelayer_remote_force, self.projectiledeathtype | HITTYPE_BOUNCE, world);
  85
  86         if (self.owner.weapon == WEP_MINE_LAYER)
  87         {
  88                 if(self.owner.ammo_rockets < autocvar_g_balance_minelayer_ammo)
  89                 {
  90                         self.owner.cnt = WEP_MINE_LAYER;
  91                         ATTACK_FINISHED(self.owner) = time;
  92                         self.owner.switchweapon = w_getbestweapon(self.owner);
  93                 }
  94         }
  95         remove (self);
  96 }
  97
  98 void W_Mine_RemoteExplode ()
  99 {
 100         if(self.owner.deadflag == DEAD_NO)
 101                 if((self.spawnshieldtime >= 0)
 102                         ? (time >= self.spawnshieldtime) // timer
 103                         : (vlen(NearestPointOnBox(self.owner, self.origin) - self.origin) > autocvar_g_balance_minelayer_remote_radius) // safety device
 104                 )
 105                 {
 106                         W_Mine_DoRemoteExplode();
 107                 }
 108 }
 109
 110 void W_Mine_ProximityExplode ()
 111 {
 112         // make sure no friend is in the mine's radius. If there is any, explosion is delayed until he's at a safe distance
 113         if(autocvar_g_balance_minelayer_protection)
 114         {
 115                 entity head;
 116                 head = findradius(self.origin, autocvar_g_balance_minelayer_radius);
 117                 while(head)
 118                 {
 119                         if(head == self.owner || !IsDifferentTeam(head, self.owner))
 120                                 return;
 121                         head = head.chain;
 122                 }
 123         }
 124
 125         self.mine_time = 0;
 126         W_Mine_Explode();
 127 }
 128
 129 void W_Mine_Think (void)
 130 {
 131         entity head;
 132
 133         self.nextthink = time;
 134
 135         // our lifetime has expired, it's time to die - mine_time just allows us to play a sound for this
 136         // TODO: replace this mine_trigger.wav sound with a real countdown
 137         if ((time > self.cnt) && (!self.mine_time))
 138         {
 139                 spamsound (self, CHAN_PROJECTILE, "weapons/mine_trigger.wav", VOL_BASE, ATTN_NORM);
 140                 self.mine_time = time + autocvar_g_balance_minelayer_lifetime_countdown;
 141         }
 142
 143         // a player's mines shall explode if he disconnects or dies
 144         // TODO: Do this on team change too -- Samual: But isn't a player killed when they switch teams?
 145         if(self.owner.classname != "player" || self.owner.deadflag != DEAD_NO)
 146         {
 147                 other = world;
 148                 self.projectiledeathtype |= HITTYPE_BOUNCE;
 149                 W_Mine_Explode();
 150                 return;
 151         }
 152
 153         // set the mine for detonation when a foe gets close enough
 154         head = findradius(self.origin, autocvar_g_balance_minelayer_proximityradius);
 155         while(head)
 156         {
 157                 if(head.classname == "player" && head.deadflag == DEAD_NO)
 158                 if(head != self.owner && IsDifferentTeam(head, self.owner)) // don't trigger for team mates
 159                 if(!self.mine_time)
 160                 {
 161                         spamsound (self, CHAN_PROJECTILE, "weapons/mine_trigger.wav", VOL_BASE, ATTN_NORM);
 162                         self.mine_time = time + autocvar_g_balance_minelayer_time;
 163                 }
 164                 head = head.chain;
 165         }
 166
 167         // explode if it's time to
 168         if(self.mine_time && time >= self.mine_time)
 169         {
 170                 W_Mine_ProximityExplode();
 171                 return;
 172         }
 173
 174         // remote detonation
 175         if (self.owner.weapon == WEP_MINE_LAYER)
 176         if (self.owner.deadflag == DEAD_NO)
 177         if (self.minelayer_detonate)
 178                 W_Mine_RemoteExplode();
 179 }
 180
 181 void W_Mine_Touch (void)
 182 {
 183         PROJECTILE_TOUCH;
 184         if(!other || (other.takedamage != DAMAGE_AIM && other.movetype == MOVETYPE_NONE))
 185                 W_Mine_Stick();
 186         else if(self.movetype != MOVETYPE_NONE) // don't unstick a locked mine when someone touches it
 187                 self.velocity = '0 0 0';
 188 }
 189
 190 void W_Mine_Damage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 191 {
 192         if (self.health <= 0)
 193                 return;
 194         self.health = self.health - damage;
 195         self.angles = vectoangles(self.velocity);
 196         if (self.health <= 0)
 197                 W_PrepareExplosionByDamage(attacker, W_Mine_Explode);
 198 }
 199
 200 void W_Mine_Attack (void)
 201 {
 202         entity mine;
 203         entity flash;
 204
 205         // scan how many mines we placed, and return if we reached our limit
 206         if(autocvar_g_balance_minelayer_limit)
 207         {
 208                 self.minelayer_mines = 0;
 209                 for(mine = world; (mine = find(mine, classname, "mine")); ) if(mine.owner == self)
 210                         self.minelayer_mines += 1;
 211
 212                 if(self.minelayer_mines >= autocvar_g_balance_minelayer_limit)
 213                 {
 214                         // the refire delay keeps this message from being spammed
 215                         sprint(self, strcat("You cannot place more than ^2", ftos(autocvar_g_balance_minelayer_limit), " ^7mines at a time\n") );
 216                         play2(self, "weapons/unavailable.wav");
 217                         return;
 218                 }
 219         }
 220
 221         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
 222                 self.ammo_rockets = self.ammo_rockets - autocvar_g_balance_minelayer_ammo;
 223
 224         W_SetupShot_ProjectileSize (self, '-4 -4 -4', '4 4 4', FALSE, 5, "weapons/mine_fire.wav", CHAN_WEAPON, autocvar_g_balance_minelayer_damage);
 225         pointparticles(particleeffectnum("rocketlauncher_muzzleflash"), w_shotorg, w_shotdir * 1000, 1);
 226
 227         mine = WarpZone_RefSys_SpawnSameRefSys(self);
 228         mine.owner = self;
 229         if(autocvar_g_balance_minelayer_detonatedelay >= 0)
 230                 mine.spawnshieldtime = time + autocvar_g_balance_minelayer_detonatedelay;
 231         else
 232                 mine.spawnshieldtime = -1;
 233         mine.classname = "mine";
 234         mine.bot_dodge = TRUE;
 235         mine.bot_dodgerating = autocvar_g_balance_minelayer_damage * 2; // * 2 because it can detonate inflight which makes it even more dangerous
 236
 237         mine.takedamage = DAMAGE_YES;
 238         mine.damageforcescale = autocvar_g_balance_minelayer_damageforcescale;
 239         mine.health = autocvar_g_balance_minelayer_health;
 240         mine.event_damage = W_Mine_Damage;
 241
 242         mine.movetype = MOVETYPE_TOSS;
 243         PROJECTILE_MAKETRIGGER(mine);
 244         mine.projectiledeathtype = WEP_MINE_LAYER;
 245         setsize (mine, '-4 -4 -4', '4 4 4'); // give it some size so it can be shot
 246
 247         setorigin (mine, w_shotorg - v_forward * 4); // move it back so it hits the wall at the right point
 248         W_SetupProjectileVelocity(mine, autocvar_g_balance_minelayer_speed, 0);
 249         mine.angles = vectoangles (mine.velocity);
 250
 251         mine.touch = W_Mine_Touch;
 252         mine.think = W_Mine_Think;
 253         mine.nextthink = time;
 254         mine.cnt = time + (autocvar_g_balance_minelayer_lifetime - autocvar_g_balance_minelayer_lifetime_countdown);
 255         mine.flags = FL_PROJECTILE;
 256
 257         CSQCProjectile(mine, TRUE, PROJECTILE_MINE, TRUE);
 258
 259         // muzzle flash for 1st person view
 260         flash = spawn ();
 261         setmodel (flash, "models/flash.md3"); // precision set below
 262         SUB_SetFade (flash, time, 0.1);
 263         flash.effects = EF_ADDITIVE | EF_FULLBRIGHT | EF_LOWPRECISION;
 264         W_AttachToShotorg(flash, '5 0 0');
 265
 266         // common properties
 267
 268         other = mine; MUTATOR_CALLHOOK(EditProjectile);
 269 }
 270
 271 void spawnfunc_weapon_minelayer (void); // defined in t_items.qc
 272
 273 float w_minelayer(float req)
 274 {
 275         entity mine;
 276         float minfound;
 277         if (req == WR_AIM)
 278         {
 279                 // aim and decide to fire if appropriate
 280                 self.BUTTON_ATCK = bot_aim(autocvar_g_balance_minelayer_speed, 0, autocvar_g_balance_minelayer_lifetime, FALSE);
 281                 if(skill >= 2) // skill 0 and 1 bots won't detonate mines!
 282                 {
 283                         // decide whether to detonate mines
 284                         entity targetlist, targ;
 285                         float edgedamage, coredamage, edgeradius, recipricoledgeradius, d;
 286                         float selfdamage, teamdamage, enemydamage;
 287                         edgedamage = autocvar_g_balance_minelayer_edgedamage;
 288                         coredamage = autocvar_g_balance_minelayer_damage;
 289                         edgeradius = autocvar_g_balance_minelayer_radius;
 290                         recipricoledgeradius = 1 / edgeradius;
 291                         selfdamage = 0;
 292                         teamdamage = 0;
 293                         enemydamage = 0;
 294                         targetlist = findchainfloat(bot_attack, TRUE);
 295                         mine = find(world, classname, "mine");
 296                         while (mine)
 297                         {
 298                                 if (mine.owner != self)
 299                                 {
 300                                         mine = find(mine, classname, "mine");
 301                                         continue;
 302                                 }
 303                                 targ = targetlist;
 304                                 while (targ)
 305                                 {
 306                                         d = vlen(targ.origin + (targ.mins + targ.maxs) * 0.5 - mine.origin);
 307                                         d = bound(0, edgedamage + (coredamage - edgedamage) * sqrt(1 - d * recipricoledgeradius), 10000);
 308                                         // count potential damage according to type of target
 309                                         if (targ == self)
 310                                                 selfdamage = selfdamage + d;
 311                                         else if (targ.team == self.team && teams_matter)
 312                                                 teamdamage = teamdamage + d;
 313                                         else if (bot_shouldattack(targ))
 314                                                 enemydamage = enemydamage + d;
 315                                         targ = targ.chain;
 316                                 }
 317                                 mine = find(mine, classname, "mine");
 318                         }
 319                         float desirabledamage;
 320                         desirabledamage = enemydamage;
 321                         if (time > self.invincible_finished && time > self.spawnshieldtime)
 322                                 desirabledamage = desirabledamage - selfdamage * autocvar_g_balance_selfdamagepercent;
 323                         if (teams_matter && self.team)
 324                                 desirabledamage = desirabledamage - teamdamage;
 325
 326                         mine = find(world, classname, "mine");
 327                         while (mine)
 328                         {
 329                                 if (mine.owner != self)
 330                                 {
 331                                         mine = find(mine, classname, "mine");
 332                                         continue;
 333                                 }
 334                                 makevectors(mine.v_angle);
 335                                 targ = targetlist;
 336                                 if (skill > 9) // normal players only do this for the target they are tracking
 337                                 {
 338                                         targ = targetlist;
 339                                         while (targ)
 340                                         {
 341                                                 if (
 342                                                         (v_forward * normalize(mine.origin - targ.origin)< 0.1)
 343                                                         && desirabledamage > 0.1*coredamage
 344                                                 )self.BUTTON_ATCK2 = TRUE;
 345                                                 targ = targ.chain;
 346                                         }
 347                                 }else{
 348                                         float distance; distance= bound(300,vlen(self.origin-self.enemy.origin),30000);
 349                                         //As the distance gets larger, a correct detonation gets near imposible
 350                                         //Bots are assumed to use the mine spawnfunc_light to see if the mine gets near a player
 351                                         if(v_forward * normalize(mine.origin - self.enemy.origin)< 0.1)
 352                                                 if(self.enemy.classname == "player")
 353                                                         if(desirabledamage >= 0.1*coredamage)
 354                                                                 if(random()/distance*300 > frametime*bound(0,(10-skill)*0.2,1))
 355                                                                         self.BUTTON_ATCK2 = TRUE;
 356                                 //      dprint(ftos(random()/distance*300),">");dprint(ftos(frametime*bound(0,(10-skill)*0.2,1)),"\n");
 357                                 }
 358
 359                                 mine = find(mine, classname, "mine");
 360                         }
 361                         // if we would be doing at X percent of the core damage, detonate it
 362                         // but don't fire a new shot at the same time!
 363                         if (desirabledamage >= 0.75 * coredamage) //this should do group damage in rare fortunate events
 364                                 self.BUTTON_ATCK2 = TRUE;
 365                         if ((skill > 6.5) && (selfdamage > self.health))
 366                                 self.BUTTON_ATCK2 = FALSE;
 367                         //if(self.BUTTON_ATCK2 == TRUE)
 368                         //      dprint(ftos(desirabledamage),"\n");
 369                         if (self.BUTTON_ATCK2 == TRUE) self.BUTTON_ATCK = FALSE;
 370                 }
 371         }
 372         else if (req == WR_THINK)
 373         {
 374                 if (self.BUTTON_ATCK)
 375                 {
 376                         if(weapon_prepareattack(0, autocvar_g_balance_minelayer_refire))
 377                         {
 378                                 W_Mine_Attack();
 379                                 weapon_thinkf(WFRAME_FIRE1, autocvar_g_balance_minelayer_animtime, w_ready);
 380                         }
 381                 }
 382
 383                 if (self.BUTTON_ATCK2)
 384                 {
 385                         minfound = 0;
 386                         for(mine = world; (mine = find(mine, classname, "mine")); ) if(mine.owner == self)
 387                         {
 388                                 if(!mine.minelayer_detonate)
 389                                 {
 390                                         mine.minelayer_detonate = TRUE;
 391                                         minfound = 1;
 392                                 }
 393                         }
 394                         if(minfound)
 395                                 sound (self, CHAN_WEAPON2, "weapons/mine_det.wav", VOL_BASE, ATTN_NORM);
 396                 }
 397         }
 398         else if (req == WR_PRECACHE)
 399         {
 400                 precache_model ("models/flash.md3");
 401                 precache_model ("models/mine.md3");
 402                 precache_model ("models/weapons/g_minelayer.md3");
 403                 precache_model ("models/weapons/v_minelayer.md3");
 404                 precache_model ("models/weapons/h_minelayer.iqm");
 405                 precache_sound ("weapons/mine_det.wav");
 406                 precache_sound ("weapons/mine_fire.wav");
 407                 precache_sound ("weapons/mine_stick.wav");
 408                 precache_sound ("weapons/mine_trigger.wav");
 409         }
 410         else if (req == WR_SETUP)
 411         {
 412                 weapon_setup(WEP_MINE_LAYER);
 413         }
 414         else if (req == WR_CHECKAMMO1)
 415         {
 416                 // don't switch while placing a mine
 417                 if ((ATTACK_FINISHED(self) <= time || self.weapon != WEP_MINE_LAYER)
 418                         && self.ammo_rockets < autocvar_g_balance_minelayer_ammo)
 419                         return FALSE;
 420         }
 421         else if (req == WR_CHECKAMMO2)
 422                 return FALSE;
 423         return TRUE;
 424 };
 425 #endif
 426 #ifdef CSQC
 427 float w_minelayer(float req)
 428 {
 429         if(req == WR_IMPACTEFFECT)
 430         {
 431                 vector org2;
 432                 org2 = w_org + w_backoff * 12;
 433                 pointparticles(particleeffectnum("rocket_explode"), org2, '0 0 0', 1);
 434                 if(!w_issilent)
 435                         sound(self, CHAN_PROJECTILE, "weapons/mine_exp.wav", VOL_BASE, ATTN_NORM);
 436         }
 437         else if(req == WR_PRECACHE)
 438         {
 439                 precache_sound("weapons/mine_exp.wav");
 440         }
 441         else if (req == WR_SUICIDEMESSAGE)
 442                 w_deathtypestring = _("%s exploded");
 443         else if (req == WR_KILLMESSAGE)
 444         {
 445                 if(w_deathtype & HITTYPE_BOUNCE) // (remote detonation)
 446                         w_deathtypestring = _("%s got too close to %s's mine");
 447                 else if(w_deathtype & HITTYPE_SPLASH)
 448                         w_deathtypestring = _("%s almost dodged %s's mine");
 449                 else
 450                         w_deathtypestring = _("%s stepped on %s's mine");
 451         }
 452         return TRUE;
 453 }
 454 #endif
 455 #endif