qcsrc/server/weapons/tracing.qc

   1 #include "tracing.qh"
   2
   3 #include <common/effects/all.qh>
   4
   5 #include "accuracy.qh"
   6 #include "common.qh"
   7 #include "hitplot.qh"
   8 #include "weaponsystem.qh"
   9
  10 #include "../g_damage.qh"
  11 #include "../g_subs.qh"
  12 #include "../antilag.qh"
  13
  14 #include <common/constants.qh>
  15 #include <common/net_linked.qh>
  16 #include <common/util.qh>
  17
  18 #include <common/weapons/_all.qh>
  19 #include <common/state.qh>
  20
  21 #include <lib/warpzone/common.qh>
  22
  23 // this function calculates w_shotorg and w_shotdir based on the weapon model
  24 // offset, trueaim and antilag, and won't put w_shotorg inside a wall.
  25 // make sure you call makevectors first (FIXME?)
  26 void W_SetupShot_Dir_ProjectileSize_Range(entity ent, .entity weaponentity, vector s_forward, vector mi, vector ma, float antilag, float recoil, Sound snd, float chan, float maxdamage, float range)
  27 {
  28         TC(Sound, snd);
  29         float nudge = 1; // added to traceline target and subtracted from result  TOOD(divVerent): do we still need this? Doesn't the engine do this now for us?
  30         float oldsolid = ent.dphitcontentsmask;
  31         if(!IS_CLIENT(ent))
  32                 antilag = false; // no antilag for non-clients!
  33         if (IS_PLAYER(ent) && (ent.(weaponentity).m_weapon.spawnflags & WEP_FLAG_PENETRATEWALLS))
  34                 ent.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_CORPSE;
  35         else
  36                 ent.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
  37         if(antilag)
  38                 WarpZone_traceline_antilag(NULL, ent.origin + ent.view_ofs, ent.origin + ent.view_ofs + s_forward * range, MOVE_NORMAL, ent, ANTILAG_LATENCY(ent));
  39                 // passing NULL, because we do NOT want it to touch dphitcontentsmask
  40         else
  41                 WarpZone_TraceLine(ent.origin + ent.view_ofs, ent.origin + ent.view_ofs + s_forward * range, MOVE_NOMONSTERS, ent);
  42         ent.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
  43
  44         vector vf, vr, vu;
  45         vf = v_forward;
  46         vr = v_right;
  47         vu = v_up;
  48         w_shotend = WarpZone_UnTransformOrigin(WarpZone_trace_transform, trace_endpos); // warpzone support
  49         v_forward = vf;
  50         v_right = vr;
  51         v_up = vu;
  52
  53         // un-adjust trueaim if shotend is too close
  54         if(vdist(w_shotend - (ent.origin + ent.view_ofs), <, autocvar_g_trueaim_minrange))
  55                 w_shotend = ent.origin + ent.view_ofs + s_forward * autocvar_g_trueaim_minrange;
  56
  57         // track max damage
  58         if (IS_PLAYER(ent) && accuracy_canbegooddamage(ent))
  59                 accuracy_add(ent, ent.(weaponentity).m_weapon.m_id, maxdamage, 0);
  60
  61         if(IS_PLAYER(ent))
  62                 W_HitPlotAnalysis(ent, weaponentity, v_forward, v_right, v_up);
  63
  64         vector md = ent.(weaponentity).movedir;
  65         vector vecs = ((md.x > 0) ? md : '0 0 0');
  66
  67         vector dv = v_right * -vecs.y + v_up * vecs.z;
  68         w_shotorg = ent.origin + ent.view_ofs + dv;
  69
  70         // now move the shotorg forward as much as requested if possible
  71         if(antilag)
  72         {
  73                 if(CS(ent).antilag_debug)
  74                         tracebox_antilag(ent, w_shotorg, mi, ma, w_shotorg + v_forward * (vecs.x + nudge), MOVE_NORMAL, ent, CS(ent).antilag_debug);
  75                 else
  76                         tracebox_antilag(ent, w_shotorg, mi, ma, w_shotorg + v_forward * (vecs.x + nudge), MOVE_NORMAL, ent, ANTILAG_LATENCY(ent));
  77         }
  78         else
  79                 tracebox(w_shotorg, mi, ma, w_shotorg + v_forward * (vecs.x + nudge), MOVE_NORMAL, ent);
  80         w_shotorg = trace_endpos - v_forward * nudge;
  81         // calculate the shotdir from the chosen shotorg
  82         w_shotdir = normalize(w_shotend - w_shotorg);
  83
  84         //vector prevdir = w_shotdir;
  85         //vector prevorg = w_shotorg;
  86         //vector prevend = w_shotend;
  87
  88         if (antilag)
  89         if (!CS(ent).cvar_cl_noantilag)
  90         {
  91                 if (autocvar_g_antilag == 1) // switch to "ghost" if not hitting original
  92                 {
  93                         traceline(w_shotorg, w_shotorg + w_shotdir * range, MOVE_NORMAL, ent);
  94                         if (!trace_ent.takedamage)
  95                         {
  96                                 traceline_antilag_force (ent, w_shotorg, w_shotorg + w_shotdir * range, MOVE_NORMAL, ent, ANTILAG_LATENCY(ent));
  97                                 if (trace_ent.takedamage && IS_PLAYER(trace_ent))
  98                                 {
  99                                         entity e;
 100                                         e = trace_ent;
 101                                         traceline(w_shotorg, e.origin, MOVE_NORMAL, ent);
 102                                         if(trace_ent == e)
 103                                                 w_shotdir = normalize(trace_ent.origin - w_shotorg);
 104                                 }
 105                         }
 106                 }
 107                 else if(autocvar_g_antilag == 3) // client side hitscan
 108                 {
 109                         // this part MUST use prydon cursor
 110                         if (CS(ent).cursor_trace_ent)                 // client was aiming at someone
 111                         if (CS(ent).cursor_trace_ent != ent)         // just to make sure
 112                         if (CS(ent).cursor_trace_ent.takedamage)      // and that person is killable
 113                         if (IS_PLAYER(CS(ent).cursor_trace_ent)) // and actually a player
 114                         {
 115                                 // verify that the shot would miss without antilag
 116                                 // (avoids an issue where guns would always shoot at their origin)
 117                                 traceline(w_shotorg, w_shotorg + w_shotdir * range, MOVE_NORMAL, ent);
 118                                 if (!trace_ent.takedamage)
 119                                 {
 120                                         // verify that the shot would hit if altered
 121                                         traceline(w_shotorg, CS(ent).cursor_trace_ent.origin, MOVE_NORMAL, ent);
 122                                         if (trace_ent == CS(ent).cursor_trace_ent)
 123                                                 w_shotdir = normalize(CS(ent).cursor_trace_ent.origin - w_shotorg);
 124                                         else
 125                                                 LOG_INFO("antilag fail");
 126                                 }
 127                         }
 128                 }
 129         }
 130
 131         ent.dphitcontentsmask = oldsolid; // restore solid type (generally SOLID_SLIDEBOX)
 132
 133         if (!autocvar_g_norecoil)
 134                 ent.punchangle_x = recoil * -1;
 135
 136         if (snd != SND_Null) {
 137                 int held_weapons = 0; // HACK: muffle weapon sounds slightly while dual wielding!
 138                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 139                 {
 140                         .entity wep_ent = weaponentities[slot];
 141                         if(ent.(wep_ent) && ent.(wep_ent).m_switchweapon != WEP_Null)
 142                                 ++held_weapons;
 143                 }
 144                 sound (ent, chan, snd, ((held_weapons > 1) ? VOL_BASE * 0.7 : VOL_BASE), ATTN_NORM);
 145                 W_PlayStrengthSound(ent);
 146         }
 147
 148         // nudge w_shotend so a trace to w_shotend hits
 149         w_shotend = w_shotend + normalize(w_shotend - w_shotorg) * nudge;
 150         //if(w_shotend != prevend) { printf("SERVER: shotEND differs: %s - %s\n", vtos(w_shotend), vtos(prevend)); }
 151         //if(w_shotorg != prevorg) { printf("SERVER: shotORG differs: %s - %s\n", vtos(w_shotorg), vtos(prevorg)); }
 152         //if(w_shotdir != prevdir) { printf("SERVER: shotDIR differs: %s - %s\n", vtos(w_shotdir), vtos(prevdir)); }
 153 }
 154
 155 vector W_CalculateProjectileVelocity(entity actor, vector pvelocity, vector mvelocity, float forceAbsolute)
 156 {
 157         vector mdirection;
 158         float mspeed;
 159         vector outvelocity;
 160
 161         mvelocity = mvelocity * W_WeaponSpeedFactor(actor);
 162
 163         mdirection = normalize(mvelocity);
 164         mspeed = vlen(mvelocity);
 165
 166         outvelocity = get_shotvelocity(pvelocity, mdirection, mspeed, (forceAbsolute ? 0 : autocvar_g_projectiles_newton_style), autocvar_g_projectiles_newton_style_2_minfactor, autocvar_g_projectiles_newton_style_2_maxfactor);
 167
 168         return outvelocity;
 169 }
 170
 171 void W_SetupProjVelocity_Explicit(entity proj, vector dir, vector upDir, float pSpeed, float pUpSpeed, float pZSpeed, float spread, float forceAbsolute)
 172 {
 173         if(proj.owner == NULL)
 174                 error("Unowned missile");
 175
 176         dir = dir + upDir * (pUpSpeed / pSpeed);
 177         dir.z += pZSpeed / pSpeed;
 178         pSpeed *= vlen(dir);
 179         dir = normalize(dir);
 180
 181         #if 0
 182         if(autocvar_g_projectiles_spread_style != mspercallsstyle)
 183         {
 184                 mspercallsum = mspercallcount = 0;
 185                 mspercallsstyle = autocvar_g_projectiles_spread_style;
 186         }
 187         mspercallsum -= gettime(GETTIME_HIRES);
 188         #endif
 189
 190         dir = W_CalculateSpread(dir, spread, g_weaponspreadfactor, autocvar_g_projectiles_spread_style);
 191
 192         #if 0
 193         mspercallsum += gettime(GETTIME_HIRES);
 194         mspercallcount += 1;
 195         LOG_INFO("avg: ", ftos(mspercallcount / mspercallsum), " per sec");
 196         #endif
 197
 198         proj.velocity = W_CalculateProjectileVelocity(proj.owner, proj.owner.velocity, pSpeed * dir, forceAbsolute);
 199 }
 200
 201
 202 // ====================
 203 //  Ballistics Tracing
 204 // ====================
 205
 206 void FireRailgunBullet (entity this, .entity weaponentity, vector start, vector end, float bdamage, float bforce, float mindist, float maxdist, float halflifedist, float forcehalflifedist, int deathtype)
 207 {
 208         entity pseudoprojectile = NULL;
 209
 210         vector dir = normalize(end - start);
 211         float length = vlen(end - start);
 212         vector force = dir * bforce;
 213
 214         // go a little bit into the wall because we need to hit this wall later
 215         end = end + dir;
 216
 217         float totaldmg = 0;
 218
 219         // trace multiple times until we hit a wall, each obstacle will be made
 220         // non-solid so we can hit the next, while doing this we spawn effects and
 221         // note down which entities were hit so we can damage them later
 222         entity o = this;
 223         while (1)
 224         {
 225                 if(CS(this).antilag_debug)
 226                         WarpZone_traceline_antilag (this, start, end, false, o, CS(this).antilag_debug);
 227                 else
 228                         WarpZone_traceline_antilag (this, start, end, false, o, ANTILAG_LATENCY(this));
 229                 if(o && WarpZone_trace_firstzone)
 230                 {
 231                         o = NULL;
 232                         continue;
 233                 }
 234
 235                 if(trace_ent.solid == SOLID_BSP || trace_ent.solid == SOLID_SLIDEBOX)
 236                         Damage_DamageInfo(trace_endpos, bdamage, 0, 0, force, deathtype, trace_ent.species, this);
 237
 238                 // if it is NULL we can't hurt it so stop now
 239                 if (trace_ent == NULL || trace_fraction == 1)
 240                         break;
 241
 242                 // make the entity non-solid so we can hit the next one
 243                 IL_PUSH(g_railgunhit, trace_ent);
 244                 trace_ent.railgunhit = true;
 245                 trace_ent.railgunhitloc = end;
 246                 trace_ent.railgunhitsolidbackup = trace_ent.solid;
 247                 trace_ent.railgundistance = vlen(WarpZone_UnTransformOrigin(WarpZone_trace_transform, trace_endpos) - start);
 248                 trace_ent.railgunforce = WarpZone_TransformVelocity(WarpZone_trace_transform, force);
 249
 250                 // stop if this is a wall
 251                 if (trace_ent.solid == SOLID_BSP)
 252                         break;
 253
 254                 // make the entity non-solid
 255                 trace_ent.solid = SOLID_NOT;
 256         }
 257
 258         vector endpoint = trace_endpos;
 259         entity endent = trace_ent;
 260         float endq3surfaceflags = trace_dphitq3surfaceflags;
 261
 262         // find all the entities the railgun hit and restore their solid state
 263         IL_EACH(g_railgunhit, it.railgunhit,
 264         {
 265                 it.solid = it.railgunhitsolidbackup;
 266         });
 267
 268         // spawn a temporary explosion entity for RadiusDamage calls
 269         //explosion = spawn();
 270
 271         // Find all non-hit players the beam passed close by
 272         if(deathtype == WEP_VAPORIZER.m_id || deathtype == WEP_VORTEX.m_id)
 273         {
 274                 FOREACH_CLIENT(IS_REAL_CLIENT(it) && it != this, {
 275                         if(!it.railgunhit)
 276                         if(!(IS_SPEC(it) && it.enemy == this))
 277                         {
 278                                 msg_entity = it;
 279                                 // nearest point on the beam
 280                                 vector beampos = start + dir * bound(0, (msg_entity.origin - start) * dir, length);
 281
 282                                 float f = bound(0, 1 - vlen(beampos - msg_entity.origin) / 512, 1);
 283                                 if(f <= 0)
 284                                         continue;
 285
 286                                 if(!pseudoprojectile)
 287                                         pseudoprojectile = spawn(); // we need this so the sound uses the "entchannel4" volume
 288                                 soundtoat(MSG_ONE, pseudoprojectile, beampos, CH_SHOTS, SND(NEXWHOOSH_RANDOM()), VOL_BASE * f, ATTEN_NONE);
 289                         }
 290                 });
 291
 292                 if(pseudoprojectile)
 293                         delete(pseudoprojectile);
 294         }
 295
 296         // find all the entities the railgun hit and hurt them
 297         IL_EACH(g_railgunhit, it.railgunhit,
 298         {
 299                 // removal from the list is handled below
 300
 301                 // get the details we need to call the damage function
 302                 vector hitloc = it.railgunhitloc;
 303
 304                 float foff = ExponentialFalloff(mindist, maxdist, halflifedist, it.railgundistance);
 305                 float ffs = ExponentialFalloff(mindist, maxdist, forcehalflifedist, it.railgundistance);
 306
 307                 if(accuracy_isgooddamage(this, it))
 308                         totaldmg += bdamage * foff;
 309
 310                 // apply the damage
 311                 if (it.takedamage)
 312                         Damage (it, this, this, bdamage * foff, deathtype, hitloc, it.railgunforce * ffs);
 313
 314                 // create a small explosion to throw gibs around (if applicable)
 315                 //setorigin(explosion, hitloc);
 316                 //RadiusDamage (explosion, this, 10, 0, 50, NULL, NULL, 300, deathtype);
 317
 318                 it.railgunhitloc = '0 0 0';
 319                 it.railgunhitsolidbackup = SOLID_NOT;
 320                 it.railgunhit = false;
 321                 it.railgundistance = 0;
 322         });
 323
 324         IL_CLEAR(g_railgunhit);
 325
 326         // calculate hits and fired shots for hitscan
 327         accuracy_add(this, this.(weaponentity).m_weapon.m_id, 0, min(bdamage, totaldmg));
 328
 329         trace_endpos = endpoint;
 330         trace_ent = endent;
 331         trace_dphitq3surfaceflags = endq3surfaceflags;
 332 }
 333
 334 void fireBullet_trace_callback(vector start, vector hit, vector end)
 335 {
 336         if(vdist(hit - start, >, 16))
 337                 trailparticles(NULL, fireBullet_trace_callback_eff, start, hit);
 338         WarpZone_trace_forent = NULL;
 339         fireBullet_last_hit = NULL;
 340 }
 341
 342 void fireBullet(entity this, .entity weaponentity, vector start, vector dir, float spread, float max_solid_penetration, float damage, float force, float dtype, int tracereffects)
 343 {
 344         vector  end;
 345
 346         dir = normalize(dir + randomvec() * spread);
 347         end = start + dir * max_shot_distance;
 348
 349         fireBullet_last_hit = NULL;
 350         float solid_penetration_left = 1;
 351         float total_damage = 0;
 352
 353         if(tracereffects & EF_RED)
 354                 fireBullet_trace_callback_eff = EFFECT_RIFLE;
 355         else if(tracereffects & EF_BLUE)
 356                 fireBullet_trace_callback_eff = EFFECT_RIFLE_WEAK;
 357         else
 358                 fireBullet_trace_callback_eff = EFFECT_BULLET;
 359
 360         float lag = ((IS_REAL_CLIENT(this)) ? ANTILAG_LATENCY(this) : 0);
 361         if(lag < 0.001)
 362                 lag = 0;
 363         bool noantilag = ((IS_CLIENT(this)) ? CS(this).cvar_cl_noantilag : false);
 364         if(autocvar_g_antilag == 0 || noantilag)
 365                 lag = 0; // only do hitscan, but no antilag
 366         if(lag)
 367                 antilag_takeback_all(this, lag);
 368
 369         // change shooter to SOLID_BBOX so the shot can hit corpses
 370         int oldsolid = this.dphitcontentsmask;
 371         if(this)
 372                 this.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 373
 374         WarpZone_trace_forent = this;
 375
 376         for (;;)
 377         {
 378                 // TODO also show effect while tracing
 379                 WarpZone_TraceBox_ThroughZone(start, '0 0 0', '0 0 0', end, false, WarpZone_trace_forent, NULL, fireBullet_trace_callback);
 380                 dir = WarpZone_TransformVelocity(WarpZone_trace_transform, dir);
 381                 end = WarpZone_TransformOrigin(WarpZone_trace_transform, end);
 382                 start = trace_endpos;
 383                 entity hit = trace_ent;
 384
 385                 // traced up to max_shot_distance and didn't hit anything at all
 386                 if (trace_fraction == 1.0)
 387                         break;
 388
 389                 // When hitting sky, stop.
 390                 if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_SKY)
 391                         break;
 392
 393                 // can't use noimpact, as we need to pass through walls
 394                 //if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
 395                         //break;
 396
 397                 // if we hit "weapclip", bail out
 398                 //
 399                 // rationale of this check:
 400                 //
 401                 // any shader that is solid, nodraw AND trans is meant to clip weapon
 402                 // shots and players, but has no other effect!
 403                 //
 404                 // if it is not trans, it is caulk and should not have this side effect
 405                 //
 406                 // matching shaders:
 407                 //   common/weapclip (intended)
 408                 //   common/noimpact (is supposed to eat projectiles, but is erased anyway)
 409                 bool is_weapclip = false;
 410                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NODRAW)
 411                 if (!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NONSOLID))
 412                 if (!(trace_dphitcontents & DPCONTENTS_OPAQUE))
 413                         is_weapclip = true;
 414
 415                 if(!hit || hit.solid == SOLID_BSP || hit.solid == SOLID_SLIDEBOX)
 416                         Damage_DamageInfo(start, damage * solid_penetration_left, 0, 0, max(1, force) * dir * solid_penetration_left, dtype, hit.species, this);
 417
 418                 if (hit && hit != WarpZone_trace_forent && hit != fireBullet_last_hit)  // Avoid self-damage (except after going through a warp); avoid hitting the same entity twice (engine bug).
 419                 {
 420                         fireBullet_last_hit = hit;
 421                         yoda = 0;
 422                         MUTATOR_CALLHOOK(FireBullet_Hit, this, hit, start, end, damage, this.(weaponentity));
 423                         damage = M_ARGV(4, float);
 424                         float g = accuracy_isgooddamage(this, hit);
 425                         Damage(hit, this, this, damage * solid_penetration_left, dtype, start, force * dir * solid_penetration_left);
 426                         // calculate hits for ballistic weapons
 427                         if(g)
 428                         {
 429                                 // do not exceed 100%
 430                                 float added_damage = min(damage - total_damage, damage * solid_penetration_left);
 431                                 total_damage += damage * solid_penetration_left;
 432                                 accuracy_add(this, this.(weaponentity).m_weapon.m_id, 0, added_damage);
 433                         }
 434                 }
 435
 436                 if (is_weapclip && !autocvar_g_ballistics_penetrate_clips)
 437                         break;
 438
 439                 // go through solid!
 440                 // outside the world? forget it
 441                 if(start.x > world.maxs.x || start.y > world.maxs.y || start.z > world.maxs.z || start.x < world.mins.x || start.y < world.mins.y || start.z < world.mins.z)
 442                         break;
 443
 444                 float maxdist;
 445                 entity hitstore = IS_PLAYER(hit) ? PS(hit) : hit;
 446                 if(max_solid_penetration < 0)
 447                         break;
 448                 else if(hitstore.ballistics_density < -1)
 449                         break; // -2: no solid penetration, ever
 450                 else if(hitstore.ballistics_density < 0)
 451                         maxdist = vlen(hit.maxs - hit.mins) + 1; // -1: infinite travel distance
 452                 else if(hitstore.ballistics_density == 0)
 453                         maxdist = max_solid_penetration * solid_penetration_left;
 454                 else
 455                         maxdist = max_solid_penetration * solid_penetration_left * hitstore.ballistics_density;
 456
 457                 if(maxdist <= autocvar_g_ballistics_mindistance)
 458                         break;
 459
 460                 // move the entity along its velocity until it's out of solid, then let it resume
 461                 // The previously hit entity is ignored here!
 462                 traceline_inverted (start, start + dir * maxdist, MOVE_NORMAL, WarpZone_trace_forent, true, hit);
 463                 if(trace_fraction == 1) // 1: we never got out of solid
 464                         break;
 465
 466                 float dist_taken = max(autocvar_g_ballistics_mindistance, vlen(trace_endpos - start));
 467                 // fraction_used_of_what_is_left = dist_taken / maxdist
 468                 // solid_penetration_left = solid_penetration_left - solid_penetration_left * fraction_used_of_what_is_left
 469                 solid_penetration_left *= 1 - dist_taken / maxdist;
 470                 solid_penetration_left = max(solid_penetration_left, 0);
 471
 472                 // Only show effect when going through a player (invisible otherwise)
 473                 if (hit && (hit.solid != SOLID_BSP))
 474                         if(vdist(trace_endpos - start, >, 4))
 475                                 trailparticles(this, fireBullet_trace_callback_eff, start, trace_endpos);
 476
 477                 start = trace_endpos;
 478
 479                 if(hit.solid == SOLID_BSP)
 480                         Damage_DamageInfo(start, 0, 0, 0, max(1, force) * normalize(dir) * -solid_penetration_left, dtype, 0, this);
 481         }
 482
 483         if(lag)
 484                 antilag_restore_all(this);
 485
 486         // restore shooter solid type
 487         if(this)
 488                 this.dphitcontentsmask = oldsolid;
 489 }