qcsrc/server/w_minelayer.qc

   1 #ifdef REGISTER_WEAPON
   2 REGISTER_WEAPON(MINE_LAYER, w_minelayer, IT_ROCKETS, 4, WEP_FLAG_NORMAL | WEP_FLAG_RELOADABLE | WEP_TYPE_SPLASH, BOT_PICKUP_RATING_HIGH, "minelayer", "minelayer", _("Mine Layer"))
   3 #else
   4 #ifdef SVQC
   5 void W_Mine_Think (void);
   6 .float minelayer_detonate, mine_explodeanyway;
   7 .float mine_time;
   8
   9 void spawnfunc_weapon_minelayer (void)
  10 {
  11         weapon_defaultspawnfunc(WEP_MINE_LAYER);
  12 }
  13
  14 void W_Mine_Stick ()
  15 {
  16         spamsound (self, CHAN_PROJECTILE, "weapons/mine_stick.wav", VOL_BASE, ATTN_NORM);
  17
  18         // in order for mines to face properly when sticking to the ground, they must be a server side entity rather than a csqc projectile
  19
  20         entity newmine;
  21         newmine = spawn();
  22         newmine.classname = self.classname;
  23
  24         newmine.bot_dodge = self.bot_dodge;
  25         newmine.bot_dodgerating = self.bot_dodgerating;
  26
  27         newmine.owner = self.owner;
  28         setsize(newmine, '-4 -4 -4', '4 4 4');
  29         setorigin(newmine, self.origin);
  30         setmodel(newmine, "models/mine.md3");
  31         newmine.angles = vectoangles(-trace_plane_normal); // face against the surface
  32
  33         newmine.takedamage = self.takedamage;
  34         newmine.damageforcescale = self.damageforcescale;
  35         newmine.health = self.health;
  36         newmine.event_damage = self.event_damage;
  37         newmine.spawnshieldtime = self.spawnshieldtime;
  38
  39         newmine.movetype = MOVETYPE_NONE; // lock the mine in place
  40         newmine.projectiledeathtype = self.projectiledeathtype;
  41
  42         newmine.mine_time = self.mine_time;
  43
  44         newmine.touch = SUB_Null;
  45         newmine.think = W_Mine_Think;
  46         newmine.nextthink = time;
  47         newmine.cnt = self.cnt;
  48         newmine.flags = self.flags;
  49
  50         remove(self);
  51         self = newmine;
  52 }
  53
  54 void W_Mine_Explode ()
  55 {
  56         if(other.takedamage == DAMAGE_AIM)
  57                 if(other.classname == "player")
  58                         if(IsDifferentTeam(self.owner, other))
  59                                 if(IsFlying(other))
  60                                         AnnounceTo(self.owner, "airshot");
  61
  62         self.event_damage = SUB_Null;
  63         self.takedamage = DAMAGE_NO;
  64
  65         RadiusDamage (self, self.owner, autocvar_g_balance_minelayer_damage, autocvar_g_balance_minelayer_edgedamage, autocvar_g_balance_minelayer_radius, world, autocvar_g_balance_minelayer_force, self.projectiledeathtype, other);
  66
  67         if (self.owner.weapon == WEP_MINE_LAYER)
  68         {
  69                 if(self.owner.ammo_rockets < autocvar_g_balance_minelayer_ammo)
  70                 {
  71                         self.owner.cnt = WEP_MINE_LAYER;
  72                         ATTACK_FINISHED(self.owner) = time;
  73                         self.owner.switchweapon = w_getbestweapon(self.owner);
  74                 }
  75         }
  76         self.owner.minelayer_mines -= 1;
  77         remove (self);
  78 }
  79
  80 void W_Mine_DoRemoteExplode ()
  81 {
  82         self.event_damage = SUB_Null;
  83         self.takedamage = DAMAGE_NO;
  84
  85         RadiusDamage (self, self.owner, autocvar_g_balance_minelayer_remote_damage, autocvar_g_balance_minelayer_remote_edgedamage, autocvar_g_balance_minelayer_remote_radius, world, autocvar_g_balance_minelayer_remote_force, self.projectiledeathtype | HITTYPE_BOUNCE, world);
  86
  87         if (self.owner.weapon == WEP_MINE_LAYER)
  88         {
  89                 if(self.owner.ammo_rockets < autocvar_g_balance_minelayer_ammo)
  90                 {
  91                         self.owner.cnt = WEP_MINE_LAYER;
  92                         ATTACK_FINISHED(self.owner) = time;
  93                         self.owner.switchweapon = w_getbestweapon(self.owner);
  94                 }
  95         }
  96         self.owner.minelayer_mines -= 1;
  97         remove (self);
  98 }
  99
 100 void W_Mine_RemoteExplode ()
 101 {
 102         if(self.owner.deadflag == DEAD_NO)
 103                 if((self.spawnshieldtime >= 0)
 104                         ? (time >= self.spawnshieldtime) // timer
 105                         : (vlen(NearestPointOnBox(self.owner, self.origin) - self.origin) > autocvar_g_balance_minelayer_remote_radius) // safety device
 106                 )
 107                 {
 108                         W_Mine_DoRemoteExplode();
 109                 }
 110 }
 111
 112 void W_Mine_ProximityExplode ()
 113 {
 114         // make sure no friend is in the mine's radius. If there is any, explosion is delayed until he's at a safe distance
 115         if(autocvar_g_balance_minelayer_protection && self.mine_explodeanyway == 0)
 116         {
 117                 entity head;
 118                 head = findradius(self.origin, autocvar_g_balance_minelayer_radius);
 119                 while(head)
 120                 {
 121                         if(head == self.owner || !IsDifferentTeam(head, self.owner))
 122                                 return;
 123                         head = head.chain;
 124                 }
 125         }
 126
 127         self.mine_time = 0;
 128         W_Mine_Explode();
 129 }
 130
 131 float W_Mine_Count(entity e)
 132 {
 133         float minecount;
 134         entity mine;
 135         for(mine = world; (mine = find(mine, classname, "mine")); ) if(mine.owner == e)
 136                 minecount += 1;
 137
 138         return minecount;
 139 }
 140
 141 void W_Mine_Think (void)
 142 {
 143         entity head;
 144
 145         self.nextthink = time;
 146
 147         // our lifetime has expired, it's time to die - mine_time just allows us to play a sound for this
 148         // TODO: replace this mine_trigger.wav sound with a real countdown
 149         if ((time > self.cnt) && (!self.mine_time))
 150         {
 151                 if(autocvar_g_balance_minelayer_lifetime_countdown > 0)
 152                         spamsound (self, CHAN_PROJECTILE, "weapons/mine_trigger.wav", VOL_BASE, ATTN_NORM);
 153                 self.mine_time = time + autocvar_g_balance_minelayer_lifetime_countdown;
 154                 self.mine_explodeanyway = 1; // make the mine super aggressive -- Samual: Rather, make it not care if a team mate is near.
 155         }
 156
 157         // a player's mines shall explode if he disconnects or dies
 158         // TODO: Do this on team change too -- Samual: But isn't a player killed when they switch teams?
 159         if(self.owner.classname != "player" || self.owner.deadflag != DEAD_NO)
 160         {
 161                 other = world;
 162                 self.projectiledeathtype |= HITTYPE_BOUNCE;
 163                 W_Mine_Explode();
 164                 return;
 165         }
 166
 167         // set the mine for detonation when a foe gets close enough
 168         head = findradius(self.origin, autocvar_g_balance_minelayer_proximityradius);
 169         while(head)
 170         {
 171                 if(head.classname == "player" && head.deadflag == DEAD_NO)
 172                 if(head != self.owner && IsDifferentTeam(head, self.owner)) // don't trigger for team mates
 173                 if(!self.mine_time)
 174                 {
 175                         spamsound (self, CHAN_PROJECTILE, "weapons/mine_trigger.wav", VOL_BASE, ATTN_NORM);
 176                         self.mine_time = time + autocvar_g_balance_minelayer_time;
 177                 }
 178                 head = head.chain;
 179         }
 180
 181         // explode if it's time to
 182         if(self.mine_time && time >= self.mine_time)
 183         {
 184                 W_Mine_ProximityExplode();
 185                 return;
 186         }
 187
 188         // remote detonation
 189         if (self.owner.weapon == WEP_MINE_LAYER)
 190         if (self.owner.deadflag == DEAD_NO)
 191         if (self.minelayer_detonate)
 192                 W_Mine_RemoteExplode();
 193 }
 194
 195 void W_Mine_Touch (void)
 196 {
 197         PROJECTILE_TOUCH;
 198         if(!other || (other.takedamage != DAMAGE_AIM && other.movetype == MOVETYPE_NONE))
 199                 W_Mine_Stick();
 200         else if(self.movetype != MOVETYPE_NONE) // don't unstick a locked mine when someone touches it
 201                 self.velocity = '0 0 0';
 202 }
 203
 204 void W_Mine_Damage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 205 {
 206         if (self.health <= 0)
 207                 return;
 208         self.health = self.health - damage;
 209         self.angles = vectoangles(self.velocity);
 210         if (self.health <= 0)
 211                 W_PrepareExplosionByDamage(attacker, W_Mine_Explode);
 212 }
 213
 214 void W_Mine_Attack (void)
 215 {
 216         entity mine;
 217         entity flash;
 218
 219         // scan how many mines we placed, and return if we reached our limit
 220         if(autocvar_g_balance_minelayer_limit)
 221         {
 222
 223                 if(W_Mine_Count(self) >= autocvar_g_balance_minelayer_limit)
 224                 {
 225                         // the refire delay keeps this message from being spammed
 226                         sprint(self, strcat("You cannot place more than ^2", ftos(autocvar_g_balance_minelayer_limit), " ^7mines at a time\n") );
 227                         play2(self, "weapons/unavailable.wav");
 228                         return;
 229                 }
 230         }
 231
 232         W_DecreaseAmmo(ammo_rockets, autocvar_g_balance_minelayer_ammo, autocvar_g_balance_minelayer_reload_ammo);
 233
 234         W_SetupShot_ProjectileSize (self, '-4 -4 -4', '4 4 4', FALSE, 5, "weapons/mine_fire.wav", CHAN_WEAPON, autocvar_g_balance_minelayer_damage);
 235         pointparticles(particleeffectnum("rocketlauncher_muzzleflash"), w_shotorg, w_shotdir * 1000, 1);
 236
 237         mine = WarpZone_RefSys_SpawnSameRefSys(self);
 238         mine.owner = self;
 239         if(autocvar_g_balance_minelayer_detonatedelay >= 0)
 240                 mine.spawnshieldtime = time + autocvar_g_balance_minelayer_detonatedelay;
 241         else
 242                 mine.spawnshieldtime = -1;
 243         mine.classname = "mine";
 244         mine.bot_dodge = TRUE;
 245         mine.bot_dodgerating = autocvar_g_balance_minelayer_damage * 2; // * 2 because it can detonate inflight which makes it even more dangerous
 246
 247         mine.takedamage = DAMAGE_YES;
 248         mine.damageforcescale = autocvar_g_balance_minelayer_damageforcescale;
 249         mine.health = autocvar_g_balance_minelayer_health;
 250         mine.event_damage = W_Mine_Damage;
 251
 252         mine.movetype = MOVETYPE_TOSS;
 253         PROJECTILE_MAKETRIGGER(mine);
 254         mine.projectiledeathtype = WEP_MINE_LAYER;
 255         setsize (mine, '-4 -4 -4', '4 4 4'); // give it some size so it can be shot
 256
 257         setorigin (mine, w_shotorg - v_forward * 4); // move it back so it hits the wall at the right point
 258         W_SetupProjectileVelocity(mine, autocvar_g_balance_minelayer_speed, 0);
 259         mine.angles = vectoangles (mine.velocity);
 260
 261         mine.touch = W_Mine_Touch;
 262         mine.think = W_Mine_Think;
 263         mine.nextthink = time;
 264         mine.cnt = time + (autocvar_g_balance_minelayer_lifetime - autocvar_g_balance_minelayer_lifetime_countdown);
 265         mine.flags = FL_PROJECTILE;
 266
 267         CSQCProjectile(mine, TRUE, PROJECTILE_MINE, TRUE);
 268
 269         // muzzle flash for 1st person view
 270         flash = spawn ();
 271         setmodel (flash, "models/flash.md3"); // precision set below
 272         SUB_SetFade (flash, time, 0.1);
 273         flash.effects = EF_ADDITIVE | EF_FULLBRIGHT | EF_LOWPRECISION;
 274         W_AttachToShotorg(flash, '5 0 0');
 275
 276         // common properties
 277
 278         other = mine; MUTATOR_CALLHOOK(EditProjectile);
 279
 280         self.minelayer_mines = W_Mine_Count(self);
 281 }
 282
 283 void spawnfunc_weapon_minelayer (void); // defined in t_items.qc
 284
 285 float w_minelayer(float req)
 286 {
 287         entity mine;
 288         float minfound;
 289         float ammo_amount;
 290
 291         if (req == WR_AIM)
 292         {
 293                 // aim and decide to fire if appropriate
 294                 self.BUTTON_ATCK = bot_aim(autocvar_g_balance_minelayer_speed, 0, autocvar_g_balance_minelayer_lifetime, FALSE);
 295                 if(skill >= 2) // skill 0 and 1 bots won't detonate mines!
 296                 {
 297                         // decide whether to detonate mines
 298                         entity targetlist, targ;
 299                         float edgedamage, coredamage, edgeradius, recipricoledgeradius, d;
 300                         float selfdamage, teamdamage, enemydamage;
 301                         edgedamage = autocvar_g_balance_minelayer_edgedamage;
 302                         coredamage = autocvar_g_balance_minelayer_damage;
 303                         edgeradius = autocvar_g_balance_minelayer_radius;
 304                         recipricoledgeradius = 1 / edgeradius;
 305                         selfdamage = 0;
 306                         teamdamage = 0;
 307                         enemydamage = 0;
 308                         targetlist = findchainfloat(bot_attack, TRUE);
 309                         mine = find(world, classname, "mine");
 310                         while (mine)
 311                         {
 312                                 if (mine.owner != self)
 313                                 {
 314                                         mine = find(mine, classname, "mine");
 315                                         continue;
 316                                 }
 317                                 targ = targetlist;
 318                                 while (targ)
 319                                 {
 320                                         d = vlen(targ.origin + (targ.mins + targ.maxs) * 0.5 - mine.origin);
 321                                         d = bound(0, edgedamage + (coredamage - edgedamage) * sqrt(1 - d * recipricoledgeradius), 10000);
 322                                         // count potential damage according to type of target
 323                                         if (targ == self)
 324                                                 selfdamage = selfdamage + d;
 325                                         else if (targ.team == self.team && teams_matter)
 326                                                 teamdamage = teamdamage + d;
 327                                         else if (bot_shouldattack(targ))
 328                                                 enemydamage = enemydamage + d;
 329                                         targ = targ.chain;
 330                                 }
 331                                 mine = find(mine, classname, "mine");
 332                         }
 333                         float desirabledamage;
 334                         desirabledamage = enemydamage;
 335                         if (time > self.invincible_finished && time > self.spawnshieldtime)
 336                                 desirabledamage = desirabledamage - selfdamage * autocvar_g_balance_selfdamagepercent;
 337                         if (teams_matter && self.team)
 338                                 desirabledamage = desirabledamage - teamdamage;
 339
 340                         mine = find(world, classname, "mine");
 341                         while (mine)
 342                         {
 343                                 if (mine.owner != self)
 344                                 {
 345                                         mine = find(mine, classname, "mine");
 346                                         continue;
 347                                 }
 348                                 makevectors(mine.v_angle);
 349                                 targ = targetlist;
 350                                 if (skill > 9) // normal players only do this for the target they are tracking
 351                                 {
 352                                         targ = targetlist;
 353                                         while (targ)
 354                                         {
 355                                                 if (
 356                                                         (v_forward * normalize(mine.origin - targ.origin)< 0.1)
 357                                                         && desirabledamage > 0.1*coredamage
 358                                                 )self.BUTTON_ATCK2 = TRUE;
 359                                                 targ = targ.chain;
 360                                         }
 361                                 }else{
 362                                         float distance; distance= bound(300,vlen(self.origin-self.enemy.origin),30000);
 363                                         //As the distance gets larger, a correct detonation gets near imposible
 364                                         //Bots are assumed to use the mine spawnfunc_light to see if the mine gets near a player
 365                                         if(v_forward * normalize(mine.origin - self.enemy.origin)< 0.1)
 366                                                 if(self.enemy.classname == "player")
 367                                                         if(desirabledamage >= 0.1*coredamage)
 368                                                                 if(random()/distance*300 > frametime*bound(0,(10-skill)*0.2,1))
 369                                                                         self.BUTTON_ATCK2 = TRUE;
 370                                 //      dprint(ftos(random()/distance*300),">");dprint(ftos(frametime*bound(0,(10-skill)*0.2,1)),"\n");
 371                                 }
 372
 373                                 mine = find(mine, classname, "mine");
 374                         }
 375                         // if we would be doing at X percent of the core damage, detonate it
 376                         // but don't fire a new shot at the same time!
 377                         if (desirabledamage >= 0.75 * coredamage) //this should do group damage in rare fortunate events
 378                                 self.BUTTON_ATCK2 = TRUE;
 379                         if ((skill > 6.5) && (selfdamage > self.health))
 380                                 self.BUTTON_ATCK2 = FALSE;
 381                         //if(self.BUTTON_ATCK2 == TRUE)
 382                         //      dprint(ftos(desirabledamage),"\n");
 383                         if (self.BUTTON_ATCK2 == TRUE) self.BUTTON_ATCK = FALSE;
 384                 }
 385         }
 386         else if (req == WR_THINK)
 387         {
 388                 if(autocvar_g_balance_minelayer_reload_ammo && self.clip_load < autocvar_g_balance_minelayer_ammo) // forced reload
 389                         weapon_action(self.weapon, WR_RELOAD);
 390                 else if (self.BUTTON_ATCK)
 391                 {
 392                         if(weapon_prepareattack(0, autocvar_g_balance_minelayer_refire))
 393                         {
 394                                 W_Mine_Attack();
 395                                 weapon_thinkf(WFRAME_FIRE1, autocvar_g_balance_minelayer_animtime, w_ready);
 396                         }
 397                 }
 398
 399                 else if (self.BUTTON_ATCK2)
 400                 {
 401                         minfound = 0;
 402                         for(mine = world; (mine = find(mine, classname, "mine")); ) if(mine.owner == self)
 403                         {
 404                                 if(!mine.minelayer_detonate)
 405                                 {
 406                                         mine.minelayer_detonate = TRUE;
 407                                         minfound = 1;
 408                                 }
 409                         }
 410                         if(minfound)
 411                                 sound (self, CHAN_WEAPON2, "weapons/mine_det.wav", VOL_BASE, ATTN_NORM);
 412                 }
 413         }
 414         else if (req == WR_PRECACHE)
 415         {
 416                 precache_model ("models/flash.md3");
 417                 precache_model ("models/mine.md3");
 418                 precache_model ("models/weapons/g_minelayer.md3");
 419                 precache_model ("models/weapons/v_minelayer.md3");
 420                 precache_model ("models/weapons/h_minelayer.iqm");
 421                 precache_sound ("weapons/mine_det.wav");
 422                 precache_sound ("weapons/mine_fire.wav");
 423                 precache_sound ("weapons/mine_stick.wav");
 424                 precache_sound ("weapons/mine_trigger.wav");
 425                 //precache_sound ("weapons/reload.wav"); // until weapons have individual reload sounds, precache the reload sound somewhere else
 426         }
 427         else if (req == WR_SETUP)
 428         {
 429                 weapon_setup(WEP_MINE_LAYER);
 430                 self.current_ammo = ammo_rockets;
 431         }
 432         else if (req == WR_CHECKAMMO1)
 433         {
 434                 // don't switch while placing a mine
 435                 if (ATTACK_FINISHED(self) <= time || self.weapon != WEP_MINE_LAYER)
 436                 {
 437                         if(autocvar_g_balance_minelayer_reload_ammo)
 438                         {
 439                                 if(self.ammo_rockets < autocvar_g_balance_minelayer_ammo && self.weapon_load[WEP_MINE_LAYER] < autocvar_g_balance_minelayer_ammo)
 440                                         ammo_amount = TRUE;
 441                         }
 442                         else if(self.ammo_rockets < autocvar_g_balance_minelayer_ammo)
 443                                 ammo_amount = TRUE;
 444                         return !ammo_amount;
 445                 }
 446         }
 447         else if (req == WR_CHECKAMMO2)
 448         {
 449                 return FALSE;
 450         }
 451         else if (req == WR_RELOAD)
 452         {
 453                 W_Reload(autocvar_g_balance_minelayer_ammo, autocvar_g_balance_minelayer_reload_ammo, autocvar_g_balance_minelayer_reload_time, "weapons/reload.wav");
 454         }
 455         return TRUE;
 456 };
 457 #endif
 458 #ifdef CSQC
 459 float w_minelayer(float req)
 460 {
 461         if(req == WR_IMPACTEFFECT)
 462         {
 463                 vector org2;
 464                 org2 = w_org + w_backoff * 12;
 465                 pointparticles(particleeffectnum("rocket_explode"), org2, '0 0 0', 1);
 466                 if(!w_issilent)
 467                         sound(self, CHAN_PROJECTILE, "weapons/mine_exp.wav", VOL_BASE, ATTN_NORM);
 468         }
 469         else if(req == WR_PRECACHE)
 470         {
 471                 precache_sound("weapons/mine_exp.wav");
 472         }
 473         else if (req == WR_SUICIDEMESSAGE)
 474                 w_deathtypestring = _("%s exploded");
 475         else if (req == WR_KILLMESSAGE)
 476         {
 477                 if(w_deathtype & HITTYPE_BOUNCE) // (remote detonation)
 478                         w_deathtypestring = _("%s got too close to %s's mine");
 479                 else if(w_deathtype & HITTYPE_SPLASH)
 480                         w_deathtypestring = _("%s almost dodged %s's mine");
 481                 else
 482                         w_deathtypestring = _("%s stepped on %s's mine");
 483         }
 484         return TRUE;
 485 }
 486 #endif
 487 #endif