qcsrc/server/w_shotgun.qc

   1 #ifdef REGISTER_WEAPON
   2 REGISTER_WEAPON(SHOTGUN, w_shotgun, IT_SHELLS, 2, WEP_FLAG_NORMAL | WEP_FLAG_RELOADABLE | WEP_TYPE_HITSCAN, BOT_PICKUP_RATING_LOW, "shotgun", "shotgun", _("Shotgun"))
   3 #else
   4 #ifdef SVQC
   5
   6 void W_Shotgun_Attack (void)
   7 {
   8         float   sc;
   9         float   ammoamount;
  10         float   bullets;
  11         float   d;
  12         float   f;
  13         float   spread;
  14         float   bulletspeed;
  15         float   bulletconstant;
  16         local entity flash;
  17
  18         ammoamount = autocvar_g_balance_shotgun_primary_ammo;
  19         bullets = autocvar_g_balance_shotgun_primary_bullets;
  20         d = autocvar_g_balance_shotgun_primary_damage;
  21         f = autocvar_g_balance_shotgun_primary_force;
  22         spread = autocvar_g_balance_shotgun_primary_spread;
  23         bulletspeed = autocvar_g_balance_shotgun_primary_speed;
  24         bulletconstant = autocvar_g_balance_shotgun_primary_bulletconstant;
  25
  26         // if this weapon is reloadable, decrease its load. Else decrease the player's ammo
  27         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
  28         {
  29                 if(autocvar_g_balance_shotgun_reload_ammo)
  30                 {
  31                         self.clip_load -= ammoamount;
  32                         self.weapon_load[WEP_SHOTGUN] = self.clip_load;
  33                 }
  34                 else
  35                         self.ammo_shells -= ammoamount;
  36         }
  37
  38         W_SetupShot (self, autocvar_g_antilag_bullets && bulletspeed >= autocvar_g_antilag_bullets, 5, "weapons/shotgun_fire.wav", CHAN_WEAPON, d * bullets);
  39         for (sc = 0;sc < bullets;sc = sc + 1)
  40                 fireBallisticBullet(w_shotorg, w_shotdir, spread, bulletspeed, 5, d, 0, f, WEP_SHOTGUN, 0, 1, bulletconstant);
  41         endFireBallisticBullet();
  42
  43         pointparticles(particleeffectnum("shotgun_muzzleflash"), w_shotorg, w_shotdir * 1000, autocvar_g_balance_shotgun_primary_ammo);
  44
  45         // casing code
  46         if (autocvar_g_casings >= 1)
  47                 for (sc = 0;sc < ammoamount;sc = sc + 1)
  48                         SpawnCasing (((random () * 50 + 50) * v_right) - (v_forward * (random () * 25 + 25)) - ((random () * 5 - 30) * v_up), 2, vectoangles(v_forward),'0 250 0', 100, 1, self);
  49
  50         // muzzle flash for 1st person view
  51         flash = spawn();
  52         setmodel(flash, "models/uziflash.md3"); // precision set below
  53         flash.think = SUB_Remove;
  54         flash.nextthink = time + 0.06;
  55         flash.effects = EF_ADDITIVE | EF_FULLBRIGHT | EF_LOWPRECISION;
  56         W_AttachToShotorg(flash, '5 0 0');
  57 }
  58
  59 void shotgun_meleethink (void)
  60 {
  61         // store time when we started swinging down inside self.cnt
  62         if(!self.cnt)
  63                 self.cnt = time;
  64
  65         makevectors(self.owner.v_angle);
  66         vector angle;
  67         angle = v_forward;
  68
  69         float meleetime;
  70         meleetime = autocvar_g_balance_shotgun_secondary_melee_time * W_WeaponRateFactor();
  71
  72         // perform trace
  73         float f;
  74         f = (self.cnt + meleetime - time) / meleetime * 2 - 1;
  75         vector targpos;
  76         targpos = self.owner.origin + self.owner.view_ofs + angle * autocvar_g_balance_shotgun_secondary_melee_range + v_right * f * autocvar_g_balance_shotgun_secondary_melee_swing + v_up * f * autocvar_g_balance_shotgun_secondary_melee_swing;
  77
  78         WarpZone_traceline_antilag(self.owner, self.owner.origin + self.owner.view_ofs, targpos, FALSE, self.owner, ANTILAG_LATENCY(self.owner));
  79
  80         // apply the damage, also remove self
  81         if(trace_fraction < 1 && trace_ent.takedamage == DAMAGE_AIM && (trace_ent.classname == "player" || trace_ent.classname == "body"))
  82         {
  83                 vector force;
  84                 force = angle * autocvar_g_balance_shotgun_secondary_force;
  85                 if(accuracy_isgooddamage(self.owner, trace_ent))
  86                         accuracy_add(self.owner, WEP_SHOTGUN, 0, autocvar_g_balance_shotgun_secondary_damage * min(1, f + 1));
  87                 Damage (trace_ent, self.owner, self.owner, autocvar_g_balance_shotgun_secondary_damage * min(1, f + 1), WEP_SHOTGUN | HITTYPE_SECONDARY , self.owner.origin + self.owner.view_ofs, force);
  88                 remove(self);
  89         }
  90         else if(time >= self.cnt + meleetime) // missed, remove ent
  91                 remove(self);
  92         else // continue swinging the weapon in hope of hitting someone :)
  93                 self.nextthink = time;
  94 }
  95
  96 void W_Shotgun_Attack2 (void)
  97 {
  98         sound (self, CHAN_PROJECTILE, "weapons/shotgun_melee.wav", VOL_BASE, ATTN_NORM);
  99         weapon_thinkf(WFRAME_FIRE2, autocvar_g_balance_shotgun_secondary_animtime, w_ready);
 100
 101         entity meleetemp;
 102         meleetemp = spawn();
 103         meleetemp.owner = self;
 104         meleetemp.think = shotgun_meleethink;
 105         meleetemp.nextthink = time + autocvar_g_balance_shotgun_secondary_melee_delay;
 106         W_SetupShot_Range(self, TRUE, 0, "", 0, autocvar_g_balance_shotgun_secondary_damage, autocvar_g_balance_shotgun_secondary_melee_range);
 107 }
 108
 109 void spawnfunc_weapon_shotgun(); // defined in t_items.qc
 110
 111 .float shotgun_primarytime;
 112
 113 float w_shotgun(float req)
 114 {
 115         float ammo_amount;
 116         if (req == WR_AIM)
 117                 if(vlen(self.origin-self.enemy.origin) <= autocvar_g_balance_shotgun_secondary_melee_range)
 118                         self.BUTTON_ATCK2 = bot_aim(1000000, 0, 0.001, FALSE);
 119                 else
 120                         self.BUTTON_ATCK = bot_aim(1000000, 0, 0.001, FALSE);
 121         else if (req == WR_THINK)
 122         {
 123                 if(autocvar_g_balance_shotgun_reload_ammo && self.clip_load < autocvar_g_balance_shotgun_primary_ammo) // forced reload
 124                 {
 125                         // don't force reload an empty shotgun if its melee attack is active
 126                         if not(autocvar_g_balance_shotgun_secondary && self.ammo_shells < autocvar_g_balance_shotgun_primary_ammo)
 127                                 weapon_action(self.weapon, WR_RELOAD);
 128                 }
 129                 else
 130                 {
 131                         if (self.BUTTON_ATCK)
 132                         {
 133                                 if (time >= self.shotgun_primarytime) // handle refire separately so the secondary can be fired straight after a primary
 134                                 {
 135                                         if(weapon_prepareattack(0, autocvar_g_balance_shotgun_primary_animtime))
 136                                         {
 137                                                 W_Shotgun_Attack();
 138                                                 self.shotgun_primarytime = time + autocvar_g_balance_shotgun_primary_refire;
 139                                                 weapon_thinkf(WFRAME_FIRE1, autocvar_g_balance_shotgun_primary_animtime, w_ready);
 140                                         }
 141                                 }
 142                         }
 143                 }
 144                 if (self.BUTTON_ATCK2 && autocvar_g_balance_shotgun_secondary)
 145                 if (weapon_prepareattack(1, autocvar_g_balance_shotgun_secondary_refire))
 146                 {
 147                         // attempt forcing playback of the anim by switching to another anim (that we never play) here...
 148                         weapon_thinkf(WFRAME_FIRE1, 0, W_Shotgun_Attack2);
 149                 }
 150         }
 151         else if (req == WR_PRECACHE)
 152         {
 153                 precache_model ("models/uziflash.md3");
 154                 precache_model ("models/weapons/g_shotgun.md3");
 155                 precache_model ("models/weapons/v_shotgun.md3");
 156                 precache_model ("models/weapons/h_shotgun.iqm");
 157                 precache_sound ("misc/itempickup.wav");
 158                 precache_sound ("weapons/shotgun_fire.wav");
 159                 precache_sound ("weapons/shotgun_melee.wav");
 160                 precache_sound ("weapons/reload.wav");
 161         }
 162         else if (req == WR_SETUP)
 163         {
 164                 weapon_setup(WEP_SHOTGUN);
 165         }
 166         else if (req == WR_CHECKAMMO1)
 167         {
 168                 ammo_amount = self.ammo_shells >= autocvar_g_balance_shotgun_primary_ammo;
 169                 ammo_amount += self.weapon_load[WEP_SHOTGUN] >= autocvar_g_balance_shotgun_primary_ammo;
 170                 return ammo_amount;
 171         }
 172         else if (req == WR_CHECKAMMO2)
 173         {
 174                 // melee attack is always available
 175                 return TRUE;
 176         }
 177         else if (req == WR_RELOAD)
 178         {
 179                 W_Reload(ammo_shells, autocvar_g_balance_shotgun_primary_ammo, autocvar_g_balance_shotgun_reload_ammo, autocvar_g_balance_shotgun_reload_time, "weapons/reload.wav");
 180         }
 181         return TRUE;
 182 };
 183 #endif
 184 #ifdef CSQC
 185 .float prevric;
 186 float w_shotgun(float req)
 187 {
 188         if(req == WR_IMPACTEFFECT)
 189         {
 190                 vector org2;
 191                 org2 = w_org + w_backoff * 2;
 192                 pointparticles(particleeffectnum("shotgun_impact"), org2, w_backoff * 1000, 1);
 193                 if(!w_issilent && time - self.prevric > 0.25)
 194                 {
 195                         if(w_random < 0.0165)
 196                                 sound(self, CHAN_PROJECTILE, "weapons/ric1.wav", VOL_BASE, ATTN_NORM);
 197                         else if(w_random < 0.033)
 198                                 sound(self, CHAN_PROJECTILE, "weapons/ric2.wav", VOL_BASE, ATTN_NORM);
 199                         else if(w_random < 0.05)
 200                                 sound(self, CHAN_PROJECTILE, "weapons/ric3.wav", VOL_BASE, ATTN_NORM);
 201                         self.prevric = time;
 202                 }
 203         }
 204         else if(req == WR_PRECACHE)
 205         {
 206                 precache_sound("weapons/ric1.wav");
 207                 precache_sound("weapons/ric2.wav");
 208                 precache_sound("weapons/ric3.wav");
 209         }
 210         else if (req == WR_SUICIDEMESSAGE)
 211                 w_deathtypestring = _("%s did the impossible");
 212         else if (req == WR_KILLMESSAGE)
 213         {
 214                 if(w_deathtype & HITTYPE_SECONDARY)
 215                         w_deathtypestring = _("%2$s ^7slapped %1$s ^7around a bit with a large ^2shotgun");
 216                 else
 217                         w_deathtypestring = _("%s was gunned by %s");
 218         }
 219         return TRUE;
 220 }
 221 #endif
 222 #endif