qcsrc/server/w_minelayer.qc

   1 #ifdef REGISTER_WEAPON
   2 REGISTER_WEAPON(MINE_LAYER, w_minelayer, IT_ROCKETS, 4, WEP_FLAG_RELOADABLE | WEP_TYPE_SPLASH, BOT_PICKUP_RATING_HIGH, "minelayer", "minelayer", _("Mine Layer"))
   3 #else
   4 #ifdef SVQC
   5 void W_Mine_Think (void);
   6 .float minelayer_detonate, mine_explodeanyway;
   7 .float mine_time;
   8
   9 void spawnfunc_weapon_minelayer (void)
  10 {
  11         weapon_defaultspawnfunc(WEP_MINE_LAYER);
  12 }
  13
  14 void W_Mine_Stick ()
  15 {
  16         spamsound (self, CHAN_PROJECTILE, "weapons/mine_stick.wav", VOL_BASE, ATTN_NORM);
  17
  18         // in order for mines to face properly when sticking to the ground, they must be a server side entity rather than a csqc projectile
  19
  20         entity newmine;
  21         newmine = spawn();
  22         newmine.classname = self.classname;
  23
  24         newmine.bot_dodge = self.bot_dodge;
  25         newmine.bot_dodgerating = self.bot_dodgerating;
  26
  27         newmine.owner = self.owner;
  28         setsize(newmine, '-4 -4 -4', '4 4 4');
  29         setorigin(newmine, self.origin);
  30         setmodel(newmine, "models/mine.md3");
  31         newmine.angles = vectoangles(-trace_plane_normal); // face against the surface
  32
  33         newmine.takedamage = self.takedamage;
  34         newmine.damageforcescale = self.damageforcescale;
  35         newmine.health = self.health;
  36         newmine.event_damage = self.event_damage;
  37         newmine.spawnshieldtime = self.spawnshieldtime;
  38
  39         newmine.movetype = MOVETYPE_NONE; // lock the mine in place
  40         newmine.projectiledeathtype = self.projectiledeathtype;
  41
  42         newmine.mine_time = self.mine_time;
  43
  44         newmine.touch = SUB_Null;
  45         newmine.think = W_Mine_Think;
  46         newmine.nextthink = time;
  47         newmine.cnt = self.cnt;
  48         newmine.flags = self.flags;
  49
  50         remove(self);
  51         self = newmine;
  52 }
  53
  54 void W_Mine_Explode ()
  55 {
  56         if(other.takedamage == DAMAGE_AIM)
  57                 if(other.classname == "player")
  58                         if(IsDifferentTeam(self.owner, other))
  59                                 if(IsFlying(other))
  60                                         AnnounceTo(self.owner, "airshot");
  61
  62         self.event_damage = SUB_Null;
  63         self.takedamage = DAMAGE_NO;
  64
  65         RadiusDamage (self, self.owner, autocvar_g_balance_minelayer_damage, autocvar_g_balance_minelayer_edgedamage, autocvar_g_balance_minelayer_radius, world, autocvar_g_balance_minelayer_force, self.projectiledeathtype, other);
  66
  67         if (self.owner.weapon == WEP_MINE_LAYER)
  68         {
  69                 entity oldself;
  70                 oldself = self;
  71                 self = self.owner;
  72                 if (!weapon_action(WEP_MINE_LAYER, WR_CHECKAMMO1))
  73                 {
  74                         self.cnt = WEP_MINE_LAYER;
  75                         ATTACK_FINISHED(self) = time;
  76                         self.switchweapon = w_getbestweapon(self);
  77                 }
  78                 self = oldself;
  79         }
  80         self.owner.minelayer_mines -= 1;
  81         remove (self);
  82 }
  83
  84 void W_Mine_DoRemoteExplode ()
  85 {
  86         self.event_damage = SUB_Null;
  87         self.takedamage = DAMAGE_NO;
  88
  89         RadiusDamage (self, self.owner, autocvar_g_balance_minelayer_remote_damage, autocvar_g_balance_minelayer_remote_edgedamage, autocvar_g_balance_minelayer_remote_radius, world, autocvar_g_balance_minelayer_remote_force, self.projectiledeathtype | HITTYPE_BOUNCE, world);
  90
  91         if (self.owner.weapon == WEP_MINE_LAYER)
  92         {
  93                 entity oldself;
  94                 oldself = self;
  95                 self = self.owner;
  96                 if (!weapon_action(WEP_MINE_LAYER, WR_CHECKAMMO1))
  97                 {
  98                         self.cnt = WEP_MINE_LAYER;
  99                         ATTACK_FINISHED(self) = time;
 100                         self.switchweapon = w_getbestweapon(self);
 101                 }
 102                 self = oldself;
 103         }
 104         self.owner.minelayer_mines -= 1;
 105         remove (self);
 106 }
 107
 108 void W_Mine_RemoteExplode ()
 109 {
 110         if(self.owner.deadflag == DEAD_NO)
 111                 if((self.spawnshieldtime >= 0)
 112                         ? (time >= self.spawnshieldtime) // timer
 113                         : (vlen(NearestPointOnBox(self.owner, self.origin) - self.origin) > autocvar_g_balance_minelayer_remote_radius) // safety device
 114                 )
 115                 {
 116                         W_Mine_DoRemoteExplode();
 117                 }
 118 }
 119
 120 void W_Mine_ProximityExplode ()
 121 {
 122         // make sure no friend is in the mine's radius. If there is any, explosion is delayed until he's at a safe distance
 123         if(autocvar_g_balance_minelayer_protection && self.mine_explodeanyway == 0)
 124         {
 125                 entity head;
 126                 head = findradius(self.origin, autocvar_g_balance_minelayer_radius);
 127                 while(head)
 128                 {
 129                         if(head == self.owner || !IsDifferentTeam(head, self.owner))
 130                                 return;
 131                         head = head.chain;
 132                 }
 133         }
 134
 135         self.mine_time = 0;
 136         W_Mine_Explode();
 137 }
 138
 139 float W_Mine_Count(entity e)
 140 {
 141         float minecount;
 142         entity mine;
 143         for(mine = world; (mine = find(mine, classname, "mine")); ) if(mine.owner == e)
 144                 minecount += 1;
 145
 146         return minecount;
 147 }
 148
 149 void W_Mine_Think (void)
 150 {
 151         entity head;
 152
 153         self.nextthink = time;
 154
 155         // our lifetime has expired, it's time to die - mine_time just allows us to play a sound for this
 156         // TODO: replace this mine_trigger.wav sound with a real countdown
 157         if ((time > self.cnt) && (!self.mine_time))
 158         {
 159                 if(autocvar_g_balance_minelayer_lifetime_countdown > 0)
 160                         spamsound (self, CHAN_PROJECTILE, "weapons/mine_trigger.wav", VOL_BASE, ATTN_NORM);
 161                 self.mine_time = time + autocvar_g_balance_minelayer_lifetime_countdown;
 162                 self.mine_explodeanyway = 1; // make the mine super aggressive -- Samual: Rather, make it not care if a team mate is near.
 163         }
 164
 165         // a player's mines shall explode if he disconnects or dies
 166         // TODO: Do this on team change too -- Samual: But isn't a player killed when they switch teams?
 167         if(self.owner.classname != "player" || self.owner.deadflag != DEAD_NO)
 168         {
 169                 other = world;
 170                 self.projectiledeathtype |= HITTYPE_BOUNCE;
 171                 W_Mine_Explode();
 172                 return;
 173         }
 174
 175         // set the mine for detonation when a foe gets close enough
 176         head = findradius(self.origin, autocvar_g_balance_minelayer_proximityradius);
 177         while(head)
 178         {
 179                 if(head.classname == "player" && head.deadflag == DEAD_NO)
 180                 if(head != self.owner && IsDifferentTeam(head, self.owner)) // don't trigger for team mates
 181                 if(!self.mine_time)
 182                 {
 183                         spamsound (self, CHAN_PROJECTILE, "weapons/mine_trigger.wav", VOL_BASE, ATTN_NORM);
 184                         self.mine_time = time + autocvar_g_balance_minelayer_time;
 185                 }
 186                 head = head.chain;
 187         }
 188
 189         // explode if it's time to
 190         if(self.mine_time && time >= self.mine_time)
 191         {
 192                 W_Mine_ProximityExplode();
 193                 return;
 194         }
 195
 196         // remote detonation
 197         if (self.owner.weapon == WEP_MINE_LAYER)
 198         if (self.owner.deadflag == DEAD_NO)
 199         if (self.minelayer_detonate)
 200                 W_Mine_RemoteExplode();
 201 }
 202
 203 void W_Mine_Touch (void)
 204 {
 205         PROJECTILE_TOUCH;
 206         if(!other || (other.takedamage != DAMAGE_AIM && other.movetype == MOVETYPE_NONE))
 207                 W_Mine_Stick();
 208         else if(self.movetype != MOVETYPE_NONE) // don't unstick a locked mine when someone touches it
 209                 self.velocity = '0 0 0';
 210 }
 211
 212 void W_Mine_Damage (entity inflictor, entity attacker, float damage, float deathtype, vector hitloc, vector force)
 213 {
 214         if (self.health <= 0)
 215                 return;
 216         self.health = self.health - damage;
 217         self.angles = vectoangles(self.velocity);
 218         if (self.health <= 0)
 219                 W_PrepareExplosionByDamage(attacker, W_Mine_Explode);
 220 }
 221
 222 void W_Mine_Attack (void)
 223 {
 224         entity mine;
 225         entity flash;
 226
 227         // scan how many mines we placed, and return if we reached our limit
 228         if(autocvar_g_balance_minelayer_limit)
 229         {
 230
 231                 if(W_Mine_Count(self) >= autocvar_g_balance_minelayer_limit)
 232                 {
 233                         // the refire delay keeps this message from being spammed
 234                         sprint(self, strcat("You cannot place more than ^2", ftos(autocvar_g_balance_minelayer_limit), " ^7mines at a time\n") );
 235                         play2(self, "weapons/unavailable.wav");
 236                         return;
 237                 }
 238         }
 239
 240         W_DecreaseAmmo(ammo_rockets, autocvar_g_balance_minelayer_ammo, autocvar_g_balance_minelayer_reload_ammo);
 241
 242         W_SetupShot_ProjectileSize (self, '-4 -4 -4', '4 4 4', FALSE, 5, "weapons/mine_fire.wav", CHAN_WEAPON, autocvar_g_balance_minelayer_damage);
 243         pointparticles(particleeffectnum("rocketlauncher_muzzleflash"), w_shotorg, w_shotdir * 1000, 1);
 244
 245         mine = WarpZone_RefSys_SpawnSameRefSys(self);
 246         mine.owner = self;
 247         if(autocvar_g_balance_minelayer_detonatedelay >= 0)
 248                 mine.spawnshieldtime = time + autocvar_g_balance_minelayer_detonatedelay;
 249         else
 250                 mine.spawnshieldtime = -1;
 251         mine.classname = "mine";
 252         mine.bot_dodge = TRUE;
 253         mine.bot_dodgerating = autocvar_g_balance_minelayer_damage * 2; // * 2 because it can detonate inflight which makes it even more dangerous
 254
 255         mine.takedamage = DAMAGE_YES;
 256         mine.damageforcescale = autocvar_g_balance_minelayer_damageforcescale;
 257         mine.health = autocvar_g_balance_minelayer_health;
 258         mine.event_damage = W_Mine_Damage;
 259
 260         mine.movetype = MOVETYPE_TOSS;
 261         PROJECTILE_MAKETRIGGER(mine);
 262         mine.projectiledeathtype = WEP_MINE_LAYER;
 263         setsize (mine, '-4 -4 -4', '4 4 4'); // give it some size so it can be shot
 264
 265         setorigin (mine, w_shotorg - v_forward * 4); // move it back so it hits the wall at the right point
 266         W_SetupProjectileVelocity(mine, autocvar_g_balance_minelayer_speed, 0);
 267         mine.angles = vectoangles (mine.velocity);
 268
 269         mine.touch = W_Mine_Touch;
 270         mine.think = W_Mine_Think;
 271         mine.nextthink = time;
 272         mine.cnt = time + (autocvar_g_balance_minelayer_lifetime - autocvar_g_balance_minelayer_lifetime_countdown);
 273         mine.flags = FL_PROJECTILE;
 274
 275         CSQCProjectile(mine, TRUE, PROJECTILE_MINE, TRUE);
 276
 277         // muzzle flash for 1st person view
 278         flash = spawn ();
 279         setmodel (flash, "models/flash.md3"); // precision set below
 280         SUB_SetFade (flash, time, 0.1);
 281         flash.effects = EF_ADDITIVE | EF_FULLBRIGHT | EF_LOWPRECISION;
 282         W_AttachToShotorg(flash, '5 0 0');
 283
 284         // common properties
 285
 286         other = mine; MUTATOR_CALLHOOK(EditProjectile);
 287
 288         self.minelayer_mines = W_Mine_Count(self);
 289 }
 290
 291 void spawnfunc_weapon_minelayer (void); // defined in t_items.qc
 292
 293 float W_PlacedMines(float detonate)
 294 {
 295         entity mine;
 296         float minfound;
 297
 298         for(mine = world; (mine = find(mine, classname, "mine")); ) if(mine.owner == self)
 299         {
 300                 if(detonate)
 301                 {
 302                         if(!mine.minelayer_detonate)
 303                         {
 304                                 mine.minelayer_detonate = TRUE;
 305                                 minfound = 1;
 306                         }
 307                 }
 308                 else
 309                         minfound = 1;
 310         }
 311         return minfound;
 312 }
 313
 314 float w_minelayer(float req)
 315 {
 316         entity mine;
 317         float ammo_amount;
 318
 319         if (req == WR_AIM)
 320         {
 321                 // aim and decide to fire if appropriate
 322                 self.BUTTON_ATCK = bot_aim(autocvar_g_balance_minelayer_speed, 0, autocvar_g_balance_minelayer_lifetime, FALSE);
 323                 if(skill >= 2) // skill 0 and 1 bots won't detonate mines!
 324                 {
 325                         // decide whether to detonate mines
 326                         entity targetlist, targ;
 327                         float edgedamage, coredamage, edgeradius, recipricoledgeradius, d;
 328                         float selfdamage, teamdamage, enemydamage;
 329                         edgedamage = autocvar_g_balance_minelayer_edgedamage;
 330                         coredamage = autocvar_g_balance_minelayer_damage;
 331                         edgeradius = autocvar_g_balance_minelayer_radius;
 332                         recipricoledgeradius = 1 / edgeradius;
 333                         selfdamage = 0;
 334                         teamdamage = 0;
 335                         enemydamage = 0;
 336                         targetlist = findchainfloat(bot_attack, TRUE);
 337                         mine = find(world, classname, "mine");
 338                         while (mine)
 339                         {
 340                                 if (mine.owner != self)
 341                                 {
 342                                         mine = find(mine, classname, "mine");
 343                                         continue;
 344                                 }
 345                                 targ = targetlist;
 346                                 while (targ)
 347                                 {
 348                                         d = vlen(targ.origin + (targ.mins + targ.maxs) * 0.5 - mine.origin);
 349                                         d = bound(0, edgedamage + (coredamage - edgedamage) * sqrt(1 - d * recipricoledgeradius), 10000);
 350                                         // count potential damage according to type of target
 351                                         if (targ == self)
 352                                                 selfdamage = selfdamage + d;
 353                                         else if (targ.team == self.team && teams_matter)
 354                                                 teamdamage = teamdamage + d;
 355                                         else if (bot_shouldattack(targ))
 356                                                 enemydamage = enemydamage + d;
 357                                         targ = targ.chain;
 358                                 }
 359                                 mine = find(mine, classname, "mine");
 360                         }
 361                         float desirabledamage;
 362                         desirabledamage = enemydamage;
 363                         if (time > self.invincible_finished && time > self.spawnshieldtime)
 364                                 desirabledamage = desirabledamage - selfdamage * autocvar_g_balance_selfdamagepercent;
 365                         if (teams_matter && self.team)
 366                                 desirabledamage = desirabledamage - teamdamage;
 367
 368                         mine = find(world, classname, "mine");
 369                         while (mine)
 370                         {
 371                                 if (mine.owner != self)
 372                                 {
 373                                         mine = find(mine, classname, "mine");
 374                                         continue;
 375                                 }
 376                                 makevectors(mine.v_angle);
 377                                 targ = targetlist;
 378                                 if (skill > 9) // normal players only do this for the target they are tracking
 379                                 {
 380                                         targ = targetlist;
 381                                         while (targ)
 382                                         {
 383                                                 if (
 384                                                         (v_forward * normalize(mine.origin - targ.origin)< 0.1)
 385                                                         && desirabledamage > 0.1*coredamage
 386                                                 )self.BUTTON_ATCK2 = TRUE;
 387                                                 targ = targ.chain;
 388                                         }
 389                                 }else{
 390                                         float distance; distance= bound(300,vlen(self.origin-self.enemy.origin),30000);
 391                                         //As the distance gets larger, a correct detonation gets near imposible
 392                                         //Bots are assumed to use the mine spawnfunc_light to see if the mine gets near a player
 393                                         if(v_forward * normalize(mine.origin - self.enemy.origin)< 0.1)
 394                                                 if(self.enemy.classname == "player")
 395                                                         if(desirabledamage >= 0.1*coredamage)
 396                                                                 if(random()/distance*300 > frametime*bound(0,(10-skill)*0.2,1))
 397                                                                         self.BUTTON_ATCK2 = TRUE;
 398                                 //      dprint(ftos(random()/distance*300),">");dprint(ftos(frametime*bound(0,(10-skill)*0.2,1)),"\n");
 399                                 }
 400
 401                                 mine = find(mine, classname, "mine");
 402                         }
 403                         // if we would be doing at X percent of the core damage, detonate it
 404                         // but don't fire a new shot at the same time!
 405                         if (desirabledamage >= 0.75 * coredamage) //this should do group damage in rare fortunate events
 406                                 self.BUTTON_ATCK2 = TRUE;
 407                         if ((skill > 6.5) && (selfdamage > self.health))
 408                                 self.BUTTON_ATCK2 = FALSE;
 409                         //if(self.BUTTON_ATCK2 == TRUE)
 410                         //      dprint(ftos(desirabledamage),"\n");
 411                         if (self.BUTTON_ATCK2 == TRUE) self.BUTTON_ATCK = FALSE;
 412                 }
 413         }
 414         else if (req == WR_THINK)
 415         {
 416                 if(autocvar_g_balance_minelayer_reload_ammo && self.clip_load < autocvar_g_balance_minelayer_ammo) // forced reload
 417                 {
 418                         // not if we're holding the minelayer without enough ammo, but can detonate existing mines
 419                         if not (W_PlacedMines(FALSE) && self.ammo_rockets < autocvar_g_balance_minelayer_ammo)
 420                                 weapon_action(self.weapon, WR_RELOAD);
 421                 }
 422                 else if (self.BUTTON_ATCK)
 423                 {
 424                         if(weapon_prepareattack(0, autocvar_g_balance_minelayer_refire))
 425                         {
 426                                 W_Mine_Attack();
 427                                 weapon_thinkf(WFRAME_FIRE1, autocvar_g_balance_minelayer_animtime, w_ready);
 428                         }
 429                 }
 430
 431                 if (self.BUTTON_ATCK2)
 432                 {
 433                         if(W_PlacedMines(TRUE))
 434                                 sound (self, CHAN_WEAPON2, "weapons/mine_det.wav", VOL_BASE, ATTN_NORM);
 435                 }
 436         }
 437         else if (req == WR_PRECACHE)
 438         {
 439                 precache_model ("models/flash.md3");
 440                 precache_model ("models/mine.md3");
 441                 precache_model ("models/weapons/g_minelayer.md3");
 442                 precache_model ("models/weapons/v_minelayer.md3");
 443                 precache_model ("models/weapons/h_minelayer.iqm");
 444                 precache_sound ("weapons/mine_det.wav");
 445                 precache_sound ("weapons/mine_fire.wav");
 446                 precache_sound ("weapons/mine_stick.wav");
 447                 precache_sound ("weapons/mine_trigger.wav");
 448                 //precache_sound ("weapons/reload.wav"); // until weapons have individual reload sounds, precache the reload sound somewhere else
 449         }
 450         else if (req == WR_SETUP)
 451         {
 452                 weapon_setup(WEP_MINE_LAYER);
 453                 self.current_ammo = ammo_rockets;
 454         }
 455         else if (req == WR_CHECKAMMO1)
 456         {
 457                 // don't switch while placing a mine
 458                 if (ATTACK_FINISHED(self) <= time || self.weapon != WEP_MINE_LAYER)
 459                 {
 460                         ammo_amount = self.ammo_rockets >= autocvar_g_balance_minelayer_ammo;
 461                         ammo_amount += self.weapon_load[WEP_MINE_LAYER] >= autocvar_g_balance_minelayer_ammo;
 462                         return ammo_amount;
 463                 }
 464         }
 465         else if (req == WR_CHECKAMMO2)
 466         {
 467                 if (W_PlacedMines(FALSE))
 468                         return TRUE;
 469                 else
 470                         return FALSE;
 471         }
 472         else if (req == WR_RELOAD)
 473         {
 474                 W_Reload(autocvar_g_balance_minelayer_ammo, autocvar_g_balance_minelayer_reload_ammo, autocvar_g_balance_minelayer_reload_time, "weapons/reload.wav");
 475         }
 476         return TRUE;
 477 };
 478 #endif
 479 #ifdef CSQC
 480 float w_minelayer(float req)
 481 {
 482         if(req == WR_IMPACTEFFECT)
 483         {
 484                 vector org2;
 485                 org2 = w_org + w_backoff * 12;
 486                 pointparticles(particleeffectnum("rocket_explode"), org2, '0 0 0', 1);
 487                 if(!w_issilent)
 488                         sound(self, CHAN_PROJECTILE, "weapons/mine_exp.wav", VOL_BASE, ATTN_NORM);
 489         }
 490         else if(req == WR_PRECACHE)
 491         {
 492                 precache_sound("weapons/mine_exp.wav");
 493         }
 494         else if (req == WR_SUICIDEMESSAGE)
 495                 w_deathtypestring = _("%s exploded");
 496         else if (req == WR_KILLMESSAGE)
 497         {
 498                 if(w_deathtype & HITTYPE_BOUNCE) // (remote detonation)
 499                         w_deathtypestring = _("%s got too close to %s's mine");
 500                 else if(w_deathtype & HITTYPE_SPLASH)
 501                         w_deathtypestring = _("%s almost dodged %s's mine");
 502                 else
 503                         w_deathtypestring = _("%s stepped on %s's mine");
 504         }
 505         return TRUE;
 506 }
 507 #endif
 508 #endif