qcsrc/server/w_minelayer.qc

   1 #ifdef REGISTER_WEAPON
   2 REGISTER_WEAPON(MINE_LAYER, w_minelayer, IT_ROCKETS, 4, WEP_FLAG_MUTATORBLOCKED | WEP_FLAG_RELOADABLE | WEP_TYPE_SPLASH, BOT_PICKUP_RATING_HIGH, "minelayer", "minelayer", _("Mine Layer"))
   3 #else
   4 #ifdef SVQC
   5 void W_Mine_Think (void);
   6 .float minelayer_detonate, mine_explodeanyway;
   7 .float mine_time;
   8 .vector mine_orientation;
   9
  10 void spawnfunc_weapon_minelayer (void)
  11 {
  12         weapon_defaultspawnfunc(WEP_MINE_LAYER);
  13 }
  14
  15 void W_Mine_Stick (entity to)
  16 {
  17         spamsound (self, CH_SHOTS, "weapons/mine_stick.wav", VOL_BASE, ATTN_NORM);
  18
  19         // in order for mines to face properly when sticking to the ground, they must be a server side entity rather than a csqc projectile
  20
  21         entity newmine;
  22         newmine = spawn();
  23         newmine.classname = self.classname;
  24
  25         newmine.bot_dodge = self.bot_dodge;
  26         newmine.bot_dodgerating = self.bot_dodgerating;
  27
  28         newmine.owner = self.owner;
  29         newmine.realowner = self.realowner;
  30         setsize(newmine, '-4 -4 -4', '4 4 4');
  31         setorigin(newmine, self.origin);
  32         setmodel(newmine, "models/mine.md3");
  33         newmine.angles = vectoangles(-trace_plane_normal); // face against the surface
  34
  35         newmine.mine_orientation = -trace_plane_normal;
  36
  37         newmine.takedamage = self.takedamage;
  38         newmine.damageforcescale = self.damageforcescale;
  39         newmine.health = self.health;
  40         newmine.event_damage = self.event_damage;
  41         newmine.spawnshieldtime = self.spawnshieldtime;
  42         newmine.damagedbycontents = TRUE;
  43
  44         newmine.movetype = MOVETYPE_NONE; // lock the mine in place
  45         newmine.projectiledeathtype = self.projectiledeathtype;
  46
  47         newmine.mine_time = self.mine_time;
  48
  49         newmine.touch = func_null;
  50         newmine.think = W_Mine_Think;
  51         newmine.nextthink = time;
  52         newmine.cnt = self.cnt;
  53         newmine.flags = self.flags;
  54
  55         remove(self);
  56         self = newmine;
  57
  58         if(to)
  59                 SetMovetypeFollow(self, to);
  60 }
  61
  62 void W_Mine_Explode ()
  63 {
  64         if(other.takedamage == DAMAGE_AIM)
  65                 if(other.classname == "player")
  66                         if(IsDifferentTeam(self.realowner, other))
  67                                 if(other.deadflag == DEAD_NO)
  68                                         if(IsFlying(other))
  69                                                 AnnounceTo(self.realowner, "airshot");
  70
  71         self.event_damage = func_null;
  72         self.takedamage = DAMAGE_NO;
  73
  74         RadiusDamage (self, self.realowner, autocvar_g_balance_minelayer_damage, autocvar_g_balance_minelayer_edgedamage, autocvar_g_balance_minelayer_radius, world, autocvar_g_balance_minelayer_force, self.projectiledeathtype, other);
  75
  76         if (self.realowner.weapon == WEP_MINE_LAYER)
  77         {
  78                 entity oldself;
  79                 oldself = self;
  80                 self = self.realowner;
  81                 if (!weapon_action(WEP_MINE_LAYER, WR_CHECKAMMO1))
  82                 {
  83                         self.cnt = WEP_MINE_LAYER;
  84                         ATTACK_FINISHED(self) = time;
  85                         self.switchweapon = w_getbestweapon(self);
  86                 }
  87                 self = oldself;
  88         }
  89         self.realowner.minelayer_mines -= 1;
  90         remove (self);
  91 }
  92
  93 void W_Mine_DoRemoteExplode ()
  94 {
  95         self.event_damage = func_null;
  96         self.takedamage = DAMAGE_NO;
  97
  98         if(self.movetype == MOVETYPE_NONE || self.movetype == MOVETYPE_FOLLOW)
  99                 self.velocity = self.mine_orientation; // particle fx and decals need .velocity
 100
 101         RadiusDamage (self, self.realowner, autocvar_g_balance_minelayer_remote_damage, autocvar_g_balance_minelayer_remote_edgedamage, autocvar_g_balance_minelayer_remote_radius, world, autocvar_g_balance_minelayer_remote_force, self.projectiledeathtype | HITTYPE_BOUNCE, world);
 102
 103         if (self.realowner.weapon == WEP_MINE_LAYER)
 104         {
 105                 entity oldself;
 106                 oldself = self;
 107                 self = self.realowner;
 108                 if (!weapon_action(WEP_MINE_LAYER, WR_CHECKAMMO1))
 109                 {
 110                         self.cnt = WEP_MINE_LAYER;
 111                         ATTACK_FINISHED(self) = time;
 112                         self.switchweapon = w_getbestweapon(self);
 113                 }
 114                 self = oldself;
 115         }
 116         self.realowner.minelayer_mines -= 1;
 117         remove (self);
 118 }
 119
 120 void W_Mine_RemoteExplode ()
 121 {
 122         if(self.realowner.deadflag == DEAD_NO)
 123                 if((self.spawnshieldtime >= 0)
 124                         ? (time >= self.spawnshieldtime) // timer
 125                         : (vlen(NearestPointOnBox(self.realowner, self.origin) - self.origin) > autocvar_g_balance_minelayer_remote_radius) // safety device
 126                 )
 127                 {
 128                         W_Mine_DoRemoteExplode();
 129                 }
 130 }
 131
 132 void W_Mine_ProximityExplode ()
 133 {
 134         // make sure no friend is in the mine's radius. If there is any, explosion is delayed until he's at a safe distance
 135         if(autocvar_g_balance_minelayer_protection && self.mine_explodeanyway == 0)
 136         {
 137                 entity head;
 138                 head = findradius(self.origin, autocvar_g_balance_minelayer_radius);
 139                 while(head)
 140                 {
 141                         if(head == self.realowner || !IsDifferentTeam(head, self.realowner))
 142                                 return;
 143                         head = head.chain;
 144                 }
 145         }
 146
 147         self.mine_time = 0;
 148         W_Mine_Explode();
 149 }
 150
 151 float W_Mine_Count(entity e)
 152 {
 153         float minecount = 0;
 154         entity mine;
 155         for(mine = world; (mine = find(mine, classname, "mine")); ) if(mine.realowner == e)
 156                 minecount += 1;
 157
 158         return minecount;
 159 }
 160
 161 void W_Mine_Think (void)
 162 {
 163         entity head;
 164
 165         self.nextthink = time;
 166
 167         if(self.movetype == MOVETYPE_FOLLOW)
 168         {
 169                 if(LostMovetypeFollow(self))
 170                 {
 171                         UnsetMovetypeFollow(self);
 172                         self.movetype = MOVETYPE_NONE;
 173                 }
 174         }
 175
 176         // our lifetime has expired, it's time to die - mine_time just allows us to play a sound for this
 177         // TODO: replace this mine_trigger.wav sound with a real countdown
 178         if ((time > self.cnt) && (!self.mine_time))
 179         {
 180                 if(autocvar_g_balance_minelayer_lifetime_countdown > 0)
 181                         spamsound (self, CH_SHOTS, "weapons/mine_trigger.wav", VOL_BASE, ATTN_NORM);
 182                 self.mine_time = time + autocvar_g_balance_minelayer_lifetime_countdown;
 183                 self.mine_explodeanyway = 1; // make the mine super aggressive -- Samual: Rather, make it not care if a team mate is near.
 184         }
 185
 186         // a player's mines shall explode if he disconnects or dies
 187         // TODO: Do this on team change too -- Samual: But isn't a player killed when they switch teams?
 188         if(self.realowner.classname != "player" || self.realowner.deadflag != DEAD_NO)
 189         {
 190                 other = world;
 191                 self.projectiledeathtype |= HITTYPE_BOUNCE;
 192                 W_Mine_Explode();
 193                 return;
 194         }
 195
 196         // set the mine for detonation when a foe gets close enough
 197         head = findradius(self.origin, autocvar_g_balance_minelayer_proximityradius);
 198         while(head)
 199         {
 200                 if(head.classname == "player" && head.deadflag == DEAD_NO)
 201                 if(head != self.realowner && IsDifferentTeam(head, self.realowner)) // don't trigger for team mates
 202                 if(!self.mine_time)
 203                 {
 204                         spamsound (self, CH_SHOTS, "weapons/mine_trigger.wav", VOL_BASE, ATTN_NORM);
 205                         self.mine_time = time + autocvar_g_balance_minelayer_time;
 206                 }
 207                 head = head.chain;
 208         }
 209
 210         // explode if it's time to
 211         if(self.mine_time && time >= self.mine_time)
 212         {
 213                 W_Mine_ProximityExplode();
 214                 return;
 215         }
 216
 217         // remote detonation
 218         if (self.realowner.weapon == WEP_MINE_LAYER)
 219         if (self.realowner.deadflag == DEAD_NO)
 220         if (self.minelayer_detonate)
 221                 W_Mine_RemoteExplode();
 222 }
 223
 224 void W_Mine_Touch (void)
 225 {
 226         if(self.movetype == MOVETYPE_NONE || self.movetype == MOVETYPE_FOLLOW)
 227                 return; // we're already a stuck mine, why do we get called? TODO does this even happen?
 228
 229         PROJECTILE_TOUCH;
 230
 231         if(other && other.classname == "player" && other.deadflag == DEAD_NO)
 232         {
 233                 // hit a player
 234                 // don't stick
 235         }
 236         else
 237         {
 238                 W_Mine_Stick(other);
 239         }
 240 }
 241
 242 void W_Mine_Damage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 243 {
 244         if (self.health <= 0)
 245                 return;
 246
 247         float is_from_enemy = (inflictor.realowner != self.realowner);
 248
 249         if (!W_CheckProjectileDamage(inflictor.realowner, self.realowner, deathtype, (is_from_enemy ? 1 : -1)))
 250                 return; // g_projectiles_damage says to halt
 251
 252         self.health = self.health - damage;
 253         self.angles = vectoangles(self.velocity);
 254
 255         if (self.health <= 0)
 256                 W_PrepareExplosionByDamage(attacker, W_Mine_Explode);
 257 }
 258
 259 void W_Mine_Attack (void)
 260 {
 261         entity mine;
 262         entity flash;
 263
 264         // scan how many mines we placed, and return if we reached our limit
 265         if(autocvar_g_balance_minelayer_limit)
 266         {
 267                 if(self.minelayer_mines >= autocvar_g_balance_minelayer_limit)
 268                 {
 269                         // the refire delay keeps this message from being spammed
 270                         sprint(self, strcat("minelayer: You cannot place more than ^2", ftos(autocvar_g_balance_minelayer_limit), " ^7mines at a time\n") );
 271                         play2(self, "weapons/unavailable.wav");
 272                         return;
 273                 }
 274         }
 275
 276         W_DecreaseAmmo(ammo_rockets, autocvar_g_balance_minelayer_ammo, autocvar_g_balance_minelayer_reload_ammo);
 277
 278         W_SetupShot_ProjectileSize (self, '-4 -4 -4', '4 4 4', FALSE, 5, "weapons/mine_fire.wav", CH_WEAPON_A, autocvar_g_balance_minelayer_damage);
 279         pointparticles(particleeffectnum("rocketlauncher_muzzleflash"), w_shotorg, w_shotdir * 1000, 1);
 280
 281         mine = WarpZone_RefSys_SpawnSameRefSys(self);
 282         mine.owner = mine.realowner = self;
 283         if(autocvar_g_balance_minelayer_detonatedelay >= 0)
 284                 mine.spawnshieldtime = time + autocvar_g_balance_minelayer_detonatedelay;
 285         else
 286                 mine.spawnshieldtime = -1;
 287         mine.classname = "mine";
 288         mine.bot_dodge = TRUE;
 289         mine.bot_dodgerating = autocvar_g_balance_minelayer_damage * 2; // * 2 because it can detonate inflight which makes it even more dangerous
 290
 291         mine.takedamage = DAMAGE_YES;
 292         mine.damageforcescale = autocvar_g_balance_minelayer_damageforcescale;
 293         mine.health = autocvar_g_balance_minelayer_health;
 294         mine.event_damage = W_Mine_Damage;
 295         mine.damagedbycontents = TRUE;
 296
 297         mine.movetype = MOVETYPE_TOSS;
 298         PROJECTILE_MAKETRIGGER(mine);
 299         mine.projectiledeathtype = WEP_MINE_LAYER;
 300         setsize (mine, '-4 -4 -4', '4 4 4'); // give it some size so it can be shot
 301
 302         setorigin (mine, w_shotorg - v_forward * 4); // move it back so it hits the wall at the right point
 303         W_SetupProjectileVelocity(mine, autocvar_g_balance_minelayer_speed, 0);
 304         mine.angles = vectoangles (mine.velocity);
 305
 306         mine.touch = W_Mine_Touch;
 307         mine.think = W_Mine_Think;
 308         mine.nextthink = time;
 309         mine.cnt = time + (autocvar_g_balance_minelayer_lifetime - autocvar_g_balance_minelayer_lifetime_countdown);
 310         mine.flags = FL_PROJECTILE;
 311         mine.missile_flags = MIF_SPLASH | MIF_ARC | MIF_PROXY;
 312
 313         CSQCProjectile(mine, TRUE, PROJECTILE_MINE, TRUE);
 314
 315         // muzzle flash for 1st person view
 316         flash = spawn ();
 317         setmodel (flash, "models/flash.md3"); // precision set below
 318         SUB_SetFade (flash, time, 0.1);
 319         flash.effects = EF_ADDITIVE | EF_FULLBRIGHT | EF_LOWPRECISION;
 320         W_AttachToShotorg(flash, '5 0 0');
 321
 322         // common properties
 323
 324         other = mine; MUTATOR_CALLHOOK(EditProjectile);
 325
 326         self.minelayer_mines = W_Mine_Count(self);
 327 }
 328
 329 float W_PlacedMines(float detonate)
 330 {
 331         entity mine;
 332         float minfound = 0;
 333
 334         for(mine = world; (mine = find(mine, classname, "mine")); ) if(mine.realowner == self)
 335         {
 336                 if(detonate)
 337                 {
 338                         if(!mine.minelayer_detonate)
 339                         {
 340                                 mine.minelayer_detonate = TRUE;
 341                                 minfound = 1;
 342                         }
 343                 }
 344                 else
 345                         minfound = 1;
 346         }
 347         return minfound;
 348 }
 349
 350 float w_minelayer(float req)
 351 {
 352         entity mine;
 353         float ammo_amount;
 354
 355         if (req == WR_AIM)
 356         {
 357                 // aim and decide to fire if appropriate
 358                 if(self.minelayer_mines >= autocvar_g_balance_minelayer_limit)
 359                         self.BUTTON_ATCK = FALSE;
 360                 else
 361                         self.BUTTON_ATCK = bot_aim(autocvar_g_balance_minelayer_speed, 0, autocvar_g_balance_minelayer_lifetime, FALSE);
 362                 if(skill >= 2) // skill 0 and 1 bots won't detonate mines!
 363                 {
 364                         // decide whether to detonate mines
 365                         entity targetlist, targ;
 366                         float edgedamage, coredamage, edgeradius, recipricoledgeradius, d;
 367                         float selfdamage, teamdamage, enemydamage;
 368                         edgedamage = autocvar_g_balance_minelayer_edgedamage;
 369                         coredamage = autocvar_g_balance_minelayer_damage;
 370                         edgeradius = autocvar_g_balance_minelayer_radius;
 371                         recipricoledgeradius = 1 / edgeradius;
 372                         selfdamage = 0;
 373                         teamdamage = 0;
 374                         enemydamage = 0;
 375                         targetlist = findchainfloat(bot_attack, TRUE);
 376                         mine = find(world, classname, "mine");
 377                         while (mine)
 378                         {
 379                                 if (mine.realowner != self)
 380                                 {
 381                                         mine = find(mine, classname, "mine");
 382                                         continue;
 383                                 }
 384                                 targ = targetlist;
 385                                 while (targ)
 386                                 {
 387                                         d = vlen(targ.origin + (targ.mins + targ.maxs) * 0.5 - mine.origin);
 388                                         d = bound(0, edgedamage + (coredamage - edgedamage) * sqrt(1 - d * recipricoledgeradius), 10000);
 389                                         // count potential damage according to type of target
 390                                         if (targ == self)
 391                                                 selfdamage = selfdamage + d;
 392                                         else if (targ.team == self.team && teamplay)
 393                                                 teamdamage = teamdamage + d;
 394                                         else if (bot_shouldattack(targ))
 395                                                 enemydamage = enemydamage + d;
 396                                         targ = targ.chain;
 397                                 }
 398                                 mine = find(mine, classname, "mine");
 399                         }
 400                         float desirabledamage;
 401                         desirabledamage = enemydamage;
 402                         if (time > self.invincible_finished && time > self.spawnshieldtime)
 403                                 desirabledamage = desirabledamage - selfdamage * autocvar_g_balance_selfdamagepercent;
 404                         if (teamplay && self.team)
 405                                 desirabledamage = desirabledamage - teamdamage;
 406
 407                         mine = find(world, classname, "mine");
 408                         while (mine)
 409                         {
 410                                 if (mine.realowner != self)
 411                                 {
 412                                         mine = find(mine, classname, "mine");
 413                                         continue;
 414                                 }
 415                                 makevectors(mine.v_angle);
 416                                 targ = targetlist;
 417                                 if (skill > 9) // normal players only do this for the target they are tracking
 418                                 {
 419                                         targ = targetlist;
 420                                         while (targ)
 421                                         {
 422                                                 if (
 423                                                         (v_forward * normalize(mine.origin - targ.origin)< 0.1)
 424                                                         && desirabledamage > 0.1*coredamage
 425                                                 )self.BUTTON_ATCK2 = TRUE;
 426                                                 targ = targ.chain;
 427                                         }
 428                                 }else{
 429                                         float distance; distance= bound(300,vlen(self.origin-self.enemy.origin),30000);
 430                                         //As the distance gets larger, a correct detonation gets near imposible
 431                                         //Bots are assumed to use the mine spawnfunc_light to see if the mine gets near a player
 432                                         if(v_forward * normalize(mine.origin - self.enemy.origin)< 0.1)
 433                                                 if(self.enemy.classname == "player")
 434                                                         if(desirabledamage >= 0.1*coredamage)
 435                                                                 if(random()/distance*300 > frametime*bound(0,(10-skill)*0.2,1))
 436                                                                         self.BUTTON_ATCK2 = TRUE;
 437                                 //      dprint(ftos(random()/distance*300),">");dprint(ftos(frametime*bound(0,(10-skill)*0.2,1)),"\n");
 438                                 }
 439
 440                                 mine = find(mine, classname, "mine");
 441                         }
 442                         // if we would be doing at X percent of the core damage, detonate it
 443                         // but don't fire a new shot at the same time!
 444                         if (desirabledamage >= 0.75 * coredamage) //this should do group damage in rare fortunate events
 445                                 self.BUTTON_ATCK2 = TRUE;
 446                         if ((skill > 6.5) && (selfdamage > self.health))
 447                                 self.BUTTON_ATCK2 = FALSE;
 448                         //if(self.BUTTON_ATCK2 == TRUE)
 449                         //      dprint(ftos(desirabledamage),"\n");
 450                         if (self.BUTTON_ATCK2 == TRUE) self.BUTTON_ATCK = FALSE;
 451                 }
 452         }
 453         else if (req == WR_THINK)
 454         {
 455                 if(autocvar_g_balance_minelayer_reload_ammo && self.clip_load < autocvar_g_balance_minelayer_ammo) // forced reload
 456                 {
 457                         // not if we're holding the minelayer without enough ammo, but can detonate existing mines
 458                         if not (W_PlacedMines(FALSE) && self.ammo_rockets < autocvar_g_balance_minelayer_ammo)
 459                                 weapon_action(self.weapon, WR_RELOAD);
 460                 }
 461                 else if (self.BUTTON_ATCK)
 462                 {
 463                         if(weapon_prepareattack(0, autocvar_g_balance_minelayer_refire))
 464                         {
 465                                 W_Mine_Attack();
 466                                 weapon_thinkf(WFRAME_FIRE1, autocvar_g_balance_minelayer_animtime, w_ready);
 467                         }
 468                 }
 469
 470                 if (self.BUTTON_ATCK2)
 471                 {
 472                         if(W_PlacedMines(TRUE))
 473                                 sound (self, CH_WEAPON_B, "weapons/mine_det.wav", VOL_BASE, ATTN_NORM);
 474                 }
 475         }
 476         else if (req == WR_PRECACHE)
 477         {
 478                 precache_model ("models/flash.md3");
 479                 precache_model ("models/mine.md3");
 480                 precache_model ("models/weapons/g_minelayer.md3");
 481                 precache_model ("models/weapons/v_minelayer.md3");
 482                 precache_model ("models/weapons/h_minelayer.iqm");
 483                 precache_sound ("weapons/mine_det.wav");
 484                 precache_sound ("weapons/mine_fire.wav");
 485                 precache_sound ("weapons/mine_stick.wav");
 486                 precache_sound ("weapons/mine_trigger.wav");
 487                 //precache_sound ("weapons/reload.wav"); // until weapons have individual reload sounds, precache the reload sound somewhere else
 488         }
 489         else if (req == WR_SETUP)
 490         {
 491                 weapon_setup(WEP_MINE_LAYER);
 492                 self.current_ammo = ammo_rockets;
 493         }
 494         else if (req == WR_CHECKAMMO1)
 495         {
 496                 // don't switch while placing a mine
 497                 if (ATTACK_FINISHED(self) <= time || self.weapon != WEP_MINE_LAYER)
 498                 {
 499                         ammo_amount = self.ammo_rockets >= autocvar_g_balance_minelayer_ammo;
 500                         ammo_amount += self.(weapon_load[WEP_MINE_LAYER]) >= autocvar_g_balance_minelayer_ammo;
 501                         return ammo_amount;
 502                 }
 503         }
 504         else if (req == WR_CHECKAMMO2)
 505         {
 506                 if (W_PlacedMines(FALSE))
 507                         return TRUE;
 508                 else
 509                         return FALSE;
 510         }
 511         else if (req == WR_RELOAD)
 512         {
 513                 W_Reload(autocvar_g_balance_minelayer_ammo, autocvar_g_balance_minelayer_reload_ammo, autocvar_g_balance_minelayer_reload_time, "weapons/reload.wav");
 514         }
 515         return TRUE;
 516 }
 517 #endif
 518 #ifdef CSQC
 519 float w_minelayer(float req)
 520 {
 521         if(req == WR_IMPACTEFFECT)
 522         {
 523                 vector org2;
 524                 org2 = w_org + w_backoff * 12;
 525                 pointparticles(particleeffectnum("rocket_explode"), org2, '0 0 0', 1);
 526                 if(!w_issilent)
 527                         sound(self, CH_SHOTS, "weapons/mine_exp.wav", VOL_BASE, ATTN_NORM);
 528         }
 529         else if(req == WR_PRECACHE)
 530         {
 531                 precache_sound("weapons/mine_exp.wav");
 532         }
 533         else if (req == WR_SUICIDEMESSAGE)
 534                 if(w_deathtype & HITTYPE_BOUNCE) // (remote detonation)
 535                         w_deathtypestring = _("%s blew themself up with their minelayer");
 536                 else
 537                         w_deathtypestring = _("%s forgot about their mine");
 538         else if (req == WR_KILLMESSAGE)
 539         {
 540                 if(w_deathtype & HITTYPE_BOUNCE) // (remote detonation)
 541                         w_deathtypestring = _("%s got too close to %s's mine");
 542                 else if(w_deathtype & HITTYPE_SPLASH)
 543                         w_deathtypestring = _("%s almost dodged %s's mine");
 544                 else
 545                         w_deathtypestring = _("%s stepped on %s's mine");
 546         }
 547         return TRUE;
 548 }
 549 #endif
 550 #endif