qcsrc/server/weapons/tracing.qc

   1 // this function calculates w_shotorg and w_shotdir based on the weapon model
   2 // offset, trueaim and antilag, and won't put w_shotorg inside a wall.
   3 // make sure you call makevectors first (FIXME?)
   4 void W_SetupShot_Dir_ProjectileSize_Range(entity ent, vector s_forward, vector mi, vector ma, float antilag, float recoil, string snd, float chan, float maxdamage, float range)
   5 {
   6         float nudge = 1; // added to traceline target and subtracted from result
   7         float oldsolid;
   8         vector vecs, dv;
   9         oldsolid = ent.dphitcontentsmask;
  10         if(ent.weapon == WEP_RIFLE)
  11                 ent.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_CORPSE;
  12         else
  13                 ent.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
  14         if(antilag)
  15                 WarpZone_traceline_antilag(world, ent.origin + ent.view_ofs, ent.origin + ent.view_ofs + s_forward * range, MOVE_NORMAL, ent, ANTILAG_LATENCY(ent));
  16                 // passing world, because we do NOT want it to touch dphitcontentsmask
  17         else
  18                 WarpZone_TraceLine(ent.origin + ent.view_ofs, ent.origin + ent.view_ofs + s_forward * range, MOVE_NOMONSTERS, ent);
  19         ent.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
  20
  21         vector vf, vr, vu;
  22         vf = v_forward;
  23         vr = v_right;
  24         vu = v_up;
  25         w_shotend = WarpZone_UnTransformOrigin(WarpZone_trace_transform, trace_endpos); // warpzone support
  26         v_forward = vf;
  27         v_right = vr;
  28         v_up = vu;
  29
  30         // un-adjust trueaim if shotend is too close
  31         if(vlen(w_shotend - (ent.origin + ent.view_ofs)) < autocvar_g_trueaim_minrange)
  32                 w_shotend = ent.origin + ent.view_ofs + s_forward * autocvar_g_trueaim_minrange;
  33
  34         // track max damage
  35         if(accuracy_canbegooddamage(ent))
  36                 accuracy_add(ent, ent.weapon, maxdamage, 0);
  37
  38         W_HitPlotAnalysis(ent, v_forward, v_right, v_up);
  39
  40         if(ent.weaponentity.movedir_x > 0)
  41                 vecs = ent.weaponentity.movedir;
  42         else
  43                 vecs = '0 0 0';
  44
  45         dv = v_right * -vecs_y + v_up * vecs_z;
  46         w_shotorg = ent.origin + ent.view_ofs + dv;
  47
  48         // now move the shotorg forward as much as requested if possible
  49         if(antilag)
  50         {
  51                 if(ent.antilag_debug)
  52                         tracebox_antilag(ent, w_shotorg, mi, ma, w_shotorg + v_forward * (vecs_x + nudge), MOVE_NORMAL, ent, ent.antilag_debug);
  53                 else
  54                         tracebox_antilag(ent, w_shotorg, mi, ma, w_shotorg + v_forward * (vecs_x + nudge), MOVE_NORMAL, ent, ANTILAG_LATENCY(ent));
  55         }
  56         else
  57                 tracebox(w_shotorg, mi, ma, w_shotorg + v_forward * (vecs_x + nudge), MOVE_NORMAL, ent);
  58         w_shotorg = trace_endpos - v_forward * nudge;
  59         // calculate the shotdir from the chosen shotorg
  60         w_shotdir = normalize(w_shotend - w_shotorg);
  61
  62         if (antilag)
  63         if (!ent.cvar_cl_noantilag)
  64         {
  65                 if (autocvar_g_antilag == 1) // switch to "ghost" if not hitting original
  66                 {
  67                         traceline(w_shotorg, w_shotorg + w_shotdir * range, MOVE_NORMAL, ent);
  68                         if (!trace_ent.takedamage)
  69                         {
  70                                 traceline_antilag_force (ent, w_shotorg, w_shotorg + w_shotdir * range, MOVE_NORMAL, ent, ANTILAG_LATENCY(ent));
  71                                 if (trace_ent.takedamage && IS_PLAYER(trace_ent))
  72                                 {
  73                                         entity e;
  74                                         e = trace_ent;
  75                                         traceline(w_shotorg, e.origin, MOVE_NORMAL, ent);
  76                                         if(trace_ent == e)
  77                                                 w_shotdir = normalize(trace_ent.origin - w_shotorg);
  78                                 }
  79                         }
  80                 }
  81                 else if(autocvar_g_antilag == 3) // client side hitscan
  82                 {
  83                         // this part MUST use prydon cursor
  84                         if (ent.cursor_trace_ent)                 // client was aiming at someone
  85                         if (ent.cursor_trace_ent != ent)         // just to make sure
  86                         if (ent.cursor_trace_ent.takedamage)      // and that person is killable
  87                         if (IS_PLAYER(ent.cursor_trace_ent)) // and actually a player
  88                         {
  89                                 // verify that the shot would miss without antilag
  90                                 // (avoids an issue where guns would always shoot at their origin)
  91                                 traceline(w_shotorg, w_shotorg + w_shotdir * range, MOVE_NORMAL, ent);
  92                                 if (!trace_ent.takedamage)
  93                                 {
  94                                         // verify that the shot would hit if altered
  95                                         traceline(w_shotorg, ent.cursor_trace_ent.origin, MOVE_NORMAL, ent);
  96                                         if (trace_ent == ent.cursor_trace_ent)
  97                                                 w_shotdir = normalize(ent.cursor_trace_ent.origin - w_shotorg);
  98                                         else
  99                                                 print("antilag fail\n");
 100                                 }
 101                         }
 102                 }
 103         }
 104
 105         ent.dphitcontentsmask = oldsolid; // restore solid type (generally SOLID_SLIDEBOX)
 106
 107         if (!autocvar_g_norecoil)
 108                 ent.punchangle_x = recoil * -1;
 109
 110         if (snd != "")
 111         {
 112                 sound (ent, chan, snd, VOL_BASE, ATTN_NORM);
 113                 W_PlayStrengthSound(ent);
 114         }
 115
 116         // nudge w_shotend so a trace to w_shotend hits
 117         w_shotend = w_shotend + normalize(w_shotend - w_shotorg) * nudge;
 118 }
 119
 120 vector W_CalculateProjectileVelocity(vector pvelocity, vector mvelocity, float forceAbsolute)
 121 {
 122         vector mdirection;
 123         float mspeed;
 124         vector outvelocity;
 125
 126         mvelocity = mvelocity * g_weaponspeedfactor;
 127
 128         mdirection = normalize(mvelocity);
 129         mspeed = vlen(mvelocity);
 130
 131         outvelocity = get_shotvelocity(pvelocity, mdirection, mspeed, (forceAbsolute ? 0 : autocvar_g_projectiles_newton_style), autocvar_g_projectiles_newton_style_2_minfactor, autocvar_g_projectiles_newton_style_2_maxfactor);
 132
 133         return outvelocity;
 134 }
 135
 136 #if 0
 137 float mspercallsum;
 138 float mspercallsstyle;
 139 float mspercallcount;
 140 #endif
 141 void W_SetupProjectileVelocityEx(entity missile, vector dir, vector upDir, float pSpeed, float pUpSpeed, float pZSpeed, float spread, float forceAbsolute)
 142 {
 143         if(missile.owner == world)
 144                 error("Unowned missile");
 145
 146         dir = dir + upDir * (pUpSpeed / pSpeed);
 147         dir_z += pZSpeed / pSpeed;
 148         pSpeed *= vlen(dir);
 149         dir = normalize(dir);
 150
 151 #if 0
 152         if(autocvar_g_projectiles_spread_style != mspercallsstyle)
 153         {
 154                 mspercallsum = mspercallcount = 0;
 155                 mspercallsstyle = autocvar_g_projectiles_spread_style;
 156         }
 157         mspercallsum -= gettime(GETTIME_HIRES);
 158 #endif
 159         dir = W_CalculateSpread(dir, spread, g_weaponspreadfactor, autocvar_g_projectiles_spread_style);
 160 #if 0
 161         mspercallsum += gettime(GETTIME_HIRES);
 162         mspercallcount += 1;
 163         print("avg: ", ftos(mspercallcount / mspercallsum), " per sec\n");
 164 #endif
 165
 166         missile.velocity = W_CalculateProjectileVelocity(missile.owner.velocity, pSpeed * dir, forceAbsolute);
 167 }
 168
 169 void W_SetupProjectileVelocity(entity missile, float pSpeed, float spread) // WEAPONTODO
 170 {
 171         W_SetupProjectileVelocityEx(missile, w_shotdir, v_up, pSpeed, 0, 0, spread, FALSE);
 172 }
 173
 174
 175 // ====================
 176 //  Ballistics Tracing
 177 // ====================
 178
 179 void FireRailgunBullet (vector start, vector end, float bdamage, float bforce, float mindist, float maxdist, float halflifedist, float forcehalflifedist, float deathtype)
 180 {
 181         vector hitloc, force, endpoint, dir;
 182         entity ent, endent;
 183         float endq3surfaceflags;
 184         float totaldmg;
 185         entity o;
 186
 187         float length;
 188         vector beampos;
 189         string snd;
 190         entity pseudoprojectile;
 191         float f, ffs;
 192
 193         pseudoprojectile = world;
 194
 195         railgun_start = start;
 196         railgun_end = end;
 197
 198         dir = normalize(end - start);
 199         length = vlen(end - start);
 200         force = dir * bforce;
 201
 202         // go a little bit into the wall because we need to hit this wall later
 203         end = end + dir;
 204
 205         totaldmg = 0;
 206
 207         // trace multiple times until we hit a wall, each obstacle will be made
 208         // non-solid so we can hit the next, while doing this we spawn effects and
 209         // note down which entities were hit so we can damage them later
 210         o = self;
 211         while (1)
 212         {
 213                 if(self.antilag_debug)
 214                         WarpZone_traceline_antilag (self, start, end, FALSE, o, self.antilag_debug);
 215                 else
 216                         WarpZone_traceline_antilag (self, start, end, FALSE, o, ANTILAG_LATENCY(self));
 217                 if(o && WarpZone_trace_firstzone)
 218                 {
 219                         o = world;
 220                         continue;
 221                 }
 222
 223                 if(trace_ent.solid == SOLID_BSP || trace_ent.solid == SOLID_SLIDEBOX)
 224                         Damage_DamageInfo(trace_endpos, bdamage, 0, 0, force, deathtype, trace_ent.species, self);
 225
 226                 // if it is world we can't hurt it so stop now
 227                 if (trace_ent == world || trace_fraction == 1)
 228                         break;
 229
 230                 // make the entity non-solid so we can hit the next one
 231                 trace_ent.railgunhit = TRUE;
 232                 trace_ent.railgunhitloc = end;
 233                 trace_ent.railgunhitsolidbackup = trace_ent.solid;
 234                 trace_ent.railgundistance = vlen(WarpZone_UnTransformOrigin(WarpZone_trace_transform, trace_endpos) - start);
 235                 trace_ent.railgunforce = WarpZone_TransformVelocity(WarpZone_trace_transform, force);
 236
 237                 // stop if this is a wall
 238                 if (trace_ent.solid == SOLID_BSP)
 239                         break;
 240
 241                 // make the entity non-solid
 242                 trace_ent.solid = SOLID_NOT;
 243         }
 244
 245         endpoint = trace_endpos;
 246         endent = trace_ent;
 247         endq3surfaceflags = trace_dphitq3surfaceflags;
 248
 249         // find all the entities the railgun hit and restore their solid state
 250         ent = findfloat(world, railgunhit, TRUE);
 251         while (ent)
 252         {
 253                 // restore their solid type
 254                 ent.solid = ent.railgunhitsolidbackup;
 255                 ent = findfloat(ent, railgunhit, TRUE);
 256         }
 257
 258         // spawn a temporary explosion entity for RadiusDamage calls
 259         //explosion = spawn();
 260
 261         // Find all non-hit players the beam passed close by
 262         if(deathtype == WEP_MINSTANEX || deathtype == WEP_NEX)
 263         {
 264                 FOR_EACH_REALCLIENT(msg_entity)
 265                 if(msg_entity != self)
 266                 if(!msg_entity.railgunhit)
 267                 if(!(IS_SPEC(msg_entity) && msg_entity.enemy == self)) // we use realclient, so spectators can hear the whoosh too
 268                 {
 269                         // nearest point on the beam
 270                         beampos = start + dir * bound(0, (msg_entity.origin - start) * dir, length);
 271
 272                         f = bound(0, 1 - vlen(beampos - msg_entity.origin) / 512, 1);
 273                         if(f <= 0)
 274                                 continue;
 275
 276                         snd = strcat("weapons/nexwhoosh", ftos(floor(random() * 3) + 1), ".wav");
 277
 278                         if(!pseudoprojectile)
 279                                 pseudoprojectile = spawn(); // we need this so the sound uses the "entchannel4" volume
 280                         soundtoat(MSG_ONE, pseudoprojectile, beampos, CH_SHOTS, snd, VOL_BASE * f, ATTEN_NONE);
 281                 }
 282
 283                 if(pseudoprojectile)
 284                         remove(pseudoprojectile);
 285         }
 286
 287         // find all the entities the railgun hit and hurt them
 288         ent = findfloat(world, railgunhit, TRUE);
 289         while (ent)
 290         {
 291                 // get the details we need to call the damage function
 292                 hitloc = ent.railgunhitloc;
 293
 294                 f = ExponentialFalloff(mindist, maxdist, halflifedist, ent.railgundistance);
 295                 ffs = ExponentialFalloff(mindist, maxdist, forcehalflifedist, ent.railgundistance);
 296
 297                 if(accuracy_isgooddamage(self.realowner, ent))
 298                         totaldmg += bdamage * f;
 299
 300                 // apply the damage
 301                 if (ent.takedamage)
 302                         Damage (ent, self, self, bdamage * f, deathtype, hitloc, ent.railgunforce * ffs);
 303
 304                 // create a small explosion to throw gibs around (if applicable)
 305                 //setorigin (explosion, hitloc);
 306                 //RadiusDamage (explosion, self, 10, 0, 50, world, world, 300, deathtype);
 307
 308                 ent.railgunhitloc = '0 0 0';
 309                 ent.railgunhitsolidbackup = SOLID_NOT;
 310                 ent.railgunhit = FALSE;
 311                 ent.railgundistance = 0;
 312
 313                 // advance to the next entity
 314                 ent = findfloat(ent, railgunhit, TRUE);
 315         }
 316
 317         // calculate hits and fired shots for hitscan
 318         accuracy_add(self, self.weapon, 0, min(bdamage, totaldmg));
 319
 320         trace_endpos = endpoint;
 321         trace_ent = endent;
 322         trace_dphitq3surfaceflags = endq3surfaceflags;
 323 }
 324
 325 void W_BallisticBullet_Hit (void)
 326 {
 327         float f, q, g;
 328
 329         f = pow(bound(0, vlen(self.velocity) / vlen(self.oldvelocity), 1), 2); // energy multiplier
 330         q = 1 + self.dmg_edge / self.dmg;
 331
 332         if(other.solid == SOLID_BSP || other.solid == SOLID_SLIDEBOX)
 333                 Damage_DamageInfo(self.origin, self.dmg * f, 0, 0, max(1, self.dmg_force) * normalize(self.velocity) * f, self.projectiledeathtype, other.species, self);
 334
 335         if(other && other != self.enemy)
 336         {
 337                 endzcurveparticles();
 338
 339                 yoda = 0;
 340                 railgun_start = self.origin - 2 * frametime * self.velocity;
 341                 railgun_end = self.origin + 2 * frametime * self.velocity;
 342                 g = accuracy_isgooddamage(self.realowner, other);
 343                 Damage(other, self, self.realowner, self.dmg * f, self.projectiledeathtype, self.origin, self.dmg_force * normalize(self.velocity) * f);
 344
 345                 /*if(yoda && (time > (self.last_yoda + 5)))
 346                 {
 347                         Send_Notification(NOTIF_ONE, self.realowner, MSG_ANNCE, ANNCE_ACHIEVEMENT_YODA);
 348                         self.last_yoda = time;
 349                 }*/
 350
 351                 // calculate hits for ballistic weapons
 352                 if(g)
 353                 {
 354                         // do not exceed 100%
 355                         q = min(self.dmg * q, self.dmg_total + f * self.dmg) - self.dmg_total;
 356                         self.dmg_total += f * self.dmg;
 357                         accuracy_add(self.realowner, self.realowner.weapon, 0, q);
 358                 }
 359         }
 360
 361         self.enemy = other; // don't hit the same player twice with the same bullet
 362 }
 363
 364 void W_BallisticBullet_LeaveSolid_think()
 365 {
 366         setorigin(self, self.W_BallisticBullet_LeaveSolid_origin);
 367         self.velocity = self.W_BallisticBullet_LeaveSolid_velocity;
 368
 369         self.think = self.W_BallisticBullet_LeaveSolid_think_save;
 370         self.nextthink = max(time, self.W_BallisticBullet_LeaveSolid_nextthink_save);
 371         self.W_BallisticBullet_LeaveSolid_think_save = func_null;
 372
 373         self.flags &= ~FL_ONGROUND;
 374
 375         if(self.enemy.solid == SOLID_BSP)
 376         {
 377                 float f;
 378                 f = pow(bound(0, vlen(self.velocity) / vlen(self.oldvelocity), 1), 2); // energy multiplier
 379                 Damage_DamageInfo(self.origin, 0, 0, 0, max(1, self.dmg_force) * normalize(self.velocity) * -f, self.projectiledeathtype, 0, self);
 380         }
 381
 382         UpdateCSQCProjectile(self);
 383 }
 384
 385 float W_BallisticBullet_LeaveSolid(float eff)
 386 {
 387         // move the entity along its velocity until it's out of solid, then let it resume
 388         vector vel = self.velocity;
 389         float dt, dst, velfactor, v0, vs;
 390         float maxdist;
 391         float E0_m, Es_m;
 392         float constant = self.dmg_radius * (other.ballistics_density ? other.ballistics_density : 1);
 393
 394         // outside the world? forget it
 395         if(self.origin_x > world.maxs_x || self.origin_y > world.maxs_y || self.origin_z > world.maxs_z || self.origin_x < world.mins_x || self.origin_y < world.mins_y || self.origin_z < world.mins_z)
 396                 return 0;
 397
 398         // special case for zero density and zero bullet constant:
 399
 400         if(self.dmg_radius == 0)
 401         {
 402                 if(other.ballistics_density < 0)
 403                         constant = 0; // infinite travel distance
 404                 else
 405                         return 0; // no penetration
 406         }
 407         else
 408         {
 409                 if(other.ballistics_density < 0)
 410                         constant = 0; // infinite travel distance
 411                 else if(other.ballistics_density == 0)
 412                         constant = self.dmg_radius;
 413                 else
 414                         constant = self.dmg_radius * other.ballistics_density;
 415         }
 416
 417         // E(s) = E0 - constant * s, constant = area of bullet circle * material constant / mass
 418         v0 = vlen(vel);
 419
 420         E0_m = 0.5 * v0 * v0;
 421
 422         if(constant)
 423         {
 424                 maxdist = E0_m / constant;
 425                 // maxdist = 0.5 * v0 * v0 / constant
 426                 // dprint("max dist = ", ftos(maxdist), "\n");
 427
 428                 if(maxdist <= autocvar_g_ballistics_mindistance)
 429                         return 0;
 430         }
 431         else
 432         {
 433                 maxdist = vlen(other.maxs - other.mins) + 1; // any distance, as long as we leave the entity
 434         }
 435
 436         traceline_inverted (self.origin, self.origin + normalize(vel) * maxdist, MOVE_NORMAL, self, TRUE);
 437         if(trace_fraction == 1) // 1: we never got out of solid
 438                 return 0;
 439
 440         self.W_BallisticBullet_LeaveSolid_origin = trace_endpos;
 441
 442         dst = max(autocvar_g_ballistics_mindistance, vlen(trace_endpos - self.origin));
 443         // E(s) = E0 - constant * s, constant = area of bullet circle * material constant / mass
 444         Es_m = E0_m - constant * dst;
 445         if(Es_m <= 0)
 446         {
 447                 // roundoff errors got us
 448                 return 0;
 449         }
 450         vs = sqrt(2 * Es_m);
 451         velfactor = vs / v0;
 452
 453         dt = dst / (0.5 * (v0 + vs));
 454         // this is not correct, but the differential equations have no analytic
 455         // solution - and these times are very small anyway
 456         //print("dt = ", ftos(dt), "\n");
 457
 458         self.W_BallisticBullet_LeaveSolid_think_save = self.think;
 459         self.W_BallisticBullet_LeaveSolid_nextthink_save = self.nextthink;
 460         self.think = W_BallisticBullet_LeaveSolid_think;
 461         self.nextthink = time + dt;
 462
 463         vel = vel * velfactor;
 464
 465         self.velocity = '0 0 0';
 466         self.flags |= FL_ONGROUND; // prevent moving
 467         self.W_BallisticBullet_LeaveSolid_velocity = vel;
 468
 469         if(eff >= 0)
 470                 if(vlen(trace_endpos - self.origin) > 4)
 471                 {
 472                         endzcurveparticles();
 473                         trailparticles(self, eff, self.origin, trace_endpos);
 474                 }
 475
 476         return 1;
 477 }
 478
 479 void W_BallisticBullet_Touch (void)
 480 {
 481         //float density;
 482
 483         if(self.think == W_BallisticBullet_LeaveSolid_think) // skip this!
 484                 return;
 485
 486         PROJECTILE_TOUCH;
 487         W_BallisticBullet_Hit ();
 488
 489         if(self.dmg_radius < 0) // these NEVER penetrate solid
 490         {
 491                 remove(self);
 492                 return;
 493         }
 494
 495         // if we hit "weapclip", bail out
 496         //
 497         // rationale of this check:
 498         //
 499         // any shader that is solid, nodraw AND trans is meant to clip weapon
 500         // shots and players, but has no other effect!
 501         //
 502         // if it is not trans, it is caulk and should not have this side effect
 503         //
 504         // matching shaders:
 505         //   common/weapclip (intended)
 506         //   common/noimpact (is supposed to eat projectiles, but is erased farther above)
 507         if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NODRAW)
 508         if (!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NONSOLID))
 509         if (!(trace_dphitcontents & DPCONTENTS_OPAQUE))
 510         {
 511                 remove(self);
 512                 return;
 513         }
 514
 515         // go through solid!
 516         if(!W_BallisticBullet_LeaveSolid(-1))
 517         {
 518                 remove(self);
 519                 return;
 520         }
 521
 522         self.projectiledeathtype |= HITTYPE_BOUNCE;
 523 }
 524
 525 void endFireBallisticBullet() // WEAPONTODO
 526 {
 527         endzcurveparticles();
 528 }
 529
 530 void fireBallisticBullet_trace_callback(vector start, vector hit, vector end)
 531 {
 532         if(vlen(trace_endpos - fireBallisticBullet_trace_callback_ent.origin) > 16)
 533                 zcurveparticles_from_tracetoss(fireBallisticBullet_trace_callback_eff, fireBallisticBullet_trace_callback_ent.origin, trace_endpos, fireBallisticBullet_trace_callback_ent.velocity);
 534         WarpZone_trace_forent = world;
 535         self.owner = world;
 536 }
 537
 538 void fireBallisticBullet(vector start, vector dir, float spread, float pSpeed, float lifetime, float damage, float force, float dtype, float tracereffects, float bulletconstant)
 539 {
 540         float lag, dt, savetime; //, density;
 541         entity pl, oldself;
 542
 543         entity proj;
 544         proj = spawn();
 545         proj.classname = "bullet";
 546         proj.owner = proj.realowner = self;
 547         PROJECTILE_MAKETRIGGER(proj);
 548         proj.movetype = MOVETYPE_FLY;
 549         proj.think = SUB_Remove;
 550         proj.nextthink = time + lifetime; // min(pLifetime, vlen(world.maxs - world.mins) / pSpeed);
 551         W_SetupProjectileVelocityEx(proj, dir, v_up, pSpeed, 0, 0, spread, TRUE);
 552         proj.angles = vectoangles(proj.velocity);
 553         if(bulletconstant > 0)
 554                 proj.dmg_radius = autocvar_g_ballistics_materialconstant / bulletconstant;
 555         else if(bulletconstant == 0)
 556                 proj.dmg_radius = 0;
 557         else
 558                 proj.dmg_radius = -1;
 559         // so: bulletconstant = bullet mass / area of bullet circle
 560         setorigin(proj, start);
 561         proj.flags = FL_PROJECTILE;
 562
 563         proj.touch = W_BallisticBullet_Touch;
 564         proj.dmg = damage;
 565         proj.dmg_force = force;
 566         proj.projectiledeathtype = dtype;
 567
 568         proj.oldvelocity = proj.velocity;
 569
 570         other = proj; MUTATOR_CALLHOOK(EditProjectile);
 571
 572         float eff;
 573
 574         if(tracereffects & EF_RED)
 575                 eff = particleeffectnum("tr_rifle");
 576         else if(tracereffects & EF_BLUE)
 577                 eff = particleeffectnum("tr_rifle_weak");
 578         else
 579                 eff = particleeffectnum("tr_bullet");
 580
 581         // NOTE: this may severely throw off weapon balance
 582         lag = ANTILAG_LATENCY(self);
 583         if(lag < 0.001)
 584                 lag = 0;
 585         if (!IS_REAL_CLIENT(self))
 586                 lag = 0;
 587         if(autocvar_g_antilag == 0 || self.cvar_cl_noantilag)
 588                 lag = 0; // only do hitscan, but no antilag
 589
 590         if(lag)
 591                 FOR_EACH_PLAYER(pl)
 592                         if(pl != self)
 593                                 antilag_takeback(pl, time - lag);
 594
 595         oldself = self;
 596         self = proj;
 597
 598         savetime = frametime;
 599         frametime = 0.05;
 600
 601         for(;;)
 602         {
 603                 // DP tracetoss is stupid and always traces in 0.05s
 604                 // ticks. This makes it trace in 0.05*0.125s ticks
 605                 // instead.
 606                 vector v0;
 607                 v0 = self.velocity;
 608                 self.velocity = self.velocity * 0.125;
 609                 trace_fraction = 0;
 610                 fireBallisticBullet_trace_callback_ent = self;
 611                 fireBallisticBullet_trace_callback_eff = eff;
 612                 WarpZone_TraceToss_ThroughZone(self, self.owner, world, fireBallisticBullet_trace_callback);
 613                 self.velocity = v0;
 614
 615                 if(trace_fraction == 1)
 616                         break;
 617                         // won't hit anything anytime soon (DP's
 618                         // tracetoss does 200 tics of, here,
 619                         // 0.05*0.125s, that is, 1.25 seconds
 620
 621                 other = trace_ent;
 622                 dt = WarpZone_tracetoss_time * 0.125; // this is only approximate!
 623                 setorigin(self, trace_endpos);
 624                 self.velocity = WarpZone_tracetoss_velocity * (1 / 0.125);
 625
 626                 if(!SUB_OwnerCheck())
 627                 {
 628                         if(SUB_NoImpactCheck())
 629                                 break;
 630
 631                         // hit the player
 632                         W_BallisticBullet_Hit();
 633                 }
 634
 635                 if(proj.dmg_radius < 0) // these NEVER penetrate solid
 636                         break;
 637
 638                 // if we hit "weapclip", bail out
 639                 //
 640                 // rationale of this check:
 641                 //
 642                 // any shader that is solid, nodraw AND trans is meant to clip weapon
 643                 // shots and players, but has no other effect!
 644                 //
 645                 // if it is not trans, it is caulk and should not have this side effect
 646                 //
 647                 // matching shaders:
 648                 //   common/weapclip (intended)
 649                 //   common/noimpact (is supposed to eat projectiles, but is erased farther above)
 650                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NODRAW)
 651                 if (!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NONSOLID))
 652                 if (!(trace_dphitcontents & DPCONTENTS_OPAQUE))
 653                         break;
 654
 655                 // go through solid!
 656                 if(!W_BallisticBullet_LeaveSolid((other && (other.solid != SOLID_BSP)) ? eff : -1))
 657                         break;
 658
 659                 W_BallisticBullet_LeaveSolid_think();
 660
 661                 self.projectiledeathtype |= HITTYPE_BOUNCE;
 662         }
 663         frametime = savetime;
 664         self = oldself;
 665
 666         if(lag)
 667                 FOR_EACH_PLAYER(pl)
 668                         if(pl != self)
 669                                 antilag_restore(pl);
 670
 671         remove(proj);
 672
 673         return;
 674 }
 675
 676 void fireBullet (vector start, vector dir, float spread, float damage, float force, float dtype, float tracer)
 677 {
 678         vector  end;
 679
 680         dir = normalize(dir + randomvec() * spread);
 681         end = start + dir * MAX_SHOT_DISTANCE;
 682         if(self.antilag_debug)
 683                 traceline_antilag (self, start, end, FALSE, self, self.antilag_debug);
 684         else
 685                 traceline_antilag (self, start, end, FALSE, self, ANTILAG_LATENCY(self));
 686
 687         end = trace_endpos;
 688
 689         if (pointcontents (trace_endpos) != CONTENT_SKY)
 690         {
 691                 if (!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT))
 692                         Damage_DamageInfo(trace_endpos, damage, 0, 0, dir * max(1, force), dtype, trace_ent.species, self);
 693
 694                 Damage (trace_ent, self, self, damage, dtype, trace_endpos, dir * force);
 695         }
 696         trace_endpos = end;
 697 }