qcsrc/server/w_minelayer.qc

   1 #ifdef REGISTER_WEAPON
   2 REGISTER_WEAPON(MINE_LAYER, w_minelayer, IT_ROCKETS, 4, WEP_TYPE_SPLASH, BOT_PICKUP_RATING_HIGH, "minelayer", "minelayer", _("Mine Layer"))
   3 #else
   4 #ifdef SVQC
   5 void W_Mine_Think (void);
   6 .float minelayer_detonate, minelayer_mines;
   7 .float mine_time;
   8
   9 void spawnfunc_weapon_minelayer (void)
  10 {
  11         weapon_defaultspawnfunc(WEP_MINE_LAYER);
  12 }
  13
  14 void W_Mine_Stick ()
  15 {
  16         spamsound (self, CHAN_PROJECTILE, "weapons/mine_stick.wav", VOL_BASE, ATTN_NORM);
  17
  18         // in order for mines to face properly when sticking to the ground, they must be a server side entity rather than a csqc projectile
  19
  20         entity newmine;
  21         newmine = spawn();
  22         newmine.classname = self.classname;
  23
  24         newmine.bot_dodge = self.bot_dodge;
  25         newmine.bot_dodgerating = self.bot_dodgerating;
  26
  27         newmine.owner = self.owner;
  28         setsize(newmine, '-4 -4 -4', '4 4 4');
  29         setorigin(newmine, self.origin);
  30         setmodel(newmine, "models/mine.md3");
  31         newmine.angles = vectoangles(-trace_plane_normal); // face against the surface
  32
  33         newmine.takedamage = self.takedamage;
  34         newmine.damageforcescale = self.damageforcescale;
  35         newmine.health = self.health;
  36         newmine.event_damage = self.event_damage;
  37         newmine.spawnshieldtime = self.spawnshieldtime;
  38
  39         newmine.movetype = MOVETYPE_NONE; // lock the mine in place
  40         newmine.projectiledeathtype = self.projectiledeathtype;
  41
  42         newmine.mine_time = self.mine_time;
  43
  44         newmine.touch = SUB_Null;
  45         newmine.think = W_Mine_Think;
  46         newmine.nextthink = time;
  47         newmine.cnt = self.cnt;
  48         newmine.flags = self.flags;
  49
  50         remove(self);
  51         self = newmine;
  52 }
  53
  54 void W_Mine_Explode ()
  55 {
  56         if(other.takedamage == DAMAGE_AIM)
  57                 if(other.classname == "player")
  58                         if(IsDifferentTeam(self.owner, other))
  59                                 if(IsFlying(other))
  60                                         AnnounceTo(self.owner, "airshot");
  61
  62         self.event_damage = SUB_Null;
  63         self.takedamage = DAMAGE_NO;
  64
  65         RadiusDamage (self, self.owner, autocvar_g_balance_minelayer_damage, autocvar_g_balance_minelayer_edgedamage, autocvar_g_balance_minelayer_radius, world, autocvar_g_balance_minelayer_force, self.projectiledeathtype, other);
  66
  67         if (self.owner.weapon == WEP_MINE_LAYER)
  68         {
  69                 if(self.owner.ammo_rockets < autocvar_g_balance_minelayer_ammo)
  70                 {
  71                         self.owner.cnt = WEP_MINE_LAYER;
  72                         ATTACK_FINISHED(self.owner) = time;
  73                         self.owner.switchweapon = w_getbestweapon(self.owner);
  74                 }
  75         }
  76         remove (self);
  77 }
  78
  79 void W_Mine_DoRemoteExplode ()
  80 {
  81         self.event_damage = SUB_Null;
  82         self.takedamage = DAMAGE_NO;
  83
  84         RadiusDamage (self, self.owner, autocvar_g_balance_minelayer_remote_damage, autocvar_g_balance_minelayer_remote_edgedamage, autocvar_g_balance_minelayer_remote_radius, world, autocvar_g_balance_minelayer_remote_force, self.projectiledeathtype | HITTYPE_BOUNCE, world);
  85
  86         if (self.owner.weapon == WEP_MINE_LAYER)
  87         {
  88                 if(self.owner.ammo_rockets < autocvar_g_balance_minelayer_ammo)
  89                 {
  90                         self.owner.cnt = WEP_MINE_LAYER;
  91                         ATTACK_FINISHED(self.owner) = time;
  92                         self.owner.switchweapon = w_getbestweapon(self.owner);
  93                 }
  94         }
  95         remove (self);
  96 }
  97
  98 void W_Mine_RemoteExplode ()
  99 {
 100         if(self.owner.deadflag == DEAD_NO)
 101                 if((self.spawnshieldtime >= 0)
 102                         ? (time >= self.spawnshieldtime) // timer
 103                         : (vlen(NearestPointOnBox(self.owner, self.origin) - self.origin) > autocvar_g_balance_minelayer_remote_radius) // safety device
 104                 )
 105                 {
 106                         W_Mine_DoRemoteExplode();
 107                 }
 108 }
 109
 110 void W_Mine_ProximityExplode ()
 111 {
 112         // make sure no friend is in the mine's radius. If there is any, explosion is delayed until he's at a safe distance
 113         if(autocvar_g_balance_minelayer_protection)
 114         {
 115                 entity head;
 116                 head = findradius(self.origin, autocvar_g_balance_minelayer_radius);
 117                 while(head)
 118                 {
 119                         if(head == self.owner || !IsDifferentTeam(head, self.owner))
 120                                 return;
 121                         head = head.chain;
 122                 }
 123         }
 124
 125         self.mine_time = 0;
 126         W_Mine_Explode();
 127 }
 128
 129 void W_Mine_Think (void)
 130 {
 131         entity head;
 132
 133         self.nextthink = time;
 134         if ((time > self.cnt) && (!self.mine_time))
 135         {
 136                 spamsound (self, CHAN_PROJECTILE, "weapons/mine_trigger.wav", VOL_BASE, ATTN_NORM);
 137                 self.mine_time = time + autocvar_g_balance_minelayer_lifetime_countdown;
 138         }
 139
 140         // a player's mines shall explode if he disconnects or dies
 141         // TODO: Do this on team change too -- Samual: But isn't a player killed when they switch teams?
 142         if(self.owner.classname != "player" || self.owner.deadflag != DEAD_NO)
 143         {
 144                 other = world;
 145                 self.projectiledeathtype |= HITTYPE_BOUNCE;
 146                 W_Mine_Explode();
 147                 return;
 148         }
 149
 150         // set the mine for detonation when a foe gets close enough
 151         head = findradius(self.origin, autocvar_g_balance_minelayer_proximityradius);
 152         while(head)
 153         {
 154                 if(head.classname == "player" && head.deadflag == DEAD_NO)
 155                 if(head != self.owner && IsDifferentTeam(head, self.owner)) // don't trigger for team mates
 156                 if(!self.mine_time)
 157                 {
 158                         spamsound (self, CHAN_PROJECTILE, "weapons/mine_trigger.wav", VOL_BASE, ATTN_NORM);
 159                         self.mine_time = time + autocvar_g_balance_minelayer_time;
 160                 }
 161                 head = head.chain;
 162         }
 163
 164         // explode if it's time to
 165         if(self.mine_time && time >= self.mine_time)
 166         {
 167                 W_Mine_ProximityExplode();
 168                 return;
 169         }
 170
 171         // remote detonation
 172         if (self.owner.weapon == WEP_MINE_LAYER)
 173         if (self.owner.deadflag == DEAD_NO)
 174         if (self.minelayer_detonate)
 175                 W_Mine_RemoteExplode();
 176 }
 177
 178 void W_Mine_Touch (void)
 179 {
 180         PROJECTILE_TOUCH;
 181         if(!other || (other.takedamage != DAMAGE_AIM && other.movetype == MOVETYPE_NONE))
 182                 W_Mine_Stick();
 183         else if(self.movetype != MOVETYPE_NONE) // don't unstick a locked mine when someone touches it
 184                 self.velocity = '0 0 0';
 185 }
 186
 187 void W_Mine_Damage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 188 {
 189         if (self.health <= 0)
 190                 return;
 191         self.health = self.health - damage;
 192         self.angles = vectoangles(self.velocity);
 193         if (self.health <= 0)
 194                 W_PrepareExplosionByDamage(attacker, W_Mine_Explode);
 195 }
 196
 197 void W_Mine_Attack (void)
 198 {
 199         entity mine;
 200         entity flash;
 201
 202         // scan how many mines we placed, and return if we reached our limit
 203         if(autocvar_g_balance_minelayer_limit)
 204         {
 205                 self.minelayer_mines = 0;
 206                 for(mine = world; (mine = find(mine, classname, "mine")); ) if(mine.owner == self)
 207                         self.minelayer_mines += 1;
 208
 209                 if(self.minelayer_mines >= autocvar_g_balance_minelayer_limit)
 210                 {
 211                         // the refire delay keeps this message from being spammed
 212                         sprint(self, strcat("You cannot place more than ^2", ftos(autocvar_g_balance_minelayer_limit), " ^7mines at a time\n") );
 213                         play2(self, "weapons/unavailable.wav");
 214                         return;
 215                 }
 216         }
 217
 218         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
 219                 self.ammo_rockets = self.ammo_rockets - autocvar_g_balance_minelayer_ammo;
 220
 221         W_SetupShot_ProjectileSize (self, '-4 -4 -4', '4 4 4', FALSE, 5, "weapons/mine_fire.wav", CHAN_WEAPON, autocvar_g_balance_minelayer_damage);
 222         pointparticles(particleeffectnum("rocketlauncher_muzzleflash"), w_shotorg, w_shotdir * 1000, 1);
 223
 224         mine = WarpZone_RefSys_SpawnSameRefSys(self);
 225         mine.owner = self;
 226         if(autocvar_g_balance_minelayer_detonatedelay >= 0)
 227                 mine.spawnshieldtime = time + autocvar_g_balance_minelayer_detonatedelay;
 228         else
 229                 mine.spawnshieldtime = -1;
 230         mine.classname = "mine";
 231         mine.bot_dodge = TRUE;
 232         mine.bot_dodgerating = autocvar_g_balance_minelayer_damage * 2; // * 2 because it can detonate inflight which makes it even more dangerous
 233
 234         mine.takedamage = DAMAGE_YES;
 235         mine.damageforcescale = autocvar_g_balance_minelayer_damageforcescale;
 236         mine.health = autocvar_g_balance_minelayer_health;
 237         mine.event_damage = W_Mine_Damage;
 238
 239         mine.movetype = MOVETYPE_TOSS;
 240         PROJECTILE_MAKETRIGGER(mine);
 241         mine.projectiledeathtype = WEP_MINE_LAYER;
 242         setsize (mine, '-4 -4 -4', '4 4 4'); // give it some size so it can be shot
 243
 244         setorigin (mine, w_shotorg - v_forward * 4); // move it back so it hits the wall at the right point
 245         W_SetupProjectileVelocity(mine, autocvar_g_balance_minelayer_speed, 0);
 246         mine.angles = vectoangles (mine.velocity);
 247
 248         mine.touch = W_Mine_Touch;
 249         mine.think = W_Mine_Think;
 250         mine.nextthink = time;
 251         mine.cnt = time + (autocvar_g_balance_minelayer_lifetime - autocvar_g_balance_minelayer_lifetime_countdown);
 252         mine.flags = FL_PROJECTILE;
 253
 254         CSQCProjectile(mine, TRUE, PROJECTILE_MINE, TRUE);
 255
 256         // muzzle flash for 1st person view
 257         flash = spawn ();
 258         setmodel (flash, "models/flash.md3"); // precision set below
 259         SUB_SetFade (flash, time, 0.1);
 260         flash.effects = EF_ADDITIVE | EF_FULLBRIGHT | EF_LOWPRECISION;
 261         W_AttachToShotorg(flash, '5 0 0');
 262
 263         // common properties
 264
 265         other = mine; MUTATOR_CALLHOOK(EditProjectile);
 266 }
 267
 268 void spawnfunc_weapon_minelayer (void); // defined in t_items.qc
 269
 270 float w_minelayer(float req)
 271 {
 272         entity mine;
 273         float minfound;
 274         if (req == WR_AIM)
 275         {
 276                 // aim and decide to fire if appropriate
 277                 self.BUTTON_ATCK = bot_aim(autocvar_g_balance_minelayer_speed, 0, autocvar_g_balance_minelayer_lifetime, FALSE);
 278                 if(skill >= 2) // skill 0 and 1 bots won't detonate mines!
 279                 {
 280                         // decide whether to detonate mines
 281                         entity targetlist, targ;
 282                         float edgedamage, coredamage, edgeradius, recipricoledgeradius, d;
 283                         float selfdamage, teamdamage, enemydamage;
 284                         edgedamage = autocvar_g_balance_minelayer_edgedamage;
 285                         coredamage = autocvar_g_balance_minelayer_damage;
 286                         edgeradius = autocvar_g_balance_minelayer_radius;
 287                         recipricoledgeradius = 1 / edgeradius;
 288                         selfdamage = 0;
 289                         teamdamage = 0;
 290                         enemydamage = 0;
 291                         targetlist = findchainfloat(bot_attack, TRUE);
 292                         mine = find(world, classname, "mine");
 293                         while (mine)
 294                         {
 295                                 if (mine.owner != self)
 296                                 {
 297                                         mine = find(mine, classname, "mine");
 298                                         continue;
 299                                 }
 300                                 targ = targetlist;
 301                                 while (targ)
 302                                 {
 303                                         d = vlen(targ.origin + (targ.mins + targ.maxs) * 0.5 - mine.origin);
 304                                         d = bound(0, edgedamage + (coredamage - edgedamage) * sqrt(1 - d * recipricoledgeradius), 10000);
 305                                         // count potential damage according to type of target
 306                                         if (targ == self)
 307                                                 selfdamage = selfdamage + d;
 308                                         else if (targ.team == self.team && teams_matter)
 309                                                 teamdamage = teamdamage + d;
 310                                         else if (bot_shouldattack(targ))
 311                                                 enemydamage = enemydamage + d;
 312                                         targ = targ.chain;
 313                                 }
 314                                 mine = find(mine, classname, "mine");
 315                         }
 316                         float desirabledamage;
 317                         desirabledamage = enemydamage;
 318                         if (time > self.invincible_finished && time > self.spawnshieldtime)
 319                                 desirabledamage = desirabledamage - selfdamage * autocvar_g_balance_selfdamagepercent;
 320                         if (teams_matter && self.team)
 321                                 desirabledamage = desirabledamage - teamdamage;
 322
 323                         mine = find(world, classname, "mine");
 324                         while (mine)
 325                         {
 326                                 if (mine.owner != self)
 327                                 {
 328                                         mine = find(mine, classname, "mine");
 329                                         continue;
 330                                 }
 331                                 makevectors(mine.v_angle);
 332                                 targ = targetlist;
 333                                 if (skill > 9) // normal players only do this for the target they are tracking
 334                                 {
 335                                         targ = targetlist;
 336                                         while (targ)
 337                                         {
 338                                                 if (
 339                                                         (v_forward * normalize(mine.origin - targ.origin)< 0.1)
 340                                                         && desirabledamage > 0.1*coredamage
 341                                                 )self.BUTTON_ATCK2 = TRUE;
 342                                                 targ = targ.chain;
 343                                         }
 344                                 }else{
 345                                         float distance; distance= bound(300,vlen(self.origin-self.enemy.origin),30000);
 346                                         //As the distance gets larger, a correct detonation gets near imposible
 347                                         //Bots are assumed to use the mine spawnfunc_light to see if the mine gets near a player
 348                                         if(v_forward * normalize(mine.origin - self.enemy.origin)< 0.1)
 349                                                 if(self.enemy.classname == "player")
 350                                                         if(desirabledamage >= 0.1*coredamage)
 351                                                                 if(random()/distance*300 > frametime*bound(0,(10-skill)*0.2,1))
 352                                                                         self.BUTTON_ATCK2 = TRUE;
 353                                 //      dprint(ftos(random()/distance*300),">");dprint(ftos(frametime*bound(0,(10-skill)*0.2,1)),"\n");
 354                                 }
 355
 356                                 mine = find(mine, classname, "mine");
 357                         }
 358                         // if we would be doing at X percent of the core damage, detonate it
 359                         // but don't fire a new shot at the same time!
 360                         if (desirabledamage >= 0.75 * coredamage) //this should do group damage in rare fortunate events
 361                                 self.BUTTON_ATCK2 = TRUE;
 362                         if ((skill > 6.5) && (selfdamage > self.health))
 363                                 self.BUTTON_ATCK2 = FALSE;
 364                         //if(self.BUTTON_ATCK2 == TRUE)
 365                         //      dprint(ftos(desirabledamage),"\n");
 366                         if (self.BUTTON_ATCK2 == TRUE) self.BUTTON_ATCK = FALSE;
 367                 }
 368         }
 369         else if (req == WR_THINK)
 370         {
 371                 if (self.BUTTON_ATCK)
 372                 {
 373                         if(weapon_prepareattack(0, autocvar_g_balance_minelayer_refire))
 374                         {
 375                                 W_Mine_Attack();
 376                                 weapon_thinkf(WFRAME_FIRE1, autocvar_g_balance_minelayer_animtime, w_ready);
 377                         }
 378                 }
 379
 380                 if (self.BUTTON_ATCK2)
 381                 {
 382                         minfound = 0;
 383                         for(mine = world; (mine = find(mine, classname, "mine")); ) if(mine.owner == self)
 384                         {
 385                                 if(!mine.minelayer_detonate)
 386                                 {
 387                                         mine.minelayer_detonate = TRUE;
 388                                         minfound = 1;
 389                                 }
 390                         }
 391                         if(minfound)
 392                                 sound (self, CHAN_WEAPON2, "weapons/mine_det.wav", VOL_BASE, ATTN_NORM);
 393                 }
 394         }
 395         else if (req == WR_PRECACHE)
 396         {
 397                 precache_model ("models/flash.md3");
 398                 precache_model ("models/mine.md3");
 399                 precache_model ("models/weapons/g_minelayer.md3");
 400                 precache_model ("models/weapons/v_minelayer.md3");
 401                 precache_model ("models/weapons/h_minelayer.iqm");
 402                 precache_sound ("weapons/mine_det.wav");
 403                 precache_sound ("weapons/mine_fire.wav");
 404                 precache_sound ("weapons/mine_stick.wav");
 405                 precache_sound ("weapons/mine_trigger.wav");
 406         }
 407         else if (req == WR_SETUP)
 408         {
 409                 weapon_setup(WEP_MINE_LAYER);
 410         }
 411         else if (req == WR_CHECKAMMO1)
 412         {
 413                 // don't switch while placing a mine
 414                 if ((ATTACK_FINISHED(self) <= time || self.weapon != WEP_MINE_LAYER)
 415                         && self.ammo_rockets < autocvar_g_balance_minelayer_ammo)
 416                         return FALSE;
 417         }
 418         else if (req == WR_CHECKAMMO2)
 419                 return FALSE;
 420         return TRUE;
 421 };
 422 #endif
 423 #ifdef CSQC
 424 float w_minelayer(float req)
 425 {
 426         if(req == WR_IMPACTEFFECT)
 427         {
 428                 vector org2;
 429                 org2 = w_org + w_backoff * 12;
 430                 pointparticles(particleeffectnum("rocket_explode"), org2, '0 0 0', 1);
 431                 if(!w_issilent)
 432                         sound(self, CHAN_PROJECTILE, "weapons/mine_exp.wav", VOL_BASE, ATTN_NORM);
 433         }
 434         else if(req == WR_PRECACHE)
 435         {
 436                 precache_sound("weapons/mine_exp.wav");
 437         }
 438         else if (req == WR_SUICIDEMESSAGE)
 439                 w_deathtypestring = _("%s exploded");
 440         else if (req == WR_KILLMESSAGE)
 441         {
 442                 if(w_deathtype & HITTYPE_BOUNCE) // (remote detonation)
 443                         w_deathtypestring = _("%s got too close to %s's mine");
 444                 else if(w_deathtype & HITTYPE_SPLASH)
 445                         w_deathtypestring = _("%s almost dodged %s's mine");
 446                 else
 447                         w_deathtypestring = _("%s stepped on %s's mine");
 448         }
 449         return TRUE;
 450 }
 451 #endif
 452 #endif