qcsrc/server/w_tuba.qc

   1 #ifdef REGISTER_WEAPON
   2 REGISTER_WEAPON(TUBA, w_tuba, 0, 1, WEP_FLAG_HIDDEN | WEP_TYPE_SPLASH, BOT_PICKUP_RATING_MID, "tuba", "tuba", _("@!#%'n Tuba"))
   3 #else
   4 #ifdef SVQC
   5 //#define TUBA_NOTE(n) strcat("weapons/tuba_note", ftos(n), ".wav")
   6 .entity tuba_note;
   7 .float tuba_smoketime;
   8 .float tuba_instrument;
   9
  10 float Tuba_GetNote(entity pl, float hittype)
  11 {
  12         float note;
  13         float movestate;
  14         movestate = 5;
  15         if(pl.movement_x < 0) movestate -= 3;
  16         if(pl.movement_x > 0) movestate += 3;
  17         if(pl.movement_y < 0) movestate -= 1;
  18         if(pl.movement_y > 0) movestate += 1;
  19         switch(movestate)
  20         {
  21         // layout: originally I wanted
  22         //   eb e  e#=f
  23         //   B  c  d
  24         //   Gb G  G#
  25         // but then you only use forward and right key. So to make things more
  26         // interesting, I swapped B with e#. Har har har...
  27         //   eb e  B
  28         // f=e# c  d
  29         //   Gb G  G#
  30                 case 1: note = -6; break; // Gb
  31                 case 2: note = -5; break; // G
  32                 case 3: note = -4; break; // G#
  33                 case 4: note = +5; break; // e#
  34                 case 5: note =  0; break; // c
  35                 case 6: note = +2; break; // d
  36                 case 7: note = +3; break; // eb
  37                 case 8: note = +4; break; // e
  38                 case 9: note = -1; break; // B
  39         }
  40         if(pl.BUTTON_CROUCH)
  41                 note -= 12;
  42         if(pl.BUTTON_JUMP)
  43                 note += 12;
  44         if(hittype & HITTYPE_SECONDARY)
  45                 note += 7;
  46
  47         // we support two kinds of tubas, those tuned in Eb and those tuned in C
  48         // kind of tuba currently is player slot number, or team number if in
  49         // teamplay
  50         // that way, holes in the range of notes are "plugged"
  51         if(teamplay)
  52         {
  53                 if(pl.team == COLOR_TEAM2 || pl.team == COLOR_TEAM4)
  54                         note += 3;
  55         }
  56         else
  57         {
  58                 if(pl.clientcolors & 1)
  59                         note += 3;
  60         }
  61
  62         // total range of notes:
  63         //                       0
  64         //                 ***  ** ****
  65         //                        ***  ** ****
  66         //     ***  ** ****
  67         //            ***  ** ****
  68         //     ***  ********************* ****
  69         //     -18.........................+12
  70         //        ***  ********************* ****
  71         //     -18............................+15
  72         //     with jump: ... +24
  73         //     ... +27
  74         return note;
  75 }
  76
  77 float W_Tuba_NoteSendEntity(entity to, float sf)
  78 {
  79         float f;
  80
  81         WriteByte(MSG_ENTITY, ENT_CLIENT_TUBANOTE);
  82         WriteByte(MSG_ENTITY, sf);
  83         if(sf & 1)
  84         {
  85                 WriteChar(MSG_ENTITY, self.cnt);
  86                 f = 0;
  87                 if(self.realowner != to)
  88                         f |= 1;
  89                 f |= 2 * self.tuba_instrument;
  90                 WriteByte(MSG_ENTITY, f);
  91         }
  92         if(sf & 2)
  93         {
  94                 WriteCoord(MSG_ENTITY, self.origin_x);
  95                 WriteCoord(MSG_ENTITY, self.origin_y);
  96                 WriteCoord(MSG_ENTITY, self.origin_z);
  97         }
  98         return TRUE;
  99 }
 100
 101 void W_Tuba_NoteThink()
 102 {
 103         float dist_mult;
 104         float vol0, vol1;
 105         vector dir0, dir1;
 106         vector v;
 107         entity e;
 108         if(time > self.teleport_time)
 109         {
 110                 self.realowner.tuba_note = world;
 111                 remove(self);
 112                 return;
 113         }
 114         self.nextthink = time;
 115         dist_mult = autocvar_g_balance_tuba_attenuation / autocvar_snd_soundradius;
 116         FOR_EACH_REALCLIENT(e)
 117         if(e != self.realowner)
 118         {
 119                 v = self.origin - (e.origin + e.view_ofs);
 120                 vol0 = max(0, 1 - vlen(v) * dist_mult);
 121                 dir0 = normalize(v);
 122                 v = self.realowner.origin - (e.origin + e.view_ofs);
 123                 vol1 = max(0, 1 - vlen(v) * dist_mult);
 124                 dir1 = normalize(v);
 125                 if(fabs(vol0 - vol1) > 0.005) // 0.5 percent change in volume
 126                 {
 127                         setorigin(self, self.realowner.origin);
 128                         self.SendFlags |= 2;
 129                         break;
 130                 }
 131                 if(dir0 * dir1 < 0.9994) // 2 degrees change in angle
 132                 {
 133                         setorigin(self, self.realowner.origin);
 134                         self.SendFlags |= 2;
 135                         break;
 136                 }
 137         }
 138 }
 139
 140 void W_Tuba_Attack(float hittype)
 141 {
 142         vector o;
 143         float n;
 144         W_SetupShot(self, FALSE, 2, "", 0, autocvar_g_balance_tuba_damage);
 145
 146         n = Tuba_GetNote(self, hittype);
 147
 148         if(self.tuba_note)
 149         {
 150                 if(self.tuba_note.cnt != n || self.tuba_note.tuba_instrument != self.tuba_instrument)
 151                 {
 152                         remove(self.tuba_note);
 153                         self.tuba_note = world;
 154                 }
 155         }
 156
 157         if not(self.tuba_note)
 158         {
 159                 self.tuba_note = spawn();
 160                 self.tuba_note.owner = self.tuba_note.realowner = self;
 161                 self.tuba_note.cnt = n;
 162                 self.tuba_note.tuba_instrument = self.tuba_instrument;
 163                 self.tuba_note.think = W_Tuba_NoteThink;
 164                 self.tuba_note.nextthink = time;
 165                 Net_LinkEntity(self.tuba_note, FALSE, 0, W_Tuba_NoteSendEntity);
 166         }
 167
 168         self.tuba_note.teleport_time = time + autocvar_g_balance_tuba_refire * 2 * W_WeaponRateFactor(); // so it can get prolonged safely
 169
 170         //sound(self, c, TUBA_NOTE(n), bound(0, VOL_BASE * cvar("g_balance_tuba_volume"), 1), autocvar_g_balance_tuba_attenuation);
 171         RadiusDamage(self, self, autocvar_g_balance_tuba_damage, autocvar_g_balance_tuba_edgedamage, autocvar_g_balance_tuba_radius, world, autocvar_g_balance_tuba_force, hittype | WEP_TUBA, world);
 172
 173         o = gettaginfo(self.exteriorweaponentity, 0);
 174         if(time > self.tuba_smoketime)
 175         {
 176                 pointparticles(particleeffectnum("smoke_ring"), o + v_up * 45 + v_right * -6 + v_forward * 8, v_up * 100, 1);
 177                 self.tuba_smoketime = time + 0.25;
 178         }
 179 }
 180
 181 void spawnfunc_weapon_tuba (void)
 182 {
 183         weapon_defaultspawnfunc(WEP_TUBA);
 184 }
 185
 186 float w_tuba(float req)
 187 {
 188         if (req == WR_AIM)
 189         {
 190                 // bots cannot play the Tuba well yet
 191                 // I think they should start with the recorder first
 192                 if(vlen(self.origin - self.enemy.origin) < autocvar_g_balance_tuba_radius)
 193                 {
 194                         if(random() > 0.5)
 195                                 self.BUTTON_ATCK = 1;
 196                         else
 197                                 self.BUTTON_ATCK2 = 1;
 198                 }
 199         }
 200         else if (req == WR_THINK)
 201         {
 202                 if (self.BUTTON_ATCK)
 203                 if (weapon_prepareattack(0, autocvar_g_balance_tuba_refire))
 204                 {
 205                         W_Tuba_Attack(0);
 206                         //weapon_thinkf(WFRAME_FIRE1, autocvar_g_balance_tuba_animtime, w_ready);
 207                         weapon_thinkf(WFRAME_IDLE, autocvar_g_balance_tuba_animtime, w_ready);
 208                 }
 209                 if (self.BUTTON_ATCK2)
 210                 if (weapon_prepareattack(1, autocvar_g_balance_tuba_refire))
 211                 {
 212                         W_Tuba_Attack(HITTYPE_SECONDARY);
 213                         //weapon_thinkf(WFRAME_FIRE2, autocvar_g_balance_tuba_animtime, w_ready);
 214                         weapon_thinkf(WFRAME_IDLE, autocvar_g_balance_tuba_animtime, w_ready);
 215                 }
 216                 if(self.tuba_note)
 217                 {
 218                         if(!self.BUTTON_ATCK && !self.BUTTON_ATCK2)
 219                         {
 220                                 remove(self.tuba_note);
 221                                 self.tuba_note = world;
 222                         }
 223                 }
 224         }
 225         else if (req == WR_PRECACHE)
 226         {
 227                 precache_model ("models/weapons/g_tuba.md3");
 228                 precache_model ("models/weapons/v_tuba.md3");
 229                 precache_model ("models/weapons/h_tuba.iqm");
 230
 231                 //float i;
 232                 //for(i = -18; i <= +27; ++i)
 233                 //      precache_sound(TUBA_NOTE(i));
 234         }
 235         else if (req == WR_SETUP)
 236         {
 237                 weapon_setup(WEP_TUBA);
 238                 self.current_ammo = ammo_none;
 239                 self.tuba_instrument = 0;
 240         }
 241         else if (req == WR_RELOAD)
 242         {
 243                 // TODO switch to alternate instruments :)
 244                 if(self.weaponentity.state == WS_READY)
 245                 {
 246                         /*
 247                         switch(self.tuba_instrument)
 248                         {
 249                                 case 0:
 250                                         self.tuba_instrument = 1;
 251                                         self.weaponname = "laser";
 252                                         break;
 253                                 case 1:
 254                                         self.tuba_instrument = 0;
 255                                         self.weaponname = "tuba";
 256                                         break;
 257                         }
 258                         */
 259                         W_SetupShot(self, FALSE, 0, "", 0, 0);
 260                         pointparticles(particleeffectnum("teleport"), w_shotorg, '0 0 0', 1);
 261                         self.weaponentity.state = WS_INUSE;
 262                         weapon_thinkf(WFRAME_RELOAD, 0.5, w_ready);
 263                 }
 264         }
 265         else if (req == WR_CHECKAMMO1)
 266                 return TRUE; // TODO use fuel?
 267         else if (req == WR_CHECKAMMO2)
 268                 return TRUE; // TODO use fuel?
 269         return TRUE;
 270 };
 271 #endif
 272 #ifdef CSQC
 273 float w_tuba(float req)
 274 {
 275         if(req == WR_IMPACTEFFECT)
 276         {
 277                 // nothing to do here; particles of tuba are handled differently
 278         }
 279         else if(req == WR_PRECACHE)
 280         {
 281                 // nothing to do
 282         }
 283         else if (req == WR_SUICIDEMESSAGE)
 284         {
 285                 w_deathtypestring = _("%s hurt his own ears with the @!#%%'n Tuba");
 286         }
 287         else if (req == WR_KILLMESSAGE)
 288         {
 289                 w_deathtypestring = _("%s died of %s's great playing on the @!#%%'n Tuba");
 290         }
 291         return TRUE;
 292 }
 293 #endif
 294 #endif