qcsrc/server/w_nex.qc

   1 #ifdef REGISTER_WEAPON
   2 REGISTER_WEAPON(NEX, w_nex, IT_CELLS, 7, WEP_FLAG_NORMAL | WEP_TYPE_HITSCAN, BOT_PICKUP_RATING_HIGH, "nex", "nex", _("Nex"))
   3 #else
   4 #ifdef SVQC
   5
   6 // weapon load persistence, for weapons that support reloading
   7 .float nex_load;
   8
   9 void W_Nex_SetAmmoCounter()
  10 {
  11         // set clip_load to the weapon we have switched to, if the gun uses reloading
  12         if(!autocvar_g_balance_nex_reload_ammo)
  13                 self.clip_load = 0; // also keeps crosshair ammo from displaying
  14         else
  15         {
  16                 self.clip_load = self.nex_load;
  17                 self.clip_size = autocvar_g_balance_nex_reload_ammo; // for the crosshair ammo display
  18         }
  19 }
  20
  21 void W_Nex_ReloadedAndReady()
  22 {
  23         float t;
  24
  25         // now do the ammo transfer
  26         self.clip_load = self.old_clip_load; // restore the ammo counter, in case we still had ammo in the weapon before reloading
  27         while(self.clip_load < autocvar_g_balance_nex_reload_ammo && self.ammo_cells) // make sure we don't add more ammo than we have
  28         {
  29                 self.clip_load += 1;
  30                 self.ammo_cells -= 1;
  31         }
  32         self.nex_load = self.clip_load;
  33
  34         t = ATTACK_FINISHED(self) - autocvar_g_balance_nex_reload_time - 1;
  35         ATTACK_FINISHED(self) = t;
  36         w_ready();
  37 }
  38
  39 void W_Nex_Reload()
  40 {
  41         // return if reloading is disabled for this weapon
  42         if(!autocvar_g_balance_nex_reload_ammo)
  43                 return;
  44
  45         if(!W_ReloadCheck(self.ammo_cells, min(autocvar_g_balance_nex_primary_ammo, autocvar_g_balance_nex_secondary_ammo)))
  46                 return;
  47
  48         float t;
  49
  50         sound (self, CHAN_WEAPON2, "weapons/reload.wav", VOL_BASE, ATTN_NORM);
  51
  52         t = max(time, ATTACK_FINISHED(self)) + autocvar_g_balance_nex_reload_time + 1;
  53         ATTACK_FINISHED(self) = t;
  54
  55         weapon_thinkf(WFRAME_RELOAD, autocvar_g_balance_nex_reload_time, W_Nex_ReloadedAndReady);
  56
  57         self.old_clip_load = self.clip_load;
  58         self.clip_load = -1;
  59 }
  60
  61 void SendCSQCNexBeamParticle(float charge) {
  62         vector v;
  63         v = WarpZone_UnTransformOrigin(WarpZone_trace_transform, trace_endpos);
  64         WriteByte(MSG_BROADCAST, SVC_TEMPENTITY);
  65         WriteByte(MSG_BROADCAST, TE_CSQC_NEXGUNBEAMPARTICLE);
  66         WriteCoord(MSG_BROADCAST, w_shotorg_x);
  67         WriteCoord(MSG_BROADCAST, w_shotorg_y);
  68         WriteCoord(MSG_BROADCAST, w_shotorg_z);
  69         WriteCoord(MSG_BROADCAST, v_x);
  70         WriteCoord(MSG_BROADCAST, v_y);
  71         WriteCoord(MSG_BROADCAST, v_z);
  72         WriteByte(MSG_BROADCAST, bound(0, 255 * charge, 255));
  73 }
  74
  75 void W_Nex_Attack (float issecondary)
  76 {
  77         float mydmg, myforce, mymindist, mymaxdist, myhalflife, myforcehalflife, myammo, charge;
  78         if(issecondary)
  79         {
  80                 mydmg = autocvar_g_balance_nex_secondary_damage;
  81                 myforce = autocvar_g_balance_nex_secondary_force;
  82                 mymindist = autocvar_g_balance_nex_secondary_damagefalloff_mindist;
  83                 mymaxdist = autocvar_g_balance_nex_secondary_damagefalloff_maxdist;
  84                 myhalflife = autocvar_g_balance_nex_secondary_damagefalloff_halflife;
  85                 myforcehalflife = autocvar_g_balance_nex_secondary_damagefalloff_forcehalflife;
  86                 myammo = autocvar_g_balance_nex_secondary_ammo;
  87         }
  88         else
  89         {
  90                 mydmg = autocvar_g_balance_nex_primary_damage;
  91                 myforce = autocvar_g_balance_nex_primary_force;
  92                 mymindist = autocvar_g_balance_nex_primary_damagefalloff_mindist;
  93                 mymaxdist = autocvar_g_balance_nex_primary_damagefalloff_maxdist;
  94                 myhalflife = autocvar_g_balance_nex_primary_damagefalloff_halflife;
  95                 myforcehalflife = autocvar_g_balance_nex_primary_damagefalloff_forcehalflife;
  96                 myammo = autocvar_g_balance_nex_primary_ammo;
  97         }
  98
  99         float flying;
 100         flying = IsFlying(self); // do this BEFORE to make the trace values from FireRailgunBullet last
 101
 102         if(autocvar_g_balance_nex_charge)
 103         {
 104                 charge = autocvar_g_balance_nex_charge_mindmg / mydmg + (1 - autocvar_g_balance_nex_charge_mindmg / mydmg) * self.nex_charge;
 105                 self.nex_charge *= autocvar_g_balance_nex_charge_shot_multiplier; // do this AFTER setting mydmg/myforce
 106                 // O RLY? -- divVerent
 107                 // YA RLY -- FruitieX
 108         }
 109         else
 110                 charge = 1;
 111         mydmg *= charge;
 112         myforce *= charge;
 113
 114         W_SetupShot (self, TRUE, 5, "weapons/nexfire.wav", CHAN_WEAPON, mydmg);
 115         if(charge > autocvar_g_balance_nex_charge_limit && autocvar_g_balance_nex_charge_limit) // if the Nex is overcharged, we play an extra sound
 116         {
 117                 sound (self, CHAN_WEAPON2, "weapons/nexcharge.wav", VOL_BASE * (charge - 0.5 * autocvar_g_balance_nex_charge_limit) / (1 - 0.5 * autocvar_g_balance_nex_charge_limit), ATTN_NORM);
 118         }
 119
 120         yoda = 0;
 121         FireRailgunBullet (w_shotorg, w_shotorg + w_shotdir * MAX_SHOT_DISTANCE, mydmg, myforce, mymindist, mymaxdist, myhalflife, myforcehalflife, WEP_NEX);
 122
 123         if(yoda && flying)
 124                 AnnounceTo(self, "yoda");
 125
 126         //beam and muzzle flash done on client
 127         SendCSQCNexBeamParticle(charge);
 128
 129         // flash and burn the wall
 130         if (trace_ent.solid == SOLID_BSP && !(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
 131                 Damage_DamageInfo(trace_endpos, mydmg, 0, 0, myforce * w_shotdir, WEP_NEX, self);
 132
 133         // if this weapon is reloadable, decrease its load. Else decrease the player's ammo
 134         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
 135         {
 136                 if(autocvar_g_balance_nex_reload_ammo)
 137                 {
 138                         self.clip_load -= myammo;
 139                         self.nex_load = self.clip_load;
 140                 }
 141                 else
 142                         self.ammo_cells -= myammo;
 143         }
 144 }
 145
 146 void spawnfunc_weapon_nex (void); // defined in t_items.qc
 147
 148 .float nex_chargepool_pauseregen_finished;
 149 float w_nex(float req)
 150 {
 151         float dt;
 152         float ammo_amount;
 153         if (req == WR_AIM)
 154         {
 155                 self.BUTTON_ATCK = bot_aim(1000000, 0, 1, FALSE);
 156                 self.BUTTON_ATCK2 = bot_aim(1000000, 0, 1, FALSE);
 157         }
 158         else if (req == WR_THINK)
 159         {
 160                 if(autocvar_g_balance_nex_charge && self.nex_charge < autocvar_g_balance_nex_charge_limit)
 161                         self.nex_charge = min(1, self.nex_charge + autocvar_g_balance_nex_charge_rate * frametime / W_TICSPERFRAME);
 162
 163                 if(autocvar_g_balance_nex_secondary_chargepool)
 164                         if(self.nex_chargepool_ammo < 1)
 165                         {
 166                                 if(self.nex_chargepool_pauseregen_finished < time)
 167                                         self.nex_chargepool_ammo = min(1, self.nex_chargepool_ammo + autocvar_g_balance_nex_secondary_chargepool_regen * frametime / W_TICSPERFRAME);
 168                                 self.pauseregen_finished = max(self.pauseregen_finished, time + autocvar_g_balance_nex_secondary_chargepool_pause_health_regen);
 169                         }
 170
 171                 if(autocvar_g_balance_nex_reload_ammo && self.clip_load < min(autocvar_g_balance_nex_primary_ammo, autocvar_g_balance_nex_secondary_ammo)) // forced reload
 172                         W_Nex_Reload();
 173                 else
 174                 {
 175                         if (self.BUTTON_ATCK)
 176                         {
 177                                 if (weapon_prepareattack(0, autocvar_g_balance_nex_primary_refire))
 178                                 {
 179                                         W_Nex_Attack(0);
 180                                         weapon_thinkf(WFRAME_FIRE1, autocvar_g_balance_nex_primary_animtime, w_ready);
 181                                 }
 182                         }
 183                         if ((autocvar_g_balance_nex_secondary_charge && !autocvar_g_balance_nex_secondary) ? self.BUTTON_ZOOM : self.BUTTON_ATCK2)
 184                         {
 185                                 if(autocvar_g_balance_nex_secondary_charge)
 186                                 {
 187                                         self.nex_charge_rottime = time + autocvar_g_balance_nex_charge_rot_pause;
 188                                         dt = frametime / W_TICSPERFRAME;
 189
 190                                         if(self.nex_charge < 1)
 191                                         {
 192                                                 if(autocvar_g_balance_nex_secondary_chargepool)
 193                                                 {
 194                                                         if(autocvar_g_balance_nex_secondary_ammo)
 195                                                         {
 196                                                                 // always deplete if secondary is held
 197                                                                 self.nex_chargepool_ammo = max(0, self.nex_chargepool_ammo - autocvar_g_balance_nex_secondary_ammo * dt);
 198
 199                                                                 dt = min(dt, (1 - self.nex_charge) / autocvar_g_balance_nex_secondary_charge_rate);
 200                                                                 self.nex_chargepool_pauseregen_finished = time + autocvar_g_balance_nex_secondary_chargepool_pause_regen;
 201                                                                 dt = min(dt, self.nex_chargepool_ammo);
 202                                                                 dt = max(0, dt);
 203
 204                                                                 self.nex_charge += dt * autocvar_g_balance_nex_secondary_charge_rate;
 205                                                         }
 206                                                 }
 207
 208                                                 else if(autocvar_g_balance_nex_secondary_ammo)
 209                                                 {
 210                                                         if(self.BUTTON_ATCK2) // only eat ammo when the button is pressed
 211                                                         {
 212                                                                 dt = min(dt, (1 - self.nex_charge) / autocvar_g_balance_nex_secondary_charge_rate);
 213                                                                 if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
 214                                                                 {
 215                                                                         // if this weapon is reloadable, decrease its load. Else decrease the player's ammo
 216                                                                         if(autocvar_g_balance_nex_reload_ammo)
 217                                                                         {
 218                                                                                 dt = min(dt, (self.clip_load - autocvar_g_balance_nex_primary_ammo) / autocvar_g_balance_nex_secondary_ammo);
 219                                                                                 dt = max(0, dt);
 220                                                                                 if(dt > 0)
 221                                                                                 {
 222                                                                                         self.clip_load = max(autocvar_g_balance_nex_secondary_ammo, self.clip_load - autocvar_g_balance_nex_secondary_ammo * dt);
 223                                                                                 }
 224                                                                                 self.nex_load = self.clip_load;
 225                                                                         }
 226                                                                         else
 227                                                                         {
 228                                                                                 dt = min(dt, (self.ammo_cells - autocvar_g_balance_nex_primary_ammo) / autocvar_g_balance_nex_secondary_ammo);
 229                                                                                 dt = max(0, dt);
 230                                                                                 if(dt > 0)
 231                                                                                 {
 232                                                                                         self.ammo_cells = max(autocvar_g_balance_nex_secondary_ammo, self.ammo_cells - autocvar_g_balance_nex_secondary_ammo * dt);
 233                                                                                 }
 234                                                                         }
 235                                                                 }
 236                                                                 self.nex_charge += dt * autocvar_g_balance_nex_secondary_charge_rate;
 237                                                         }
 238                                                 }
 239
 240                                                 else
 241                                                 {
 242                                                         dt = min(dt, (1 - self.nex_charge) / autocvar_g_balance_nex_secondary_charge_rate);
 243                                                         self.nex_charge += dt * autocvar_g_balance_nex_secondary_charge_rate;
 244                                                 }
 245                                         }
 246                                 }
 247                                 else if(autocvar_g_balance_nex_secondary)
 248                                 {
 249                                         if (weapon_prepareattack(0, autocvar_g_balance_nex_secondary_refire))
 250                                         {
 251                                                 W_Nex_Attack(1);
 252                                                 weapon_thinkf(WFRAME_FIRE1, autocvar_g_balance_nex_secondary_animtime, w_ready);
 253                                         }
 254                                 }
 255                         }
 256                 }
 257
 258                 if(autocvar_g_balance_nex_charge)
 259                 {
 260                         self.weaponentity_glowmod_x = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_red_half * min(1, self.nex_charge / autocvar_g_balance_nex_charge_limit);
 261                         self.weaponentity_glowmod_y = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_green_half * min(1, self.nex_charge / autocvar_g_balance_nex_charge_limit);
 262                         self.weaponentity_glowmod_z = autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_blue_half * min(1, self.nex_charge / autocvar_g_balance_nex_charge_limit);
 263
 264                         if(self.nex_charge > autocvar_g_balance_nex_charge_limit)
 265                         {
 266                                 self.weaponentity_glowmod_x = self.weaponentity_glowmod_x + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_red_full * (self.nex_charge - autocvar_g_balance_nex_charge_limit) / (1 - autocvar_g_balance_nex_charge_limit);
 267                                 self.weaponentity_glowmod_y = self.weaponentity_glowmod_y + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_green_full * (self.nex_charge - autocvar_g_balance_nex_charge_limit) / (1 - autocvar_g_balance_nex_charge_limit);
 268                                 self.weaponentity_glowmod_z = self.weaponentity_glowmod_z + autocvar_g_weapon_charge_colormod_hdrmultiplier * autocvar_g_weapon_charge_colormod_blue_full * (self.nex_charge - autocvar_g_balance_nex_charge_limit) / (1 - autocvar_g_balance_nex_charge_limit);
 269                         }
 270                 }
 271         }
 272         else if (req == WR_PRECACHE)
 273         {
 274                 precache_model ("models/nexflash.md3");
 275                 precache_model ("models/weapons/g_nex.md3");
 276                 precache_model ("models/weapons/v_nex.md3");
 277                 precache_model ("models/weapons/h_nex.iqm");
 278                 precache_sound ("weapons/nexfire.wav");
 279                 precache_sound ("weapons/nexcharge.wav");
 280                 precache_sound ("weapons/nexwhoosh1.wav");
 281                 precache_sound ("weapons/nexwhoosh2.wav");
 282                 precache_sound ("weapons/nexwhoosh3.wav");
 283                 precache_sound ("weapons/reload.wav");
 284         }
 285         else if (req == WR_SETUP)
 286         {
 287                 weapon_setup(WEP_NEX);
 288                 W_Nex_SetAmmoCounter();
 289         }
 290         else if (req == WR_CHECKAMMO1)
 291         {
 292                 ammo_amount = self.ammo_cells >= autocvar_g_balance_nex_primary_ammo;
 293                 ammo_amount += (autocvar_g_balance_nex_reload_ammo && self.nex_load >= autocvar_g_balance_nex_primary_ammo);
 294                 return ammo_amount;
 295         }
 296         else if (req == WR_CHECKAMMO2)
 297         {
 298                 // don't allow charging if we don't have enough ammo
 299                 ammo_amount = self.ammo_cells >= autocvar_g_balance_nex_secondary_ammo;
 300                 ammo_amount += (autocvar_g_balance_nex_reload_ammo && self.nex_load >= autocvar_g_balance_nex_secondary_ammo);
 301                 return ammo_amount;
 302         }
 303         else if (req == WR_RESETPLAYER)
 304         {
 305                 // all weapons must be fully loaded when we spawn
 306                 self.nex_load = autocvar_g_balance_nex_reload_ammo;
 307         }
 308         else if (req == WR_RELOAD)
 309         {
 310                 W_Nex_Reload();
 311         }
 312
 313         return TRUE;
 314 };
 315 #endif
 316 #ifdef CSQC
 317 float w_nex(float req)
 318 {
 319         if(req == WR_IMPACTEFFECT)
 320         {
 321                 vector org2;
 322                 org2 = w_org + w_backoff * 6;
 323                 pointparticles(particleeffectnum("nex_impact"), org2, '0 0 0', 1);
 324                 if(!w_issilent)
 325                         sound(self, CHAN_PROJECTILE, "weapons/neximpact.wav", VOL_BASE, ATTN_NORM);
 326         }
 327         else if(req == WR_PRECACHE)
 328         {
 329                 precache_sound("weapons/neximpact.wav");
 330         }
 331         else if (req == WR_SUICIDEMESSAGE)
 332                 w_deathtypestring = _("%s did the impossible");
 333         else if (req == WR_KILLMESSAGE)
 334                 w_deathtypestring = _("%s has been vaporized by %s");
 335         return TRUE;
 336 }
 337 #endif
 338 #endif