qcsrc/server/w_shotgun.qc

   1 #ifdef REGISTER_WEAPON
   2 REGISTER_WEAPON(SHOTGUN, w_shotgun, IT_SHELLS, 2, WEP_FLAG_NORMAL | WEP_FLAG_RELOADABLE | WEP_TYPE_HITSCAN, BOT_PICKUP_RATING_LOW, "shotgun", "shotgun", _("Shotgun"))
   3 #else
   4 #ifdef SVQC
   5
   6 void W_Shotgun_Attack (void)
   7 {
   8         float   sc;
   9         float   ammoamount;
  10         float   bullets;
  11         float   d;
  12         float   f;
  13         float   spread;
  14         float   bulletspeed;
  15         float   bulletconstant;
  16         local entity flash;
  17
  18         ammoamount = autocvar_g_balance_shotgun_primary_ammo;
  19         bullets = autocvar_g_balance_shotgun_primary_bullets;
  20         d = autocvar_g_balance_shotgun_primary_damage;
  21         f = autocvar_g_balance_shotgun_primary_force;
  22         spread = autocvar_g_balance_shotgun_primary_spread;
  23         bulletspeed = autocvar_g_balance_shotgun_primary_speed;
  24         bulletconstant = autocvar_g_balance_shotgun_primary_bulletconstant;
  25
  26         W_DecreaseAmmo(ammo_shells, ammoamount, autocvar_g_balance_shotgun_reload_ammo);
  27
  28         W_SetupShot (self, autocvar_g_antilag_bullets && bulletspeed >= autocvar_g_antilag_bullets, 5, "weapons/shotgun_fire.wav", CH_WEAPON_A, d * bullets);
  29         for (sc = 0;sc < bullets;sc = sc + 1)
  30                 fireBallisticBullet(w_shotorg, w_shotdir, spread, bulletspeed, 5, d, 0, f, WEP_SHOTGUN, 0, 1, bulletconstant);
  31         endFireBallisticBullet();
  32
  33         pointparticles(particleeffectnum("shotgun_muzzleflash"), w_shotorg, w_shotdir * 1000, autocvar_g_balance_shotgun_primary_ammo);
  34
  35         // casing code
  36         if (autocvar_g_casings >= 1)
  37                 for (sc = 0;sc < ammoamount;sc = sc + 1)
  38                         SpawnCasing (((random () * 50 + 50) * v_right) - (v_forward * (random () * 25 + 25)) - ((random () * 5 - 30) * v_up), 2, vectoangles(v_forward),'0 250 0', 100, 1, self);
  39
  40         // muzzle flash for 1st person view
  41         flash = spawn();
  42         setmodel(flash, "models/uziflash.md3"); // precision set below
  43         flash.think = SUB_Remove;
  44         flash.nextthink = time + 0.06;
  45         flash.effects = EF_ADDITIVE | EF_FULLBRIGHT | EF_LOWPRECISION;
  46         W_AttachToShotorg(flash, '5 0 0');
  47 }
  48
  49 .float swing_prev;
  50 .entity swing_alreadyhit;
  51 void shotgun_meleethink (void)
  52 {
  53         // declarations
  54         float i, f, swing, swing_factor, swing_damage, meleetime, is_player;
  55         vector targpos;
  56
  57         if(!self.cnt) { self.cnt = time; } // set start time of melee
  58
  59         makevectors(self.realowner.v_angle); // update values for v_* vectors
  60
  61         // calculate swing percentage based on time
  62         meleetime = autocvar_g_balance_shotgun_secondary_melee_time * W_WeaponRateFactor();
  63         swing = bound(0, (self.cnt + meleetime - time) / meleetime, 1);
  64         f = ((1 - swing) * autocvar_g_balance_shotgun_secondary_melee_traces);
  65
  66         // check to see if we can still continue, otherwise give up now
  67         if(time >= self.cnt + meleetime || (self.realowner.deadflag != DEAD_NO && autocvar_g_balance_shotgun_secondary_melee_no_doubleslap))
  68         {
  69                 remove(self);
  70                 return;
  71         }
  72
  73         // if okay, perform the traces needed for this frame
  74         for(i=self.swing_prev; i < f; ++i)
  75         {
  76                 swing_factor = ((1 - (i / autocvar_g_balance_shotgun_secondary_melee_traces)) * 2 - 1);
  77
  78                 targpos = (self.realowner.origin + self.realowner.view_ofs
  79                         + (v_forward * autocvar_g_balance_shotgun_secondary_melee_range)
  80                         + (v_up * swing_factor * autocvar_g_balance_shotgun_secondary_melee_swing_up)
  81                         + (v_right * swing_factor * autocvar_g_balance_shotgun_secondary_melee_swing_side));
  82
  83                 WarpZone_traceline_antilag(self.realowner, self.realowner.origin + self.realowner.view_ofs, targpos, FALSE, lgbeam_owner_ent, ANTILAG_LATENCY(self.realowner));
  84
  85                 // draw lightning beams for debugging
  86                 // te_lightning2(world, targpos, self.realowner.origin + self.realowner.view_ofs + v_forward * 5 - v_up * 5);
  87                 // te_customflash(targpos, 40,  2, '1 1 1');
  88
  89                 is_player = (trace_ent.classname == "player" || trace_ent.classname == "body");
  90
  91                 if((trace_fraction < 1) // if trace is good, apply the damage and remove self
  92                         && (trace_ent.takedamage == DAMAGE_AIM)
  93                         && (trace_ent != self.swing_alreadyhit)
  94                         && (is_player || autocvar_g_balance_shotgun_secondary_melee_nonplayerdamage))
  95                 {
  96                         if(is_player) // this allows us to be able to nerf the non-player damage done in e.g. assault or onslaught.
  97                                 swing_damage = (autocvar_g_balance_shotgun_secondary_damage * min(1, swing_factor + 1));
  98                         else
  99                                 swing_damage = (autocvar_g_balance_shotgun_secondary_melee_nonplayerdamage * min(1, swing_factor + 1));
 100
 101                         Damage(trace_ent, self.realowner, self.realowner,
 102                                 swing_damage, WEP_SHOTGUN | HITTYPE_SECONDARY,
 103                                 self.realowner.origin + self.realowner.view_ofs,
 104                                 v_forward * autocvar_g_balance_shotgun_secondary_force);
 105
 106                         if(accuracy_isgooddamage(self.realowner, trace_ent))
 107                                 accuracy_add(self.realowner, WEP_SHOTGUN, 0, swing_damage);
 108
 109                         // draw large red flash for debugging
 110                         // te_customflash(targpos, 200, 2, '15 0 0');
 111
 112                         if(autocvar_g_balance_shotgun_secondary_melee_multihit) // allow multiple hits with one swing, but not against the same player twice.
 113                         {
 114                                 self.swing_alreadyhit = trace_ent;
 115                                 continue; // move along to next trace
 116                         }
 117                         else
 118                         {
 119                                 remove(self);
 120                                 return;
 121                         }
 122                 }
 123         }
 124
 125         // set up next frame
 126         self.swing_prev = i;
 127         self.nextthink = time;
 128 }
 129
 130 void W_Shotgun_Attack2 (void)
 131 {
 132         sound (self, CH_SHOTS, "weapons/shotgun_melee.wav", VOL_BASE, ATTN_NORM);
 133         weapon_thinkf(WFRAME_FIRE2, autocvar_g_balance_shotgun_secondary_animtime, w_ready);
 134
 135         entity meleetemp;
 136         meleetemp = spawn();
 137         meleetemp.owner = meleetemp.realowner = self;
 138         meleetemp.think = shotgun_meleethink;
 139         meleetemp.nextthink = time + autocvar_g_balance_shotgun_secondary_melee_delay * W_WeaponRateFactor();
 140         W_SetupShot_Range(self, TRUE, 0, "", 0, autocvar_g_balance_shotgun_secondary_damage, autocvar_g_balance_shotgun_secondary_melee_range);
 141 }
 142
 143 void spawnfunc_weapon_shotgun(); // defined in t_items.qc
 144
 145 .float shotgun_primarytime;
 146
 147 float w_shotgun(float req)
 148 {
 149         float ammo_amount;
 150         if (req == WR_AIM)
 151                 if(vlen(self.origin-self.enemy.origin) <= autocvar_g_balance_shotgun_secondary_melee_range)
 152                         self.BUTTON_ATCK2 = bot_aim(1000000, 0, 0.001, FALSE);
 153                 else
 154                 {
 155                         if(autocvar_g_antilag_bullets)
 156                                 self.BUTTON_ATCK = bot_aim(1000000, 0, 0.001, FALSE);
 157                         else
 158                                 self.BUTTON_ATCK = bot_aim(autocvar_g_balance_shotgun_primary_speed, 0, 0.001, FALSE);
 159                 }
 160
 161         else if (req == WR_THINK)
 162         {
 163                 if(autocvar_g_balance_shotgun_reload_ammo && self.clip_load < autocvar_g_balance_shotgun_primary_ammo) // forced reload
 164                 {
 165                         // don't force reload an empty shotgun if its melee attack is active
 166                         if not(autocvar_g_balance_shotgun_secondary && self.ammo_shells < autocvar_g_balance_shotgun_primary_ammo)
 167                                 weapon_action(self.weapon, WR_RELOAD);
 168                 }
 169                 else
 170                 {
 171                         if (self.BUTTON_ATCK)
 172                         {
 173                                 if (time >= self.shotgun_primarytime) // handle refire separately so the secondary can be fired straight after a primary
 174                                 {
 175                                         if(weapon_prepareattack(0, autocvar_g_balance_shotgun_primary_animtime))
 176                                         {
 177                                                 W_Shotgun_Attack();
 178                                                 self.shotgun_primarytime = time + autocvar_g_balance_shotgun_primary_refire * W_WeaponRateFactor();
 179                                                 weapon_thinkf(WFRAME_FIRE1, autocvar_g_balance_shotgun_primary_animtime, w_ready);
 180                                         }
 181                                 }
 182                         }
 183                 }
 184                 if (self.clip_load >= 0) // we are not currently reloading
 185                 if (self.BUTTON_ATCK2 && autocvar_g_balance_shotgun_secondary)
 186                 if (weapon_prepareattack(1, autocvar_g_balance_shotgun_secondary_refire))
 187                 {
 188                         // attempt forcing playback of the anim by switching to another anim (that we never play) here...
 189                         weapon_thinkf(WFRAME_FIRE1, 0, W_Shotgun_Attack2);
 190                 }
 191         }
 192         else if (req == WR_PRECACHE)
 193         {
 194                 precache_model ("models/uziflash.md3");
 195                 precache_model ("models/weapons/g_shotgun.md3");
 196                 precache_model ("models/weapons/v_shotgun.md3");
 197                 precache_model ("models/weapons/h_shotgun.iqm");
 198                 precache_sound ("misc/itempickup.wav");
 199                 precache_sound ("weapons/shotgun_fire.wav");
 200                 precache_sound ("weapons/shotgun_melee.wav");
 201                 //precache_sound ("weapons/reload.wav"); // until weapons have individual reload sounds, precache the reload sound somewhere else
 202         }
 203         else if (req == WR_SETUP)
 204         {
 205                 weapon_setup(WEP_SHOTGUN);
 206                 self.current_ammo = ammo_shells;
 207         }
 208         else if (req == WR_CHECKAMMO1)
 209         {
 210                 ammo_amount = self.ammo_shells >= autocvar_g_balance_shotgun_primary_ammo;
 211                 ammo_amount += self.weapon_load[WEP_SHOTGUN] >= autocvar_g_balance_shotgun_primary_ammo;
 212                 return ammo_amount;
 213         }
 214         else if (req == WR_CHECKAMMO2)
 215         {
 216                 // melee attack is always available
 217                 return TRUE;
 218         }
 219         else if (req == WR_RELOAD)
 220         {
 221                 W_Reload(autocvar_g_balance_shotgun_primary_ammo, autocvar_g_balance_shotgun_reload_ammo, autocvar_g_balance_shotgun_reload_time, "weapons/reload.wav");
 222         }
 223         return TRUE;
 224 };
 225 #endif
 226 #ifdef CSQC
 227 .float prevric;
 228 float w_shotgun(float req)
 229 {
 230         if(req == WR_IMPACTEFFECT)
 231         {
 232                 vector org2;
 233                 org2 = w_org + w_backoff * 2;
 234                 pointparticles(particleeffectnum("shotgun_impact"), org2, w_backoff * 1000, 1);
 235                 if(!w_issilent && time - self.prevric > 0.25)
 236                 {
 237                         if(w_random < 0.0165)
 238                                 sound(self, CH_SHOTS, "weapons/ric1.wav", VOL_BASE, ATTN_NORM);
 239                         else if(w_random < 0.033)
 240                                 sound(self, CH_SHOTS, "weapons/ric2.wav", VOL_BASE, ATTN_NORM);
 241                         else if(w_random < 0.05)
 242                                 sound(self, CH_SHOTS, "weapons/ric3.wav", VOL_BASE, ATTN_NORM);
 243                         self.prevric = time;
 244                 }
 245         }
 246         else if(req == WR_PRECACHE)
 247         {
 248                 precache_sound("weapons/ric1.wav");
 249                 precache_sound("weapons/ric2.wav");
 250                 precache_sound("weapons/ric3.wav");
 251         }
 252         else if (req == WR_SUICIDEMESSAGE)
 253                 w_deathtypestring = _("%s is now thinking with portals");
 254         else if (req == WR_KILLMESSAGE)
 255         {
 256                 if(w_deathtype & HITTYPE_SECONDARY)
 257                         w_deathtypestring = _("%2$s ^7slapped %1$s ^7around a bit with a large ^2shotgun");
 258                 else
 259                         w_deathtypestring = _("%s was gunned by %s");
 260         }
 261         return TRUE;
 262 }
 263 #endif
 264 #endif