qcsrc/server/w_minelayer.qc

   1 #ifdef REGISTER_WEAPON
   2 REGISTER_WEAPON(MINE_LAYER, w_minelayer, IT_ROCKETS, 9, WEP_FLAG_NORMAL | WEP_TYPE_SPLASH, BOT_PICKUP_RATING_HIGH, "minelayer", "minelayer", "Mine Layer");
   3 #else
   4 #ifdef SVQC
   5 .float minelayer_detonate;
   6 .float mine_number, mine_time;
   7
   8 void spawnfunc_weapon_minelayer (void)
   9 {
  10         weapon_defaultspawnfunc(WEP_MINE_LAYER);
  11 }
  12
  13 void W_Mine_Unregister()
  14 {
  15         if(self.owner && self.owner.lastmine == self)
  16                 self.owner.lastmine = world;
  17 }
  18
  19 void W_Mine_Explode ()
  20 {
  21         W_Mine_Unregister();
  22
  23         if(other.takedamage == DAMAGE_AIM)
  24                 if(other.classname == "player")
  25                         if(IsDifferentTeam(self.owner, other))
  26                                 if(IsFlying(other))
  27                                         AnnounceTo(self.owner, "airshot");
  28
  29         self.event_damage = SUB_Null;
  30         self.takedamage = DAMAGE_NO;
  31
  32         RadiusDamage (self, self.owner, cvar("g_balance_minelayer_damage"), cvar("g_balance_minelayer_edgedamage"), cvar("g_balance_minelayer_radius"), world, cvar("g_balance_minelayer_force"), self.projectiledeathtype, other);
  33
  34         if (self.owner.weapon == WEP_MINE_LAYER)
  35         {
  36                 if(self.owner.ammo_rockets < cvar("g_balance_minelayer_ammo"))
  37                 {
  38                         self.owner.cnt = WEP_MINE_LAYER;
  39                         ATTACK_FINISHED(self.owner) = time;
  40                         self.owner.switchweapon = w_getbestweapon(self.owner);
  41                 }
  42         }
  43         remove (self);
  44 }
  45
  46 void W_Mine_DoRemoteExplode ()
  47 {
  48         W_Mine_Unregister();
  49
  50         self.event_damage = SUB_Null;
  51         self.takedamage = DAMAGE_NO;
  52
  53         RadiusDamage (self, self.owner, cvar("g_balance_minelayer_remote_damage"), cvar("g_balance_minelayer_remote_edgedamage"), cvar("g_balance_minelayer_remote_radius"), world, cvar("g_balance_minelayer_remote_force"), self.projectiledeathtype | HITTYPE_BOUNCE, world);
  54
  55         if (self.owner.weapon == WEP_MINE_LAYER)
  56         {
  57                 if(self.owner.ammo_rockets < cvar("g_balance_minelayer_ammo"))
  58                 {
  59                         self.owner.cnt = WEP_MINE_LAYER;
  60                         ATTACK_FINISHED(self.owner) = time;
  61                         self.owner.switchweapon = w_getbestweapon(self.owner);
  62                 }
  63         }
  64         remove (self);
  65 }
  66
  67 void W_Mine_RemoteExplode()
  68 {
  69         if(self.owner.deadflag == DEAD_NO)
  70         if(self.owner.lastmine)
  71         {
  72                 if((self.spawnshieldtime >= 0)
  73                         ? (time >= self.spawnshieldtime) // timer
  74                         : (vlen(NearestPointOnBox(self.owner, self.origin) - self.origin) > cvar("g_balance_minelayer_radius")) // safety device
  75                 )
  76                 {
  77                         W_Mine_DoRemoteExplode();
  78                 }
  79         }
  80 }
  81
  82 void W_Mine_Think (void)
  83 {
  84         self.nextthink = time;
  85         if (time > self.cnt)
  86         {
  87                 other = world;
  88                 self.projectiledeathtype |= HITTYPE_BOUNCE;
  89                 W_Mine_Explode ();
  90                 return;
  91         }
  92
  93         // detect players who are close the mine and explode if the player should detonate it
  94         entity head;
  95         head = findradius(self.origin, cvar("g_balance_minelayer_detectionradius"));
  96
  97         while(head)
  98         {
  99                 if(head.classname == "player" && head.deadflag == DEAD_NO)
 100                 if(head != self.owner)
 101                 if(IsDifferentTeam(head, self.owner)) // don't detonate for team mates
 102                 {
 103                         self.mine_time = time + cvar("g_balance_minelayer_time");
 104                 }
 105                 head = head.chain;
 106         }
 107
 108         // explode if it's time
 109         if(time >= self.mine_time)
 110                 W_Mine_Explode();
 111
 112         // remote detonation
 113         if (self.owner.weapon == WEP_MINE_LAYER)
 114         if (self.owner.deadflag == DEAD_NO)
 115         if (self.minelayer_detonate)
 116                 W_Mine_RemoteExplode();
 117
 118         if(self.csqcprojectile_clientanimate == 0)
 119                 UpdateCSQCProjectile(self);
 120 }
 121
 122 void W_Mine_Touch (void)
 123 {
 124         PROJECTILE_TOUCH;
 125         spamsound (self, CHAN_PROJECTILE, "weapons/mine_stick.wav", VOL_BASE, ATTN_NORM);
 126         self.movetype = MOVETYPE_NONE; // lock the mine in place
 127         // TODO: make sure this doesn't cause the mine to get stuck in the air if it falls over a moving entity
 128 }
 129
 130 void W_Mine_Damage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 131 {
 132         if (self.health <= 0)
 133                 return;
 134         self.health = self.health - damage;
 135         self.angles = vectoangles(self.velocity);
 136         if (self.health <= 0)
 137                 W_PrepareExplosionByDamage(attacker, W_Mine_Explode);
 138 }
 139
 140 void W_Mine_Attack (void)
 141 {
 142         local entity mine;
 143         local entity flash;
 144
 145         // scan how many mines we placed, and return if we reached our limit
 146         if(cvar("g_balance_minelayer_limit"))
 147         {
 148                 entity mine;
 149                 self.mine_number = 0;
 150                 for(mine = world; (mine = find(mine, classname, "mine")); ) if(mine.owner == self)
 151                         self.mine_number += 1;
 152
 153                 if(self.mine_number >= cvar("g_balance_minelayer_limit"))
 154                 {
 155                         // the refire delay keeps this message from being spammed
 156                         sprint(self, strcat("You cannot place more than ^2", cvar_string("g_balance_minelayer_limit"), " ^7mines at a time\n") );
 157                         play2(self, "weapons/unavailable.wav");
 158                         return;
 159                 }
 160         }
 161
 162         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
 163                 self.ammo_rockets = self.ammo_rockets - cvar("g_balance_minelayer_ammo");
 164
 165         W_SetupShot_ProjectileSize (self, '-4 -4 -4', '4 4 4', FALSE, 5, "weapons/mine_fire.wav", cvar("g_balance_minelayer_damage"));
 166         pointparticles(particleeffectnum("rocketlauncher_muzzleflash"), w_shotorg, w_shotdir * 1000, 1);
 167
 168         mine = WarpZone_RefSys_SpawnSameRefSys(self);
 169         mine.owner = self;
 170         self.lastmine = mine;
 171         if(cvar("g_balance_minelayer_detonatedelay") >= 0)
 172                 mine.spawnshieldtime = time + cvar("g_balance_minelayer_detonatedelay");
 173         else
 174                 mine.spawnshieldtime = -1;
 175         mine.classname = "mine";
 176         mine.bot_dodge = TRUE;
 177         mine.bot_dodgerating = cvar("g_balance_minelayer_damage") * 2; // * 2 because it can detonate inflight which makes it even more dangerous
 178
 179         mine.takedamage = DAMAGE_YES;
 180         mine.damageforcescale = cvar("g_balance_minelayer_damageforcescale");
 181         mine.health = cvar("g_balance_minelayer_health");
 182         mine.event_damage = W_Mine_Damage;
 183
 184         mine.movetype = MOVETYPE_TOSS;
 185         PROJECTILE_MAKETRIGGER(mine);
 186         mine.projectiledeathtype = WEP_MINE_LAYER;
 187         setsize (mine, '-4 -4 -4', '4 4 4'); // give it some size so it can be shot
 188
 189         setorigin (mine, w_shotorg - v_forward * 4); // move it back so it hits the wall at the right point
 190         W_SetupProjectileVelocity(mine, cvar("g_balance_minelayer_speedstart"), 0);
 191         mine.angles = vectoangles (mine.velocity);
 192
 193         mine.touch = W_Mine_Touch;
 194         mine.think = W_Mine_Think;
 195         mine.nextthink = time;
 196         mine.cnt = time + cvar("g_balance_minelayer_lifetime");
 197         mine.flags = FL_PROJECTILE;
 198
 199         CSQCProjectile(mine, FALSE, PROJECTILE_MINE, TRUE);
 200
 201         // muzzle flash for 1st person view
 202         flash = spawn ();
 203         setmodel (flash, "models/flash.md3"); // precision set below
 204         SUB_SetFade (flash, time, 0.1);
 205         flash.effects = EF_ADDITIVE | EF_FULLBRIGHT | EF_LOWPRECISION;
 206         W_AttachToShotorg(flash, '5 0 0');
 207
 208         // common properties
 209 }
 210
 211 void spawnfunc_weapon_minelayer (void); // defined in t_items.qc
 212
 213 float w_minelayer(float req)
 214 {
 215         entity mine;
 216         float minfound;
 217         if (req == WR_AIM)
 218         {
 219                 // aim and decide to fire if appropriate
 220                 self.BUTTON_ATCK = bot_aim(cvar("g_balance_minelayer_speed"), 0, cvar("g_balance_minelayer_lifetime"), FALSE);
 221                 if(skill >= 2) // skill 0 and 1 bots won't detonate mines!
 222                 {
 223                         // decide whether to detonate mines
 224                         local entity mine, targetlist, targ;
 225                         local float edgedamage, coredamage, edgeradius, recipricoledgeradius, d;
 226                         local float selfdamage, teamdamage, enemydamage;
 227                         edgedamage = cvar("g_balance_minelayer_edgedamage");
 228                         coredamage = cvar("g_balance_minelayer_damage");
 229                         edgeradius = cvar("g_balance_minelayer_radius");
 230                         recipricoledgeradius = 1 / edgeradius;
 231                         selfdamage = 0;
 232                         teamdamage = 0;
 233                         enemydamage = 0;
 234                         targetlist = findchainfloat(bot_attack, TRUE);
 235                         mine = find(world, classname, "mine");
 236                         while (mine)
 237                         {
 238                                 if (mine.owner != self)
 239                                 {
 240                                         mine = find(mine, classname, "mine");
 241                                         continue;
 242                                 }
 243                                 targ = targetlist;
 244                                 while (targ)
 245                                 {
 246                                         d = vlen(targ.origin + (targ.mins + targ.maxs) * 0.5 - mine.origin);
 247                                         d = bound(0, edgedamage + (coredamage - edgedamage) * sqrt(1 - d * recipricoledgeradius), 10000);
 248                                         // count potential damage according to type of target
 249                                         if (targ == self)
 250                                                 selfdamage = selfdamage + d;
 251                                         else if (targ.team == self.team && teams_matter)
 252                                                 teamdamage = teamdamage + d;
 253                                         else if (bot_shouldattack(targ))
 254                                                 enemydamage = enemydamage + d;
 255                                         targ = targ.chain;
 256                                 }
 257                                 mine = find(mine, classname, "mine");
 258                         }
 259                         local float desirabledamage;
 260                         desirabledamage = enemydamage;
 261                         if (teamplay != 1 && time > self.invincible_finished && time > self.spawnshieldtime)
 262                                 desirabledamage = desirabledamage - selfdamage * cvar("g_balance_selfdamagepercent");
 263                         if (self.team && teamplay != 1)
 264                                 desirabledamage = desirabledamage - teamdamage;
 265
 266                         mine = find(world, classname, "mine");
 267                         while (mine)
 268                         {
 269                                 if (mine.owner != self)
 270                                 {
 271                                         mine = find(mine, classname, "mine");
 272                                         continue;
 273                                 }
 274                                 makevectors(mine.v_angle);
 275                                 targ = targetlist;
 276                                 if (skill > 9) // normal players only do this for the target they are tracking
 277                                 {
 278                                         targ = targetlist;
 279                                         while (targ)
 280                                         {
 281                                                 if (
 282                                                         (v_forward * normalize(mine.origin - targ.origin)< 0.1)
 283                                                         && desirabledamage > 0.1*coredamage
 284                                                 )self.BUTTON_ATCK2 = TRUE;
 285                                                 targ = targ.chain;
 286                                         }
 287                                 }else{
 288                                         local float distance; distance= bound(300,vlen(self.origin-self.enemy.origin),30000);
 289                                         //As the distance gets larger, a correct detonation gets near imposible
 290                                         //Bots are assumed to use the mine spawnfunc_light to see if the mine gets near a player
 291                                         if(v_forward * normalize(mine.origin - self.enemy.origin)< 0.1)
 292                                                 if(self.enemy.classname == "player")
 293                                                         if(desirabledamage >= 0.1*coredamage)
 294                                                                 if(random()/distance*300 > frametime*bound(0,(10-skill)*0.2,1))
 295                                                                         self.BUTTON_ATCK2 = TRUE;
 296                                 //      dprint(ftos(random()/distance*300),">");dprint(ftos(frametime*bound(0,(10-skill)*0.2,1)),"\n");
 297                                 }
 298
 299                                 mine = find(mine, classname, "mine");
 300                         }
 301                         // if we would be doing at X percent of the core damage, detonate it
 302                         // but don't fire a new shot at the same time!
 303                         if (desirabledamage >= 0.75 * coredamage) //this should do group damage in rare fortunate events
 304                                 self.BUTTON_ATCK2 = TRUE;
 305                         if ((skill > 6.5) && (selfdamage > self.health))
 306                                 self.BUTTON_ATCK2 = FALSE;
 307                         //if(self.BUTTON_ATCK2 == TRUE)
 308                         //      dprint(ftos(desirabledamage),"\n");
 309                         if (self.BUTTON_ATCK2 == TRUE) self.BUTTON_ATCK = FALSE;
 310                 }
 311         }
 312         else if (req == WR_THINK)
 313         {
 314                 if (self.BUTTON_ATCK)
 315                 {
 316                         if(weapon_prepareattack(0, cvar("g_balance_minelayer_refire")))
 317                         {
 318                                 W_Mine_Attack();
 319                                 weapon_thinkf(WFRAME_FIRE1, cvar("g_balance_minelayer_animtime"), w_ready);
 320                         }
 321                 }
 322
 323                 if (self.BUTTON_ATCK2)
 324                 {
 325                         minfound = 0;
 326                         for(mine = world; (mine = find(mine, classname, "mine")); ) if(mine.owner == self)
 327                         {
 328                                 if(!mine.minelayer_detonate)
 329                                 {
 330                                         mine.minelayer_detonate = TRUE;
 331                                         minfound = 1;
 332                                 }
 333                         }
 334                         if(minfound)
 335                                 sound (self, CHAN_WEAPON2, "weapons/mine_det.wav", VOL_BASE, ATTN_NORM);
 336                 }
 337         }
 338         else if (req == WR_PRECACHE)
 339         {
 340                 precache_model ("models/flash.md3");
 341                 precache_model ("models/weapons/g_minelayer.md3");
 342                 precache_model ("models/weapons/v_minelayer.md3");
 343                 precache_model ("models/weapons/h_minelayer.iqm");
 344                 precache_sound ("weapons/mine_det.wav");
 345                 precache_sound ("weapons/mine_fire.wav");
 346                 precache_sound ("weapons/mine_stick.wav");
 347         }
 348         else if (req == WR_SETUP)
 349         {
 350                 weapon_setup(WEP_MINE_LAYER);
 351         }
 352         else if (req == WR_CHECKAMMO1)
 353         {
 354                 // don't switch while placing a mine
 355                 if ((ATTACK_FINISHED(self) <= time || self.weapon != WEP_MINE_LAYER)
 356                         && self.ammo_rockets < cvar("g_balance_minelayer_ammo"))
 357                         return FALSE;
 358         }
 359         else if (req == WR_CHECKAMMO2)
 360                 return FALSE;
 361         return TRUE;
 362 };
 363 #endif
 364 #ifdef CSQC
 365 float w_minelayer(float req)
 366 {
 367         if(req == WR_IMPACTEFFECT)
 368         {
 369                 vector org2;
 370                 org2 = w_org + w_backoff * 12;
 371                 pointparticles(particleeffectnum("rocket_explode"), org2, '0 0 0', 1);
 372                 if(!w_issilent)
 373                         sound(self, CHAN_PROJECTILE, "weapons/mine_exp.wav", VOL_BASE, ATTN_NORM);
 374         }
 375         else if(req == WR_PRECACHE)
 376         {
 377                 precache_sound("weapons/mine_exp.wav");
 378         }
 379         else if (req == WR_SUICIDEMESSAGE)
 380                 w_deathtypestring = "%s exploded";
 381         else if (req == WR_KILLMESSAGE)
 382         {
 383                 if(w_deathtype & HITTYPE_BOUNCE) // (remote detonation)
 384                         w_deathtypestring = "%s got too close to %s's mine";
 385                 else if(w_deathtype & HITTYPE_SPLASH)
 386                         w_deathtypestring = "%s almost dodged %s's mine";
 387                 else
 388                         w_deathtypestring = "%s stepped on %s's mine";
 389         }
 390         return TRUE;
 391 }
 392 #endif
 393 #endif