Makefile: use `-I.`
[xonotic/xonotic-data.pk3dir.git] / qcsrc / server / weapons / weaponsystem.qc
1 #include "weaponsystem.qh"
2
3 #include "selection.qh"
4
5 #include "../command/common.qh"
6 #include "../mutators/all.qh"
7 #include "../round_handler.qh"
8 #include <common/t_items.qh>
9 #include <common/animdecide.qh>
10 #include <common/constants.qh>
11 #include <common/monsters/all.qh>
12 #include <common/notifications.qh>
13 #include <common/util.qh>
14 #include <common/weapons/all.qh>
15 #include <lib/csqcmodel/sv_model.qh>
16
17 .int state;
18
19 .float weapon_frametime;
20
21 float W_WeaponRateFactor()
22 {
23         float t = 1.0 / g_weaponratefactor;
24
25         MUTATOR_CALLHOOK(WeaponRateFactor, t);
26         t = weapon_rate;
27
28         return t;
29 }
30
31 float W_WeaponSpeedFactor()
32 {
33         float t = 1.0 * g_weaponspeedfactor;
34
35         MUTATOR_CALLHOOK(WeaponSpeedFactor, t);
36         t = ret_float;
37
38         return t;
39 }
40
41
42 bool CL_Weaponentity_CustomizeEntityForClient()
43 {
44         SELFPARAM();
45         this.viewmodelforclient = this.owner;
46         if (IS_SPEC(other) && other.enemy == this.owner) this.viewmodelforclient = other;
47         return true;
48 }
49
50 vector CL_Weapon_GetShotOrg(int wpn)
51 {
52         entity wi = Weapons_from(wpn);
53         entity e = spawn();
54         CL_WeaponEntity_SetModel(e, wi.mdl);
55         vector ret = e.movedir;
56         CL_WeaponEntity_SetModel(e, "");
57         remove(e);
58         return ret;
59 }
60
61 ..entity weaponentity_fld;
62 .float m_alpha;
63
64 void CL_Weaponentity_Think()
65 {
66         SELFPARAM();
67         this.nextthink = time;
68         if (intermission_running) this.frame = this.anim_idle.x;
69         .entity weaponentity = this.weaponentity_fld;
70         if (this.owner.(weaponentity) != this)
71         {
72                 // owner has new gun; remove self
73                 if (this.weaponchild) remove(this.weaponchild);
74                 remove(this);
75                 return;
76         }
77         if (this.owner.deadflag != DEAD_NO)
78         {
79                 // owner died; disappear
80                 this.model = "";
81                 if (this.weaponchild) this.weaponchild.model = "";
82                 return;
83         }
84         if (this.weaponname != this.owner.weaponname
85             || this.dmg != this.owner.modelindex
86             || this.deadflag != this.owner.deadflag)
87         {
88                 // owner changed weapons; update appearance
89                 this.weaponname = this.owner.weaponname;
90                 this.dmg = this.owner.modelindex;
91                 this.deadflag = this.owner.deadflag;
92
93                 CL_WeaponEntity_SetModel(this, this.owner.weaponname);
94         }
95
96         this.alpha = -1;  // TODO: don't render this entity at all
97
98         if (this.owner.alpha == default_player_alpha) this.m_alpha = default_weapon_alpha;
99         else if (this.owner.alpha != 0) this.m_alpha = this.owner.alpha;
100         else this.m_alpha  = 1;
101
102         if (this.weaponchild)
103         {
104                 this.weaponchild.alpha = this.alpha;
105                 this.weaponchild.effects = this.effects;
106         }
107 }
108
109 void CL_ExteriorWeaponentity_Think()
110 {
111         SELFPARAM();
112         this.nextthink = time;
113         if (this.owner.exteriorweaponentity != this)
114         {
115                 remove(this);
116                 return;
117         }
118         if (this.owner.deadflag != DEAD_NO)
119         {
120                 this.model = "";
121                 return;
122         }
123         if (this.weaponname != this.owner.weaponname || this.dmg != this.owner.modelindex
124             || this.deadflag != this.owner.deadflag)
125         {
126                 this.weaponname = this.owner.weaponname;
127                 this.dmg = this.owner.modelindex;
128                 this.deadflag = this.owner.deadflag;
129                 if (this.owner.weaponname != "") _setmodel(this, W_Model(strcat("v_", this.owner.weaponname, ".md3")));
130                 else this.model = "";
131
132                 int tag_found;
133                 if ((tag_found = gettagindex(this.owner, "tag_weapon")))
134                 {
135                         this.tag_index = tag_found;
136                         this.tag_entity = this.owner;
137                 }
138                 else
139                 {
140                         setattachment(this, this.owner, "bip01 r hand");
141                 }
142         }
143         this.effects = this.owner.effects;
144         this.effects |= EF_LOWPRECISION;
145         this.effects = this.effects & EFMASK_CHEAP;  // eat performance
146         if (this.owner.alpha == default_player_alpha) this.alpha = default_weapon_alpha;
147         else if (this.owner.alpha != 0) this.alpha = this.owner.alpha;
148         else this.alpha = 1;
149
150         this.glowmod = this.owner.weaponentity_glowmod;
151         this.colormap = this.owner.colormap;
152
153         CSQCMODEL_AUTOUPDATE(this);
154 }
155
156 // spawning weaponentity for client
157 void CL_SpawnWeaponentity(entity actor, .entity weaponentity)
158 {
159         entity view = actor.(weaponentity) = new(weaponentity);
160         make_pure(view);
161         view.solid = SOLID_NOT;
162         view.owner = actor;
163         setmodel(view, MDL_Null);  // precision set when changed
164         setorigin(view, '0 0 0');
165         view.weaponentity_fld = weaponentity;
166         view.think = CL_Weaponentity_Think;
167         view.nextthink = time;
168         view.viewmodelforclient = actor;
169         view.customizeentityforclient = CL_Weaponentity_CustomizeEntityForClient;
170
171         if (weaponentity == weaponentities[0])
172         {
173                 entity exterior = actor.exteriorweaponentity = new(exteriorweaponentity);
174                 make_pure(exterior);
175                 exterior.solid = SOLID_NOT;
176                 exterior.owner = actor;
177                 setorigin(exterior, '0 0 0');
178                 exterior.think = CL_ExteriorWeaponentity_Think;
179                 exterior.nextthink = time;
180
181                 CSQCMODEL_AUTOINIT(exterior);
182         }
183 }
184
185 // Weapon subs
186 void w_clear(Weapon thiswep, entity actor, .entity weaponentity, int fire)
187 {
188         PS(actor).m_weapon = WEP_Null;
189         PS(actor).m_switchingweapon = WEP_Null;
190         entity this = actor.(weaponentity);
191         if (this)
192         {
193                 this.state = WS_CLEAR;
194                 this.effects = 0;
195         }
196 }
197
198 void w_ready(Weapon thiswep, entity actor, .entity weaponentity, int fire)
199 {
200         entity this = actor.(weaponentity);
201         if (this) this.state = WS_READY;
202         weapon_thinkf(actor, weaponentity, WFRAME_IDLE, 1000000, w_ready);
203 }
204
205 .float prevdryfire;
206 .float prevwarntime;
207 bool weapon_prepareattack_checkammo(Weapon thiswep, entity actor, bool secondary)
208 {
209         if ((actor.items & IT_UNLIMITED_WEAPON_AMMO)) return true;
210         bool ammo = false;
211         if (secondary) WITH(entity, self, actor, ammo = thiswep.wr_checkammo2(thiswep));
212         else WITH(entity, self, actor, ammo = thiswep.wr_checkammo1(thiswep));
213         if (ammo) return true;
214         // always keep the Mine Layer if we placed mines, so that we can detonate them
215         if (thiswep == WEP_MINE_LAYER)
216                 for (entity mine; (mine = find(mine, classname, "mine")); )
217                         if (mine.owner == actor) return false;
218
219         if (thiswep == WEP_SHOTGUN)
220                 if (!secondary && WEP_CVAR(shotgun, secondary) == 1) return false;           // no clicking, just allow
221
222         if (thiswep == PS(actor).m_switchweapon && time - actor.prevdryfire > 1) // only play once BEFORE starting to switch weapons
223         {
224                 sound(actor, CH_WEAPON_A, SND_DRYFIRE, VOL_BASE, ATTEN_NORM);
225                 actor.prevdryfire = time;
226         }
227
228         // check if the other firing mode has enough ammo
229         bool ammo_other = false;
230         if (secondary) WITH(entity, self, actor, ammo_other = thiswep.wr_checkammo1(thiswep));
231         else WITH(entity, self, actor, ammo_other = thiswep.wr_checkammo2(thiswep));
232         if (ammo_other)
233         {
234                 if (time - actor.prevwarntime > 1)
235                 {
236                         Send_Notification(
237                                 NOTIF_ONE,
238                                 actor,
239                                 MSG_MULTI,
240                                 ITEM_WEAPON_PRIMORSEC,
241                                 thiswep.m_id,
242                                 secondary,
243                                 (1 - secondary)
244                                          );
245                 }
246                 actor.prevwarntime = time;
247         }
248         else  // this weapon is totally unable to fire, switch to another one
249         {
250                 W_SwitchToOtherWeapon(actor);
251         }
252
253         return false;
254 }
255
256 .float race_penalty;
257 bool weapon_prepareattack_check(Weapon thiswep, entity actor, .entity weaponentity, bool secondary, float attacktime)
258 {
259         if (actor.weaponentity == NULL) return true;
260         if (!weapon_prepareattack_checkammo(thiswep, actor, secondary)) return false;
261
262         // if sv_ready_restart_after_countdown is set, don't allow the player to shoot
263         // if all players readied up and the countdown is running
264         if (time < game_starttime || time < actor.race_penalty) return false;
265
266         if (timeout_status == TIMEOUT_ACTIVE)  // don't allow the player to shoot while game is paused
267                 return false;
268
269         // do not even think about shooting if switching
270         if (PS(actor).m_switchweapon != PS(actor).m_weapon) return false;
271
272         if (attacktime >= 0)
273         {
274                 int slot = weaponslot(weaponentity);
275                 // don't fire if previous attack is not finished
276                 if (ATTACK_FINISHED(actor, slot) > time + actor.weapon_frametime * 0.5) return false;
277                 entity this = actor.(weaponentity);
278                 // don't fire while changing weapon
279                 if (this.state != WS_READY) return false;
280         }
281         return true;
282 }
283
284 void weapon_prepareattack_do(entity actor, .entity weaponentity, bool secondary, float attacktime)
285 {
286         entity this = actor.(weaponentity);
287         if (this == NULL) return;
288         this.state = WS_INUSE;
289
290         actor.spawnshieldtime = min(actor.spawnshieldtime, time);  // kill spawn shield when you fire
291
292         // if the weapon hasn't been firing continuously, reset the timer
293         if (attacktime >= 0)
294         {
295                 int slot = weaponslot(weaponentity);
296                 if (ATTACK_FINISHED(actor, slot) < time - actor.weapon_frametime * 1.5)
297                 {
298                         ATTACK_FINISHED(actor, slot) = time;
299                         // dprint("resetting attack finished to ", ftos(time), "\n");
300                 }
301                 ATTACK_FINISHED(actor, slot) = ATTACK_FINISHED(actor, slot) + attacktime * W_WeaponRateFactor();
302         }
303         actor.bulletcounter += 1;
304         // dprint("attack finished ", ftos(ATTACK_FINISHED(actor, slot)), "\n");
305 }
306
307 bool weapon_prepareattack(Weapon thiswep, entity actor, .entity weaponentity, bool secondary, float attacktime)
308 {
309         if (weapon_prepareattack_check(thiswep, actor, weaponentity, secondary, attacktime))
310         {
311                 weapon_prepareattack_do(actor, weaponentity, secondary, attacktime);
312                 return true;
313         }
314         return false;
315 }
316
317 void wframe_send(entity actor, entity weaponentity, vector a, bool restartanim);
318
319 /**
320  * @param t defer thinking until time + t
321  * @param func next think function
322  */
323 void weapon_thinkf(entity actor, .entity weaponentity, WFRAME fr, float t, void(Weapon thiswep, entity actor,
324         .entity weaponentity, int fire) func)
325 {
326         entity this = actor.(weaponentity);
327         if (this == NULL) return;
328         bool restartanim;
329         if (fr == WFRAME_DONTCHANGE)
330         {
331                 fr = this.wframe;
332                 restartanim = false;
333         }
334         else
335         {
336                 restartanim = fr != WFRAME_IDLE;
337         }
338
339         vector of = v_forward;
340         vector or = v_right;
341         vector ou = v_up;
342
343         vector a = '0 0 0';
344     this.wframe = fr;
345     if (fr == WFRAME_IDLE) a = this.anim_idle;
346     else if (fr == WFRAME_FIRE1) a = this.anim_fire1;
347     else if (fr == WFRAME_FIRE2) a = this.anim_fire2;
348     else  // if (fr == WFRAME_RELOAD)
349         a = this.anim_reload;
350     a.z *= g_weaponratefactor;
351
352         v_forward = of;
353         v_right = or;
354         v_up = ou;
355
356         if (this.weapon_think == w_ready && func != w_ready && this.state == WS_RAISE) backtrace(
357                         "Tried to override initial weapon think function - should this really happen?");
358
359         t *= W_WeaponRateFactor();
360
361         // VorteX: haste can be added here
362         if (this.weapon_think == w_ready)
363         {
364                 this.weapon_nextthink = time;
365                 // dprint("started firing at ", ftos(time), "\n");
366         }
367         if (this.weapon_nextthink < time - actor.weapon_frametime * 1.5
368             || this.weapon_nextthink > time + actor.weapon_frametime * 1.5)
369         {
370                 this.weapon_nextthink = time;
371                 // dprint("reset weapon animation timer at ", ftos(time), "\n");
372         }
373         this.weapon_nextthink += t;
374         if (weaponentity == weaponentities[0]) STAT(WEAPON_NEXTTHINK, actor) = this.weapon_nextthink;
375         this.weapon_think = func;
376         // dprint("next ", ftos(this.weapon_nextthink), "\n");
377
378         if (this)
379         {
380                 FOREACH_CLIENT(true, LAMBDA(
381                         if(it == actor || (IS_SPEC(it) && it.enemy == actor))
382                                 wframe_send(it, this, a, restartanim);
383                 ));
384         }
385
386         if ((fr == WFRAME_FIRE1 || fr == WFRAME_FIRE2) && t)
387         {
388                 int act = (fr == WFRAME_FIRE2 && (PS(actor).m_weapon == WEP_SHOCKWAVE || PS(actor).m_weapon == WEP_SHOTGUN))
389                         ? ANIMACTION_MELEE
390                         : ANIMACTION_SHOOT
391                         ;
392                 animdecide_setaction(actor, act, restartanim);
393         }
394         else if (actor.anim_upper_action == ANIMACTION_SHOOT || actor.anim_upper_action == ANIMACTION_MELEE)
395         {
396                 actor.anim_upper_action = 0;
397         }
398 }
399
400 bool forbidWeaponUse(entity player)
401 {
402         if (time < game_starttime && !autocvar_sv_ready_restart_after_countdown) return true;
403         if (round_handler_IsActive() && !round_handler_IsRoundStarted()) return true;
404         if (player.player_blocked) return true;
405         if (player.frozen) return true;
406         if (player.weapon_blocked) return true;
407         return false;
408 }
409
410 .bool hook_switchweapon;
411
412 void W_WeaponFrame(entity actor)
413 {
414         .entity weaponentity = weaponentities[0];  // TODO: unhardcode
415         entity this = actor.(weaponentity);
416         if (frametime) actor.weapon_frametime = frametime;
417
418         if (!this || actor.health < 1) return;  // Dead player can't use weapons and injure impulse commands
419
420
421         if (forbidWeaponUse(actor))
422         {
423                 if (actor.(weaponentity).state != WS_CLEAR)
424                 {
425                         Weapon wpn = PS(actor).m_weapon;
426                         w_ready(wpn, actor, weaponentity, (actor.BUTTON_ATCK ? 1 : 0) | (actor.BUTTON_ATCK2 ? 2 : 0));
427                         return;
428                 }
429         }
430
431         if (PS(actor).m_switchweapon == WEP_Null)
432         {
433                 PS(actor).m_weapon = WEP_Null;
434                 PS(actor).m_switchingweapon = WEP_Null;
435                 this.state = WS_CLEAR;
436                 actor.weaponname = "";
437                 // actor.items &= ~IT_AMMO;
438                 return;
439         }
440
441         makevectors(actor.v_angle);
442         vector fo = v_forward;  // save them in case the weapon think functions change it
443         vector ri = v_right;
444         vector up = v_up;
445
446         // Change weapon
447         if (PS(actor).m_weapon != PS(actor).m_switchweapon)
448         {
449                 switch (this.state)
450                 {
451                         default:
452                                 LOG_WARNINGF("unhandled weaponentity (%i) state for player (%i): %d\n", this, actor, this.state);
453                                 break;
454                         case WS_INUSE:
455                         case WS_RAISE:
456                                 break;
457                         case WS_CLEAR:
458                         {
459                                 // end switching!
460                                 Weapon newwep = PS(actor).m_switchweapon;
461                                 PS(actor).m_switchingweapon = newwep;
462
463                                 // the two weapon entities will notice this has changed and update their models
464                                 PS(actor).m_weapon = newwep;
465                                 actor.weaponname = newwep.mdl;
466                                 actor.bulletcounter = 0;
467                                 actor.ammo_field = newwep.ammo_field;
468                                 newwep.wr_setup(newwep);
469                                 this.state = WS_RAISE;
470
471                                 // set our clip load to the load of the weapon we switched to, if it's reloadable
472                                 if ((newwep.spawnflags & WEP_FLAG_RELOADABLE) && newwep.reloading_ammo)  // prevent accessing undefined cvars
473                                 {
474                                         actor.clip_load = actor.(weapon_load[PS(actor).m_switchweapon.m_id]);
475                                         actor.clip_size = newwep.reloading_ammo;
476                                 }
477                                 else
478                                 {
479                                         actor.clip_load = actor.clip_size = 0;
480                                 }
481
482                                 weapon_thinkf(actor, weaponentity, WFRAME_IDLE, newwep.switchdelay_raise, w_ready);
483                                 break;
484                         }
485                         case WS_DROP:
486                         {
487                                 // in dropping phase we can switch at any time
488                                 PS(actor).m_switchingweapon = PS(actor).m_switchweapon;
489                                 break;
490                         }
491                         case WS_READY:
492                         {
493                                 // start switching!
494                                 PS(actor).m_switchingweapon = PS(actor).m_switchweapon;
495                                 entity oldwep = PS(actor).m_weapon;
496
497                                 // set up weapon switch think in the future, and start drop anim
498                                 if (INDEPENDENT_ATTACK_FINISHED || ATTACK_FINISHED(actor, weaponslot(weaponentity)) <= time + actor.weapon_frametime * 0.5)
499                                 {
500                                         sound(actor, CH_WEAPON_SINGLE, SND_WEAPON_SWITCH, VOL_BASE, ATTN_NORM);
501                                         this.state = WS_DROP;
502                                         weapon_thinkf(actor, weaponentity, WFRAME_DONTCHANGE, oldwep.switchdelay_drop, w_clear);
503                                 }
504                                 break;
505                         }
506                 }
507         }
508
509         // LordHavoc: network timing test code
510         // if (actor.button0)
511         //      print(ftos(frametime), " ", ftos(time), " >= ", ftos(ATTACK_FINISHED(actor, slot)), " >= ", ftos(this.weapon_nextthink), "\n");
512
513         int w = PS(actor).m_weapon.m_id;
514
515         // call the think code which may fire the weapon
516         // and do so multiple times to resolve framerate dependency issues if the
517         // server framerate is very low and the weapon fire rate very high
518         for (int c = 0; c < W_TICSPERFRAME; ++c)
519         {
520                 if (w && !(actor.weapons & WepSet_FromWeapon(Weapons_from(w))))
521                 {
522                         if (PS(actor).m_weapon == PS(actor).m_switchweapon) W_SwitchWeapon_Force(actor, w_getbestweapon(actor));
523                         w = 0;
524                 }
525
526                 v_forward = fo;
527                 v_right = ri;
528                 v_up = up;
529
530                 bool block_weapon = false;
531                 {
532                         bool key_pressed = actor.BUTTON_HOOK && !actor.vehicle;
533                         Weapon off = actor.offhand;
534                         if (off && !(actor.weapons & WEPSET(HOOK)))
535                         {
536                                 if (off.offhand_think) off.offhand_think(off, actor, key_pressed);
537                         }
538                         else
539                         {
540                                 if (key_pressed && PS(actor).m_switchweapon != WEP_HOOK && !actor.hook_switchweapon)
541                                         W_SwitchWeapon(WEP_HOOK);
542                                 actor.hook_switchweapon = key_pressed;
543                                 Weapon h = WEP_HOOK;
544                                 block_weapon = (PS(actor).m_weapon == h && (actor.BUTTON_ATCK || key_pressed));
545                                 h.wr_think(h, actor, weaponentity, block_weapon ? 1 : 0);
546                         }
547                 }
548
549                 v_forward = fo;
550                 v_right = ri;
551                 v_up = up;
552
553                 if (!block_weapon)
554                 {
555                         if (w)
556                         {
557                                 Weapon e = PS(actor).m_weapon;
558                                 e.wr_think(e, actor, weaponentity, (actor.BUTTON_ATCK ? 1 : 0) | (actor.BUTTON_ATCK2 ? 2 : 0));
559                         }
560                         else
561                         {
562                                 Weapon w = PS(actor).m_weapon;
563                                 w.wr_gonethink(w);
564                         }
565                 }
566
567                 if (time + actor.weapon_frametime * 0.5 >= this.weapon_nextthink)
568                 {
569                         if (this.weapon_think)
570                         {
571                                 v_forward = fo;
572                                 v_right = ri;
573                                 v_up = up;
574                                 Weapon wpn = PS(actor).m_weapon;
575                                 this.weapon_think(wpn, actor, weaponentity,
576                                         (actor.BUTTON_ATCK ? 1 : 0) | (actor.BUTTON_ATCK2 ? 2 : 0));
577                         }
578                         else
579                         {
580                                 bprint("\{1}^1ERROR: undefined weapon think function for ", actor.netname, "\n");
581                         }
582                 }
583         }
584 }
585
586 void W_AttachToShotorg(entity actor, entity flash, vector offset)
587 {
588         .entity weaponentity = weaponentities[0];
589         flash.owner = actor;
590         flash.angles_z = random() * 360;
591
592         entity view = actor.(weaponentity);
593         entity exterior = actor.exteriorweaponentity;
594
595         if (gettagindex(view, "shot")) setattachment(flash, view, "shot");
596         else setattachment(flash, view, "tag_shot");
597         setorigin(flash, offset);
598
599         entity xflash = spawn();
600         copyentity(flash, xflash);
601
602         flash.viewmodelforclient = actor;
603
604         if (view.oldorigin.x > 0)
605         {
606                 setattachment(xflash, exterior, "");
607                 setorigin(xflash, view.oldorigin + offset);
608         }
609         else
610         {
611                 if (gettagindex(exterior, "shot")) setattachment(xflash, exterior, "shot");
612                 else setattachment(xflash, exterior, "tag_shot");
613                 setorigin(xflash, offset);
614         }
615 }
616
617 void W_DecreaseAmmo(Weapon wep, entity actor, float ammo_use)
618 {
619         if (MUTATOR_CALLHOOK(W_DecreaseAmmo, actor)) return;
620
621         if ((actor.items & IT_UNLIMITED_WEAPON_AMMO) && !wep.reloading_ammo) return;
622
623         // if this weapon is reloadable, decrease its load. Else decrease the player's ammo
624         if (wep.reloading_ammo)
625         {
626                 actor.clip_load -= ammo_use;
627                 actor.(weapon_load[PS(actor).m_weapon.m_id]) = actor.clip_load;
628         }
629         else if (wep.ammo_field != ammo_none)
630         {
631                 actor.(wep.ammo_field) -= ammo_use;
632                 if (actor.(wep.ammo_field) < 0)
633                 {
634                         backtrace(sprintf(
635                                 "W_DecreaseAmmo(%.2f): '%s' subtracted too much %s from '%s', resulting with '%.2f' left... "
636                                 "Please notify Samual immediately with a copy of this backtrace!\n",
637                                 ammo_use,
638                                 wep.netname,
639                                 GetAmmoPicture(wep.ammo_field),
640                                 actor.netname,
641                                 actor.(wep.ammo_field)
642                                              ));
643                 }
644         }
645 }
646
647 // weapon reloading code
648
649 .float reload_ammo_amount, reload_ammo_min, reload_time;
650 .float reload_complain;
651 .string reload_sound;
652
653 void W_ReloadedAndReady(Weapon thiswep, entity actor, .entity weaponentity, int fire)
654 {
655         // finish the reloading process, and do the ammo transfer
656
657         actor.clip_load = actor.old_clip_load;  // restore the ammo counter, in case we still had ammo in the weapon before reloading
658
659         // if the gun uses no ammo, max out weapon load, else decrease ammo as we increase weapon load
660         if (!actor.reload_ammo_min || actor.items & IT_UNLIMITED_WEAPON_AMMO || actor.ammo_field == ammo_none)
661         {
662                 actor.clip_load = actor.reload_ammo_amount;
663         }
664         else
665         {
666                 // make sure we don't add more ammo than we have
667                 float load = min(actor.reload_ammo_amount - actor.clip_load, actor.(actor.ammo_field));
668                 actor.clip_load += load;
669                 actor.(actor.ammo_field) -= load;
670         }
671         actor.(weapon_load[PS(actor).m_weapon.m_id]) = actor.clip_load;
672
673         // do not set ATTACK_FINISHED in reload code any more. This causes annoying delays if eg: You start reloading a weapon,
674         // then quickly switch to another weapon and back. Reloading is canceled, but the reload delay is still there,
675         // so your weapon is disabled for a few seconds without reason
676
677         // ATTACK_FINISHED(actor, slot) -= actor.reload_time - 1;
678
679         Weapon wpn = Weapons_from(PS(actor).m_weapon.m_id);
680         w_ready(wpn, actor, weaponentity, (actor.BUTTON_ATCK ? 1 : 0) | (actor.BUTTON_ATCK2 ? 2 : 0));
681 }
682
683 void W_Reload(entity actor, float sent_ammo_min, string sent_sound)
684 {
685         .entity weaponentity = weaponentities[0];
686         // set global values to work with
687         Weapon e = PS(actor).m_weapon;
688
689         if (MUTATOR_CALLHOOK(W_Reload, actor)) return;
690
691         actor.reload_ammo_min = sent_ammo_min;
692         actor.reload_ammo_amount = e.reloading_ammo;
693         actor.reload_time = e.reloading_time;
694         actor.reload_sound = sent_sound;
695
696         // don't reload weapons that don't have the RELOADABLE flag
697         if (!(e.spawnflags & WEP_FLAG_RELOADABLE))
698         {
699                 LOG_TRACE(
700                         "Warning: Attempted to reload a weapon that does not have the WEP_FLAG_RELOADABLE flag. Fix your code!\n");
701                 return;
702         }
703
704         // return if reloading is disabled for this weapon
705         if (!actor.reload_ammo_amount) return;
706
707         // our weapon is fully loaded, no need to reload
708         if (actor.clip_load >= actor.reload_ammo_amount) return;
709
710         // no ammo, so nothing to load
711         if (actor.ammo_field != ammo_none)
712         {
713                 if (!actor.(actor.ammo_field) && actor.reload_ammo_min)
714                 {
715                         if (!(actor.items & IT_UNLIMITED_WEAPON_AMMO))
716                         {
717                                 if (IS_REAL_CLIENT(actor) && actor.reload_complain < time)
718                                 {
719                                         play2(actor, SND(UNAVAILABLE));
720                                         sprint(actor, strcat("You don't have enough ammo to reload the ^2", PS(actor).m_weapon.m_name, "\n"));
721                                         actor.reload_complain = time + 1;
722                                 }
723                                 // switch away if the amount of ammo is not enough to keep using this weapon
724                                 Weapon w = PS(actor).m_weapon;
725                                 if (!(w.wr_checkammo1(w) + w.wr_checkammo2(w)))
726                                 {
727                                         actor.clip_load = -1;  // reload later
728                                         W_SwitchToOtherWeapon(actor);
729                                 }
730                                 return;
731                         }
732                 }
733         }
734
735         entity this = actor.(weaponentity);
736         if (this)
737         {
738                 if (this.wframe == WFRAME_RELOAD) return;
739
740                 // allow switching away while reloading, but this will cause a new reload!
741                 this.state = WS_READY;
742         }
743
744         // now begin the reloading process
745
746         _sound(actor, CH_WEAPON_SINGLE, actor.reload_sound, VOL_BASE, ATTEN_NORM);
747
748         // do not set ATTACK_FINISHED in reload code any more. This causes annoying delays if eg: You start reloading a weapon,
749         // then quickly switch to another weapon and back. Reloading is canceled, but the reload delay is still there,
750         // so your weapon is disabled for a few seconds without reason
751
752         // ATTACK_FINISHED(actor, slot) = max(time, ATTACK_FINISHED(actor, slot)) + actor.reload_time + 1;
753
754         weapon_thinkf(actor, weaponentity, WFRAME_RELOAD, actor.reload_time, W_ReloadedAndReady);
755
756         if (actor.clip_load < 0) actor.clip_load = 0;
757         actor.old_clip_load = actor.clip_load;
758         actor.clip_load = actor.(weapon_load[PS(actor).m_weapon.m_id]) = -1;
759 }
760
761 void W_DropEvent(.void(Weapon) event, entity player, float weapon_type, entity weapon_item)
762 {
763         Weapon w = Weapons_from(weapon_type);
764         weapon_dropevent_item = weapon_item;
765         WITH(entity, self, player, w.event(w));
766 }