qcsrc/server/w_minelayer.qc

   1 #ifdef REGISTER_WEAPON
   2 REGISTER_WEAPON(MINE_LAYER, w_minelayer, IT_ROCKETS, 4, WEP_TYPE_SPLASH, BOT_PICKUP_RATING_HIGH, "minelayer", "minelayer", _("Mine Layer"))
   3 #else
   4 #ifdef SVQC
   5 void W_Mine_Think (void);
   6 .float minelayer_detonate, minelayer_mines;
   7 .float mine_time;
   8
   9 // weapon load persistence, for weapons that support reloading
  10 .float minelayer_load;
  11
  12 void W_MineLayer_SetAmmoCounter()
  13 {
  14         // set clip_load to the weapon we have switched to, if the gun uses reloading
  15         if(!autocvar_g_balance_minelayer_reload_ammo)
  16                 self.clip_load = 0; // also keeps crosshair ammo from displaying
  17         else
  18         {
  19                 self.clip_load = self.minelayer_load;
  20                 self.clip_size = autocvar_g_balance_minelayer_reload_ammo; // for the crosshair ammo display
  21         }
  22 }
  23
  24 void W_MineLayer_Reload()
  25 {
  26         self.reload_ammo_player = ammo_fuel;
  27         self.reload_ammo_min = autocvar_g_balance_minelayer_ammo;
  28         self.reload_ammo_amount = autocvar_g_balance_minelayer_reload_ammo;
  29         self.reload_time = autocvar_g_balance_minelayer_reload_time;
  30         self.reload_sound = "weapons/reload.wav";
  31
  32         W_Reload();
  33 }
  34
  35 void spawnfunc_weapon_minelayer (void)
  36 {
  37         weapon_defaultspawnfunc(WEP_MINE_LAYER);
  38 }
  39
  40 void W_Mine_Stick ()
  41 {
  42         spamsound (self, CHAN_PROJECTILE, "weapons/mine_stick.wav", VOL_BASE, ATTN_NORM);
  43
  44         // in order for mines to face properly when sticking to the ground, they must be a server side entity rather than a csqc projectile
  45
  46         entity newmine;
  47         newmine = spawn();
  48         newmine.classname = self.classname;
  49
  50         newmine.bot_dodge = self.bot_dodge;
  51         newmine.bot_dodgerating = self.bot_dodgerating;
  52
  53         newmine.owner = self.owner;
  54         setsize(newmine, '-4 -4 -4', '4 4 4');
  55         setorigin(newmine, self.origin);
  56         setmodel(newmine, "models/mine.md3");
  57         newmine.angles = vectoangles(-trace_plane_normal); // face against the surface
  58
  59         newmine.takedamage = self.takedamage;
  60         newmine.damageforcescale = self.damageforcescale;
  61         newmine.health = self.health;
  62         newmine.event_damage = self.event_damage;
  63         newmine.spawnshieldtime = self.spawnshieldtime;
  64
  65         newmine.movetype = MOVETYPE_NONE; // lock the mine in place
  66         newmine.projectiledeathtype = self.projectiledeathtype;
  67
  68         newmine.mine_time = self.mine_time;
  69
  70         newmine.touch = SUB_Null;
  71         newmine.think = W_Mine_Think;
  72         newmine.nextthink = time;
  73         newmine.cnt = self.cnt;
  74         newmine.flags = self.flags;
  75
  76         remove(self);
  77         self = newmine;
  78 }
  79
  80 void W_Mine_Explode ()
  81 {
  82         if(other.takedamage == DAMAGE_AIM)
  83                 if(other.classname == "player")
  84                         if(IsDifferentTeam(self.owner, other))
  85                                 if(IsFlying(other))
  86                                         AnnounceTo(self.owner, "airshot");
  87
  88         self.event_damage = SUB_Null;
  89         self.takedamage = DAMAGE_NO;
  90
  91         RadiusDamage (self, self.owner, autocvar_g_balance_minelayer_damage, autocvar_g_balance_minelayer_edgedamage, autocvar_g_balance_minelayer_radius, world, autocvar_g_balance_minelayer_force, self.projectiledeathtype, other);
  92
  93         if (self.owner.weapon == WEP_MINE_LAYER)
  94         {
  95                 if(self.owner.ammo_rockets < autocvar_g_balance_minelayer_ammo)
  96                 {
  97                         self.owner.cnt = WEP_MINE_LAYER;
  98                         ATTACK_FINISHED(self.owner) = time;
  99                         self.owner.switchweapon = w_getbestweapon(self.owner);
 100                 }
 101         }
 102         remove (self);
 103 }
 104
 105 void W_Mine_DoRemoteExplode ()
 106 {
 107         self.event_damage = SUB_Null;
 108         self.takedamage = DAMAGE_NO;
 109
 110         RadiusDamage (self, self.owner, autocvar_g_balance_minelayer_remote_damage, autocvar_g_balance_minelayer_remote_edgedamage, autocvar_g_balance_minelayer_remote_radius, world, autocvar_g_balance_minelayer_remote_force, self.projectiledeathtype | HITTYPE_BOUNCE, world);
 111
 112         if (self.owner.weapon == WEP_MINE_LAYER)
 113         {
 114                 if(self.owner.ammo_rockets < autocvar_g_balance_minelayer_ammo)
 115                 {
 116                         self.owner.cnt = WEP_MINE_LAYER;
 117                         ATTACK_FINISHED(self.owner) = time;
 118                         self.owner.switchweapon = w_getbestweapon(self.owner);
 119                 }
 120         }
 121         remove (self);
 122 }
 123
 124 void W_Mine_RemoteExplode ()
 125 {
 126         if(self.owner.deadflag == DEAD_NO)
 127                 if((self.spawnshieldtime >= 0)
 128                         ? (time >= self.spawnshieldtime) // timer
 129                         : (vlen(NearestPointOnBox(self.owner, self.origin) - self.origin) > autocvar_g_balance_minelayer_remote_radius) // safety device
 130                 )
 131                 {
 132                         W_Mine_DoRemoteExplode();
 133                 }
 134 }
 135
 136 void W_Mine_ProximityExplode ()
 137 {
 138         // make sure no friend is in the mine's radius. If there is any, explosion is delayed until he's at a safe distance
 139         if(autocvar_g_balance_minelayer_protection)
 140         {
 141                 entity head;
 142                 head = findradius(self.origin, autocvar_g_balance_minelayer_radius);
 143                 while(head)
 144                 {
 145                         if(head == self.owner || !IsDifferentTeam(head, self.owner))
 146                                 return;
 147                         head = head.chain;
 148                 }
 149         }
 150
 151         self.mine_time = 0;
 152         W_Mine_Explode();
 153 }
 154
 155 void W_Mine_Think (void)
 156 {
 157         entity head;
 158
 159         self.nextthink = time;
 160         if (time > self.cnt)
 161         {
 162                 other = world;
 163                 self.projectiledeathtype |= HITTYPE_BOUNCE;
 164                 W_Mine_Explode();
 165                 return;
 166         }
 167
 168         // a player's mines shall explode if he disconnects or dies
 169         // TODO: Do this on team change too
 170         if(self.owner.classname != "player" || self.owner.deadflag != DEAD_NO)
 171         {
 172                 other = world;
 173                 self.projectiledeathtype |= HITTYPE_BOUNCE;
 174                 W_Mine_Explode();
 175                 return;
 176         }
 177
 178         // set the mine for detonation when a foe gets close enough
 179         head = findradius(self.origin, autocvar_g_balance_minelayer_proximityradius);
 180         while(head)
 181         {
 182                 if(head.classname == "player" && head.deadflag == DEAD_NO)
 183                 if(head != self.owner && IsDifferentTeam(head, self.owner)) // don't trigger for team mates
 184                 if(!self.mine_time)
 185                 {
 186                         spamsound (self, CHAN_PROJECTILE, "weapons/mine_trigger.wav", VOL_BASE, ATTN_NORM);
 187                         self.mine_time = time + autocvar_g_balance_minelayer_time;
 188                 }
 189                 head = head.chain;
 190         }
 191
 192         // explode if it's time to
 193         if(self.mine_time && time >= self.mine_time)
 194                 W_Mine_ProximityExplode();
 195
 196         // remote detonation
 197         if (self.owner.weapon == WEP_MINE_LAYER)
 198         if (self.owner.deadflag == DEAD_NO)
 199         if (self.minelayer_detonate)
 200                 W_Mine_RemoteExplode();
 201 }
 202
 203 void W_Mine_Touch (void)
 204 {
 205         PROJECTILE_TOUCH;
 206         if(!other || (other.takedamage != DAMAGE_AIM && other.movetype == MOVETYPE_NONE))
 207                 W_Mine_Stick();
 208         else if(self.movetype != MOVETYPE_NONE) // don't unstick a locked mine when someone touches it
 209                 self.velocity = '0 0 0';
 210 }
 211
 212 void W_Mine_Damage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 213 {
 214         if (self.health <= 0)
 215                 return;
 216         self.health = self.health - damage;
 217         self.angles = vectoangles(self.velocity);
 218         if (self.health <= 0)
 219                 W_PrepareExplosionByDamage(attacker, W_Mine_Explode);
 220 }
 221
 222 void W_Mine_Attack (void)
 223 {
 224         entity mine;
 225         entity flash;
 226
 227         // scan how many mines we placed, and return if we reached our limit
 228         if(autocvar_g_balance_minelayer_limit)
 229         {
 230                 self.minelayer_mines = 0;
 231                 for(mine = world; (mine = find(mine, classname, "mine")); ) if(mine.owner == self)
 232                         self.minelayer_mines += 1;
 233
 234                 if(self.minelayer_mines >= autocvar_g_balance_minelayer_limit)
 235                 {
 236                         // the refire delay keeps this message from being spammed
 237                         sprint(self, strcat("You cannot place more than ^2", ftos(autocvar_g_balance_minelayer_limit), " ^7mines at a time\n") );
 238                         play2(self, "weapons/unavailable.wav");
 239                         return;
 240                 }
 241         }
 242
 243         // if this weapon is reloadable, decrease its load. Else decrease the player's ammo
 244         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
 245         {
 246                 if(autocvar_g_balance_minelayer_reload_ammo)
 247                 {
 248                         self.clip_load -= autocvar_g_balance_minelayer_ammo;
 249                         self.minelayer_load = self.clip_load;
 250                 }
 251                 else
 252                         self.ammo_rockets -= autocvar_g_balance_minelayer_ammo;
 253         }
 254
 255         W_SetupShot_ProjectileSize (self, '-4 -4 -4', '4 4 4', FALSE, 5, "weapons/mine_fire.wav", CHAN_WEAPON, autocvar_g_balance_minelayer_damage);
 256         pointparticles(particleeffectnum("rocketlauncher_muzzleflash"), w_shotorg, w_shotdir * 1000, 1);
 257
 258         mine = WarpZone_RefSys_SpawnSameRefSys(self);
 259         mine.owner = self;
 260         if(autocvar_g_balance_minelayer_detonatedelay >= 0)
 261                 mine.spawnshieldtime = time + autocvar_g_balance_minelayer_detonatedelay;
 262         else
 263                 mine.spawnshieldtime = -1;
 264         mine.classname = "mine";
 265         mine.bot_dodge = TRUE;
 266         mine.bot_dodgerating = autocvar_g_balance_minelayer_damage * 2; // * 2 because it can detonate inflight which makes it even more dangerous
 267
 268         mine.takedamage = DAMAGE_YES;
 269         mine.damageforcescale = autocvar_g_balance_minelayer_damageforcescale;
 270         mine.health = autocvar_g_balance_minelayer_health;
 271         mine.event_damage = W_Mine_Damage;
 272
 273         mine.movetype = MOVETYPE_TOSS;
 274         PROJECTILE_MAKETRIGGER(mine);
 275         mine.projectiledeathtype = WEP_MINE_LAYER;
 276         setsize (mine, '-4 -4 -4', '4 4 4'); // give it some size so it can be shot
 277
 278         setorigin (mine, w_shotorg - v_forward * 4); // move it back so it hits the wall at the right point
 279         W_SetupProjectileVelocity(mine, autocvar_g_balance_minelayer_speed, 0);
 280         mine.angles = vectoangles (mine.velocity);
 281
 282         mine.touch = W_Mine_Touch;
 283         mine.think = W_Mine_Think;
 284         mine.nextthink = time;
 285         mine.cnt = time + autocvar_g_balance_minelayer_lifetime;
 286         mine.flags = FL_PROJECTILE;
 287
 288         CSQCProjectile(mine, TRUE, PROJECTILE_MINE, TRUE);
 289
 290         // muzzle flash for 1st person view
 291         flash = spawn ();
 292         setmodel (flash, "models/flash.md3"); // precision set below
 293         SUB_SetFade (flash, time, 0.1);
 294         flash.effects = EF_ADDITIVE | EF_FULLBRIGHT | EF_LOWPRECISION;
 295         W_AttachToShotorg(flash, '5 0 0');
 296
 297         // common properties
 298
 299         other = mine; MUTATOR_CALLHOOK(EditProjectile);
 300 }
 301
 302 void spawnfunc_weapon_minelayer (void); // defined in t_items.qc
 303
 304 float w_minelayer(float req)
 305 {
 306         entity mine;
 307         float minfound;
 308         float ammo_amount;
 309
 310         if (req == WR_AIM)
 311         {
 312                 // aim and decide to fire if appropriate
 313                 self.BUTTON_ATCK = bot_aim(autocvar_g_balance_minelayer_speed, 0, autocvar_g_balance_minelayer_lifetime, FALSE);
 314                 if(skill >= 2) // skill 0 and 1 bots won't detonate mines!
 315                 {
 316                         // decide whether to detonate mines
 317                         entity targetlist, targ;
 318                         float edgedamage, coredamage, edgeradius, recipricoledgeradius, d;
 319                         float selfdamage, teamdamage, enemydamage;
 320                         edgedamage = autocvar_g_balance_minelayer_edgedamage;
 321                         coredamage = autocvar_g_balance_minelayer_damage;
 322                         edgeradius = autocvar_g_balance_minelayer_radius;
 323                         recipricoledgeradius = 1 / edgeradius;
 324                         selfdamage = 0;
 325                         teamdamage = 0;
 326                         enemydamage = 0;
 327                         targetlist = findchainfloat(bot_attack, TRUE);
 328                         mine = find(world, classname, "mine");
 329                         while (mine)
 330                         {
 331                                 if (mine.owner != self)
 332                                 {
 333                                         mine = find(mine, classname, "mine");
 334                                         continue;
 335                                 }
 336                                 targ = targetlist;
 337                                 while (targ)
 338                                 {
 339                                         d = vlen(targ.origin + (targ.mins + targ.maxs) * 0.5 - mine.origin);
 340                                         d = bound(0, edgedamage + (coredamage - edgedamage) * sqrt(1 - d * recipricoledgeradius), 10000);
 341                                         // count potential damage according to type of target
 342                                         if (targ == self)
 343                                                 selfdamage = selfdamage + d;
 344                                         else if (targ.team == self.team && teams_matter)
 345                                                 teamdamage = teamdamage + d;
 346                                         else if (bot_shouldattack(targ))
 347                                                 enemydamage = enemydamage + d;
 348                                         targ = targ.chain;
 349                                 }
 350                                 mine = find(mine, classname, "mine");
 351                         }
 352                         float desirabledamage;
 353                         desirabledamage = enemydamage;
 354                         if (time > self.invincible_finished && time > self.spawnshieldtime)
 355                                 desirabledamage = desirabledamage - selfdamage * autocvar_g_balance_selfdamagepercent;
 356                         if (teams_matter && self.team)
 357                                 desirabledamage = desirabledamage - teamdamage;
 358
 359                         mine = find(world, classname, "mine");
 360                         while (mine)
 361                         {
 362                                 if (mine.owner != self)
 363                                 {
 364                                         mine = find(mine, classname, "mine");
 365                                         continue;
 366                                 }
 367                                 makevectors(mine.v_angle);
 368                                 targ = targetlist;
 369                                 if (skill > 9) // normal players only do this for the target they are tracking
 370                                 {
 371                                         targ = targetlist;
 372                                         while (targ)
 373                                         {
 374                                                 if (
 375                                                         (v_forward * normalize(mine.origin - targ.origin)< 0.1)
 376                                                         && desirabledamage > 0.1*coredamage
 377                                                 )self.BUTTON_ATCK2 = TRUE;
 378                                                 targ = targ.chain;
 379                                         }
 380                                 }else{
 381                                         float distance; distance= bound(300,vlen(self.origin-self.enemy.origin),30000);
 382                                         //As the distance gets larger, a correct detonation gets near imposible
 383                                         //Bots are assumed to use the mine spawnfunc_light to see if the mine gets near a player
 384                                         if(v_forward * normalize(mine.origin - self.enemy.origin)< 0.1)
 385                                                 if(self.enemy.classname == "player")
 386                                                         if(desirabledamage >= 0.1*coredamage)
 387                                                                 if(random()/distance*300 > frametime*bound(0,(10-skill)*0.2,1))
 388                                                                         self.BUTTON_ATCK2 = TRUE;
 389                                 //      dprint(ftos(random()/distance*300),">");dprint(ftos(frametime*bound(0,(10-skill)*0.2,1)),"\n");
 390                                 }
 391
 392                                 mine = find(mine, classname, "mine");
 393                         }
 394                         // if we would be doing at X percent of the core damage, detonate it
 395                         // but don't fire a new shot at the same time!
 396                         if (desirabledamage >= 0.75 * coredamage) //this should do group damage in rare fortunate events
 397                                 self.BUTTON_ATCK2 = TRUE;
 398                         if ((skill > 6.5) && (selfdamage > self.health))
 399                                 self.BUTTON_ATCK2 = FALSE;
 400                         //if(self.BUTTON_ATCK2 == TRUE)
 401                         //      dprint(ftos(desirabledamage),"\n");
 402                         if (self.BUTTON_ATCK2 == TRUE) self.BUTTON_ATCK = FALSE;
 403                 }
 404         }
 405         else if (req == WR_THINK)
 406         {
 407                 if(autocvar_g_balance_minelayer_reload_ammo && self.clip_load < autocvar_g_balance_minelayer_ammo) // forced reload
 408                         W_MineLayer_Reload();
 409                 else if (self.BUTTON_ATCK)
 410                 {
 411                         if(weapon_prepareattack(0, autocvar_g_balance_minelayer_refire))
 412                         {
 413                                 W_Mine_Attack();
 414                                 weapon_thinkf(WFRAME_FIRE1, autocvar_g_balance_minelayer_animtime, w_ready);
 415                         }
 416                 }
 417
 418                 else if (self.BUTTON_ATCK2)
 419                 {
 420                         minfound = 0;
 421                         for(mine = world; (mine = find(mine, classname, "mine")); ) if(mine.owner == self)
 422                         {
 423                                 if(!mine.minelayer_detonate)
 424                                 {
 425                                         mine.minelayer_detonate = TRUE;
 426                                         minfound = 1;
 427                                 }
 428                         }
 429                         if(minfound)
 430                                 sound (self, CHAN_WEAPON2, "weapons/mine_det.wav", VOL_BASE, ATTN_NORM);
 431                 }
 432         }
 433         else if (req == WR_PRECACHE)
 434         {
 435                 precache_model ("models/flash.md3");
 436                 precache_model ("models/mine.md3");
 437                 precache_model ("models/weapons/g_minelayer.md3");
 438                 precache_model ("models/weapons/v_minelayer.md3");
 439                 precache_model ("models/weapons/h_minelayer.iqm");
 440                 precache_sound ("weapons/mine_det.wav");
 441                 precache_sound ("weapons/mine_fire.wav");
 442                 precache_sound ("weapons/mine_stick.wav");
 443                 precache_sound ("weapons/mine_trigger.wav");
 444                 precache_sound ("weapons/reload.wav");
 445         }
 446         else if (req == WR_SETUP)
 447         {
 448                 weapon_setup(WEP_MINE_LAYER);
 449                 W_MineLayer_SetAmmoCounter();
 450         }
 451         else if (req == WR_CHECKAMMO1)
 452         {
 453                 // don't switch while placing a mine
 454                 if (ATTACK_FINISHED(self) <= time || self.weapon != WEP_MINE_LAYER)
 455                 {
 456                         if(autocvar_g_balance_minelayer_reload_ammo)
 457                         {
 458                                 if(self.ammo_rockets < autocvar_g_balance_minelayer_ammo && self.minelayer_load < autocvar_g_balance_minelayer_ammo)
 459                                         ammo_amount = TRUE;
 460                         }
 461                         else if(self.ammo_rockets < autocvar_g_balance_minelayer_ammo)
 462                                 ammo_amount = TRUE;
 463                         return !ammo_amount;
 464                 }
 465         }
 466         else if (req == WR_CHECKAMMO2)
 467         {
 468                 return FALSE;
 469         }
 470         else if (req == WR_RESETPLAYER)
 471         {
 472                 // all weapons must be fully loaded when we spawn
 473                 self.minelayer_load = autocvar_g_balance_minelayer_reload_ammo;
 474         }
 475         else if (req == WR_RELOAD)
 476         {
 477                 W_MineLayer_Reload();
 478         }
 479         return TRUE;
 480 };
 481 #endif
 482 #ifdef CSQC
 483 float w_minelayer(float req)
 484 {
 485         if(req == WR_IMPACTEFFECT)
 486         {
 487                 vector org2;
 488                 org2 = w_org + w_backoff * 12;
 489                 pointparticles(particleeffectnum("rocket_explode"), org2, '0 0 0', 1);
 490                 if(!w_issilent)
 491                         sound(self, CHAN_PROJECTILE, "weapons/mine_exp.wav", VOL_BASE, ATTN_NORM);
 492         }
 493         else if(req == WR_PRECACHE)
 494         {
 495                 precache_sound("weapons/mine_exp.wav");
 496         }
 497         else if (req == WR_SUICIDEMESSAGE)
 498                 w_deathtypestring = _("%s exploded");
 499         else if (req == WR_KILLMESSAGE)
 500         {
 501                 if(w_deathtype & HITTYPE_BOUNCE) // (remote detonation)
 502                         w_deathtypestring = _("%s got too close to %s's mine");
 503                 else if(w_deathtype & HITTYPE_SPLASH)
 504                         w_deathtypestring = _("%s almost dodged %s's mine");
 505                 else
 506                         w_deathtypestring = _("%s stepped on %s's mine");
 507         }
 508         return TRUE;
 509 }
 510 #endif
 511 #endif