qcsrc/server/w_minelayer.qc

   1 #ifdef REGISTER_WEAPON
   2 REGISTER_WEAPON(MINE_LAYER, w_minelayer, IT_ROCKETS, 4, WEP_FLAG_NORMAL | WEP_FLAG_RELOADABLE | WEP_TYPE_SPLASH, BOT_PICKUP_RATING_HIGH, "minelayer", "minelayer", _("Mine Layer"))
   3 #else
   4 #ifdef SVQC
   5 void W_Mine_Think (void);
   6 .float minelayer_detonate, minelayer_mines;
   7 .float mine_time;
   8
   9 void W_MineLayer_Reload()
  10 {
  11         self.reload_ammo_player = ammo_rockets;
  12         self.reload_ammo_min = autocvar_g_balance_minelayer_ammo;
  13         self.reload_ammo_amount = autocvar_g_balance_minelayer_reload_ammo;
  14         self.reload_time = autocvar_g_balance_minelayer_reload_time;
  15         self.reload_sound = "weapons/reload.wav";
  16
  17         W_Reload();
  18 }
  19
  20 void spawnfunc_weapon_minelayer (void)
  21 {
  22         weapon_defaultspawnfunc(WEP_MINE_LAYER);
  23 }
  24
  25 void W_Mine_Stick ()
  26 {
  27         spamsound (self, CHAN_PROJECTILE, "weapons/mine_stick.wav", VOL_BASE, ATTN_NORM);
  28
  29         // in order for mines to face properly when sticking to the ground, they must be a server side entity rather than a csqc projectile
  30
  31         entity newmine;
  32         newmine = spawn();
  33         newmine.classname = self.classname;
  34
  35         newmine.bot_dodge = self.bot_dodge;
  36         newmine.bot_dodgerating = self.bot_dodgerating;
  37
  38         newmine.owner = self.owner;
  39         setsize(newmine, '-4 -4 -4', '4 4 4');
  40         setorigin(newmine, self.origin);
  41         setmodel(newmine, "models/mine.md3");
  42         newmine.angles = vectoangles(-trace_plane_normal); // face against the surface
  43
  44         newmine.takedamage = self.takedamage;
  45         newmine.damageforcescale = self.damageforcescale;
  46         newmine.health = self.health;
  47         newmine.event_damage = self.event_damage;
  48         newmine.spawnshieldtime = self.spawnshieldtime;
  49
  50         newmine.movetype = MOVETYPE_NONE; // lock the mine in place
  51         newmine.projectiledeathtype = self.projectiledeathtype;
  52
  53         newmine.mine_time = self.mine_time;
  54
  55         newmine.touch = SUB_Null;
  56         newmine.think = W_Mine_Think;
  57         newmine.nextthink = time;
  58         newmine.cnt = self.cnt;
  59         newmine.flags = self.flags;
  60
  61         remove(self);
  62         self = newmine;
  63 }
  64
  65 void W_Mine_Explode ()
  66 {
  67         if(other.takedamage == DAMAGE_AIM)
  68                 if(other.classname == "player")
  69                         if(IsDifferentTeam(self.owner, other))
  70                                 if(IsFlying(other))
  71                                         AnnounceTo(self.owner, "airshot");
  72
  73         self.event_damage = SUB_Null;
  74         self.takedamage = DAMAGE_NO;
  75
  76         RadiusDamage (self, self.owner, autocvar_g_balance_minelayer_damage, autocvar_g_balance_minelayer_edgedamage, autocvar_g_balance_minelayer_radius, world, autocvar_g_balance_minelayer_force, self.projectiledeathtype, other);
  77
  78         if (self.owner.weapon == WEP_MINE_LAYER)
  79         {
  80                 if(self.owner.ammo_rockets < autocvar_g_balance_minelayer_ammo)
  81                 {
  82                         self.owner.cnt = WEP_MINE_LAYER;
  83                         ATTACK_FINISHED(self.owner) = time;
  84                         self.owner.switchweapon = w_getbestweapon(self.owner);
  85                 }
  86         }
  87         remove (self);
  88 }
  89
  90 void W_Mine_DoRemoteExplode ()
  91 {
  92         self.event_damage = SUB_Null;
  93         self.takedamage = DAMAGE_NO;
  94
  95         RadiusDamage (self, self.owner, autocvar_g_balance_minelayer_remote_damage, autocvar_g_balance_minelayer_remote_edgedamage, autocvar_g_balance_minelayer_remote_radius, world, autocvar_g_balance_minelayer_remote_force, self.projectiledeathtype | HITTYPE_BOUNCE, world);
  96
  97         if (self.owner.weapon == WEP_MINE_LAYER)
  98         {
  99                 if(self.owner.ammo_rockets < autocvar_g_balance_minelayer_ammo)
 100                 {
 101                         self.owner.cnt = WEP_MINE_LAYER;
 102                         ATTACK_FINISHED(self.owner) = time;
 103                         self.owner.switchweapon = w_getbestweapon(self.owner);
 104                 }
 105         }
 106         remove (self);
 107 }
 108
 109 void W_Mine_RemoteExplode ()
 110 {
 111         if(self.owner.deadflag == DEAD_NO)
 112                 if((self.spawnshieldtime >= 0)
 113                         ? (time >= self.spawnshieldtime) // timer
 114                         : (vlen(NearestPointOnBox(self.owner, self.origin) - self.origin) > autocvar_g_balance_minelayer_remote_radius) // safety device
 115                 )
 116                 {
 117                         W_Mine_DoRemoteExplode();
 118                 }
 119 }
 120
 121 void W_Mine_ProximityExplode ()
 122 {
 123         // make sure no friend is in the mine's radius. If there is any, explosion is delayed until he's at a safe distance
 124         if(autocvar_g_balance_minelayer_protection)
 125         {
 126                 entity head;
 127                 head = findradius(self.origin, autocvar_g_balance_minelayer_radius);
 128                 while(head)
 129                 {
 130                         if(head == self.owner || !IsDifferentTeam(head, self.owner))
 131                                 return;
 132                         head = head.chain;
 133                 }
 134         }
 135
 136         self.mine_time = 0;
 137         W_Mine_Explode();
 138 }
 139
 140 void W_Mine_Think (void)
 141 {
 142         entity head;
 143
 144         self.nextthink = time;
 145         if (time > self.cnt)
 146         {
 147                 other = world;
 148                 self.projectiledeathtype |= HITTYPE_BOUNCE;
 149                 W_Mine_Explode();
 150                 return;
 151         }
 152
 153         // a player's mines shall explode if he disconnects or dies
 154         // TODO: Do this on team change too
 155         if(self.owner.classname != "player" || self.owner.deadflag != DEAD_NO)
 156         {
 157                 other = world;
 158                 self.projectiledeathtype |= HITTYPE_BOUNCE;
 159                 W_Mine_Explode();
 160                 return;
 161         }
 162
 163         // set the mine for detonation when a foe gets close enough
 164         head = findradius(self.origin, autocvar_g_balance_minelayer_proximityradius);
 165         while(head)
 166         {
 167                 if(head.classname == "player" && head.deadflag == DEAD_NO)
 168                 if(head != self.owner && IsDifferentTeam(head, self.owner)) // don't trigger for team mates
 169                 if(!self.mine_time)
 170                 {
 171                         spamsound (self, CHAN_PROJECTILE, "weapons/mine_trigger.wav", VOL_BASE, ATTN_NORM);
 172                         self.mine_time = time + autocvar_g_balance_minelayer_time;
 173                 }
 174                 head = head.chain;
 175         }
 176
 177         // explode if it's time to
 178         if(self.mine_time && time >= self.mine_time)
 179                 W_Mine_ProximityExplode();
 180
 181         // remote detonation
 182         if (self.owner.weapon == WEP_MINE_LAYER)
 183         if (self.owner.deadflag == DEAD_NO)
 184         if (self.minelayer_detonate)
 185                 W_Mine_RemoteExplode();
 186 }
 187
 188 void W_Mine_Touch (void)
 189 {
 190         PROJECTILE_TOUCH;
 191         if(!other || (other.takedamage != DAMAGE_AIM && other.movetype == MOVETYPE_NONE))
 192                 W_Mine_Stick();
 193         else if(self.movetype != MOVETYPE_NONE) // don't unstick a locked mine when someone touches it
 194                 self.velocity = '0 0 0';
 195 }
 196
 197 void W_Mine_Damage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 198 {
 199         if (self.health <= 0)
 200                 return;
 201         self.health = self.health - damage;
 202         self.angles = vectoangles(self.velocity);
 203         if (self.health <= 0)
 204                 W_PrepareExplosionByDamage(attacker, W_Mine_Explode);
 205 }
 206
 207 void W_Mine_Attack (void)
 208 {
 209         entity mine;
 210         entity flash;
 211
 212         // scan how many mines we placed, and return if we reached our limit
 213         if(autocvar_g_balance_minelayer_limit)
 214         {
 215                 self.minelayer_mines = 0;
 216                 for(mine = world; (mine = find(mine, classname, "mine")); ) if(mine.owner == self)
 217                         self.minelayer_mines += 1;
 218
 219                 if(self.minelayer_mines >= autocvar_g_balance_minelayer_limit)
 220                 {
 221                         // the refire delay keeps this message from being spammed
 222                         sprint(self, strcat("You cannot place more than ^2", ftos(autocvar_g_balance_minelayer_limit), " ^7mines at a time\n") );
 223                         play2(self, "weapons/unavailable.wav");
 224                         return;
 225                 }
 226         }
 227
 228         // if this weapon is reloadable, decrease its load. Else decrease the player's ammo
 229         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
 230         {
 231                 if(autocvar_g_balance_minelayer_reload_ammo)
 232                 {
 233                         self.clip_load -= autocvar_g_balance_minelayer_ammo;
 234                         self.weapon_load[WEP_MINE_LAYER] = self.clip_load;
 235                 }
 236                 else
 237                         self.ammo_rockets -= autocvar_g_balance_minelayer_ammo;
 238         }
 239
 240         W_SetupShot_ProjectileSize (self, '-4 -4 -4', '4 4 4', FALSE, 5, "weapons/mine_fire.wav", CHAN_WEAPON, autocvar_g_balance_minelayer_damage);
 241         pointparticles(particleeffectnum("rocketlauncher_muzzleflash"), w_shotorg, w_shotdir * 1000, 1);
 242
 243         mine = WarpZone_RefSys_SpawnSameRefSys(self);
 244         mine.owner = self;
 245         if(autocvar_g_balance_minelayer_detonatedelay >= 0)
 246                 mine.spawnshieldtime = time + autocvar_g_balance_minelayer_detonatedelay;
 247         else
 248                 mine.spawnshieldtime = -1;
 249         mine.classname = "mine";
 250         mine.bot_dodge = TRUE;
 251         mine.bot_dodgerating = autocvar_g_balance_minelayer_damage * 2; // * 2 because it can detonate inflight which makes it even more dangerous
 252
 253         mine.takedamage = DAMAGE_YES;
 254         mine.damageforcescale = autocvar_g_balance_minelayer_damageforcescale;
 255         mine.health = autocvar_g_balance_minelayer_health;
 256         mine.event_damage = W_Mine_Damage;
 257
 258         mine.movetype = MOVETYPE_TOSS;
 259         PROJECTILE_MAKETRIGGER(mine);
 260         mine.projectiledeathtype = WEP_MINE_LAYER;
 261         setsize (mine, '-4 -4 -4', '4 4 4'); // give it some size so it can be shot
 262
 263         setorigin (mine, w_shotorg - v_forward * 4); // move it back so it hits the wall at the right point
 264         W_SetupProjectileVelocity(mine, autocvar_g_balance_minelayer_speed, 0);
 265         mine.angles = vectoangles (mine.velocity);
 266
 267         mine.touch = W_Mine_Touch;
 268         mine.think = W_Mine_Think;
 269         mine.nextthink = time;
 270         mine.cnt = time + autocvar_g_balance_minelayer_lifetime;
 271         mine.flags = FL_PROJECTILE;
 272
 273         CSQCProjectile(mine, TRUE, PROJECTILE_MINE, TRUE);
 274
 275         // muzzle flash for 1st person view
 276         flash = spawn ();
 277         setmodel (flash, "models/flash.md3"); // precision set below
 278         SUB_SetFade (flash, time, 0.1);
 279         flash.effects = EF_ADDITIVE | EF_FULLBRIGHT | EF_LOWPRECISION;
 280         W_AttachToShotorg(flash, '5 0 0');
 281
 282         // common properties
 283
 284         other = mine; MUTATOR_CALLHOOK(EditProjectile);
 285 }
 286
 287 void spawnfunc_weapon_minelayer (void); // defined in t_items.qc
 288
 289 float w_minelayer(float req)
 290 {
 291         entity mine;
 292         float minfound;
 293         float ammo_amount;
 294
 295         if (req == WR_AIM)
 296         {
 297                 // aim and decide to fire if appropriate
 298                 self.BUTTON_ATCK = bot_aim(autocvar_g_balance_minelayer_speed, 0, autocvar_g_balance_minelayer_lifetime, FALSE);
 299                 if(skill >= 2) // skill 0 and 1 bots won't detonate mines!
 300                 {
 301                         // decide whether to detonate mines
 302                         entity targetlist, targ;
 303                         float edgedamage, coredamage, edgeradius, recipricoledgeradius, d;
 304                         float selfdamage, teamdamage, enemydamage;
 305                         edgedamage = autocvar_g_balance_minelayer_edgedamage;
 306                         coredamage = autocvar_g_balance_minelayer_damage;
 307                         edgeradius = autocvar_g_balance_minelayer_radius;
 308                         recipricoledgeradius = 1 / edgeradius;
 309                         selfdamage = 0;
 310                         teamdamage = 0;
 311                         enemydamage = 0;
 312                         targetlist = findchainfloat(bot_attack, TRUE);
 313                         mine = find(world, classname, "mine");
 314                         while (mine)
 315                         {
 316                                 if (mine.owner != self)
 317                                 {
 318                                         mine = find(mine, classname, "mine");
 319                                         continue;
 320                                 }
 321                                 targ = targetlist;
 322                                 while (targ)
 323                                 {
 324                                         d = vlen(targ.origin + (targ.mins + targ.maxs) * 0.5 - mine.origin);
 325                                         d = bound(0, edgedamage + (coredamage - edgedamage) * sqrt(1 - d * recipricoledgeradius), 10000);
 326                                         // count potential damage according to type of target
 327                                         if (targ == self)
 328                                                 selfdamage = selfdamage + d;
 329                                         else if (targ.team == self.team && teams_matter)
 330                                                 teamdamage = teamdamage + d;
 331                                         else if (bot_shouldattack(targ))
 332                                                 enemydamage = enemydamage + d;
 333                                         targ = targ.chain;
 334                                 }
 335                                 mine = find(mine, classname, "mine");
 336                         }
 337                         float desirabledamage;
 338                         desirabledamage = enemydamage;
 339                         if (time > self.invincible_finished && time > self.spawnshieldtime)
 340                                 desirabledamage = desirabledamage - selfdamage * autocvar_g_balance_selfdamagepercent;
 341                         if (teams_matter && self.team)
 342                                 desirabledamage = desirabledamage - teamdamage;
 343
 344                         mine = find(world, classname, "mine");
 345                         while (mine)
 346                         {
 347                                 if (mine.owner != self)
 348                                 {
 349                                         mine = find(mine, classname, "mine");
 350                                         continue;
 351                                 }
 352                                 makevectors(mine.v_angle);
 353                                 targ = targetlist;
 354                                 if (skill > 9) // normal players only do this for the target they are tracking
 355                                 {
 356                                         targ = targetlist;
 357                                         while (targ)
 358                                         {
 359                                                 if (
 360                                                         (v_forward * normalize(mine.origin - targ.origin)< 0.1)
 361                                                         && desirabledamage > 0.1*coredamage
 362                                                 )self.BUTTON_ATCK2 = TRUE;
 363                                                 targ = targ.chain;
 364                                         }
 365                                 }else{
 366                                         float distance; distance= bound(300,vlen(self.origin-self.enemy.origin),30000);
 367                                         //As the distance gets larger, a correct detonation gets near imposible
 368                                         //Bots are assumed to use the mine spawnfunc_light to see if the mine gets near a player
 369                                         if(v_forward * normalize(mine.origin - self.enemy.origin)< 0.1)
 370                                                 if(self.enemy.classname == "player")
 371                                                         if(desirabledamage >= 0.1*coredamage)
 372                                                                 if(random()/distance*300 > frametime*bound(0,(10-skill)*0.2,1))
 373                                                                         self.BUTTON_ATCK2 = TRUE;
 374                                 //      dprint(ftos(random()/distance*300),">");dprint(ftos(frametime*bound(0,(10-skill)*0.2,1)),"\n");
 375                                 }
 376
 377                                 mine = find(mine, classname, "mine");
 378                         }
 379                         // if we would be doing at X percent of the core damage, detonate it
 380                         // but don't fire a new shot at the same time!
 381                         if (desirabledamage >= 0.75 * coredamage) //this should do group damage in rare fortunate events
 382                                 self.BUTTON_ATCK2 = TRUE;
 383                         if ((skill > 6.5) && (selfdamage > self.health))
 384                                 self.BUTTON_ATCK2 = FALSE;
 385                         //if(self.BUTTON_ATCK2 == TRUE)
 386                         //      dprint(ftos(desirabledamage),"\n");
 387                         if (self.BUTTON_ATCK2 == TRUE) self.BUTTON_ATCK = FALSE;
 388                 }
 389         }
 390         else if (req == WR_THINK)
 391         {
 392                 if(autocvar_g_balance_minelayer_reload_ammo && self.clip_load < autocvar_g_balance_minelayer_ammo) // forced reload
 393                         W_MineLayer_Reload();
 394                 else if (self.BUTTON_ATCK)
 395                 {
 396                         if(weapon_prepareattack(0, autocvar_g_balance_minelayer_refire))
 397                         {
 398                                 W_Mine_Attack();
 399                                 weapon_thinkf(WFRAME_FIRE1, autocvar_g_balance_minelayer_animtime, w_ready);
 400                         }
 401                 }
 402
 403                 else if (self.BUTTON_ATCK2)
 404                 {
 405                         minfound = 0;
 406                         for(mine = world; (mine = find(mine, classname, "mine")); ) if(mine.owner == self)
 407                         {
 408                                 if(!mine.minelayer_detonate)
 409                                 {
 410                                         mine.minelayer_detonate = TRUE;
 411                                         minfound = 1;
 412                                 }
 413                         }
 414                         if(minfound)
 415                                 sound (self, CHAN_WEAPON2, "weapons/mine_det.wav", VOL_BASE, ATTN_NORM);
 416                 }
 417         }
 418         else if (req == WR_PRECACHE)
 419         {
 420                 precache_model ("models/flash.md3");
 421                 precache_model ("models/mine.md3");
 422                 precache_model ("models/weapons/g_minelayer.md3");
 423                 precache_model ("models/weapons/v_minelayer.md3");
 424                 precache_model ("models/weapons/h_minelayer.iqm");
 425                 precache_sound ("weapons/mine_det.wav");
 426                 precache_sound ("weapons/mine_fire.wav");
 427                 precache_sound ("weapons/mine_stick.wav");
 428                 precache_sound ("weapons/mine_trigger.wav");
 429                 precache_sound ("weapons/reload.wav");
 430         }
 431         else if (req == WR_SETUP)
 432         {
 433                 weapon_setup(WEP_MINE_LAYER);
 434         }
 435         else if (req == WR_CHECKAMMO1)
 436         {
 437                 // don't switch while placing a mine
 438                 if (ATTACK_FINISHED(self) <= time || self.weapon != WEP_MINE_LAYER)
 439                 {
 440                         if(autocvar_g_balance_minelayer_reload_ammo)
 441                         {
 442                                 if(self.ammo_rockets < autocvar_g_balance_minelayer_ammo && self.weapon_load[WEP_MINE_LAYER] < autocvar_g_balance_minelayer_ammo)
 443                                         ammo_amount = TRUE;
 444                         }
 445                         else if(self.ammo_rockets < autocvar_g_balance_minelayer_ammo)
 446                                 ammo_amount = TRUE;
 447                         return !ammo_amount;
 448                 }
 449         }
 450         else if (req == WR_CHECKAMMO2)
 451         {
 452                 return FALSE;
 453         }
 454         else if (req == WR_RELOAD)
 455         {
 456                 W_MineLayer_Reload();
 457         }
 458         return TRUE;
 459 };
 460 #endif
 461 #ifdef CSQC
 462 float w_minelayer(float req)
 463 {
 464         if(req == WR_IMPACTEFFECT)
 465         {
 466                 vector org2;
 467                 org2 = w_org + w_backoff * 12;
 468                 pointparticles(particleeffectnum("rocket_explode"), org2, '0 0 0', 1);
 469                 if(!w_issilent)
 470                         sound(self, CHAN_PROJECTILE, "weapons/mine_exp.wav", VOL_BASE, ATTN_NORM);
 471         }
 472         else if(req == WR_PRECACHE)
 473         {
 474                 precache_sound("weapons/mine_exp.wav");
 475         }
 476         else if (req == WR_SUICIDEMESSAGE)
 477                 w_deathtypestring = _("%s exploded");
 478         else if (req == WR_KILLMESSAGE)
 479         {
 480                 if(w_deathtype & HITTYPE_BOUNCE) // (remote detonation)
 481                         w_deathtypestring = _("%s got too close to %s's mine");
 482                 else if(w_deathtype & HITTYPE_SPLASH)
 483                         w_deathtypestring = _("%s almost dodged %s's mine");
 484                 else
 485                         w_deathtypestring = _("%s stepped on %s's mine");
 486         }
 487         return TRUE;
 488 }
 489 #endif
 490 #endif