qcsrc/server/w_minstanex.qc

   1 #ifdef REGISTER_WEAPON
   2 REGISTER_WEAPON(MINSTANEX, w_minstanex, IT_CELLS, 7, WEP_FLAG_RELOADABLE | WEP_FLAG_CANCLIMB | WEP_FLAG_SUPERWEAPON | WEP_TYPE_HITSCAN, BOT_PICKUP_RATING_HIGH, "minstanex", "minstanex", _("MinstaNex"))
   3 #else
   4 #ifdef SVQC
   5 .float minstanex_lasthit;
   6 .float jump_interval;
   7
   8 void W_MinstaNex_Attack (void)
   9 {
  10         float flying;
  11         flying = IsFlying(self); // do this BEFORE to make the trace values from FireRailgunBullet last
  12
  13         W_SetupShot (self, TRUE, 0, "weapons/minstanexfire.wav", CH_WEAPON_A, 10000);
  14
  15         yoda = 0;
  16         damage_goodhits = 0;
  17         headshot = 0;
  18         damage_headshotbonus = -1; // no extra damage, just count
  19         FireRailgunBullet (w_shotorg, w_shotorg + w_shotdir * MAX_SHOT_DISTANCE, 10000, 800, 0, 0, 0, 0, WEP_MINSTANEX);
  20         damage_headshotbonus = 0;
  21
  22         if(g_minstagib)
  23         {
  24                 if(yoda)
  25                         AnnounceTo(self, "yoda");
  26         }
  27         else
  28         {
  29                 if(yoda && flying)
  30                         AnnounceTo(self, "yoda");
  31                 if(headshot)
  32                 {
  33                         AnnounceTo(self, "headshot");
  34                 }
  35                 if(damage_goodhits && self.minstanex_lasthit)
  36                 {
  37                         AnnounceTo(self, "impressive");
  38                         damage_goodhits = 0; // only every second time
  39                 }
  40         }
  41
  42         self.minstanex_lasthit = damage_goodhits;
  43
  44         pointparticles(particleeffectnum("nex_muzzleflash"), w_shotorg, w_shotdir * 1000, 1);
  45
  46         // teamcolor / hit beam effect
  47         vector v;
  48         v = WarpZone_UnTransformOrigin(WarpZone_trace_transform, trace_endpos);
  49         if(teamplay)
  50         {
  51             switch(self.team)
  52             {
  53             case COLOR_TEAM1:   // Red
  54                 if(damage_goodhits)
  55                     WarpZone_TrailParticles(world, particleeffectnum("TE_TEI_G3RED_HIT"), w_shotorg, v);
  56                 else
  57                     WarpZone_TrailParticles(world, particleeffectnum("TE_TEI_G3RED"), w_shotorg, v);
  58                 break;
  59             case COLOR_TEAM2:   // Blue
  60                 if(damage_goodhits)
  61                     WarpZone_TrailParticles(world, particleeffectnum("TE_TEI_G3BLUE_HIT"), w_shotorg, v);
  62                 else
  63                     WarpZone_TrailParticles(world, particleeffectnum("TE_TEI_G3BLUE"), w_shotorg, v);
  64                 break;
  65             case COLOR_TEAM3:   // Yellow
  66                 if(damage_goodhits)
  67                     WarpZone_TrailParticles(world, particleeffectnum("TE_TEI_G3YELLOW_HIT"), w_shotorg, v);
  68                 else
  69                     WarpZone_TrailParticles(world, particleeffectnum("TE_TEI_G3YELLOW"), w_shotorg, v);
  70                 break;
  71             case COLOR_TEAM4:   // Pink
  72                 if(damage_goodhits)
  73                     WarpZone_TrailParticles(world, particleeffectnum("TE_TEI_G3PINK_HIT"), w_shotorg, v);
  74                 else
  75                     WarpZone_TrailParticles(world, particleeffectnum("TE_TEI_G3PINK"), w_shotorg, v);
  76                 break;
  77             }
  78         }
  79         else
  80         WarpZone_TrailParticles(world, particleeffectnum("TE_TEI_G3"), w_shotorg, v);
  81
  82         if (g_minstagib)
  83                 W_DecreaseAmmo(ammo_cells, 1, autocvar_g_balance_minstanex_reload_ammo);
  84         else
  85                 W_DecreaseAmmo(ammo_cells, autocvar_g_balance_minstanex_ammo, autocvar_g_balance_minstanex_reload_ammo);
  86 }
  87
  88
  89 .float minstagib_nextthink;
  90 .float minstagib_needammo;
  91 void minstagib_stop_countdown(entity e)
  92 {
  93         if (!e.minstagib_needammo)
  94                 return;
  95         Send_CSQC_Centerprint_Generic_Expire(e, CPID_MINSTA_FINDAMMO);
  96         e.minstagib_needammo = FALSE;
  97 }
  98 void minstagib_ammocheck(void)
  99 {
 100         if (time < self.minstagib_nextthink)
 101                 return;
 102
 103         if (self.deadflag || gameover)
 104                 minstagib_stop_countdown(self);
 105         else if (self.ammo_cells > 0 || (self.items & IT_UNLIMITED_WEAPON_AMMO))
 106         {
 107                 if (self.minstagib_needammo)
 108                         self.health = 100;
 109                 minstagib_stop_countdown(self);
 110         }
 111         else
 112         {
 113                 self.minstagib_needammo = TRUE;
 114                 if (self.health == 5)
 115                 {
 116                         Damage(self, self, self, 5, DEATH_NOAMMO, self.origin, '0 0 0');
 117                         AnnounceTo(self, "terminated");
 118                 }
 119                 else if (self.health == 10)
 120                 {
 121                         Damage(self, self, self, 5, DEATH_NOAMMO, self.origin, '0 0 0');
 122                         AnnounceTo(self, "1");
 123                 }
 124                 else if (self.health == 20)
 125                 {
 126                         Damage(self, self, self, 10, DEATH_NOAMMO, self.origin, '0 0 0');
 127                         AnnounceTo(self, "2");
 128                 }
 129                 else if (self.health == 30)
 130                 {
 131                         Damage(self, self, self, 10, DEATH_NOAMMO, self.origin, '0 0 0');
 132                         AnnounceTo(self, "3");
 133                 }
 134                 else if (self.health == 40)
 135                 {
 136                         Damage(self, self, self, 10, DEATH_NOAMMO, self.origin, '0 0 0');
 137                         AnnounceTo(self, "4");
 138                 }
 139                 else if (self.health == 50)
 140                 {
 141                         Damage(self, self, self, 10, DEATH_NOAMMO, self.origin, '0 0 0');
 142                         AnnounceTo(self, "5");
 143                 }
 144                 else if (self.health == 60)
 145                 {
 146                         Damage(self, self, self, 10, DEATH_NOAMMO, self.origin, '0 0 0');
 147                         AnnounceTo(self, "6");
 148                 }
 149                 else if (self.health == 70)
 150                 {
 151                         Damage(self, self, self, 10, DEATH_NOAMMO, self.origin, '0 0 0');
 152                         AnnounceTo(self, "7");
 153                 }
 154                 else if (self.health == 80)
 155                 {
 156                         Damage(self, self, self, 10, DEATH_NOAMMO, self.origin, '0 0 0');
 157                         AnnounceTo(self, "8");
 158                 }
 159                 else if (self.health == 90)
 160                 {
 161                         Send_CSQC_Centerprint_Generic(self, CPID_MINSTA_FINDAMMO, "^1%d^7 seconds left to find some ammo", 1, 9);
 162                         Damage(self, self, self, 10, DEATH_NOAMMO, self.origin, '0 0 0');
 163                         AnnounceTo(self, "9");
 164                 }
 165                 else if (self.health == 100)
 166                 {
 167                         Send_CSQC_Centerprint_Generic(self, CPID_MINSTA_FINDAMMO, "get some ammo or\nyou'll be dead in ^3%d^7 seconds...", 1, 10);
 168                         Damage(self, self, self, 10, DEATH_NOAMMO, self.origin, '0 0 0');
 169                         if not(self.flags & FL_GODMODE)
 170                                 AnnounceTo(self, "10");
 171                 }
 172         }
 173         self.minstagib_nextthink = time + 1;
 174 }
 175
 176 void spawnfunc_weapon_minstanex (void); // defined in t_items.qc
 177
 178 float w_minstanex(float req)
 179 {
 180         float ammo_amount;
 181         float minstanex_ammo;
 182
 183         // now multiple WR_s use this
 184         if(g_minstagib)
 185                 minstanex_ammo = 1;
 186         else
 187                 minstanex_ammo = autocvar_g_balance_minstanex_ammo;
 188
 189         if (req == WR_AIM)
 190         {
 191                 if(self.ammo_cells > 0)
 192                         self.BUTTON_ATCK = bot_aim(1000000, 0, 1, FALSE);
 193                 else
 194                         self.BUTTON_ATCK2 = bot_aim(autocvar_g_balance_laser_primary_speed, 0, autocvar_g_balance_laser_primary_lifetime, FALSE);
 195         }
 196         else if (req == WR_THINK)
 197         {
 198                 // if the laser uses load, we also consider its ammo for reloading
 199                 if(autocvar_g_balance_minstanex_reload_ammo && autocvar_g_balance_minstanex_laser_ammo && self.clip_load < min(minstanex_ammo, autocvar_g_balance_minstanex_laser_ammo)) // forced reload
 200                         weapon_action(self.weapon, WR_RELOAD);
 201                 else if(autocvar_g_balance_minstanex_reload_ammo && self.clip_load < minstanex_ammo) // forced reload
 202                         weapon_action(self.weapon, WR_RELOAD);
 203                 else if (self.BUTTON_ATCK)
 204                 {
 205                         if (weapon_prepareattack(0, autocvar_g_balance_minstanex_refire))
 206                         {
 207                                 W_MinstaNex_Attack();
 208                                 weapon_thinkf(WFRAME_FIRE1, autocvar_g_balance_minstanex_animtime, w_ready);
 209                         }
 210                 }
 211                 else if (self.BUTTON_ATCK2)
 212                 {
 213                         if (self.jump_interval <= time)
 214                         if (weapon_prepareattack(1, -1))
 215                         {
 216                                 // handle refire manually, so that primary and secondary can be fired without conflictions (important for minstagib)
 217                                 self.jump_interval = time + autocvar_g_balance_minstanex_laser_refire * W_WeaponRateFactor();
 218
 219                                 // decrease ammo for the laser?
 220                                 if(autocvar_g_balance_minstanex_laser_ammo)
 221                                         W_DecreaseAmmo(ammo_cells, autocvar_g_balance_minstanex_laser_ammo, autocvar_g_balance_minstanex_reload_ammo);
 222
 223                                 // ugly minstagib hack to reuse the fire mode of the laser
 224                                 float w;
 225                                 w = self.weapon;
 226                                 self.weapon = WEP_LASER;
 227                                 W_Laser_Attack(2);
 228                                 self.weapon = w;
 229
 230                                 // now do normal refire
 231                                 weapon_thinkf(WFRAME_FIRE2, autocvar_g_balance_minstanex_laser_animtime, w_ready);
 232                         }
 233                 }
 234         }
 235         else if (req == WR_PRECACHE)
 236         {
 237                 precache_model ("models/nexflash.md3");
 238                 precache_model ("models/weapons/g_minstanex.md3");
 239                 precache_model ("models/weapons/v_minstanex.md3");
 240                 precache_model ("models/weapons/h_minstanex.iqm");
 241                 precache_sound ("weapons/minstanexfire.wav");
 242                 precache_sound ("weapons/nexwhoosh1.wav");
 243                 precache_sound ("weapons/nexwhoosh2.wav");
 244                 precache_sound ("weapons/nexwhoosh3.wav");
 245                 //precache_sound ("weapons/reload.wav"); // until weapons have individual reload sounds, precache the reload sound somewhere else
 246                 w_laser(WR_PRECACHE);
 247         }
 248         else if (req == WR_SETUP)
 249         {
 250                 weapon_setup(WEP_MINSTANEX);
 251                 self.current_ammo = ammo_cells;
 252                 self.minstanex_lasthit = 0;
 253         }
 254         else if (req == WR_CHECKAMMO1)
 255         {
 256                 ammo_amount = self.ammo_cells >= minstanex_ammo;
 257                 ammo_amount += self.(weapon_load[WEP_MINSTANEX]) >= minstanex_ammo;
 258                 return ammo_amount;
 259         }
 260         else if (req == WR_CHECKAMMO2)
 261         {
 262                 if(!autocvar_g_balance_minstanex_laser_ammo)
 263                         return TRUE;
 264                 ammo_amount = self.ammo_cells >= autocvar_g_balance_minstanex_laser_ammo;
 265                 ammo_amount += self.(weapon_load[WEP_MINSTANEX]) >= autocvar_g_balance_minstanex_laser_ammo;
 266                 return ammo_amount;
 267         }
 268         else if (req == WR_RESETPLAYER)
 269         {
 270                 self.minstanex_lasthit = 0;
 271         }
 272         else if (req == WR_RELOAD)
 273         {
 274                 float used_ammo;
 275                 if(autocvar_g_balance_minstanex_laser_ammo)
 276                         used_ammo = min(minstanex_ammo, autocvar_g_balance_minstanex_laser_ammo);
 277                 else
 278                         used_ammo = minstanex_ammo;
 279
 280                 W_Reload(used_ammo, autocvar_g_balance_minstanex_reload_ammo, autocvar_g_balance_minstanex_reload_time, "weapons/reload.wav");
 281         }
 282         return TRUE;
 283 }
 284 #endif
 285 #ifdef CSQC
 286 float w_minstanex(float req)
 287 {
 288         if(req == WR_IMPACTEFFECT)
 289         {
 290                 vector org2;
 291                 org2 = w_org + w_backoff * 6;
 292                 pointparticles(particleeffectnum("nex_impact"), org2, '0 0 0', 1);
 293                 if(!w_issilent)
 294                         sound(self, CH_SHOTS, "weapons/neximpact.wav", VOL_BASE, ATTN_NORM);
 295         }
 296         else if(req == WR_PRECACHE)
 297         {
 298                 precache_sound("weapons/neximpact.wav");
 299         }
 300         else if (req == WR_SUICIDEMESSAGE)
 301                 w_deathtypestring = _("%s is now thinking with portals");
 302         else if (req == WR_KILLMESSAGE)
 303                 w_deathtypestring = _("%s has been vaporized by %s's minstanex");
 304         return TRUE;
 305 }
 306 #endif
 307 #endif