qcsrc/server/waypointsprites.qc

   1 #include "waypointsprites.qh"
   2
   3 #if defined(CSQC)
   4 #elif defined(MENUQC)
   5 #elif defined(SVQC)
   6     #include "../common/constants.qh"
   7     #include "../common/util.qh"
   8     #include "../common/buffs.qh"
   9     #include "autocvars.qh"
  10     #include "constants.qh"
  11     #include "defs.qh"
  12     #include "../common/deathtypes.qh"
  13     #include "mutators/mutators_include.qh"
  14     #include "../common/mapinfo.qh"
  15     #include "miscfunctions.qh"
  16 #endif
  17
  18 void WaypointSprite_UpdateSprites(entity e, string m1, string m2, string m3)
  19 {
  20         if(m1 != e.model1)
  21         {
  22                 e.model1 = m1;
  23                 e.SendFlags |= 2;
  24         }
  25         if(m2 != e.model2)
  26         {
  27                 e.model2 = m2;
  28                 e.SendFlags |= 4;
  29         }
  30         if(m3 != e.model3)
  31         {
  32                 e.model3 = m3;
  33                 e.SendFlags |= 8;
  34         }
  35 }
  36
  37 void WaypointSprite_UpdateHealth(entity e, float f)
  38 {
  39         f = bound(0, f, e.max_health);
  40         if(f != e.health || e.pain_finished)
  41         {
  42                 e.health = f;
  43                 e.pain_finished = 0;
  44                 e.SendFlags |= 0x80;
  45         }
  46 }
  47
  48 void WaypointSprite_UpdateMaxHealth(entity e, float f)
  49 {
  50         if(f != e.max_health || e.pain_finished)
  51         {
  52                 e.max_health = f;
  53                 e.pain_finished = 0;
  54                 e.SendFlags |= 0x80;
  55         }
  56 }
  57
  58 void WaypointSprite_UpdateBuildFinished(entity e, float f)
  59 {
  60         if(f != e.pain_finished || e.max_health)
  61         {
  62                 e.max_health = 0;
  63                 e.pain_finished = f;
  64                 e.SendFlags |= 0x80;
  65         }
  66 }
  67
  68 void WaypointSprite_UpdateOrigin(entity e, vector o)
  69 {
  70         if(o != e.origin)
  71         {
  72                 setorigin(e, o);
  73                 e.SendFlags |= 64;
  74         }
  75 }
  76
  77 void WaypointSprite_UpdateRule(entity e, float t, float r)
  78 {
  79         // no check, as this is never called without doing an actual change (usually only once)
  80         e.rule = r;
  81         e.team = t;
  82         e.SendFlags |= 1;
  83 }
  84
  85 void WaypointSprite_UpdateTeamRadar(entity e, float icon, vector col)
  86 {
  87         // no check, as this is never called without doing an actual change (usually only once)
  88         e.cnt = (icon & 0x7F) | (e.cnt & 0x80);
  89         e.colormod = col;
  90         e.SendFlags |= 32;
  91 }
  92
  93 void WaypointSprite_Ping(entity e)
  94 {
  95         // anti spam
  96         if(time < e.waypointsprite_pingtime)
  97                 return;
  98         e.waypointsprite_pingtime = time + 0.3;
  99         // ALWAYS sends (this causes a radar circle), thus no check
 100         e.cnt |= 0x80;
 101         e.SendFlags |= 32;
 102 }
 103
 104 void WaypointSprite_HelpMePing(entity e)
 105 {
 106         WaypointSprite_Ping(e);
 107         e.waypointsprite_helpmetime = time + waypointsprite_deployed_lifetime;
 108         e.SendFlags |= 32;
 109 }
 110
 111 void WaypointSprite_FadeOutIn(entity e, float t)
 112 {
 113         if(!e.fade_time)
 114         {
 115                 e.fade_time = t;
 116                 e.teleport_time = time + t;
 117         }
 118         else if(t < (e.teleport_time - time))
 119         {
 120                 // accelerate the waypoint's dying
 121                 // ensure:
 122                 //   (e.teleport_time - time) / wp.fade_time stays
 123                 //   e.teleport_time = time + fadetime
 124                 float current_fadetime;
 125                 current_fadetime = e.teleport_time - time;
 126                 e.teleport_time = time + t;
 127                 e.fade_time = e.fade_time * t / current_fadetime;
 128         }
 129
 130         e.SendFlags |= 16;
 131 }
 132
 133 void WaypointSprite_Init()
 134 {
 135         waypointsprite_limitedrange = autocvar_sv_waypointsprite_limitedrange;
 136         waypointsprite_deployed_lifetime = autocvar_sv_waypointsprite_deployed_lifetime;
 137         waypointsprite_deadlifetime = autocvar_sv_waypointsprite_deadlifetime;
 138 }
 139
 140 void WaypointSprite_InitClient(entity e)
 141 {
 142 }
 143
 144 void WaypointSprite_Kill(entity wp)
 145 {
 146         if(!wp)
 147                 return;
 148         if(wp.owner)
 149                 wp.owner.(wp.owned_by_field) = world;
 150         remove(wp);
 151 }
 152
 153 void WaypointSprite_Disown(entity wp, float fadetime)
 154 {
 155         if(!wp)
 156                 return;
 157         if(wp.classname != "sprite_waypoint")
 158         {
 159                 backtrace("Trying to disown a non-waypointsprite");
 160                 return;
 161         }
 162         if(wp.owner)
 163         {
 164                 if(wp.exteriormodeltoclient == wp.owner)
 165                         wp.exteriormodeltoclient = world;
 166                 wp.owner.(wp.owned_by_field) = world;
 167                 wp.owner = world;
 168
 169                 WaypointSprite_FadeOutIn(wp, fadetime);
 170         }
 171 }
 172
 173 void WaypointSprite_Think()
 174 {
 175         float doremove;
 176
 177         doremove = false;
 178
 179         if(self.fade_time)
 180         {
 181                 if(time >= self.teleport_time)
 182                         doremove = true;
 183         }
 184
 185         if(self.exteriormodeltoclient)
 186                 WaypointSprite_UpdateOrigin(self, self.exteriormodeltoclient.origin + self.view_ofs);
 187
 188         if(doremove)
 189                 WaypointSprite_Kill(self);
 190         else
 191                 self.nextthink = time; // WHY?!?
 192 }
 193
 194 float WaypointSprite_visible_for_player(entity e)
 195 {
 196         // personal waypoints
 197         if(self.enemy)
 198                 if(self.enemy != e)
 199                         return false;
 200
 201         // team waypoints
 202         if(self.rule == SPRITERULE_SPECTATOR)
 203         {
 204                 if(!warmup_stage && e.classname == "player")
 205                         return FALSE;
 206         }
 207         else if(self.team && self.rule == SPRITERULE_DEFAULT)
 208         {
 209                 if(self.team != e.team)
 210                         return false;
 211                 if (!IS_PLAYER(e))
 212                         return false;
 213         }
 214
 215         return true;
 216 }
 217
 218 entity WaypointSprite_getviewentity(entity e)
 219 {
 220         if(IS_SPEC(e))
 221                 e = e.enemy;
 222         /* TODO idea (check this breaks nothing)
 223         else if(e.classname == "observer")
 224                 e = world;
 225         */
 226         return e;
 227 }
 228
 229 float WaypointSprite_isteammate(entity e, entity e2)
 230 {
 231         if(teamplay)
 232         {
 233                 if(e2.team != e.team)
 234                         return false;
 235         }
 236         else
 237         {
 238                 if(e2 != e)
 239                         return false;
 240         }
 241         return true;
 242 }
 243
 244 float WaypointSprite_Customize()
 245 {
 246         // this is not in SendEntity because it shall run every frame, not just every update
 247
 248         // make spectators see what the player would see
 249         entity e;
 250         e = WaypointSprite_getviewentity(other);
 251
 252         if(MUTATOR_CALLHOOK(CustomizeWaypoint))
 253                 return false;
 254
 255         return self.waypointsprite_visible_for_player(e);
 256 }
 257
 258 float WaypointSprite_SendEntity(entity to, float sendflags)
 259 {
 260         float dt;
 261
 262         WriteByte(MSG_ENTITY, ENT_CLIENT_WAYPOINT);
 263
 264         sendflags = sendflags & 0x7F;
 265
 266         if(g_nexball)
 267                 sendflags &= ~0x80;
 268         else if(self.max_health || (self.pain_finished && (time < self.pain_finished + 0.25)))
 269                 sendflags |= 0x80;
 270
 271         WriteByte(MSG_ENTITY, sendflags);
 272
 273         if(sendflags & 0x80)
 274         {
 275                 if(self.max_health)
 276                 {
 277                         WriteByte(MSG_ENTITY, (self.health / self.max_health) * 191.0);
 278                 }
 279                 else
 280                 {
 281                         dt = self.pain_finished - time;
 282                         dt = bound(0, dt * 32, 16383);
 283                         WriteByte(MSG_ENTITY, (dt & 0xFF00) / 256 + 192);
 284                         WriteByte(MSG_ENTITY, (dt & 0x00FF));
 285                 }
 286         }
 287
 288         if(sendflags & 64)
 289         {
 290                 WriteCoord(MSG_ENTITY, self.origin.x);
 291                 WriteCoord(MSG_ENTITY, self.origin.y);
 292                 WriteCoord(MSG_ENTITY, self.origin.z);
 293         }
 294
 295         if(sendflags & 1)
 296         {
 297                 WriteByte(MSG_ENTITY, self.team);
 298                 WriteByte(MSG_ENTITY, self.rule);
 299         }
 300
 301         if(sendflags & 2)
 302                 WriteString(MSG_ENTITY, self.model1);
 303
 304         if(sendflags & 4)
 305                 WriteString(MSG_ENTITY, self.model2);
 306
 307         if(sendflags & 8)
 308                 WriteString(MSG_ENTITY, self.model3);
 309
 310         if(sendflags & 16)
 311         {
 312                 WriteCoord(MSG_ENTITY, self.fade_time);
 313                 WriteCoord(MSG_ENTITY, self.teleport_time);
 314                 WriteShort(MSG_ENTITY, self.fade_rate); // maxdist
 315                 float f;
 316                 f = 0;
 317                 if(self.currentammo)
 318                         f |= 1; // hideable
 319                 if(self.exteriormodeltoclient == to)
 320                         f |= 2; // my own
 321                 WriteByte(MSG_ENTITY, f);
 322         }
 323
 324         if(sendflags & 32)
 325         {
 326                 WriteByte(MSG_ENTITY, self.cnt); // icon on radar
 327                 WriteByte(MSG_ENTITY, self.colormod.x * 255.0);
 328                 WriteByte(MSG_ENTITY, self.colormod.y * 255.0);
 329                 WriteByte(MSG_ENTITY, self.colormod.z * 255.0);
 330
 331                 if(WaypointSprite_isteammate(self.owner, WaypointSprite_getviewentity(to)))
 332                 {
 333                         dt = (self.waypointsprite_helpmetime - time) / 0.1;
 334                         if(dt < 0)
 335                                 dt = 0;
 336                         if(dt > 255)
 337                                 dt = 255;
 338                         WriteByte(MSG_ENTITY, dt);
 339                 }
 340                 else
 341                         WriteByte(MSG_ENTITY, 0);
 342         }
 343
 344         return true;
 345 }
 346
 347 void WaypointSprite_Reset()
 348 {
 349         // if a WP wants to time out, let it time out immediately; other WPs ought to be reset/killed by their owners
 350
 351         if(self.fade_time) // there was there before: || g_keyhunt, do we really need this?
 352                 WaypointSprite_Kill(self);
 353 }
 354
 355 entity WaypointSprite_Spawn(
 356         string spr, // sprite
 357         float _lifetime, float maxdistance, // lifetime, max distance
 358         entity ref, vector ofs, // position
 359         entity showto, float t, // show to whom? Use a flag to indicate a team
 360         entity own, .entity ownfield, // remove when own gets killed
 361         float hideable, // true when it should be controlled by cl_hidewaypoints
 362         float icon, vector rgb // initial icon and color
 363 )
 364 {
 365         entity wp;
 366         wp = spawn();
 367         wp.classname = "sprite_waypoint";
 368         wp.teleport_time = time + _lifetime;
 369         wp.fade_time = _lifetime;
 370         wp.exteriormodeltoclient = ref;
 371         if(ref)
 372         {
 373                 wp.view_ofs = ofs;
 374                 setorigin(wp, ref.origin + ofs);
 375         }
 376         else
 377                 setorigin(wp, ofs);
 378         wp.enemy = showto;
 379         wp.team = t;
 380         wp.owner = own;
 381         wp.currentammo = hideable;
 382         if (own)
 383         {
 384                 if (own.(ownfield))
 385                         remove(own.(ownfield));
 386                 own.(ownfield) = wp;
 387                 wp.owned_by_field = ownfield;
 388         }
 389         wp.fade_rate = maxdistance;
 390         wp.think = WaypointSprite_Think;
 391         wp.nextthink = time;
 392         wp.model1 = spr;
 393         wp.customizeentityforclient = WaypointSprite_Customize;
 394         wp.waypointsprite_visible_for_player = WaypointSprite_visible_for_player;
 395         wp.reset2 = WaypointSprite_Reset;
 396         wp.cnt = icon;
 397         wp.colormod = rgb;
 398         Net_LinkEntity(wp, false, 0, WaypointSprite_SendEntity);
 399         return wp;
 400 }
 401
 402 entity WaypointSprite_SpawnFixed(
 403         string spr,
 404         vector ofs,
 405         entity own,
 406         .entity ownfield,
 407         float icon, vector rgb // initial icon and color
 408 )
 409 {
 410         return WaypointSprite_Spawn(spr, 0, 0, world, ofs, world, 0, own, ownfield, true, icon, rgb);
 411 }
 412
 413 entity WaypointSprite_DeployFixed(
 414         string spr,
 415         float limited_range,
 416         vector ofs,
 417         float icon, vector rgb // initial icon and color
 418 )
 419 {
 420         float t, maxdistance;
 421         if(teamplay)
 422                 t = self.team;
 423         else
 424                 t = 0;
 425         if(limited_range)
 426                 maxdistance = waypointsprite_limitedrange;
 427         else
 428                 maxdistance = 0;
 429         return WaypointSprite_Spawn(spr, waypointsprite_deployed_lifetime, maxdistance, world, ofs, world, t, self, waypointsprite_deployed_fixed, false, icon, rgb);
 430 }
 431
 432 entity WaypointSprite_DeployPersonal(
 433         string spr,
 434         vector ofs,
 435         float icon, vector rgb // initial icon and color
 436 )
 437 {
 438         return WaypointSprite_Spawn(spr, 0, 0, world, ofs, world, 0, self, waypointsprite_deployed_personal, false, icon, rgb);
 439 }
 440
 441 entity WaypointSprite_Attach(
 442         string spr,
 443         float limited_range,
 444         float icon, vector rgb // initial icon and color
 445 )
 446 {
 447         float t, maxdistance;
 448         if(self.waypointsprite_attachedforcarrier)
 449                 return world; // can't attach to FC
 450         if(teamplay)
 451                 t = self.team;
 452         else
 453                 t = 0;
 454         if(limited_range)
 455                 maxdistance = waypointsprite_limitedrange;
 456         else
 457                 maxdistance = 0;
 458         return WaypointSprite_Spawn(spr, waypointsprite_deployed_lifetime, maxdistance, self, '0 0 64', world, t, self, waypointsprite_attached, false, icon, rgb);
 459 }
 460
 461 entity WaypointSprite_AttachCarrier(
 462         string spr,
 463         entity carrier,
 464         float icon, vector rgb // initial icon and color
 465 )
 466 {
 467         entity e;
 468         WaypointSprite_Kill(carrier.waypointsprite_attached); // FC overrides attached
 469         e = WaypointSprite_Spawn(spr, 0, 0, carrier, '0 0 64', world, carrier.team, carrier, waypointsprite_attachedforcarrier, false, icon, rgb);
 470         if(e)
 471         {
 472                 WaypointSprite_UpdateMaxHealth(e, '1 0 0' * healtharmor_maxdamage(start_health, start_armorvalue, autocvar_g_balance_armor_blockpercent, DEATH_WEAPON) * 2);
 473                 WaypointSprite_UpdateHealth(e, '1 0 0' * healtharmor_maxdamage(carrier.health, carrier.armorvalue, autocvar_g_balance_armor_blockpercent, DEATH_WEAPON));
 474         }
 475         return e;
 476 }
 477
 478 void WaypointSprite_DetachCarrier(entity carrier)
 479 {
 480         WaypointSprite_Disown(carrier.waypointsprite_attachedforcarrier, waypointsprite_deadlifetime);
 481 }
 482
 483 void WaypointSprite_ClearPersonal()
 484 {
 485         WaypointSprite_Kill(self.waypointsprite_deployed_personal);
 486 }
 487
 488 void WaypointSprite_ClearOwned()
 489 {
 490         WaypointSprite_Kill(self.waypointsprite_deployed_fixed);
 491         WaypointSprite_Kill(self.waypointsprite_deployed_personal);
 492         WaypointSprite_Kill(self.waypointsprite_attached);
 493 }
 494
 495 void WaypointSprite_PlayerDead()
 496 {
 497         WaypointSprite_Disown(self.waypointsprite_attached, waypointsprite_deadlifetime);
 498         WaypointSprite_DetachCarrier(self);
 499 }
 500
 501 void WaypointSprite_PlayerGone()
 502 {
 503         WaypointSprite_Disown(self.waypointsprite_deployed_fixed, waypointsprite_deadlifetime);
 504         WaypointSprite_Kill(self.waypointsprite_deployed_personal);
 505         WaypointSprite_Disown(self.waypointsprite_attached, waypointsprite_deadlifetime);
 506         WaypointSprite_DetachCarrier(self);
 507 }