qcsrc/server/w_shotgun.qc

   1 #ifdef REGISTER_WEAPON
   2 REGISTER_WEAPON(SHOTGUN, w_shotgun, IT_SHELLS, 2, WEP_FLAG_NORMAL | WEP_TYPE_HITSCAN, BOT_PICKUP_RATING_LOW, "shotgun", "shotgun", _("Shotgun"))
   3 #else
   4 #ifdef SVQC
   5
   6 .float shotgun_load;
   7
   8 void W_Shotgun_SetAmmoCounter()
   9 {
  10         // set ammo counter to the weapon we have switched to
  11         if(!autocvar_g_balance_shotgun_reload_ammo)
  12                 self.ammo_counter = 0; // also keeps the crosshair ammo from displaying
  13         else
  14                 self.ammo_counter = self.shotgun_load;
  15 }
  16
  17 void W_Shotgun_ReloadedAndReady()
  18 {
  19         float t;
  20
  21         // now do the ammo maths
  22         self.ammo_counter = self.old_ammo_counter; // restore ammo counter, in case we still had ammo in the weapon while reloading
  23         while(self.ammo_counter < autocvar_g_balance_shotgun_reload_ammo && self.ammo_shells) // make sure we don't add more than the amount of ammo we have
  24         {
  25                 self.ammo_counter += 1;
  26                 self.ammo_shells -= 1;
  27         }
  28         self.shotgun_load = self.ammo_counter;
  29
  30         t = ATTACK_FINISHED(self) - autocvar_g_balance_shotgun_reload_time - 1;
  31         ATTACK_FINISHED(self) = t;
  32         w_ready();
  33 }
  34
  35 void W_Shotgun_Reload()
  36 {
  37         // reloading is disabled for this weapon
  38         if(!autocvar_g_balance_shotgun_reload_ammo)
  39                 return;
  40
  41         float t;
  42
  43         if(!W_ReloadCheck(self.ammo_shells))
  44                 return;
  45
  46         sound (self, CHAN_WEAPON2, "weapons/campingrifle_reload.wav", VOL_BASE, ATTN_NORM);
  47
  48         t = max(time, ATTACK_FINISHED(self)) + autocvar_g_balance_shotgun_reload_time + 1;
  49         ATTACK_FINISHED(self) = t;
  50
  51         weapon_thinkf(WFRAME_RELOAD, autocvar_g_balance_shotgun_reload_time, W_Shotgun_ReloadedAndReady);
  52
  53         self.old_ammo_counter = self.ammo_counter;
  54         self.ammo_counter = -1;
  55 }
  56
  57 void W_Shotgun_Attack (void)
  58 {
  59         float   sc;
  60         float   ammoamount;
  61         float   bullets;
  62         float   d;
  63         float   f;
  64         float   spread;
  65         float   bulletspeed;
  66         float   bulletconstant;
  67         local entity flash;
  68
  69         if(autocvar_g_balance_shotgun_reload_ammo && self.ammo_counter <= 0)
  70                 return; // reloading, so we are done
  71
  72         ammoamount = autocvar_g_balance_shotgun_primary_ammo;
  73         bullets = autocvar_g_balance_shotgun_primary_bullets;
  74         d = autocvar_g_balance_shotgun_primary_damage;
  75         f = autocvar_g_balance_shotgun_primary_force;
  76         spread = autocvar_g_balance_shotgun_primary_spread;
  77         bulletspeed = autocvar_g_balance_shotgun_primary_speed;
  78         bulletconstant = autocvar_g_balance_shotgun_primary_bulletconstant;
  79
  80         W_SetupShot (self, autocvar_g_antilag_bullets && bulletspeed >= autocvar_g_antilag_bullets, 5, "weapons/shotgun_fire.wav", CHAN_WEAPON, d * bullets);
  81         for (sc = 0;sc < bullets;sc = sc + 1)
  82                 fireBallisticBullet(w_shotorg, w_shotdir, spread, bulletspeed, 5, d, 0, f, WEP_SHOTGUN, 0, 1, bulletconstant);
  83         endFireBallisticBullet();
  84
  85         pointparticles(particleeffectnum("shotgun_muzzleflash"), w_shotorg, w_shotdir * 1000, autocvar_g_balance_shotgun_primary_ammo);
  86
  87         // casing code
  88         if (autocvar_g_casings >= 1)
  89                 for (sc = 0;sc < ammoamount;sc = sc + 1)
  90                         SpawnCasing (((random () * 50 + 50) * v_right) - (v_forward * (random () * 25 + 25)) - ((random () * 5 - 30) * v_up), 2, vectoangles(v_forward),'0 250 0', 100, 1, self);
  91
  92         // muzzle flash for 1st person view
  93         flash = spawn();
  94         setmodel(flash, "models/uziflash.md3"); // precision set below
  95         flash.think = SUB_Remove;
  96         flash.nextthink = time + 0.06;
  97         flash.effects = EF_ADDITIVE | EF_FULLBRIGHT | EF_LOWPRECISION;
  98         W_AttachToShotorg(flash, '5 0 0');
  99
 100         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
 101         {
 102                 if(!autocvar_g_balance_shotgun_reload_ammo)
 103                         self.ammo_shells -= ammoamount;
 104                 else
 105                 {
 106                         self.ammo_counter -= ammoamount;
 107                         self.shotgun_load = self.ammo_counter;
 108                 }
 109         }
 110 }
 111
 112 void shotgun_meleethink (void)
 113 {
 114         // store time when we started swinging down inside self.cnt
 115         if(!self.cnt)
 116                 self.cnt = time;
 117
 118         makevectors(self.owner.v_angle);
 119         vector angle;
 120         angle = v_forward;
 121
 122         float meleetime;
 123         meleetime = autocvar_g_balance_shotgun_secondary_melee_time * W_WeaponRateFactor();
 124
 125         // perform trace
 126         float f;
 127         f = (self.cnt + meleetime - time) / meleetime * 2 - 1;
 128         vector targpos;
 129         targpos = self.owner.origin + self.owner.view_ofs + angle * autocvar_g_balance_shotgun_secondary_melee_range + v_right * f * autocvar_g_balance_shotgun_secondary_melee_swing + v_up * f * autocvar_g_balance_shotgun_secondary_melee_swing;
 130
 131         WarpZone_traceline_antilag(self.owner, self.owner.origin + self.owner.view_ofs, targpos, FALSE, self.owner, ANTILAG_LATENCY(self.owner));
 132
 133         // apply the damage, also remove self
 134         if(trace_fraction < 1 && trace_ent.takedamage == DAMAGE_AIM && (trace_ent.classname == "player" || trace_ent.classname == "body"))
 135         {
 136                 vector force;
 137                 force = angle * autocvar_g_balance_shotgun_secondary_force;
 138                 if(accuracy_isgooddamage(self.owner, trace_ent))
 139                         accuracy_add(self.owner, WEP_SHOTGUN, 0, autocvar_g_balance_shotgun_secondary_damage * min(1, f + 1));
 140                 Damage (trace_ent, self.owner, self.owner, autocvar_g_balance_shotgun_secondary_damage * min(1, f + 1), WEP_SHOTGUN | HITTYPE_SECONDARY , self.owner.origin + self.owner.view_ofs, force);
 141                 remove(self);
 142         }
 143         else if(time >= self.cnt + meleetime) // missed, remove ent
 144                 remove(self);
 145         else // continue swinging the weapon in hope of hitting someone :)
 146                 self.nextthink = time;
 147 }
 148
 149 void W_Shotgun_Attack2 (void)
 150 {
 151         sound (self, CHAN_PROJECTILE, "weapons/shotgun_melee.wav", VOL_BASE, ATTN_NORM);
 152         weapon_thinkf(WFRAME_FIRE2, autocvar_g_balance_shotgun_secondary_animtime, w_ready);
 153
 154         entity meleetemp;
 155         meleetemp = spawn();
 156         meleetemp.owner = self;
 157         meleetemp.think = shotgun_meleethink;
 158         meleetemp.nextthink = time + autocvar_g_balance_shotgun_secondary_melee_delay;
 159         W_SetupShot_Range(self, TRUE, 0, "", 0, autocvar_g_balance_shotgun_secondary_damage, autocvar_g_balance_shotgun_secondary_melee_range);
 160 }
 161
 162 void spawnfunc_weapon_shotgun(); // defined in t_items.qc
 163
 164 .float shotgun_primarytime;
 165
 166 float w_shotgun(float req)
 167 {
 168         if (req == WR_AIM)
 169                 if(vlen(self.origin-self.enemy.origin) <= autocvar_g_balance_shotgun_secondary_melee_range)
 170                         self.BUTTON_ATCK2 = bot_aim(1000000, 0, 0.001, FALSE);
 171                 else
 172                         self.BUTTON_ATCK = bot_aim(1000000, 0, 0.001, FALSE);
 173         else if (req == WR_THINK)
 174         {
 175                 if(autocvar_g_balance_shotgun_reload_ammo && self.ammo_counter <= 0) // forced reload
 176                         W_Shotgun_Reload();
 177                 else
 178                 {
 179                         if (self.BUTTON_ATCK)
 180                         {
 181                                 if (time >= self.shotgun_primarytime) // handle refire separately so the secondary can be fired straight after a primary
 182                                 {
 183                                         if(weapon_prepareattack(0, autocvar_g_balance_shotgun_primary_animtime))
 184                                         {
 185                                                 W_Shotgun_Attack();
 186                                                 self.shotgun_primarytime = time + autocvar_g_balance_shotgun_primary_refire;
 187                                                 weapon_thinkf(WFRAME_FIRE1, autocvar_g_balance_shotgun_primary_animtime, w_ready);
 188                                         }
 189                                 }
 190                         }
 191                         if (self.BUTTON_ATCK2 && autocvar_g_balance_shotgun_secondary)
 192                         if (weapon_prepareattack(1, autocvar_g_balance_shotgun_secondary_refire))
 193                         {
 194                                 // attempt forcing playback of the anim by switching to another anim (that we never play) here...
 195                                 weapon_thinkf(WFRAME_FIRE1, 0, W_Shotgun_Attack2);
 196                         }
 197                 }
 198         if(self.wish_reload)
 199         {
 200             if(self.switchweapon == self.weapon)
 201             {
 202                 if(self.weaponentity.state == WS_READY)
 203                 {
 204                     self.wish_reload = 0;
 205                     W_Shotgun_Reload();
 206                 }
 207             }
 208         }
 209         }
 210         else if (req == WR_PRECACHE)
 211         {
 212                 precache_model ("models/uziflash.md3");
 213                 precache_model ("models/weapons/g_shotgun.md3");
 214                 precache_model ("models/weapons/v_shotgun.md3");
 215                 precache_model ("models/weapons/h_shotgun.iqm");
 216                 precache_sound ("misc/itempickup.wav");
 217                 precache_sound ("weapons/shotgun_fire.wav");
 218                 precache_sound ("weapons/shotgun_melee.wav");
 219         }
 220         else if (req == WR_SETUP)
 221         {
 222                 weapon_setup(WEP_SHOTGUN);
 223                 W_Shotgun_SetAmmoCounter();
 224         }
 225         else if (req == WR_CHECKAMMO1)
 226         {
 227                 return self.ammo_shells >= autocvar_g_balance_shotgun_primary_ammo;
 228         }
 229         else if (req == WR_CHECKAMMO2)
 230         {
 231                 return TRUE;
 232         }
 233         return TRUE;
 234 };
 235 #endif
 236 #ifdef CSQC
 237 .float prevric;
 238 float w_shotgun(float req)
 239 {
 240         if(req == WR_IMPACTEFFECT)
 241         {
 242                 vector org2;
 243                 org2 = w_org + w_backoff * 2;
 244                 pointparticles(particleeffectnum("shotgun_impact"), org2, w_backoff * 1000, 1);
 245                 if(!w_issilent && time - self.prevric > 0.25)
 246                 {
 247                         if(w_random < 0.0165)
 248                                 sound(self, CHAN_PROJECTILE, "weapons/ric1.wav", VOL_BASE, ATTN_NORM);
 249                         else if(w_random < 0.033)
 250                                 sound(self, CHAN_PROJECTILE, "weapons/ric2.wav", VOL_BASE, ATTN_NORM);
 251                         else if(w_random < 0.05)
 252                                 sound(self, CHAN_PROJECTILE, "weapons/ric3.wav", VOL_BASE, ATTN_NORM);
 253                         self.prevric = time;
 254                 }
 255         }
 256         else if(req == WR_PRECACHE)
 257         {
 258                 precache_sound("weapons/ric1.wav");
 259                 precache_sound("weapons/ric2.wav");
 260                 precache_sound("weapons/ric3.wav");
 261         }
 262         else if (req == WR_SUICIDEMESSAGE)
 263                 w_deathtypestring = "%s did the impossible";
 264         else if (req == WR_KILLMESSAGE)
 265         {
 266                 if(w_deathtype & HITTYPE_SECONDARY)
 267                         w_deathtypestring = "%2$s ^7slapped %1$s ^7around a bit with a large ^2shotgun";
 268                 else
 269                         w_deathtypestring = "%s was gunned by %s";
 270         }
 271         return TRUE;
 272 }
 273 #endif
 274 #endif