qcsrc/server/w_minelayer.qc

   1 #ifdef REGISTER_WEAPON
   2 REGISTER_WEAPON(MINE_LAYER, w_minelayer, IT_ROCKETS, 4, WEP_TYPE_SPLASH, BOT_PICKUP_RATING_HIGH, "minelayer", "minelayer", _("Mine Layer"))
   3 #else
   4 #ifdef SVQC
   5 void W_Mine_Think (void);
   6 .float minelayer_detonate, minelayer_mines;
   7 .float mine_time;
   8
   9 void W_MineLayer_SetAmmoCounter()
  10 {
  11         // set clip_load to the weapon we have switched to, if the gun uses reloading
  12         if(!autocvar_g_balance_minelayer_reload_ammo)
  13                 self.clip_load = 0; // also keeps crosshair ammo from displaying
  14         else
  15         {
  16                 self.clip_load = self.minelayer_load;
  17                 self.clip_size = autocvar_g_balance_minelayer_reload_ammo; // for the crosshair ammo display
  18         }
  19 }
  20
  21 void W_MineLayer_ReloadedAndReady()
  22 {
  23         float t;
  24
  25         // now do the ammo transfer
  26         self.clip_load = self.old_clip_load; // restore the ammo counter, in case we still had ammo in the weapon before reloading
  27         while(self.clip_load < autocvar_g_balance_minelayer_reload_ammo && self.ammo_rockets) // make sure we don't add more ammo than we have
  28         {
  29                 self.clip_load += 1;
  30                 self.ammo_rockets -= 1;
  31         }
  32         self.minelayer_load = self.clip_load;
  33
  34         t = ATTACK_FINISHED(self) - autocvar_g_balance_minelayer_reload_time - 1;
  35         ATTACK_FINISHED(self) = t;
  36         w_ready();
  37 }
  38
  39 void W_MineLayer_Reload()
  40 {
  41         // return if reloading is disabled for this weapon
  42         if(!autocvar_g_balance_minelayer_reload_ammo)
  43                 return;
  44
  45         if(!W_ReloadCheck(self.ammo_rockets, autocvar_g_balance_minelayer_ammo))
  46                 return;
  47
  48         float t;
  49
  50         sound (self, CHAN_WEAPON2, "weapons/reload.wav", VOL_BASE, ATTN_NORM);
  51
  52         t = max(time, ATTACK_FINISHED(self)) + autocvar_g_balance_minelayer_reload_time + 1;
  53         ATTACK_FINISHED(self) = t;
  54
  55         weapon_thinkf(WFRAME_RELOAD, autocvar_g_balance_minelayer_reload_time, W_MineLayer_ReloadedAndReady);
  56
  57         self.old_clip_load = self.clip_load;
  58         self.clip_load = -1;
  59 }
  60
  61 void spawnfunc_weapon_minelayer (void)
  62 {
  63         weapon_defaultspawnfunc(WEP_MINE_LAYER);
  64 }
  65
  66 void W_Mine_Stick ()
  67 {
  68         spamsound (self, CHAN_PROJECTILE, "weapons/mine_stick.wav", VOL_BASE, ATTN_NORM);
  69
  70         // in order for mines to face properly when sticking to the ground, they must be a server side entity rather than a csqc projectile
  71
  72         entity newmine;
  73         newmine = spawn();
  74         newmine.classname = self.classname;
  75
  76         newmine.bot_dodge = self.bot_dodge;
  77         newmine.bot_dodgerating = self.bot_dodgerating;
  78
  79         newmine.owner = self.owner;
  80         setsize(newmine, '-4 -4 -4', '4 4 4');
  81         setorigin(newmine, self.origin);
  82         setmodel(newmine, "models/mine.md3");
  83         newmine.angles = vectoangles(-trace_plane_normal); // face against the surface
  84
  85         newmine.takedamage = self.takedamage;
  86         newmine.damageforcescale = self.damageforcescale;
  87         newmine.health = self.health;
  88         newmine.event_damage = self.event_damage;
  89         newmine.spawnshieldtime = self.spawnshieldtime;
  90
  91         newmine.movetype = MOVETYPE_NONE; // lock the mine in place
  92         newmine.projectiledeathtype = self.projectiledeathtype;
  93
  94         newmine.mine_time = self.mine_time;
  95
  96         newmine.touch = SUB_Null;
  97         newmine.think = W_Mine_Think;
  98         newmine.nextthink = time;
  99         newmine.cnt = self.cnt;
 100         newmine.flags = self.flags;
 101
 102         remove(self);
 103         self = newmine;
 104 }
 105
 106 void W_Mine_Explode ()
 107 {
 108         if(other.takedamage == DAMAGE_AIM)
 109                 if(other.classname == "player")
 110                         if(IsDifferentTeam(self.owner, other))
 111                                 if(IsFlying(other))
 112                                         AnnounceTo(self.owner, "airshot");
 113
 114         self.event_damage = SUB_Null;
 115         self.takedamage = DAMAGE_NO;
 116
 117         RadiusDamage (self, self.owner, autocvar_g_balance_minelayer_damage, autocvar_g_balance_minelayer_edgedamage, autocvar_g_balance_minelayer_radius, world, autocvar_g_balance_minelayer_force, self.projectiledeathtype, other);
 118
 119         if (self.owner.weapon == WEP_MINE_LAYER)
 120         {
 121                 if(self.owner.ammo_rockets < autocvar_g_balance_minelayer_ammo)
 122                 {
 123                         self.owner.cnt = WEP_MINE_LAYER;
 124                         ATTACK_FINISHED(self.owner) = time;
 125                         self.owner.switchweapon = w_getbestweapon(self.owner);
 126                 }
 127         }
 128         remove (self);
 129 }
 130
 131 void W_Mine_DoRemoteExplode ()
 132 {
 133         self.event_damage = SUB_Null;
 134         self.takedamage = DAMAGE_NO;
 135
 136         RadiusDamage (self, self.owner, autocvar_g_balance_minelayer_remote_damage, autocvar_g_balance_minelayer_remote_edgedamage, autocvar_g_balance_minelayer_remote_radius, world, autocvar_g_balance_minelayer_remote_force, self.projectiledeathtype | HITTYPE_BOUNCE, world);
 137
 138         if (self.owner.weapon == WEP_MINE_LAYER)
 139         {
 140                 if(self.owner.ammo_rockets < autocvar_g_balance_minelayer_ammo)
 141                 {
 142                         self.owner.cnt = WEP_MINE_LAYER;
 143                         ATTACK_FINISHED(self.owner) = time;
 144                         self.owner.switchweapon = w_getbestweapon(self.owner);
 145                 }
 146         }
 147         remove (self);
 148 }
 149
 150 void W_Mine_RemoteExplode ()
 151 {
 152         if(self.owner.deadflag == DEAD_NO)
 153                 if((self.spawnshieldtime >= 0)
 154                         ? (time >= self.spawnshieldtime) // timer
 155                         : (vlen(NearestPointOnBox(self.owner, self.origin) - self.origin) > autocvar_g_balance_minelayer_remote_radius) // safety device
 156                 )
 157                 {
 158                         W_Mine_DoRemoteExplode();
 159                 }
 160 }
 161
 162 void W_Mine_ProximityExplode ()
 163 {
 164         // make sure no friend is in the mine's radius. If there is any, explosion is delayed until he's at a safe distance
 165         if(autocvar_g_balance_minelayer_protection)
 166         {
 167                 entity head;
 168                 head = findradius(self.origin, autocvar_g_balance_minelayer_radius);
 169                 while(head)
 170                 {
 171                         if(head == self.owner || !IsDifferentTeam(head, self.owner))
 172                                 return;
 173                         head = head.chain;
 174                 }
 175         }
 176
 177         self.mine_time = 0;
 178         W_Mine_Explode();
 179 }
 180
 181 void W_Mine_Think (void)
 182 {
 183         entity head;
 184
 185         self.nextthink = time;
 186         if (time > self.cnt)
 187         {
 188                 other = world;
 189                 self.projectiledeathtype |= HITTYPE_BOUNCE;
 190                 W_Mine_Explode();
 191                 return;
 192         }
 193
 194         // a player's mines shall explode if he disconnects or dies
 195         // TODO: Do this on team change too
 196         if(self.owner.classname != "player" || self.owner.deadflag != DEAD_NO)
 197         {
 198                 other = world;
 199                 self.projectiledeathtype |= HITTYPE_BOUNCE;
 200                 W_Mine_Explode();
 201                 return;
 202         }
 203
 204         // set the mine for detonation when a foe gets close enough
 205         head = findradius(self.origin, autocvar_g_balance_minelayer_proximityradius);
 206         while(head)
 207         {
 208                 if(head.classname == "player" && head.deadflag == DEAD_NO)
 209                 if(head != self.owner && IsDifferentTeam(head, self.owner)) // don't trigger for team mates
 210                 if(!self.mine_time)
 211                 {
 212                         spamsound (self, CHAN_PROJECTILE, "weapons/mine_trigger.wav", VOL_BASE, ATTN_NORM);
 213                         self.mine_time = time + autocvar_g_balance_minelayer_time;
 214                 }
 215                 head = head.chain;
 216         }
 217
 218         // explode if it's time to
 219         if(self.mine_time && time >= self.mine_time)
 220                 W_Mine_ProximityExplode();
 221
 222         // remote detonation
 223         if (self.owner.weapon == WEP_MINE_LAYER)
 224         if (self.owner.deadflag == DEAD_NO)
 225         if (self.minelayer_detonate)
 226                 W_Mine_RemoteExplode();
 227 }
 228
 229 void W_Mine_Touch (void)
 230 {
 231         PROJECTILE_TOUCH;
 232         if(!other || (other.takedamage != DAMAGE_AIM && other.movetype == MOVETYPE_NONE))
 233                 W_Mine_Stick();
 234         else if(self.movetype != MOVETYPE_NONE) // don't unstick a locked mine when someone touches it
 235                 self.velocity = '0 0 0';
 236 }
 237
 238 void W_Mine_Damage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 239 {
 240         if (self.health <= 0)
 241                 return;
 242         self.health = self.health - damage;
 243         self.angles = vectoangles(self.velocity);
 244         if (self.health <= 0)
 245                 W_PrepareExplosionByDamage(attacker, W_Mine_Explode);
 246 }
 247
 248 void W_Mine_Attack (void)
 249 {
 250         entity mine;
 251         entity flash;
 252
 253         // scan how many mines we placed, and return if we reached our limit
 254         if(autocvar_g_balance_minelayer_limit)
 255         {
 256                 self.minelayer_mines = 0;
 257                 for(mine = world; (mine = find(mine, classname, "mine")); ) if(mine.owner == self)
 258                         self.minelayer_mines += 1;
 259
 260                 if(self.minelayer_mines >= autocvar_g_balance_minelayer_limit)
 261                 {
 262                         // the refire delay keeps this message from being spammed
 263                         sprint(self, strcat("You cannot place more than ^2", ftos(autocvar_g_balance_minelayer_limit), " ^7mines at a time\n") );
 264                         play2(self, "weapons/unavailable.wav");
 265                         return;
 266                 }
 267         }
 268
 269         // if this weapon is reloadable, decrease its load. Else decrease the player's ammo
 270         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
 271         {
 272                 if(autocvar_g_balance_minelayer_reload_ammo)
 273                 {
 274                         self.clip_load -= autocvar_g_balance_minelayer_ammo;
 275                         self.minelayer_load = self.clip_load;
 276                 }
 277                 else
 278                         self.ammo_rockets -= autocvar_g_balance_minelayer_ammo;
 279         }
 280
 281         W_SetupShot_ProjectileSize (self, '-4 -4 -4', '4 4 4', FALSE, 5, "weapons/mine_fire.wav", CHAN_WEAPON, autocvar_g_balance_minelayer_damage);
 282         pointparticles(particleeffectnum("rocketlauncher_muzzleflash"), w_shotorg, w_shotdir * 1000, 1);
 283
 284         mine = WarpZone_RefSys_SpawnSameRefSys(self);
 285         mine.owner = self;
 286         if(autocvar_g_balance_minelayer_detonatedelay >= 0)
 287                 mine.spawnshieldtime = time + autocvar_g_balance_minelayer_detonatedelay;
 288         else
 289                 mine.spawnshieldtime = -1;
 290         mine.classname = "mine";
 291         mine.bot_dodge = TRUE;
 292         mine.bot_dodgerating = autocvar_g_balance_minelayer_damage * 2; // * 2 because it can detonate inflight which makes it even more dangerous
 293
 294         mine.takedamage = DAMAGE_YES;
 295         mine.damageforcescale = autocvar_g_balance_minelayer_damageforcescale;
 296         mine.health = autocvar_g_balance_minelayer_health;
 297         mine.event_damage = W_Mine_Damage;
 298
 299         mine.movetype = MOVETYPE_TOSS;
 300         PROJECTILE_MAKETRIGGER(mine);
 301         mine.projectiledeathtype = WEP_MINE_LAYER;
 302         setsize (mine, '-4 -4 -4', '4 4 4'); // give it some size so it can be shot
 303
 304         setorigin (mine, w_shotorg - v_forward * 4); // move it back so it hits the wall at the right point
 305         W_SetupProjectileVelocity(mine, autocvar_g_balance_minelayer_speed, 0);
 306         mine.angles = vectoangles (mine.velocity);
 307
 308         mine.touch = W_Mine_Touch;
 309         mine.think = W_Mine_Think;
 310         mine.nextthink = time;
 311         mine.cnt = time + autocvar_g_balance_minelayer_lifetime;
 312         mine.flags = FL_PROJECTILE;
 313
 314         CSQCProjectile(mine, TRUE, PROJECTILE_MINE, TRUE);
 315
 316         // muzzle flash for 1st person view
 317         flash = spawn ();
 318         setmodel (flash, "models/flash.md3"); // precision set below
 319         SUB_SetFade (flash, time, 0.1);
 320         flash.effects = EF_ADDITIVE | EF_FULLBRIGHT | EF_LOWPRECISION;
 321         W_AttachToShotorg(flash, '5 0 0');
 322
 323         // common properties
 324
 325         other = mine; MUTATOR_CALLHOOK(EditProjectile);
 326 }
 327
 328 void spawnfunc_weapon_minelayer (void); // defined in t_items.qc
 329
 330 float w_minelayer(float req)
 331 {
 332         entity mine;
 333         float minfound;
 334         if (req == WR_AIM)
 335         {
 336                 // aim and decide to fire if appropriate
 337                 self.BUTTON_ATCK = bot_aim(autocvar_g_balance_minelayer_speed, 0, autocvar_g_balance_minelayer_lifetime, FALSE);
 338                 if(skill >= 2) // skill 0 and 1 bots won't detonate mines!
 339                 {
 340                         // decide whether to detonate mines
 341                         entity targetlist, targ;
 342                         float edgedamage, coredamage, edgeradius, recipricoledgeradius, d;
 343                         float selfdamage, teamdamage, enemydamage;
 344                         edgedamage = autocvar_g_balance_minelayer_edgedamage;
 345                         coredamage = autocvar_g_balance_minelayer_damage;
 346                         edgeradius = autocvar_g_balance_minelayer_radius;
 347                         recipricoledgeradius = 1 / edgeradius;
 348                         selfdamage = 0;
 349                         teamdamage = 0;
 350                         enemydamage = 0;
 351                         targetlist = findchainfloat(bot_attack, TRUE);
 352                         mine = find(world, classname, "mine");
 353                         while (mine)
 354                         {
 355                                 if (mine.owner != self)
 356                                 {
 357                                         mine = find(mine, classname, "mine");
 358                                         continue;
 359                                 }
 360                                 targ = targetlist;
 361                                 while (targ)
 362                                 {
 363                                         d = vlen(targ.origin + (targ.mins + targ.maxs) * 0.5 - mine.origin);
 364                                         d = bound(0, edgedamage + (coredamage - edgedamage) * sqrt(1 - d * recipricoledgeradius), 10000);
 365                                         // count potential damage according to type of target
 366                                         if (targ == self)
 367                                                 selfdamage = selfdamage + d;
 368                                         else if (targ.team == self.team && teams_matter)
 369                                                 teamdamage = teamdamage + d;
 370                                         else if (bot_shouldattack(targ))
 371                                                 enemydamage = enemydamage + d;
 372                                         targ = targ.chain;
 373                                 }
 374                                 mine = find(mine, classname, "mine");
 375                         }
 376                         float desirabledamage;
 377                         desirabledamage = enemydamage;
 378                         if (time > self.invincible_finished && time > self.spawnshieldtime)
 379                                 desirabledamage = desirabledamage - selfdamage * autocvar_g_balance_selfdamagepercent;
 380                         if (teams_matter && self.team)
 381                                 desirabledamage = desirabledamage - teamdamage;
 382
 383                         mine = find(world, classname, "mine");
 384                         while (mine)
 385                         {
 386                                 if (mine.owner != self)
 387                                 {
 388                                         mine = find(mine, classname, "mine");
 389                                         continue;
 390                                 }
 391                                 makevectors(mine.v_angle);
 392                                 targ = targetlist;
 393                                 if (skill > 9) // normal players only do this for the target they are tracking
 394                                 {
 395                                         targ = targetlist;
 396                                         while (targ)
 397                                         {
 398                                                 if (
 399                                                         (v_forward * normalize(mine.origin - targ.origin)< 0.1)
 400                                                         && desirabledamage > 0.1*coredamage
 401                                                 )self.BUTTON_ATCK2 = TRUE;
 402                                                 targ = targ.chain;
 403                                         }
 404                                 }else{
 405                                         float distance; distance= bound(300,vlen(self.origin-self.enemy.origin),30000);
 406                                         //As the distance gets larger, a correct detonation gets near imposible
 407                                         //Bots are assumed to use the mine spawnfunc_light to see if the mine gets near a player
 408                                         if(v_forward * normalize(mine.origin - self.enemy.origin)< 0.1)
 409                                                 if(self.enemy.classname == "player")
 410                                                         if(desirabledamage >= 0.1*coredamage)
 411                                                                 if(random()/distance*300 > frametime*bound(0,(10-skill)*0.2,1))
 412                                                                         self.BUTTON_ATCK2 = TRUE;
 413                                 //      dprint(ftos(random()/distance*300),">");dprint(ftos(frametime*bound(0,(10-skill)*0.2,1)),"\n");
 414                                 }
 415
 416                                 mine = find(mine, classname, "mine");
 417                         }
 418                         // if we would be doing at X percent of the core damage, detonate it
 419                         // but don't fire a new shot at the same time!
 420                         if (desirabledamage >= 0.75 * coredamage) //this should do group damage in rare fortunate events
 421                                 self.BUTTON_ATCK2 = TRUE;
 422                         if ((skill > 6.5) && (selfdamage > self.health))
 423                                 self.BUTTON_ATCK2 = FALSE;
 424                         //if(self.BUTTON_ATCK2 == TRUE)
 425                         //      dprint(ftos(desirabledamage),"\n");
 426                         if (self.BUTTON_ATCK2 == TRUE) self.BUTTON_ATCK = FALSE;
 427                 }
 428         }
 429         else if (req == WR_THINK)
 430         {
 431                 if(autocvar_g_balance_minelayer_reload_ammo && self.clip_load < autocvar_g_balance_minelayer_ammo) // forced reload
 432                         W_MineLayer_Reload();
 433                 else if (self.BUTTON_ATCK)
 434                 {
 435                         if(weapon_prepareattack(0, autocvar_g_balance_minelayer_refire))
 436                         {
 437                                 W_Mine_Attack();
 438                                 weapon_thinkf(WFRAME_FIRE1, autocvar_g_balance_minelayer_animtime, w_ready);
 439                         }
 440                 }
 441
 442                 else if (self.BUTTON_ATCK2)
 443                 {
 444                         minfound = 0;
 445                         for(mine = world; (mine = find(mine, classname, "mine")); ) if(mine.owner == self)
 446                         {
 447                                 if(!mine.minelayer_detonate)
 448                                 {
 449                                         mine.minelayer_detonate = TRUE;
 450                                         minfound = 1;
 451                                 }
 452                         }
 453                         if(minfound)
 454                                 sound (self, CHAN_WEAPON2, "weapons/mine_det.wav", VOL_BASE, ATTN_NORM);
 455                 }
 456         }
 457         else if (req == WR_PRECACHE)
 458         {
 459                 precache_model ("models/flash.md3");
 460                 precache_model ("models/mine.md3");
 461                 precache_model ("models/weapons/g_minelayer.md3");
 462                 precache_model ("models/weapons/v_minelayer.md3");
 463                 precache_model ("models/weapons/h_minelayer.iqm");
 464                 precache_sound ("weapons/mine_det.wav");
 465                 precache_sound ("weapons/mine_fire.wav");
 466                 precache_sound ("weapons/mine_stick.wav");
 467                 precache_sound ("weapons/mine_trigger.wav");
 468                 precache_sound ("weapons/reload.wav");
 469         }
 470         else if (req == WR_SETUP)
 471         {
 472                 weapon_setup(WEP_MINE_LAYER);
 473                 W_MineLayer_SetAmmoCounter();
 474         }
 475         else if (req == WR_CHECKAMMO1)
 476         {
 477                 // don't switch while placing a mine
 478                 if(autocvar_g_balance_electro_reload_ammo)
 479                 {
 480                         if ((ATTACK_FINISHED(self) <= time || self.weapon != WEP_MINE_LAYER)
 481                                 && self.clip_load < autocvar_g_balance_minelayer_ammo)
 482                                 return FALSE;
 483                 }
 484                 else
 485                 {
 486                         if ((ATTACK_FINISHED(self) <= time || self.weapon != WEP_MINE_LAYER)
 487                                 && self.ammo_rockets < autocvar_g_balance_minelayer_ammo)
 488                                 return FALSE;
 489                 }
 490         }
 491         else if (req == WR_CHECKAMMO2)
 492         {
 493                 return FALSE;
 494         }
 495         else if (req == WR_RELOAD)
 496         {
 497                 W_MineLayer_Reload();
 498         }
 499         else if (req == WR_SWITCHABLE)
 500         {
 501                 // checks if this weapon can be switched to, when reloading is enabled
 502                 // returns true if there's either enough load in the weapon to use it,
 503                 // or we have enough ammo to reload the weapon to a usable point
 504                 float ammo_amount;
 505                 ammo_amount = autocvar_g_balance_minelayer_ammo;
 506                 return self.minelayer_load >= ammo_amount || self.ammo_rockets >= ammo_amount;
 507         }
 508         return TRUE;
 509 };
 510 #endif
 511 #ifdef CSQC
 512 float w_minelayer(float req)
 513 {
 514         if(req == WR_IMPACTEFFECT)
 515         {
 516                 vector org2;
 517                 org2 = w_org + w_backoff * 12;
 518                 pointparticles(particleeffectnum("rocket_explode"), org2, '0 0 0', 1);
 519                 if(!w_issilent)
 520                         sound(self, CHAN_PROJECTILE, "weapons/mine_exp.wav", VOL_BASE, ATTN_NORM);
 521         }
 522         else if(req == WR_PRECACHE)
 523         {
 524                 precache_sound("weapons/mine_exp.wav");
 525         }
 526         else if (req == WR_SUICIDEMESSAGE)
 527                 w_deathtypestring = "%s exploded";
 528         else if (req == WR_KILLMESSAGE)
 529         {
 530                 if(w_deathtype & HITTYPE_BOUNCE) // (remote detonation)
 531                         w_deathtypestring = "%s got too close to %s's mine";
 532                 else if(w_deathtype & HITTYPE_SPLASH)
 533                         w_deathtypestring = "%s almost dodged %s's mine";
 534                 else
 535                         w_deathtypestring = "%s stepped on %s's mine";
 536         }
 537         return TRUE;
 538 }
 539 #endif
 540 #endif