qcsrc/server/weapons/tracing.qc

   1 #include "tracing.qh"
   2
   3 #include <common/effects/all.qh>
   4
   5 #include "accuracy.qh"
   6 #include "common.qh"
   7 #include "hitplot.qh"
   8 #include "weaponsystem.qh"
   9
  10 #include "../g_damage.qh"
  11 #include "../antilag.qh"
  12
  13 #include <common/constants.qh>
  14 #include <common/net_linked.qh>
  15 #include <common/util.qh>
  16
  17 #include <common/weapons/_all.qh>
  18 #include <common/wepent.qh>
  19 #include <common/state.qh>
  20
  21 #include <lib/warpzone/common.qh>
  22
  23 // this function calculates w_shotorg and w_shotdir based on the weapon model
  24 // offset, trueaim and antilag, and won't put w_shotorg inside a wall.
  25 // make sure you call makevectors first (FIXME?)
  26 void W_SetupShot_Dir_ProjectileSize_Range(entity ent, .entity weaponentity, vector s_forward, vector mi, vector ma, float antilag, float recoil, Sound snd, float chan, float maxdamage, float range, int deathtype)
  27 {
  28         TC(Sound, snd);
  29         float nudge = 1; // added to traceline target and subtracted from result  TOOD(divVerent): do we still need this? Doesn't the engine do this now for us?
  30         float oldsolid = ent.dphitcontentsmask;
  31         Weapon wep = DEATH_WEAPONOF(deathtype);
  32         if(!IS_CLIENT(ent))
  33                 antilag = false; // no antilag for non-clients!
  34         if (IS_PLAYER(ent) && (wep.spawnflags & WEP_FLAG_PENETRATEWALLS))
  35         {
  36                 // This is the reason rifle, MG, OKMG and other fireBullet weapons don't hit the crosshair when shooting at walls.
  37                 // This is intentional, otherwise if you stand too close to a (glass) wall and attempt to shoot an enemy through it,
  38                 // trueaim will cause the shot to hit the wall exactly but then miss the enemy (unless shooting from eye/center).
  39                 // TODO for fireBullet, find how far the shot will penetrate and aim at that
  40                 //      for fireRailgunbullet, find the farthest target and aim at that
  41                 //      this will avoid issues when another player is passing in front of you when you shoot
  42                 //      (currently such a shot will hit him but then miss the original target)
  43                 ent.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_CORPSE;
  44         }
  45         else
  46                 ent.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
  47         if(antilag)
  48                 WarpZone_traceline_antilag(NULL, ent.origin + ent.view_ofs, ent.origin + ent.view_ofs + s_forward * range, MOVE_NORMAL, ent, ANTILAG_LATENCY(ent));
  49                 // passing NULL, because we do NOT want it to touch dphitcontentsmask
  50         else
  51                 WarpZone_TraceLine(ent.origin + ent.view_ofs, ent.origin + ent.view_ofs + s_forward * range, MOVE_NOMONSTERS, ent);
  52         ent.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
  53
  54         vector vf, vr, vu;
  55         vf = v_forward;
  56         vr = v_right;
  57         vu = v_up;
  58         w_shotend = WarpZone_UnTransformOrigin(WarpZone_trace_transform, trace_endpos); // warpzone support
  59         v_forward = vf;
  60         v_right = vr;
  61         v_up = vu;
  62
  63         // un-adjust trueaim if shotend is too close
  64         if(vdist(w_shotend - (ent.origin + ent.view_ofs), <, autocvar_g_trueaim_minrange))
  65                 w_shotend = ent.origin + ent.view_ofs + s_forward * autocvar_g_trueaim_minrange;
  66
  67         // track max damage
  68         if (IS_PLAYER(ent) && accuracy_canbegooddamage(ent))
  69                 accuracy_add(ent, wep, maxdamage, 0);
  70
  71         if(IS_PLAYER(ent))
  72                 W_HitPlotAnalysis(ent, wep, v_forward, v_right, v_up);
  73
  74         vector md = ent.(weaponentity).movedir;
  75         vector vecs = ((md.x > 0) ? md : '0 0 0');
  76
  77         // TODO this is broken - see 637056bea7bf7f5c9c0fc6113e94731a2767476 for an attempted fix
  78         // which fixes issue #1957 but causes #2129
  79         vector dv = v_right * -vecs.y + v_up * vecs.z;
  80         w_shotorg = ent.origin + ent.view_ofs + dv;
  81
  82         // now move the shotorg forward as much as requested if possible
  83         if(antilag)
  84         {
  85                 if(CS(ent).antilag_debug)
  86                         tracebox_antilag(ent, w_shotorg, mi, ma, w_shotorg + v_forward * (vecs.x + nudge), MOVE_NORMAL, ent, CS(ent).antilag_debug);
  87                 else
  88                         tracebox_antilag(ent, w_shotorg, mi, ma, w_shotorg + v_forward * (vecs.x + nudge), MOVE_NORMAL, ent, ANTILAG_LATENCY(ent));
  89         }
  90         else
  91                 tracebox(w_shotorg, mi, ma, w_shotorg + v_forward * (vecs.x + nudge), MOVE_NORMAL, ent);
  92         w_shotorg = trace_endpos - v_forward * nudge;
  93         // calculate the shotdir from the chosen shotorg
  94         if(W_DualWielding(ent))
  95                 w_shotdir = s_forward;
  96         else
  97                 w_shotdir = normalize(w_shotend - w_shotorg);
  98
  99         //vector prevdir = w_shotdir;
 100         //vector prevorg = w_shotorg;
 101         //vector prevend = w_shotend;
 102
 103         if (antilag)
 104         if (!CS(ent).cvar_cl_noantilag)
 105         {
 106                 if (autocvar_g_antilag == 1) // switch to "ghost" if not hitting original
 107                 {
 108                         traceline(w_shotorg, w_shotorg + w_shotdir * range, MOVE_NORMAL, ent);
 109                         if (!trace_ent.takedamage)
 110                         {
 111                                 traceline_antilag_force (ent, w_shotorg, w_shotorg + w_shotdir * range, MOVE_NORMAL, ent, ANTILAG_LATENCY(ent));
 112                                 if (trace_ent.takedamage && IS_PLAYER(trace_ent))
 113                                 {
 114                                         entity e;
 115                                         e = trace_ent;
 116                                         traceline(w_shotorg, e.origin, MOVE_NORMAL, ent);
 117                                         if(trace_ent == e)
 118                                                 w_shotdir = normalize(trace_ent.origin - w_shotorg);
 119                                 }
 120                         }
 121                 }
 122                 else if(autocvar_g_antilag == 3) // client side hitscan
 123                 {
 124                         // this part MUST use prydon cursor
 125                         if (CS(ent).cursor_trace_ent)                 // client was aiming at someone
 126                         if (CS(ent).cursor_trace_ent != ent)         // just to make sure
 127                         if (CS(ent).cursor_trace_ent.takedamage)      // and that person is killable
 128                         if (IS_PLAYER(CS(ent).cursor_trace_ent)) // and actually a player
 129                         {
 130                                 // verify that the shot would miss without antilag
 131                                 // (avoids an issue where guns would always shoot at their origin)
 132                                 traceline(w_shotorg, w_shotorg + w_shotdir * range, MOVE_NORMAL, ent);
 133                                 if (!trace_ent.takedamage)
 134                                 {
 135                                         // verify that the shot would hit if altered
 136                                         traceline(w_shotorg, CS(ent).cursor_trace_ent.origin, MOVE_NORMAL, ent);
 137                                         if (trace_ent == CS(ent).cursor_trace_ent)
 138                                                 w_shotdir = normalize(CS(ent).cursor_trace_ent.origin - w_shotorg);
 139                                         else
 140                                                 LOG_INFO("antilag fail");
 141                                 }
 142                         }
 143                 }
 144         }
 145
 146         ent.dphitcontentsmask = oldsolid; // restore solid type (generally SOLID_SLIDEBOX)
 147
 148         if (!autocvar_g_norecoil)
 149                 ent.punchangle_x = recoil * -1;
 150
 151         if (snd != SND_Null) {
 152                 sound(ent, chan, snd, (W_DualWielding(ent) ? VOL_BASE * 0.7 : VOL_BASE), ATTN_NORM);
 153                 W_PlayStrengthSound(ent);
 154         }
 155
 156         // nudge w_shotend so a trace to w_shotend hits
 157         w_shotend = w_shotend + normalize(w_shotend - w_shotorg) * nudge;
 158         //if(w_shotend != prevend) { printf("SERVER: shotEND differs: %s - %s\n", vtos(w_shotend), vtos(prevend)); }
 159         //if(w_shotorg != prevorg) { printf("SERVER: shotORG differs: %s - %s\n", vtos(w_shotorg), vtos(prevorg)); }
 160         //if(w_shotdir != prevdir) { printf("SERVER: shotDIR differs: %s - %s\n", vtos(w_shotdir), vtos(prevdir)); }
 161 }
 162
 163 vector W_CalculateProjectileVelocity(entity actor, vector pvelocity, vector mvelocity, float forceAbsolute)
 164 {
 165         vector mdirection;
 166         float mspeed;
 167         vector outvelocity;
 168
 169         mvelocity = mvelocity * W_WeaponSpeedFactor(actor);
 170
 171         mdirection = normalize(mvelocity);
 172         mspeed = vlen(mvelocity);
 173
 174         outvelocity = get_shotvelocity(pvelocity, mdirection, mspeed, (forceAbsolute ? 0 : autocvar_g_projectiles_newton_style), autocvar_g_projectiles_newton_style_2_minfactor, autocvar_g_projectiles_newton_style_2_maxfactor);
 175
 176         return outvelocity;
 177 }
 178
 179 void W_SetupProjVelocity_Explicit(entity proj, vector dir, vector upDir, float pSpeed, float pUpSpeed, float pZSpeed, float spread, float forceAbsolute)
 180 {
 181         if(proj.owner == NULL)
 182                 error("Unowned missile");
 183
 184         dir = dir + upDir * (pUpSpeed / pSpeed);
 185         dir.z += pZSpeed / pSpeed;
 186         pSpeed *= vlen(dir);
 187         dir = normalize(dir);
 188
 189         #if 0
 190         if(autocvar_g_projectiles_spread_style != mspercallsstyle)
 191         {
 192                 mspercallsum = mspercallcount = 0;
 193                 mspercallsstyle = autocvar_g_projectiles_spread_style;
 194         }
 195         mspercallsum -= gettime(GETTIME_HIRES);
 196         #endif
 197
 198         dir = W_CalculateSpread(dir, spread, g_weaponspreadfactor, autocvar_g_projectiles_spread_style);
 199
 200         #if 0
 201         mspercallsum += gettime(GETTIME_HIRES);
 202         mspercallcount += 1;
 203         LOG_INFO("avg: ", ftos(mspercallcount / mspercallsum), " per sec");
 204         #endif
 205
 206         proj.velocity = W_CalculateProjectileVelocity(proj.owner, proj.owner.velocity, pSpeed * dir, forceAbsolute);
 207 }
 208
 209
 210 // ====================
 211 //  Ballistics Tracing
 212 // ====================
 213
 214 void FireRailgunBullet (entity this, .entity weaponentity, vector start, vector end, float bdamage, float bforce, float mindist, float maxdist, float halflifedist, float forcehalflifedist, int deathtype)
 215 {
 216         vector dir = normalize(end - start);
 217         vector force = dir * bforce;
 218
 219         // go a little bit into the wall because we need to hit this wall later
 220         end = end + dir;
 221
 222         float totaldmg = 0;
 223
 224         // trace multiple times until we hit a wall, each obstacle will be made
 225         // non-solid so we can hit the next, while doing this we spawn effects and
 226         // note down which entities were hit so we can damage them later
 227         entity o = this;
 228         while (1)
 229         {
 230                 if(CS(this).antilag_debug)
 231                         WarpZone_traceline_antilag (this, start, end, false, o, CS(this).antilag_debug);
 232                 else
 233                         WarpZone_traceline_antilag (this, start, end, false, o, ANTILAG_LATENCY(this));
 234                 if(o && WarpZone_trace_firstzone)
 235                 {
 236                         o = NULL;
 237                         continue;
 238                 }
 239
 240                 if(trace_ent.solid == SOLID_BSP || trace_ent.solid == SOLID_SLIDEBOX)
 241                         Damage_DamageInfo(trace_endpos, bdamage, 0, 0, force, deathtype, trace_ent.species, this);
 242
 243                 // if it is NULL we can't hurt it so stop now
 244                 if (trace_ent == NULL || trace_fraction == 1)
 245                         break;
 246
 247                 // make the entity non-solid so we can hit the next one
 248                 IL_PUSH(g_railgunhit, trace_ent);
 249                 trace_ent.railgunhit = true;
 250                 trace_ent.railgunhitloc = end;
 251                 trace_ent.railgunhitsolidbackup = trace_ent.solid;
 252                 trace_ent.railgundistance = vlen(WarpZone_UnTransformOrigin(WarpZone_trace_transform, trace_endpos) - start);
 253                 trace_ent.railgunforce = WarpZone_TransformVelocity(WarpZone_trace_transform, force);
 254
 255                 // stop if this is a wall
 256                 if (trace_ent.solid == SOLID_BSP)
 257                         break;
 258
 259                 // make the entity non-solid
 260                 trace_ent.solid = SOLID_NOT;
 261         }
 262
 263         vector endpoint = trace_endpos;
 264         entity endent = trace_ent;
 265         float endq3surfaceflags = trace_dphitq3surfaceflags;
 266
 267         // find all the entities the railgun hit and restore their solid state
 268         IL_EACH(g_railgunhit, it.railgunhit,
 269         {
 270                 it.solid = it.railgunhitsolidbackup;
 271         });
 272
 273         // Find all players the beam passed close by (even those hit)
 274         float length = vlen(endpoint - start);
 275         entity pseudoprojectile = NULL;
 276         FOREACH_CLIENT(IS_REAL_CLIENT(it) && it != this, {
 277                 // not when spectating the shooter
 278                 if (IS_SPEC(it) && it.enemy == this) continue;
 279
 280                 // nearest point on the beam
 281                 vector beampos = start + dir * bound(0, (it.origin - start) * dir, length);
 282
 283                 if(!pseudoprojectile)
 284                         pseudoprojectile = spawn(); // we need this so the sound uses the "entchannel4" volume
 285
 286                 msg_entity = it;
 287                 // we want this to be very loud when close but fall off quickly -> using max base volume and high attenuation
 288                 soundtoat(MSG_ONE, pseudoprojectile, beampos, CH_SHOTS, SND(NEXWHOOSH_RANDOM()), VOL_BASEVOICE, ATTEN_IDLE);
 289         });
 290         if(pseudoprojectile)
 291                 delete(pseudoprojectile);
 292
 293         // find all the entities the railgun hit and hurt them
 294         IL_EACH(g_railgunhit, it.railgunhit,
 295         {
 296                 // removal from the list is handled below
 297
 298                 // get the details we need to call the damage function
 299                 vector hitloc = it.railgunhitloc;
 300
 301                 float foff = ExponentialFalloff(mindist, maxdist, halflifedist, it.railgundistance);
 302                 float ffs = ExponentialFalloff(mindist, maxdist, forcehalflifedist, it.railgundistance);
 303
 304                 if(accuracy_isgooddamage(this, it))
 305                         totaldmg += bdamage * foff;
 306
 307                 // apply the damage
 308                 if (it.takedamage)
 309                         Damage(it, this, this, bdamage * foff, deathtype, weaponentity, hitloc, it.railgunforce * ffs);
 310
 311                 it.railgunhitloc = '0 0 0';
 312                 it.railgunhitsolidbackup = SOLID_NOT;
 313                 it.railgunhit = false;
 314                 it.railgundistance = 0;
 315         });
 316
 317         IL_CLEAR(g_railgunhit);
 318
 319         // calculate hits and fired shots for hitscan
 320         if(this.(weaponentity))
 321                 accuracy_add(this, this.(weaponentity).m_weapon, 0, min(bdamage, totaldmg));
 322
 323         trace_endpos = endpoint;
 324         trace_ent = endent;
 325         trace_dphitq3surfaceflags = endq3surfaceflags;
 326 }
 327
 328 void fireBullet_trace_callback(vector start, vector hit, vector end)
 329 {
 330         if(vdist(hit - start, >, 16))
 331                 trailparticles(NULL, fireBullet_trace_callback_eff, start, hit);
 332         WarpZone_trace_forent = NULL;
 333         fireBullet_last_hit = NULL;
 334 }
 335
 336 void fireBullet(entity this, .entity weaponentity, vector start, vector dir, float spread, float max_solid_penetration, float damage, float force, float dtype, entity tracer_effect)
 337 {
 338         vector  end;
 339
 340         dir = normalize(dir + randomvec() * spread);
 341         end = start + dir * max_shot_distance;
 342
 343         fireBullet_last_hit = NULL;
 344         fireBullet_trace_callback_eff = tracer_effect;
 345
 346         float solid_penetration_left = 1;
 347         float total_damage = 0;
 348
 349         float lag = ((IS_REAL_CLIENT(this)) ? ANTILAG_LATENCY(this) : 0);
 350         if(lag < 0.001)
 351                 lag = 0;
 352         bool noantilag = ((IS_CLIENT(this)) ? CS(this).cvar_cl_noantilag : false);
 353         if(autocvar_g_antilag == 0 || noantilag)
 354                 lag = 0; // only do hitscan, but no antilag
 355         if(lag)
 356                 antilag_takeback_all(this, lag);
 357
 358         // change shooter to SOLID_BBOX so the shot can hit corpses
 359         int oldsolid = this.dphitcontentsmask;
 360         if(this)
 361                 this.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 362
 363         WarpZone_trace_forent = this;
 364
 365         for (;;)
 366         {
 367                 // TODO also show effect while tracing
 368                 WarpZone_TraceBox_ThroughZone(start, '0 0 0', '0 0 0', end, false, WarpZone_trace_forent, NULL, fireBullet_trace_callback);
 369                 dir = WarpZone_TransformVelocity(WarpZone_trace_transform, dir);
 370                 end = WarpZone_TransformOrigin(WarpZone_trace_transform, end);
 371                 start = trace_endpos;
 372                 entity hit = trace_ent;
 373
 374                 // traced up to max_shot_distance and didn't hit anything at all
 375                 if (trace_fraction == 1.0)
 376                         break;
 377
 378                 // When hitting sky, stop.
 379                 if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_SKY)
 380                         break;
 381
 382                 // can't use noimpact, as we need to pass through walls
 383                 //if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
 384                         //break;
 385
 386                 // if we hit "weapclip", bail out
 387                 //
 388                 // rationale of this check:
 389                 //
 390                 // any shader that is solid, nodraw AND trans is meant to clip weapon
 391                 // shots and players, but has no other effect!
 392                 //
 393                 // if it is not trans, it is caulk and should not have this side effect
 394                 //
 395                 // matching shaders:
 396                 //   common/weapclip (intended)
 397                 //   common/noimpact (is supposed to eat projectiles, but is erased anyway)
 398                 bool is_weapclip = false;
 399                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NODRAW)
 400                 if (!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NONSOLID))
 401                 if (!(trace_dphitcontents & DPCONTENTS_OPAQUE))
 402                         is_weapclip = true;
 403
 404                 if(!hit || hit.solid == SOLID_BSP || hit.solid == SOLID_SLIDEBOX)
 405                         Damage_DamageInfo(start, damage * solid_penetration_left, 0, 0, max(1, force) * dir * solid_penetration_left, dtype, hit.species, this);
 406
 407                 if (hit && hit != WarpZone_trace_forent && hit != fireBullet_last_hit)  // Avoid self-damage (except after going through a warp); avoid hitting the same entity twice (engine bug).
 408                 {
 409                         fireBullet_last_hit = hit;
 410                         yoda = 0;
 411                         MUTATOR_CALLHOOK(FireBullet_Hit, this, hit, start, end, damage, this.(weaponentity));
 412                         damage = M_ARGV(4, float);
 413                         bool gooddamage = accuracy_isgooddamage(this, hit);
 414                         Damage(hit, this, this, damage * solid_penetration_left, dtype, weaponentity, start, force * dir * solid_penetration_left);
 415                         // calculate hits for ballistic weapons
 416                         if(gooddamage)
 417                         {
 418                                 // do not exceed 100%
 419                                 float added_damage = min(damage - total_damage, damage * solid_penetration_left);
 420                                 total_damage += damage * solid_penetration_left;
 421                                 accuracy_add(this, this.(weaponentity).m_weapon, 0, added_damage);
 422                         }
 423                 }
 424
 425                 if (is_weapclip && !autocvar_g_ballistics_penetrate_clips)
 426                         break;
 427
 428                 // go through solid!
 429                 // outside the world? forget it
 430                 if(start.x > world.maxs.x || start.y > world.maxs.y || start.z > world.maxs.z || start.x < world.mins.x || start.y < world.mins.y || start.z < world.mins.z)
 431                         break;
 432
 433                 float maxdist;
 434                 entity hitstore = IS_PLAYER(hit) ? PS(hit) : hit;
 435                 if(max_solid_penetration < 0)
 436                         break;
 437                 else if(hitstore.ballistics_density < -1)
 438                         break; // -2: no solid penetration, ever
 439                 else if(hitstore.ballistics_density < 0)
 440                         maxdist = vlen(hit.maxs - hit.mins) + 1; // -1: infinite travel distance
 441                 else if(hitstore.ballistics_density == 0)
 442                         maxdist = max_solid_penetration * solid_penetration_left;
 443                 else
 444                         maxdist = max_solid_penetration * solid_penetration_left * hitstore.ballistics_density;
 445
 446                 if(maxdist <= autocvar_g_ballistics_mindistance)
 447                         break;
 448
 449                 // move the entity along its velocity until it's out of solid, then let it resume
 450                 // The previously hit entity is ignored here!
 451                 traceline_inverted (start, start + dir * maxdist, MOVE_NORMAL, WarpZone_trace_forent, true, hit);
 452                 if(trace_fraction == 1) // 1: we never got out of solid
 453                         break;
 454
 455                 float dist_taken = max(autocvar_g_ballistics_mindistance, vlen(trace_endpos - start));
 456                 // fraction_used_of_what_is_left = dist_taken / maxdist
 457                 // solid_penetration_left = solid_penetration_left - solid_penetration_left * fraction_used_of_what_is_left
 458                 solid_penetration_left *= 1 - dist_taken / maxdist;
 459                 solid_penetration_left = max(solid_penetration_left, 0);
 460
 461                 // Only show effect when going through a player (invisible otherwise)
 462                 if (hit && (hit.solid != SOLID_BSP))
 463                         if(vdist(trace_endpos - start, >, 4))
 464                                 trailparticles(this, fireBullet_trace_callback_eff, start, trace_endpos);
 465
 466                 start = trace_endpos;
 467
 468                 if(hit.solid == SOLID_BSP)
 469                         Damage_DamageInfo(start, 0, 0, 0, max(1, force) * normalize(dir) * -solid_penetration_left, dtype, 0, this);
 470         }
 471
 472         if(lag)
 473                 antilag_restore_all(this);
 474
 475         // restore shooter solid type
 476         if(this)
 477                 this.dphitcontentsmask = oldsolid;
 478 }