qcsrc/server/w_shotgun.qc

   1 #ifdef REGISTER_WEAPON
   2 REGISTER_WEAPON(SHOTGUN, w_shotgun, IT_SHELLS, 2, WEP_FLAG_NORMAL | WEP_FLAG_RELOADABLE | WEP_TYPE_HITSCAN, BOT_PICKUP_RATING_LOW, "shotgun", "shotgun", _("Shotgun"))
   3 #else
   4 #ifdef SVQC
   5
   6 void W_Shotgun_Attack (void)
   7 {
   8         float   sc;
   9         float   ammoamount;
  10         float   bullets;
  11         float   d;
  12         float   f;
  13         float   spread;
  14         float   bulletspeed;
  15         float   bulletconstant;
  16         local entity flash;
  17
  18         ammoamount = autocvar_g_balance_shotgun_primary_ammo;
  19         bullets = autocvar_g_balance_shotgun_primary_bullets;
  20         d = autocvar_g_balance_shotgun_primary_damage;
  21         f = autocvar_g_balance_shotgun_primary_force;
  22         spread = autocvar_g_balance_shotgun_primary_spread;
  23         bulletspeed = autocvar_g_balance_shotgun_primary_speed;
  24         bulletconstant = autocvar_g_balance_shotgun_primary_bulletconstant;
  25
  26         W_DecreaseAmmo(ammo_shells, ammoamount, autocvar_g_balance_shotgun_reload_ammo);
  27
  28         W_SetupShot (self, autocvar_g_antilag_bullets && bulletspeed >= autocvar_g_antilag_bullets, 5, "weapons/shotgun_fire.wav", CH_WEAPON_A, d * bullets);
  29         for (sc = 0;sc < bullets;sc = sc + 1)
  30                 fireBallisticBullet(w_shotorg, w_shotdir, spread, bulletspeed, 5, d, 0, f, WEP_SHOTGUN, 0, 1, bulletconstant);
  31         endFireBallisticBullet();
  32
  33         pointparticles(particleeffectnum("shotgun_muzzleflash"), w_shotorg, w_shotdir * 1000, autocvar_g_balance_shotgun_primary_ammo);
  34
  35         // casing code
  36         if (autocvar_g_casings >= 1)
  37                 for (sc = 0;sc < ammoamount;sc = sc + 1)
  38                         SpawnCasing (((random () * 50 + 50) * v_right) - (v_forward * (random () * 25 + 25)) - ((random () * 5 - 30) * v_up), 2, vectoangles(v_forward),'0 250 0', 100, 1, self);
  39
  40         // muzzle flash for 1st person view
  41         flash = spawn();
  42         setmodel(flash, "models/uziflash.md3"); // precision set below
  43         flash.think = SUB_Remove;
  44         flash.nextthink = time + 0.06;
  45         flash.effects = EF_ADDITIVE | EF_FULLBRIGHT | EF_LOWPRECISION;
  46         W_AttachToShotorg(flash, '5 0 0');
  47 }
  48
  49 .float swing_prev;
  50 .entity swing_alreadyhit;
  51 void shotgun_meleethink (void)
  52 {
  53         // declarations
  54         float i, f, swing, swing_factor, swing_damage, meleetime, is_player;
  55         vector targpos;
  56
  57         if(!self.cnt) { self.cnt = time; } // set start time of melee
  58
  59         makevectors(self.realowner.v_angle); // update values for v_* vectors
  60
  61         // calculate swing percentage based on time
  62         meleetime = autocvar_g_balance_shotgun_secondary_melee_time * W_WeaponRateFactor();
  63         swing = bound(0, (self.cnt + meleetime - time) / meleetime, 10);
  64         f = ((1 - swing) * autocvar_g_balance_shotgun_secondary_melee_traces);
  65
  66         // check to see if we can still continue, otherwise give up now
  67         if((self.realowner.deadflag != DEAD_NO) && autocvar_g_balance_shotgun_secondary_melee_no_doubleslap)
  68         {
  69                 remove(self);
  70                 return;
  71         }
  72
  73         // if okay, perform the traces needed for this frame
  74         for(i=self.swing_prev; i < f; ++i)
  75         {
  76                 swing_factor = ((1 - (i / autocvar_g_balance_shotgun_secondary_melee_traces)) * 2 - 1);
  77
  78                 targpos = (self.realowner.origin + self.realowner.view_ofs
  79                         + (v_forward * autocvar_g_balance_shotgun_secondary_melee_range)
  80                         + (v_up * swing_factor * autocvar_g_balance_shotgun_secondary_melee_swing_up)
  81                         + (v_right * swing_factor * autocvar_g_balance_shotgun_secondary_melee_swing_side));
  82
  83                 WarpZone_traceline_antilag(self.realowner, self.realowner.origin + self.realowner.view_ofs, targpos, FALSE, lgbeam_owner_ent, ANTILAG_LATENCY(self.realowner));
  84
  85                 // draw lightning beams for debugging
  86                 te_lightning2(world, targpos, self.realowner.origin + self.realowner.view_ofs + v_forward * 5 - v_up * 5);
  87                 te_customflash(targpos, 40,  2, '1 1 1');
  88
  89                 is_player = (trace_ent.classname == "player" || trace_ent.classname == "body");
  90
  91                 if((trace_fraction < 1) // if trace is good, apply the damage and remove self
  92                         && (trace_ent.takedamage == DAMAGE_AIM)
  93                         && (trace_ent != self.swing_alreadyhit)
  94                         && (is_player || autocvar_g_balance_shotgun_secondary_melee_nonplayerdamage))
  95                 {
  96                         if(is_player) // this allows us to be able to nerf the non-player damage done in e.g. assault or onslaught.
  97                                 swing_damage = (autocvar_g_balance_shotgun_secondary_damage * min(1, swing_factor + 1));
  98                         else
  99                                 swing_damage = (autocvar_g_balance_shotgun_secondary_melee_nonplayerdamage * min(1, swing_factor + 1));
 100
 101                         Damage(trace_ent, self.realowner, self.realowner,
 102                                 swing_damage, WEP_SHOTGUN | HITTYPE_SECONDARY,
 103                                 self.realowner.origin + self.realowner.view_ofs,
 104                                 v_forward * autocvar_g_balance_shotgun_secondary_force);
 105
 106                         if(accuracy_isgooddamage(self.realowner, trace_ent))
 107                                 accuracy_add(self.realowner, WEP_SHOTGUN, 0, swing_damage);
 108
 109                         // draw large red flash for debugging
 110                         te_customflash(targpos, 200, 2, '15 0 0');
 111
 112                         if(autocvar_g_balance_shotgun_secondary_melee_multihit) // allow multiple hits with one swing, but not against the same player twice.
 113                         {
 114                                 self.swing_alreadyhit = trace_ent;
 115                                 continue; // move along to next trace
 116                         }
 117                         else
 118                         {
 119                                 remove(self);
 120                                 return;
 121                         }
 122                 }
 123         }
 124
 125         if(time >= self.cnt + meleetime)
 126         {
 127                 // melee is finished
 128                 remove(self);
 129                 return;
 130         }
 131         else
 132         {
 133                 // set up next frame
 134                 self.swing_prev = i;
 135                 self.nextthink = time;
 136         }
 137 }
 138
 139 void W_Shotgun_Attack2 (void)
 140 {
 141         sound (self, CH_SHOTS, "weapons/shotgun_melee.wav", VOL_BASE, ATTN_NORM);
 142         weapon_thinkf(WFRAME_FIRE2, autocvar_g_balance_shotgun_secondary_animtime, w_ready);
 143
 144         entity meleetemp;
 145         meleetemp = spawn();
 146         meleetemp.owner = meleetemp.realowner = self;
 147         meleetemp.think = shotgun_meleethink;
 148         meleetemp.nextthink = time + autocvar_g_balance_shotgun_secondary_melee_delay * W_WeaponRateFactor();
 149         W_SetupShot_Range(self, TRUE, 0, "", 0, autocvar_g_balance_shotgun_secondary_damage, autocvar_g_balance_shotgun_secondary_melee_range);
 150 }
 151
 152 void spawnfunc_weapon_shotgun(); // defined in t_items.qc
 153
 154 .float shotgun_primarytime;
 155
 156 float w_shotgun(float req)
 157 {
 158         float ammo_amount;
 159         if (req == WR_AIM)
 160                 if(vlen(self.origin-self.enemy.origin) <= autocvar_g_balance_shotgun_secondary_melee_range)
 161                         self.BUTTON_ATCK2 = bot_aim(1000000, 0, 0.001, FALSE);
 162                 else
 163                 {
 164                         if(autocvar_g_antilag_bullets)
 165                                 self.BUTTON_ATCK = bot_aim(1000000, 0, 0.001, FALSE);
 166                         else
 167                                 self.BUTTON_ATCK = bot_aim(autocvar_g_balance_shotgun_primary_speed, 0, 0.001, FALSE);
 168                 }
 169
 170         else if (req == WR_THINK)
 171         {
 172                 if(autocvar_g_balance_shotgun_reload_ammo && self.clip_load < autocvar_g_balance_shotgun_primary_ammo) // forced reload
 173                 {
 174                         // don't force reload an empty shotgun if its melee attack is active
 175                         if not(autocvar_g_balance_shotgun_secondary && self.ammo_shells < autocvar_g_balance_shotgun_primary_ammo)
 176                                 weapon_action(self.weapon, WR_RELOAD);
 177                 }
 178                 else
 179                 {
 180                         if (self.BUTTON_ATCK)
 181                         {
 182                                 if (time >= self.shotgun_primarytime) // handle refire separately so the secondary can be fired straight after a primary
 183                                 {
 184                                         if(weapon_prepareattack(0, autocvar_g_balance_shotgun_primary_animtime))
 185                                         {
 186                                                 W_Shotgun_Attack();
 187                                                 self.shotgun_primarytime = time + autocvar_g_balance_shotgun_primary_refire * W_WeaponRateFactor();
 188                                                 weapon_thinkf(WFRAME_FIRE1, autocvar_g_balance_shotgun_primary_animtime, w_ready);
 189                                         }
 190                                 }
 191                         }
 192                 }
 193                 if (self.clip_load >= 0) // we are not currently reloading
 194                 if (self.BUTTON_ATCK2 && autocvar_g_balance_shotgun_secondary)
 195                 if (weapon_prepareattack(1, autocvar_g_balance_shotgun_secondary_refire))
 196                 {
 197                         // attempt forcing playback of the anim by switching to another anim (that we never play) here...
 198                         weapon_thinkf(WFRAME_FIRE1, 0, W_Shotgun_Attack2);
 199                 }
 200         }
 201         else if (req == WR_PRECACHE)
 202         {
 203                 precache_model ("models/uziflash.md3");
 204                 precache_model ("models/weapons/g_shotgun.md3");
 205                 precache_model ("models/weapons/v_shotgun.md3");
 206                 precache_model ("models/weapons/h_shotgun.iqm");
 207                 precache_sound ("misc/itempickup.wav");
 208                 precache_sound ("weapons/shotgun_fire.wav");
 209                 precache_sound ("weapons/shotgun_melee.wav");
 210                 //precache_sound ("weapons/reload.wav"); // until weapons have individual reload sounds, precache the reload sound somewhere else
 211         }
 212         else if (req == WR_SETUP)
 213         {
 214                 weapon_setup(WEP_SHOTGUN);
 215                 self.current_ammo = ammo_shells;
 216         }
 217         else if (req == WR_CHECKAMMO1)
 218         {
 219                 ammo_amount = self.ammo_shells >= autocvar_g_balance_shotgun_primary_ammo;
 220                 ammo_amount += self.weapon_load[WEP_SHOTGUN] >= autocvar_g_balance_shotgun_primary_ammo;
 221                 return ammo_amount;
 222         }
 223         else if (req == WR_CHECKAMMO2)
 224         {
 225                 // melee attack is always available
 226                 return TRUE;
 227         }
 228         else if (req == WR_RELOAD)
 229         {
 230                 W_Reload(autocvar_g_balance_shotgun_primary_ammo, autocvar_g_balance_shotgun_reload_ammo, autocvar_g_balance_shotgun_reload_time, "weapons/reload.wav");
 231         }
 232         return TRUE;
 233 };
 234 #endif
 235 #ifdef CSQC
 236 .float prevric;
 237 float w_shotgun(float req)
 238 {
 239         if(req == WR_IMPACTEFFECT)
 240         {
 241                 vector org2;
 242                 org2 = w_org + w_backoff * 2;
 243                 pointparticles(particleeffectnum("shotgun_impact"), org2, w_backoff * 1000, 1);
 244                 if(!w_issilent && time - self.prevric > 0.25)
 245                 {
 246                         if(w_random < 0.0165)
 247                                 sound(self, CH_SHOTS, "weapons/ric1.wav", VOL_BASE, ATTN_NORM);
 248                         else if(w_random < 0.033)
 249                                 sound(self, CH_SHOTS, "weapons/ric2.wav", VOL_BASE, ATTN_NORM);
 250                         else if(w_random < 0.05)
 251                                 sound(self, CH_SHOTS, "weapons/ric3.wav", VOL_BASE, ATTN_NORM);
 252                         self.prevric = time;
 253                 }
 254         }
 255         else if(req == WR_PRECACHE)
 256         {
 257                 precache_sound("weapons/ric1.wav");
 258                 precache_sound("weapons/ric2.wav");
 259                 precache_sound("weapons/ric3.wav");
 260         }
 261         else if (req == WR_SUICIDEMESSAGE)
 262                 w_deathtypestring = _("%s is now thinking with portals");
 263         else if (req == WR_KILLMESSAGE)
 264         {
 265                 if(w_deathtype & HITTYPE_SECONDARY)
 266                         w_deathtypestring = _("%2$s ^7slapped %1$s ^7around a bit with a large ^2shotgun");
 267                 else
 268                         w_deathtypestring = _("%s was gunned by %s");
 269         }
 270         return TRUE;
 271 }
 272 #endif
 273 #endif