qcsrc/server/w_minelayer.qc

   1 #ifdef REGISTER_WEAPON
   2 REGISTER_WEAPON(MINE_LAYER, w_minelayer, IT_ROCKETS, 4, WEP_FLAG_NORMAL | WEP_FLAG_RELOADABLE | WEP_TYPE_SPLASH, BOT_PICKUP_RATING_HIGH, "minelayer", "minelayer", _("Mine Layer"))
   3 #else
   4 #ifdef SVQC
   5 void W_Mine_Think (void);
   6 .float minelayer_detonate, mine_explodeanyway;
   7 .float mine_time;
   8
   9 void spawnfunc_weapon_minelayer (void)
  10 {
  11         weapon_defaultspawnfunc(WEP_MINE_LAYER);
  12 }
  13
  14 void W_Mine_Stick ()
  15 {
  16         spamsound (self, CHAN_PROJECTILE, "weapons/mine_stick.wav", VOL_BASE, ATTN_NORM);
  17
  18         // in order for mines to face properly when sticking to the ground, they must be a server side entity rather than a csqc projectile
  19
  20         entity newmine;
  21         newmine = spawn();
  22         newmine.classname = self.classname;
  23
  24         newmine.bot_dodge = self.bot_dodge;
  25         newmine.bot_dodgerating = self.bot_dodgerating;
  26
  27         newmine.owner = self.owner;
  28         setsize(newmine, '-4 -4 -4', '4 4 4');
  29         setorigin(newmine, self.origin);
  30         setmodel(newmine, "models/mine.md3");
  31         newmine.angles = vectoangles(-trace_plane_normal); // face against the surface
  32
  33         newmine.takedamage = self.takedamage;
  34         newmine.damageforcescale = self.damageforcescale;
  35         newmine.health = self.health;
  36         newmine.event_damage = self.event_damage;
  37         newmine.spawnshieldtime = self.spawnshieldtime;
  38
  39         newmine.movetype = MOVETYPE_NONE; // lock the mine in place
  40         newmine.projectiledeathtype = self.projectiledeathtype;
  41
  42         newmine.mine_time = self.mine_time;
  43
  44         newmine.touch = SUB_Null;
  45         newmine.think = W_Mine_Think;
  46         newmine.nextthink = time;
  47         newmine.cnt = self.cnt;
  48         newmine.flags = self.flags;
  49
  50         remove(self);
  51         self = newmine;
  52 }
  53
  54 void W_Mine_Explode ()
  55 {
  56         if(other.takedamage == DAMAGE_AIM)
  57                 if(other.classname == "player")
  58                         if(IsDifferentTeam(self.owner, other))
  59                                 if(IsFlying(other))
  60                                         AnnounceTo(self.owner, "airshot");
  61
  62         self.event_damage = SUB_Null;
  63         self.takedamage = DAMAGE_NO;
  64
  65         RadiusDamage (self, self.owner, autocvar_g_balance_minelayer_damage, autocvar_g_balance_minelayer_edgedamage, autocvar_g_balance_minelayer_radius, world, autocvar_g_balance_minelayer_force, self.projectiledeathtype, other);
  66
  67         // this code causes some problems, and is not really needed since another check switches weapons when we're out of ammo
  68         /*if (self.owner.weapon == WEP_MINE_LAYER)
  69         {
  70                 if (!weapon_action(WEP_MINE_LAYER, WR_CHECKAMMO1))
  71                 {
  72                         self.owner.cnt = WEP_MINE_LAYER;
  73                         ATTACK_FINISHED(self.owner) = time;
  74                         self.owner.switchweapon = w_getbestweapon(self.owner);
  75                 }
  76         }*/
  77         self.owner.minelayer_mines -= 1;
  78         remove (self);
  79 }
  80
  81 void W_Mine_DoRemoteExplode ()
  82 {
  83         self.event_damage = SUB_Null;
  84         self.takedamage = DAMAGE_NO;
  85
  86         RadiusDamage (self, self.owner, autocvar_g_balance_minelayer_remote_damage, autocvar_g_balance_minelayer_remote_edgedamage, autocvar_g_balance_minelayer_remote_radius, world, autocvar_g_balance_minelayer_remote_force, self.projectiledeathtype | HITTYPE_BOUNCE, world);
  87
  88         // this code causes some problems, and is not really needed since another check switches weapons when we're out of ammo
  89         /*if (self.owner.weapon == WEP_MINE_LAYER)
  90         {
  91                 if (!weapon_action(WEP_MINE_LAYER, WR_CHECKAMMO1))
  92                 {
  93                         self.owner.cnt = WEP_MINE_LAYER;
  94                         ATTACK_FINISHED(self.owner) = time;
  95                         self.owner.switchweapon = w_getbestweapon(self.owner);
  96                 }
  97         }*/
  98         self.owner.minelayer_mines -= 1;
  99         remove (self);
 100 }
 101
 102 void W_Mine_RemoteExplode ()
 103 {
 104         if(self.owner.deadflag == DEAD_NO)
 105                 if((self.spawnshieldtime >= 0)
 106                         ? (time >= self.spawnshieldtime) // timer
 107                         : (vlen(NearestPointOnBox(self.owner, self.origin) - self.origin) > autocvar_g_balance_minelayer_remote_radius) // safety device
 108                 )
 109                 {
 110                         W_Mine_DoRemoteExplode();
 111                 }
 112 }
 113
 114 void W_Mine_ProximityExplode ()
 115 {
 116         // make sure no friend is in the mine's radius. If there is any, explosion is delayed until he's at a safe distance
 117         if(autocvar_g_balance_minelayer_protection && self.mine_explodeanyway == 0)
 118         {
 119                 entity head;
 120                 head = findradius(self.origin, autocvar_g_balance_minelayer_radius);
 121                 while(head)
 122                 {
 123                         if(head == self.owner || !IsDifferentTeam(head, self.owner))
 124                                 return;
 125                         head = head.chain;
 126                 }
 127         }
 128
 129         self.mine_time = 0;
 130         W_Mine_Explode();
 131 }
 132
 133 float W_Mine_Count(entity e)
 134 {
 135         float minecount;
 136         entity mine;
 137         for(mine = world; (mine = find(mine, classname, "mine")); ) if(mine.owner == e)
 138                 minecount += 1;
 139
 140         return minecount;
 141 }
 142
 143 void W_Mine_Think (void)
 144 {
 145         entity head;
 146
 147         self.nextthink = time;
 148
 149         // our lifetime has expired, it's time to die - mine_time just allows us to play a sound for this
 150         // TODO: replace this mine_trigger.wav sound with a real countdown
 151         if ((time > self.cnt) && (!self.mine_time))
 152         {
 153                 if(autocvar_g_balance_minelayer_lifetime_countdown > 0)
 154                         spamsound (self, CHAN_PROJECTILE, "weapons/mine_trigger.wav", VOL_BASE, ATTN_NORM);
 155                 self.mine_time = time + autocvar_g_balance_minelayer_lifetime_countdown;
 156                 self.mine_explodeanyway = 1; // make the mine super aggressive -- Samual: Rather, make it not care if a team mate is near.
 157         }
 158
 159         // a player's mines shall explode if he disconnects or dies
 160         // TODO: Do this on team change too -- Samual: But isn't a player killed when they switch teams?
 161         if(self.owner.classname != "player" || self.owner.deadflag != DEAD_NO)
 162         {
 163                 other = world;
 164                 self.projectiledeathtype |= HITTYPE_BOUNCE;
 165                 W_Mine_Explode();
 166                 return;
 167         }
 168
 169         // set the mine for detonation when a foe gets close enough
 170         head = findradius(self.origin, autocvar_g_balance_minelayer_proximityradius);
 171         while(head)
 172         {
 173                 if(head.classname == "player" && head.deadflag == DEAD_NO)
 174                 if(head != self.owner && IsDifferentTeam(head, self.owner)) // don't trigger for team mates
 175                 if(!self.mine_time)
 176                 {
 177                         spamsound (self, CHAN_PROJECTILE, "weapons/mine_trigger.wav", VOL_BASE, ATTN_NORM);
 178                         self.mine_time = time + autocvar_g_balance_minelayer_time;
 179                 }
 180                 head = head.chain;
 181         }
 182
 183         // explode if it's time to
 184         if(self.mine_time && time >= self.mine_time)
 185         {
 186                 W_Mine_ProximityExplode();
 187                 return;
 188         }
 189
 190         // remote detonation
 191         if (self.owner.weapon == WEP_MINE_LAYER)
 192         if (self.owner.deadflag == DEAD_NO)
 193         if (self.minelayer_detonate)
 194                 W_Mine_RemoteExplode();
 195 }
 196
 197 void W_Mine_Touch (void)
 198 {
 199         PROJECTILE_TOUCH;
 200         if(!other || (other.takedamage != DAMAGE_AIM && other.movetype == MOVETYPE_NONE))
 201                 W_Mine_Stick();
 202         else if(self.movetype != MOVETYPE_NONE) // don't unstick a locked mine when someone touches it
 203                 self.velocity = '0 0 0';
 204 }
 205
 206 void W_Mine_Damage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 207 {
 208         if (self.health <= 0)
 209                 return;
 210         self.health = self.health - damage;
 211         self.angles = vectoangles(self.velocity);
 212         if (self.health <= 0)
 213                 W_PrepareExplosionByDamage(attacker, W_Mine_Explode);
 214 }
 215
 216 void W_Mine_Attack (void)
 217 {
 218         entity mine;
 219         entity flash;
 220
 221         // scan how many mines we placed, and return if we reached our limit
 222         if(autocvar_g_balance_minelayer_limit)
 223         {
 224
 225                 if(W_Mine_Count(self) >= autocvar_g_balance_minelayer_limit)
 226                 {
 227                         // the refire delay keeps this message from being spammed
 228                         sprint(self, strcat("You cannot place more than ^2", ftos(autocvar_g_balance_minelayer_limit), " ^7mines at a time\n") );
 229                         play2(self, "weapons/unavailable.wav");
 230                         return;
 231                 }
 232         }
 233
 234         W_DecreaseAmmo(ammo_rockets, autocvar_g_balance_minelayer_ammo, autocvar_g_balance_minelayer_reload_ammo);
 235
 236         W_SetupShot_ProjectileSize (self, '-4 -4 -4', '4 4 4', FALSE, 5, "weapons/mine_fire.wav", CHAN_WEAPON, autocvar_g_balance_minelayer_damage);
 237         pointparticles(particleeffectnum("rocketlauncher_muzzleflash"), w_shotorg, w_shotdir * 1000, 1);
 238
 239         mine = WarpZone_RefSys_SpawnSameRefSys(self);
 240         mine.owner = self;
 241         if(autocvar_g_balance_minelayer_detonatedelay >= 0)
 242                 mine.spawnshieldtime = time + autocvar_g_balance_minelayer_detonatedelay;
 243         else
 244                 mine.spawnshieldtime = -1;
 245         mine.classname = "mine";
 246         mine.bot_dodge = TRUE;
 247         mine.bot_dodgerating = autocvar_g_balance_minelayer_damage * 2; // * 2 because it can detonate inflight which makes it even more dangerous
 248
 249         mine.takedamage = DAMAGE_YES;
 250         mine.damageforcescale = autocvar_g_balance_minelayer_damageforcescale;
 251         mine.health = autocvar_g_balance_minelayer_health;
 252         mine.event_damage = W_Mine_Damage;
 253
 254         mine.movetype = MOVETYPE_TOSS;
 255         PROJECTILE_MAKETRIGGER(mine);
 256         mine.projectiledeathtype = WEP_MINE_LAYER;
 257         setsize (mine, '-4 -4 -4', '4 4 4'); // give it some size so it can be shot
 258
 259         setorigin (mine, w_shotorg - v_forward * 4); // move it back so it hits the wall at the right point
 260         W_SetupProjectileVelocity(mine, autocvar_g_balance_minelayer_speed, 0);
 261         mine.angles = vectoangles (mine.velocity);
 262
 263         mine.touch = W_Mine_Touch;
 264         mine.think = W_Mine_Think;
 265         mine.nextthink = time;
 266         mine.cnt = time + (autocvar_g_balance_minelayer_lifetime - autocvar_g_balance_minelayer_lifetime_countdown);
 267         mine.flags = FL_PROJECTILE;
 268
 269         CSQCProjectile(mine, TRUE, PROJECTILE_MINE, TRUE);
 270
 271         // muzzle flash for 1st person view
 272         flash = spawn ();
 273         setmodel (flash, "models/flash.md3"); // precision set below
 274         SUB_SetFade (flash, time, 0.1);
 275         flash.effects = EF_ADDITIVE | EF_FULLBRIGHT | EF_LOWPRECISION;
 276         W_AttachToShotorg(flash, '5 0 0');
 277
 278         // common properties
 279
 280         other = mine; MUTATOR_CALLHOOK(EditProjectile);
 281
 282         self.minelayer_mines = W_Mine_Count(self);
 283 }
 284
 285 void spawnfunc_weapon_minelayer (void); // defined in t_items.qc
 286
 287 float W_PlacedMines(float detonate)
 288 {
 289         entity mine;
 290         float minfound;
 291
 292         for(mine = world; (mine = find(mine, classname, "mine")); ) if(mine.owner == self)
 293         {
 294                 if(detonate)
 295                 {
 296                         if(!mine.minelayer_detonate)
 297                         {
 298                                 mine.minelayer_detonate = TRUE;
 299                                 minfound = 1;
 300                         }
 301                 }
 302                 else
 303                         minfound = 1;
 304         }
 305         return minfound;
 306 }
 307
 308 float w_minelayer(float req)
 309 {
 310         entity mine;
 311         float ammo_amount;
 312
 313         if (req == WR_AIM)
 314         {
 315                 // aim and decide to fire if appropriate
 316                 self.BUTTON_ATCK = bot_aim(autocvar_g_balance_minelayer_speed, 0, autocvar_g_balance_minelayer_lifetime, FALSE);
 317                 if(skill >= 2) // skill 0 and 1 bots won't detonate mines!
 318                 {
 319                         // decide whether to detonate mines
 320                         entity targetlist, targ;
 321                         float edgedamage, coredamage, edgeradius, recipricoledgeradius, d;
 322                         float selfdamage, teamdamage, enemydamage;
 323                         edgedamage = autocvar_g_balance_minelayer_edgedamage;
 324                         coredamage = autocvar_g_balance_minelayer_damage;
 325                         edgeradius = autocvar_g_balance_minelayer_radius;
 326                         recipricoledgeradius = 1 / edgeradius;
 327                         selfdamage = 0;
 328                         teamdamage = 0;
 329                         enemydamage = 0;
 330                         targetlist = findchainfloat(bot_attack, TRUE);
 331                         mine = find(world, classname, "mine");
 332                         while (mine)
 333                         {
 334                                 if (mine.owner != self)
 335                                 {
 336                                         mine = find(mine, classname, "mine");
 337                                         continue;
 338                                 }
 339                                 targ = targetlist;
 340                                 while (targ)
 341                                 {
 342                                         d = vlen(targ.origin + (targ.mins + targ.maxs) * 0.5 - mine.origin);
 343                                         d = bound(0, edgedamage + (coredamage - edgedamage) * sqrt(1 - d * recipricoledgeradius), 10000);
 344                                         // count potential damage according to type of target
 345                                         if (targ == self)
 346                                                 selfdamage = selfdamage + d;
 347                                         else if (targ.team == self.team && teams_matter)
 348                                                 teamdamage = teamdamage + d;
 349                                         else if (bot_shouldattack(targ))
 350                                                 enemydamage = enemydamage + d;
 351                                         targ = targ.chain;
 352                                 }
 353                                 mine = find(mine, classname, "mine");
 354                         }
 355                         float desirabledamage;
 356                         desirabledamage = enemydamage;
 357                         if (time > self.invincible_finished && time > self.spawnshieldtime)
 358                                 desirabledamage = desirabledamage - selfdamage * autocvar_g_balance_selfdamagepercent;
 359                         if (teams_matter && self.team)
 360                                 desirabledamage = desirabledamage - teamdamage;
 361
 362                         mine = find(world, classname, "mine");
 363                         while (mine)
 364                         {
 365                                 if (mine.owner != self)
 366                                 {
 367                                         mine = find(mine, classname, "mine");
 368                                         continue;
 369                                 }
 370                                 makevectors(mine.v_angle);
 371                                 targ = targetlist;
 372                                 if (skill > 9) // normal players only do this for the target they are tracking
 373                                 {
 374                                         targ = targetlist;
 375                                         while (targ)
 376                                         {
 377                                                 if (
 378                                                         (v_forward * normalize(mine.origin - targ.origin)< 0.1)
 379                                                         && desirabledamage > 0.1*coredamage
 380                                                 )self.BUTTON_ATCK2 = TRUE;
 381                                                 targ = targ.chain;
 382                                         }
 383                                 }else{
 384                                         float distance; distance= bound(300,vlen(self.origin-self.enemy.origin),30000);
 385                                         //As the distance gets larger, a correct detonation gets near imposible
 386                                         //Bots are assumed to use the mine spawnfunc_light to see if the mine gets near a player
 387                                         if(v_forward * normalize(mine.origin - self.enemy.origin)< 0.1)
 388                                                 if(self.enemy.classname == "player")
 389                                                         if(desirabledamage >= 0.1*coredamage)
 390                                                                 if(random()/distance*300 > frametime*bound(0,(10-skill)*0.2,1))
 391                                                                         self.BUTTON_ATCK2 = TRUE;
 392                                 //      dprint(ftos(random()/distance*300),">");dprint(ftos(frametime*bound(0,(10-skill)*0.2,1)),"\n");
 393                                 }
 394
 395                                 mine = find(mine, classname, "mine");
 396                         }
 397                         // if we would be doing at X percent of the core damage, detonate it
 398                         // but don't fire a new shot at the same time!
 399                         if (desirabledamage >= 0.75 * coredamage) //this should do group damage in rare fortunate events
 400                                 self.BUTTON_ATCK2 = TRUE;
 401                         if ((skill > 6.5) && (selfdamage > self.health))
 402                                 self.BUTTON_ATCK2 = FALSE;
 403                         //if(self.BUTTON_ATCK2 == TRUE)
 404                         //      dprint(ftos(desirabledamage),"\n");
 405                         if (self.BUTTON_ATCK2 == TRUE) self.BUTTON_ATCK = FALSE;
 406                 }
 407         }
 408         else if (req == WR_THINK)
 409         {
 410                 if(autocvar_g_balance_minelayer_reload_ammo && self.clip_load < autocvar_g_balance_minelayer_ammo) // forced reload
 411                 {
 412                         // not if we're holding the minelayer without enough ammo, but can detonate existing mines
 413                         if not (W_PlacedMines(FALSE) && self.ammo_rockets < autocvar_g_balance_minelayer_ammo)
 414                                 weapon_action(self.weapon, WR_RELOAD);
 415                 }
 416                 else if (self.BUTTON_ATCK)
 417                 {
 418                         if(weapon_prepareattack(0, autocvar_g_balance_minelayer_refire))
 419                         {
 420                                 W_Mine_Attack();
 421                                 weapon_thinkf(WFRAME_FIRE1, autocvar_g_balance_minelayer_animtime, w_ready);
 422                         }
 423                 }
 424
 425                 if (self.BUTTON_ATCK2)
 426                 {
 427                         if(W_PlacedMines(TRUE))
 428                                 sound (self, CHAN_WEAPON2, "weapons/mine_det.wav", VOL_BASE, ATTN_NORM);
 429                 }
 430         }
 431         else if (req == WR_PRECACHE)
 432         {
 433                 precache_model ("models/flash.md3");
 434                 precache_model ("models/mine.md3");
 435                 precache_model ("models/weapons/g_minelayer.md3");
 436                 precache_model ("models/weapons/v_minelayer.md3");
 437                 precache_model ("models/weapons/h_minelayer.iqm");
 438                 precache_sound ("weapons/mine_det.wav");
 439                 precache_sound ("weapons/mine_fire.wav");
 440                 precache_sound ("weapons/mine_stick.wav");
 441                 precache_sound ("weapons/mine_trigger.wav");
 442                 //precache_sound ("weapons/reload.wav"); // until weapons have individual reload sounds, precache the reload sound somewhere else
 443         }
 444         else if (req == WR_SETUP)
 445         {
 446                 weapon_setup(WEP_MINE_LAYER);
 447                 self.current_ammo = ammo_rockets;
 448         }
 449         else if (req == WR_CHECKAMMO1)
 450         {
 451                 // don't switch while placing a mine
 452                 if (ATTACK_FINISHED(self) <= time || self.weapon != WEP_MINE_LAYER)
 453                 {
 454                         ammo_amount = self.ammo_rockets >= autocvar_g_balance_minelayer_ammo;
 455                         ammo_amount += self.weapon_load[WEP_MINE_LAYER] >= autocvar_g_balance_minelayer_ammo;
 456                         return ammo_amount;
 457                 }
 458         }
 459         else if (req == WR_CHECKAMMO2)
 460         {
 461                 if (W_PlacedMines(FALSE))
 462                         return TRUE;
 463                 else
 464                         return FALSE;
 465         }
 466         else if (req == WR_RELOAD)
 467         {
 468                 W_Reload(autocvar_g_balance_minelayer_ammo, autocvar_g_balance_minelayer_reload_ammo, autocvar_g_balance_minelayer_reload_time, "weapons/reload.wav");
 469         }
 470         return TRUE;
 471 };
 472 #endif
 473 #ifdef CSQC
 474 float w_minelayer(float req)
 475 {
 476         if(req == WR_IMPACTEFFECT)
 477         {
 478                 vector org2;
 479                 org2 = w_org + w_backoff * 12;
 480                 pointparticles(particleeffectnum("rocket_explode"), org2, '0 0 0', 1);
 481                 if(!w_issilent)
 482                         sound(self, CHAN_PROJECTILE, "weapons/mine_exp.wav", VOL_BASE, ATTN_NORM);
 483         }
 484         else if(req == WR_PRECACHE)
 485         {
 486                 precache_sound("weapons/mine_exp.wav");
 487         }
 488         else if (req == WR_SUICIDEMESSAGE)
 489                 w_deathtypestring = _("%s exploded");
 490         else if (req == WR_KILLMESSAGE)
 491         {
 492                 if(w_deathtype & HITTYPE_BOUNCE) // (remote detonation)
 493                         w_deathtypestring = _("%s got too close to %s's mine");
 494                 else if(w_deathtype & HITTYPE_SPLASH)
 495                         w_deathtypestring = _("%s almost dodged %s's mine");
 496                 else
 497                         w_deathtypestring = _("%s stepped on %s's mine");
 498         }
 499         return TRUE;
 500 }
 501 #endif
 502 #endif