qcsrc/server/weapons/weaponsystem.qc

   1 #include "weaponsystem.qh"
   2
   3 #include "selection.qh"
   4
   5 #include "../command/common.qh"
   6 #include "../mutators/all.qh"
   7 #include "../round_handler.qh"
   8 #include "../t_items.qh"
   9 #include "../../common/animdecide.qh"
  10 #include "../../common/constants.qh"
  11 #include "../../common/monsters/all.qh"
  12 #include "../../common/notifications.qh"
  13 #include "../../common/util.qh"
  14 #include "../../common/weapons/all.qh"
  15 #include "../../lib/csqcmodel/sv_model.qh"
  16
  17 vector shotorg_adjustfromclient(vector vecs, float y_is_right, float algn)
  18 {
  19         switch (algn)
  20         {
  21                 default: case 3: break; // right alignment
  22                 case 4: vecs.y = -vecs.y;
  23                         break;              // left
  24                 case 1: case 2: vecs.y = 0;
  25                         vecs.z -= 2;
  26                         break;              // center
  27         }
  28
  29         return vecs;
  30 }
  31
  32 vector shotorg_adjust_values(vector vecs, bool y_is_right, bool visual, int algn)
  33 {
  34         string s;
  35
  36         if (visual)
  37         {
  38                 vecs = shotorg_adjustfromclient(vecs, y_is_right, algn);
  39         }
  40         else if (autocvar_g_shootfromeye)
  41         {
  42                 vecs.y = vecs.z = 0;
  43         }
  44         else if (autocvar_g_shootfromcenter)
  45         {
  46                 vecs.y = 0;
  47                 vecs.z -= 2;
  48         }
  49         else if ((s = autocvar_g_shootfromfixedorigin) != "")
  50         {
  51                 vector v = stov(s);
  52                 if (y_is_right) v.y = -v.y;
  53                 if (v.x != 0) vecs.x = v.x;
  54                 vecs.y = v.y;
  55                 vecs.z = v.z;
  56         }
  57         else  // just do the same as top
  58         {
  59                 vecs = shotorg_adjustfromclient(vecs, y_is_right, algn);
  60         }
  61
  62         return vecs;
  63 }
  64
  65 vector shotorg_adjust(vector vecs, bool y_is_right, bool visual, int algn)
  66 {
  67         return shotorg_adjust_values(vecs, y_is_right, visual, algn);
  68 }
  69
  70 .int state;
  71
  72 .float weapon_frametime;
  73
  74 float W_WeaponRateFactor()
  75 {
  76         float t = 1.0 / g_weaponratefactor;
  77
  78         MUTATOR_CALLHOOK(WeaponRateFactor, t);
  79         t = weapon_rate;
  80
  81         return t;
  82 }
  83
  84 float W_WeaponSpeedFactor()
  85 {
  86         float t = 1.0 * g_weaponspeedfactor;
  87
  88         MUTATOR_CALLHOOK(WeaponSpeedFactor, t);
  89         t = ret_float;
  90
  91         return t;
  92 }
  93
  94
  95 void weapon_thinkf(entity actor, .entity weaponentity, float fr, float t,
  96     void(Weapon thiswep, entity actor, .entity weaponentity, int fire) func);
  97
  98 bool CL_Weaponentity_CustomizeEntityForClient()
  99 {
 100         SELFPARAM();
 101         this.viewmodelforclient = this.owner;
 102         if (IS_SPEC(other) && other.enemy == this.owner) this.viewmodelforclient = other;
 103         return true;
 104 }
 105
 106 /*
 107  * supported formats:
 108  *
 109  * 1. simple animated model, muzzle flash handling on h_ model:
 110  *    h_tuba.dpm, h_tuba.dpm.framegroups - invisible model controlling the animation
 111  *      tags:
 112  *        shot = muzzle end (shot origin, also used for muzzle flashes)
 113  *        shell = casings ejection point (must be on the right hand side of the gun)
 114  *        weapon = attachment for v_tuba.md3
 115  *    v_tuba.md3 - first and third person model
 116  *    g_tuba.md3 - pickup model
 117  *
 118  * 2. simple animated model, muzzle flash handling on v_ model:
 119  *    h_tuba.dpm, h_tuba.dpm.framegroups - invisible model controlling the animation
 120  *      tags:
 121  *        weapon = attachment for v_tuba.md3
 122  *    v_tuba.md3 - first and third person model
 123  *      tags:
 124  *        shot = muzzle end (shot origin, also used for muzzle flashes)
 125  *        shell = casings ejection point (must be on the right hand side of the gun)
 126  *    g_tuba.md3 - pickup model
 127  *
 128  * 3. fully animated model, muzzle flash handling on h_ model:
 129  *    h_tuba.dpm, h_tuba.dpm.framegroups - animated first person model
 130  *      tags:
 131  *        shot = muzzle end (shot origin, also used for muzzle flashes)
 132  *        shell = casings ejection point (must be on the right hand side of the gun)
 133  *        handle = corresponding to the origin of v_tuba.md3 (used for muzzle flashes)
 134  *    v_tuba.md3 - third person model
 135  *    g_tuba.md3 - pickup model
 136  *
 137  * 4. fully animated model, muzzle flash handling on v_ model:
 138  *    h_tuba.dpm, h_tuba.dpm.framegroups - animated first person model
 139  *      tags:
 140  *        shot = muzzle end (shot origin)
 141  *        shell = casings ejection point (must be on the right hand side of the gun)
 142  *    v_tuba.md3 - third person model
 143  *      tags:
 144  *        shot = muzzle end (for muzzle flashes)
 145  *    g_tuba.md3 - pickup model
 146  */
 147
 148 // writes:
 149 //   this.origin, this.angles
 150 //   this.weaponentity
 151 //   this.movedir, this.view_ofs
 152 //   attachment stuff
 153 //   anim stuff
 154 // to free:
 155 //   call again with ""
 156 //   remove the ent
 157 void CL_WeaponEntity_SetModel(entity this, .entity weaponentity, string name)
 158 {
 159         if (name != "")
 160         {
 161                 // if there is a child entity, hide it until we're sure we use it
 162                 if (this.(weaponentity)) this.(weaponentity).model = "";
 163                 _setmodel(this, W_Model(strcat("v_", name, ".md3")));
 164                 int v_shot_idx = gettagindex(this, "shot");  // used later
 165                 if (!v_shot_idx) v_shot_idx = gettagindex(this, "tag_shot");
 166
 167                 _setmodel(this, W_Model(strcat("h_", name, ".iqm")));
 168                 // preset some defaults that work great for renamed zym files (which don't need an animinfo)
 169                 this.anim_fire1  = animfixfps(this, '0 1 0.01', '0 0 0');
 170                 this.anim_fire2  = animfixfps(this, '1 1 0.01', '0 0 0');
 171                 this.anim_idle   = animfixfps(this, '2 1 0.01', '0 0 0');
 172                 this.anim_reload = animfixfps(this, '3 1 0.01', '0 0 0');
 173
 174                 // if we have a "weapon" tag, let's attach the v_ model to it ("invisible hand" style model)
 175                 // if we don't, this is a "real" animated model
 176                 if (gettagindex(this, "weapon"))
 177                 {
 178                         if (!this.(weaponentity)) this.(weaponentity) = new(weaponentity);
 179                         _setmodel(this.(weaponentity), W_Model(strcat("v_", name, ".md3")));
 180                         setattachment(this.(weaponentity), this, "weapon");
 181                 }
 182                 else if (gettagindex(this, "tag_weapon"))
 183                 {
 184                         if (!this.(weaponentity)) this.(weaponentity) = new(weaponentity);
 185                         _setmodel(this.(weaponentity), W_Model(strcat("v_", name, ".md3")));
 186                         setattachment(this.(weaponentity), this, "tag_weapon");
 187                 }
 188                 else
 189                 {
 190                         if (this.(weaponentity)) remove(this.(weaponentity));
 191                         this.(weaponentity) = NULL;
 192                 }
 193
 194                 setorigin(this, '0 0 0');
 195                 this.angles = '0 0 0';
 196                 this.frame = 0;
 197                 this.viewmodelforclient = NULL;
 198
 199                 float idx;
 200
 201                 if (v_shot_idx)  // v_ model attached to invisible h_ model
 202                 {
 203                         this.movedir = gettaginfo(this.(weaponentity), v_shot_idx);
 204                 }
 205                 else
 206                 {
 207                         idx = gettagindex(this, "shot");
 208                         if (!idx) idx = gettagindex(this, "tag_shot");
 209                         if (idx)
 210                         {
 211                                 this.movedir = gettaginfo(this, idx);
 212                         }
 213                         else
 214                         {
 215                                 LOG_INFO("WARNING: weapon model ", this.model,
 216                                         " does not support the 'shot' tag, will display shots TOTALLY wrong\n");
 217                                 this.movedir = '0 0 0';
 218                         }
 219                 }
 220
 221                 if (this.(weaponentity))  // v_ model attached to invisible h_ model
 222                 {
 223                         idx = gettagindex(this.(weaponentity), "shell");
 224                         if (!idx) idx = gettagindex(this.(weaponentity), "tag_shell");
 225                         if (idx) this.spawnorigin = gettaginfo(this.(weaponentity), idx);
 226                 }
 227                 else
 228                 {
 229                         idx = 0;
 230                 }
 231                 if (!idx)
 232                 {
 233                         idx = gettagindex(this, "shell");
 234                         if (!idx) idx = gettagindex(this, "tag_shell");
 235                         if (idx)
 236                         {
 237                                 this.spawnorigin = gettaginfo(this, idx);
 238                         }
 239                         else
 240                         {
 241                                 LOG_INFO("WARNING: weapon model ", this.model,
 242                                         " does not support the 'shell' tag, will display casings wrong\n");
 243                                 this.spawnorigin = this.movedir;
 244                         }
 245                 }
 246
 247                 if (v_shot_idx)
 248                 {
 249                         this.oldorigin = '0 0 0';  // use regular attachment
 250                 }
 251                 else
 252                 {
 253                         if (this.(weaponentity))
 254                         {
 255                                 idx = gettagindex(this, "weapon");
 256                                 if (!idx) idx = gettagindex(this, "tag_weapon");
 257                         }
 258                         else
 259                         {
 260                                 idx = gettagindex(this, "handle");
 261                                 if (!idx) idx = gettagindex(this, "tag_handle");
 262                         }
 263                         if (idx)
 264                         {
 265                                 this.oldorigin = this.movedir - gettaginfo(this, idx);
 266                         }
 267                         else
 268                         {
 269                                 LOG_INFO("WARNING: weapon model ", this.model,
 270                                         " does not support the 'handle' tag and neither does the v_ model support the 'shot' tag, will display muzzle flashes TOTALLY wrong\n");
 271                                 this.oldorigin = '0 0 0';  // there is no way to recover from this
 272                         }
 273                 }
 274
 275                 this.viewmodelforclient = this.owner;
 276         }
 277         else
 278         {
 279                 this.model = "";
 280                 if (this.(weaponentity)) remove(this.(weaponentity));
 281                 this.(weaponentity) = NULL;
 282                 this.movedir = '0 0 0';
 283                 this.spawnorigin = '0 0 0';
 284                 this.oldorigin = '0 0 0';
 285                 this.anim_fire1  = '0 1 0.01';
 286                 this.anim_fire2  = '0 1 0.01';
 287                 this.anim_idle   = '0 1 0.01';
 288                 this.anim_reload = '0 1 0.01';
 289         }
 290
 291         this.view_ofs = '0 0 0';
 292
 293         if (this.movedir.x >= 0)
 294         {
 295                 vector v0 = this.movedir;
 296                 this.movedir = shotorg_adjust(v0, false, false, this.owner.cvar_cl_gunalign);
 297                 this.view_ofs = shotorg_adjust(v0, false, true, this.owner.cvar_cl_gunalign) - v0;
 298         }
 299         this.owner.stat_shotorg = compressShotOrigin(this.movedir);
 300         this.movedir = decompressShotOrigin(this.owner.stat_shotorg); // make them match perfectly
 301
 302         this.spawnorigin += this.view_ofs;                            // offset the casings origin by the same amount
 303
 304         // check if an instant weapon switch occurred
 305         setorigin(this, this.view_ofs);
 306         // reset animstate now
 307         this.wframe = WFRAME_IDLE;
 308         setanim(this, this.anim_idle, true, false, true);
 309 }
 310
 311 vector CL_Weapon_GetShotOrg(float wpn)
 312 {
 313         entity wi = get_weaponinfo(wpn);
 314         entity e = spawn();
 315         .entity weaponentity = weaponentities[0];
 316         CL_WeaponEntity_SetModel(e, weaponentity, wi.mdl);
 317         vector ret = e.movedir;
 318         CL_WeaponEntity_SetModel(e, weaponentity, "");
 319         remove(e);
 320         return ret;
 321 }
 322
 323 void CL_Weaponentity_Think()
 324 {
 325         SELFPARAM();
 326         this.nextthink = time;
 327         if (intermission_running) this.frame = this.anim_idle.x;
 328         .entity weaponentity = weaponentities[0]; // TODO: unhardcode
 329         if (this.owner.(weaponentity) != this)
 330         {
 331                 if (this.(weaponentity)) remove(this.(weaponentity));
 332                 remove(this);
 333                 return;
 334         }
 335         if (this.owner.deadflag != DEAD_NO)
 336         {
 337                 this.model = "";
 338                 if (this.(weaponentity)) this.(weaponentity).model = "";
 339                 return;
 340         }
 341         if (this.weaponname != this.owner.weaponname || this.dmg != this.owner.modelindex
 342             || this.deadflag != this.owner.deadflag)
 343         {
 344                 this.weaponname = this.owner.weaponname;
 345                 this.dmg = this.owner.modelindex;
 346                 this.deadflag = this.owner.deadflag;
 347
 348                 CL_WeaponEntity_SetModel(this, weaponentity, this.owner.weaponname);
 349         }
 350
 351         int tb = (this.effects & (EF_TELEPORT_BIT | EF_RESTARTANIM_BIT));
 352         this.effects = this.owner.effects & EFMASK_CHEAP;
 353         this.effects &= ~EF_LOWPRECISION;
 354         this.effects &= ~EF_FULLBRIGHT;  // can mask team color, so get rid of it
 355         this.effects &= ~EF_TELEPORT_BIT;
 356         this.effects &= ~EF_RESTARTANIM_BIT;
 357         this.effects |= tb;
 358
 359         if (this.owner.alpha == default_player_alpha) this.alpha = default_weapon_alpha;
 360         else if (this.owner.alpha != 0) this.alpha = this.owner.alpha;
 361         else this.alpha = 1;
 362
 363         this.glowmod = this.owner.weaponentity_glowmod;
 364         this.colormap = this.owner.colormap;
 365         if (this.(weaponentity))
 366         {
 367                 this.(weaponentity).effects = this.effects;
 368                 this.(weaponentity).alpha = this.alpha;
 369                 this.(weaponentity).colormap = this.colormap;
 370                 this.(weaponentity).glowmod = this.glowmod;
 371         }
 372
 373         this.angles = '0 0 0';
 374
 375         float f = (this.owner.weapon_nextthink - time);
 376         if (this.state == WS_RAISE && !intermission_running)
 377         {
 378                 entity newwep = get_weaponinfo(this.owner.switchweapon);
 379                 f = f * g_weaponratefactor / max(f, newwep.switchdelay_raise);
 380                 this.angles_x = -90 * f * f;
 381         }
 382         else if (this.state == WS_DROP && !intermission_running)
 383         {
 384                 entity oldwep = get_weaponinfo(this.owner.weapon);
 385                 f = 1 - f * g_weaponratefactor / max(f, oldwep.switchdelay_drop);
 386                 this.angles_x = -90 * f * f;
 387         }
 388         else if (this.state == WS_CLEAR)
 389         {
 390                 f = 1;
 391                 this.angles_x = -90 * f * f;
 392         }
 393 }
 394
 395 void CL_ExteriorWeaponentity_Think()
 396 {
 397         SELFPARAM();
 398         this.nextthink = time;
 399         if (this.owner.exteriorweaponentity != this)
 400         {
 401                 remove(this);
 402                 return;
 403         }
 404         if (this.owner.deadflag != DEAD_NO)
 405         {
 406                 this.model = "";
 407                 return;
 408         }
 409         if (this.weaponname != this.owner.weaponname || this.dmg != this.owner.modelindex
 410             || this.deadflag != this.owner.deadflag)
 411         {
 412                 this.weaponname = this.owner.weaponname;
 413                 this.dmg = this.owner.modelindex;
 414                 this.deadflag = this.owner.deadflag;
 415                 if (this.owner.weaponname != "") _setmodel(this, W_Model(strcat("v_", this.owner.weaponname, ".md3")));
 416                 else this.model = "";
 417
 418                 int tag_found;
 419                 if ((tag_found = gettagindex(this.owner, "tag_weapon")))
 420                 {
 421                         this.tag_index = tag_found;
 422                         this.tag_entity = this.owner;
 423                 }
 424                 else
 425                 {
 426                         setattachment(this, this.owner, "bip01 r hand");
 427                 }
 428         }
 429         this.effects = this.owner.effects;
 430         this.effects |= EF_LOWPRECISION;
 431         this.effects = this.effects & EFMASK_CHEAP;  // eat performance
 432         if (this.owner.alpha == default_player_alpha) this.alpha = default_weapon_alpha;
 433         else if (this.owner.alpha != 0) this.alpha = this.owner.alpha;
 434         else this.alpha = 1;
 435
 436         this.glowmod = this.owner.weaponentity_glowmod;
 437         this.colormap = this.owner.colormap;
 438
 439         CSQCMODEL_AUTOUPDATE(this);
 440 }
 441
 442 // spawning weaponentity for client
 443 void CL_SpawnWeaponentity(entity e, .entity weaponentity)
 444 {
 445         entity view = e.(weaponentity) = new(weaponentity);
 446         view.solid = SOLID_NOT;
 447         view.owner = e;
 448         setmodel(view, MDL_Null);  // precision set when changed
 449         setorigin(view, '0 0 0');
 450         view.angles = '0 0 0';
 451         view.viewmodelforclient = e;
 452         view.flags = 0;
 453         view.think = CL_Weaponentity_Think;
 454         view.customizeentityforclient = CL_Weaponentity_CustomizeEntityForClient;
 455         view.nextthink = time;
 456
 457         if (weaponentity == weaponentities[0])
 458         {
 459                 entity exterior = e.exteriorweaponentity = spawn();
 460                 exterior.classname = "exteriorweaponentity";
 461                 exterior.solid = SOLID_NOT;
 462                 exterior.exteriorweaponentity = exterior;
 463                 exterior.owner = e;
 464                 setorigin(exterior, '0 0 0');
 465                 exterior.angles = '0 0 0';
 466                 exterior.think = CL_ExteriorWeaponentity_Think;
 467                 exterior.nextthink = time;
 468
 469                 CSQCMODEL_AUTOINIT(exterior);
 470         }
 471 }
 472
 473 // Weapon subs
 474 void w_clear(Weapon thiswep, entity actor, .entity weaponentity, int fire)
 475 {
 476         if (actor.weapon != -1)
 477         {
 478                 actor.weapon = 0;
 479                 actor.switchingweapon = 0;
 480         }
 481         if (actor.(weaponentity))
 482         {
 483                 actor.(weaponentity).state = WS_CLEAR;
 484                 actor.(weaponentity).effects = 0;
 485         }
 486 }
 487
 488 void w_ready(Weapon thiswep, entity actor, .entity weaponentity, int fire)
 489 {
 490         if (actor.(weaponentity)) actor.(weaponentity).state = WS_READY;
 491         weapon_thinkf(actor, weaponentity, WFRAME_IDLE, 1000000, w_ready);
 492 }
 493
 494 .float prevdryfire;
 495 .float prevwarntime;
 496 bool weapon_prepareattack_checkammo(Weapon thiswep, entity actor, bool secondary)
 497 {
 498         if ((actor.items & IT_UNLIMITED_WEAPON_AMMO)) return true;
 499         bool ammo = false;
 500         if (secondary) WITH(entity, self, actor, ammo = thiswep.wr_checkammo2(thiswep));
 501         else WITH(entity, self, actor, ammo = thiswep.wr_checkammo1(thiswep));
 502         if (ammo) return true;
 503         // always keep the Mine Layer if we placed mines, so that we can detonate them
 504         if (thiswep == WEP_MINE_LAYER)
 505                 for (entity mine; (mine = find(mine, classname, "mine")); )
 506                         if (mine.owner == actor) return false;
 507
 508         if (thiswep == WEP_SHOTGUN)
 509                 if (!secondary && WEP_CVAR(shotgun, secondary) == 1) return false;             // no clicking, just allow
 510
 511         if (thiswep == get_weaponinfo(actor.switchweapon) && time - actor.prevdryfire > 1) // only play once BEFORE starting to switch weapons
 512         {
 513                 sound(actor, CH_WEAPON_A, SND_DRYFIRE, VOL_BASE, ATTEN_NORM);
 514                 actor.prevdryfire = time;
 515         }
 516
 517         // check if the other firing mode has enough ammo
 518         bool ammo_other = false;
 519         if (secondary) WITH(entity, self, actor, ammo_other = thiswep.wr_checkammo1(thiswep));
 520         else WITH(entity, self, actor, ammo_other = thiswep.wr_checkammo2(thiswep));
 521         if (ammo_other)
 522         {
 523                 if (time - actor.prevwarntime > 1)
 524                 {
 525                         Send_Notification(
 526                                 NOTIF_ONE,
 527                                 actor,
 528                                 MSG_MULTI,
 529                                 ITEM_WEAPON_PRIMORSEC,
 530                                 thiswep.m_id,
 531                                 secondary,
 532                                 (1 - secondary)
 533                                          );
 534                 }
 535                 actor.prevwarntime = time;
 536         }
 537         else  // this weapon is totally unable to fire, switch to another one
 538         {
 539                 W_SwitchToOtherWeapon(actor);
 540         }
 541
 542         return false;
 543 }
 544
 545 .float race_penalty;
 546 bool weapon_prepareattack_check(Weapon thiswep, entity actor, .entity weaponentity, bool secondary, float attacktime)
 547 {
 548         if (!weapon_prepareattack_checkammo(thiswep, actor, secondary)) return false;
 549
 550         // if sv_ready_restart_after_countdown is set, don't allow the player to shoot
 551         // if all players readied up and the countdown is running
 552         if (time < game_starttime || time < actor.race_penalty) return false;
 553
 554         if (timeout_status == TIMEOUT_ACTIVE)  // don't allow the player to shoot while game is paused
 555                 return false;
 556
 557         // do not even think about shooting if switching
 558         if (actor.switchweapon != actor.weapon) return false;
 559
 560         if (attacktime >= 0)
 561         {
 562                 int slot = weaponslot(weaponentity);
 563                 // don't fire if previous attack is not finished
 564                 if (ATTACK_FINISHED(actor, slot) > time + actor.weapon_frametime * 0.5) return false;
 565                 // don't fire while changing weapon
 566                 if (actor.(weaponentity).state != WS_READY) return false;
 567         }
 568         return true;
 569 }
 570
 571 void weapon_prepareattack_do(entity actor, .entity weaponentity, bool secondary, float attacktime)
 572 {
 573         actor.(weaponentity).state = WS_INUSE;
 574
 575         actor.spawnshieldtime = min(actor.spawnshieldtime, time);  // kill spawn shield when you fire
 576
 577         // if the weapon hasn't been firing continuously, reset the timer
 578         if (attacktime >= 0)
 579         {
 580                 int slot = weaponslot(weaponentity);
 581                 if (ATTACK_FINISHED(actor, slot) < time - actor.weapon_frametime * 1.5)
 582                 {
 583                         ATTACK_FINISHED(actor, slot) = time;
 584                         // dprint("resetting attack finished to ", ftos(time), "\n");
 585                 }
 586                 ATTACK_FINISHED(actor, slot) = ATTACK_FINISHED(actor, slot) + attacktime * W_WeaponRateFactor();
 587         }
 588         actor.bulletcounter += 1;
 589         // dprint("attack finished ", ftos(ATTACK_FINISHED(actor, slot)), "\n");
 590 }
 591
 592 bool weapon_prepareattack(Weapon thiswep, entity actor, .entity weaponentity, bool secondary, float attacktime)
 593 {
 594         if (weapon_prepareattack_check(thiswep, actor, weaponentity, secondary, attacktime))
 595         {
 596                 weapon_prepareattack_do(actor, weaponentity, secondary, attacktime);
 597                 return true;
 598         }
 599         return false;
 600 }
 601
 602 void weapon_thinkf(entity actor, .entity weaponentity, float fr, float t,
 603         void(Weapon thiswep, entity actor, .entity weaponentity, int fire) func)
 604 {
 605         bool restartanim;
 606         if (fr == WFRAME_DONTCHANGE)
 607         {
 608                 fr = actor.(weaponentity).wframe;
 609                 restartanim = false;
 610         }
 611         else if (fr == WFRAME_IDLE)
 612         {
 613                 restartanim = false;
 614         }
 615         else
 616         {
 617                 restartanim = true;
 618         }
 619
 620         vector of = v_forward;
 621         vector or = v_right;
 622         vector ou = v_up;
 623
 624         if (actor.(weaponentity))
 625         {
 626                 actor.(weaponentity).wframe = fr;
 627                 vector a = '0 0 0';
 628                 if (fr == WFRAME_IDLE) a = actor.(weaponentity).anim_idle;
 629                 else if (fr == WFRAME_FIRE1) a = actor.(weaponentity).anim_fire1;
 630                 else if (fr == WFRAME_FIRE2) a = actor.(weaponentity).anim_fire2;
 631                 else  // if (fr == WFRAME_RELOAD)
 632                         a = actor.(weaponentity).anim_reload;
 633                 a.z *= g_weaponratefactor;
 634                 setanim(actor.(weaponentity), a, restartanim == false, restartanim, restartanim);
 635         }
 636
 637         v_forward = of;
 638         v_right = or;
 639         v_up = ou;
 640
 641         if (actor.weapon_think == w_ready && func != w_ready && actor.(weaponentity).state == WS_RAISE) backtrace(
 642                         "Tried to override initial weapon think function - should this really happen?");
 643
 644         t *= W_WeaponRateFactor();
 645
 646         // VorteX: haste can be added here
 647         if (actor.weapon_think == w_ready)
 648         {
 649                 actor.weapon_nextthink = time;
 650                 // dprint("started firing at ", ftos(time), "\n");
 651         }
 652         if (actor.weapon_nextthink < time - actor.weapon_frametime * 1.5
 653             || actor.weapon_nextthink > time + actor.weapon_frametime * 1.5)
 654         {
 655                 actor.weapon_nextthink = time;
 656                 // dprint("reset weapon animation timer at ", ftos(time), "\n");
 657         }
 658         actor.weapon_nextthink = actor.weapon_nextthink + t;
 659         actor.weapon_think = func;
 660         // dprint("next ", ftos(actor.weapon_nextthink), "\n");
 661
 662         if ((fr == WFRAME_FIRE1 || fr == WFRAME_FIRE2) && t)
 663         {
 664                 if ((actor.weapon == WEP_SHOCKWAVE.m_id || actor.weapon == WEP_SHOTGUN.m_id)
 665                     && fr == WFRAME_FIRE2) animdecide_setaction(actor, ANIMACTION_MELEE, restartanim);
 666                 else animdecide_setaction(actor, ANIMACTION_SHOOT, restartanim);
 667         }
 668         else
 669         {
 670                 if (actor.anim_upper_action == ANIMACTION_SHOOT
 671                     || actor.anim_upper_action == ANIMACTION_MELEE) actor.anim_upper_action = 0;
 672         }
 673 }
 674
 675 bool forbidWeaponUse(entity player)
 676 {
 677         if (time < game_starttime && !autocvar_sv_ready_restart_after_countdown) return true;
 678         if (round_handler_IsActive() && !round_handler_IsRoundStarted()) return true;
 679         if (player.player_blocked) return true;
 680         if (player.frozen) return true;
 681         if (player.weapon_blocked) return true;
 682         return false;
 683 }
 684
 685 .bool hook_switchweapon;
 686
 687 void W_WeaponFrame(entity actor)
 688 {
 689         .entity weaponentity = weaponentities[0]; // TODO: unhardcode
 690         if (frametime) actor.weapon_frametime = frametime;
 691
 692         if (!actor.(weaponentity) || actor.health < 1) return;  // Dead player can't use weapons and injure impulse commands
 693
 694         if (forbidWeaponUse(actor))
 695         {
 696                 if (actor.(weaponentity).state != WS_CLEAR)
 697                 {
 698                         Weapon wpn = get_weaponinfo(actor.weapon);
 699                         w_ready(wpn, actor, weaponentity, (actor.BUTTON_ATCK ? 1 : 0) | (actor.BUTTON_ATCK2 ? 2 : 0));
 700                         return;
 701                 }
 702         }
 703
 704         if (!actor.switchweapon)
 705         {
 706                 actor.weapon = 0;
 707                 actor.switchingweapon = 0;
 708                 actor.(weaponentity).state = WS_CLEAR;
 709                 actor.weaponname = "";
 710                 // actor.items &= ~IT_AMMO;
 711                 return;
 712         }
 713
 714         makevectors(actor.v_angle);
 715         vector fo = v_forward;  // save them in case the weapon think functions change it
 716         vector ri = v_right;
 717         vector up = v_up;
 718
 719         // Change weapon
 720         if (actor.weapon != actor.switchweapon)
 721         {
 722                 if (actor.(weaponentity).state == WS_CLEAR)
 723                 {
 724                         // end switching!
 725                         actor.switchingweapon = actor.switchweapon;
 726                         entity newwep = get_weaponinfo(actor.switchweapon);
 727
 728                         // the two weapon entities will notice this has changed and update their models
 729                         actor.weapon = actor.switchweapon;
 730                         actor.weaponname = newwep.mdl;
 731                         actor.bulletcounter = 0;
 732                         actor.ammo_field = newwep.ammo_field;
 733                         Weapon w = get_weaponinfo(actor.switchweapon);
 734                         w.wr_setup(w);
 735                         actor.(weaponentity).state = WS_RAISE;
 736
 737                         // set our clip load to the load of the weapon we switched to, if it's reloadable
 738                         if (newwep.spawnflags & WEP_FLAG_RELOADABLE && newwep.reloading_ammo)  // prevent accessing undefined cvars
 739                         {
 740                                 actor.clip_load = actor.(weapon_load[actor.switchweapon]);
 741                                 actor.clip_size = newwep.reloading_ammo;
 742                         }
 743                         else
 744                         {
 745                                 actor.clip_load = actor.clip_size = 0;
 746                         }
 747
 748                         weapon_thinkf(actor, weaponentity, WFRAME_IDLE, newwep.switchdelay_raise, w_ready);
 749                 }
 750                 else if (actor.(weaponentity).state == WS_DROP)
 751                 {
 752                         // in dropping phase we can switch at any time
 753                         actor.switchingweapon = actor.switchweapon;
 754                 }
 755                 else if (actor.(weaponentity).state == WS_READY)
 756                 {
 757                         // start switching!
 758                         actor.switchingweapon = actor.switchweapon;
 759                         entity oldwep = get_weaponinfo(actor.weapon);
 760
 761                         // set up weapon switch think in the future, and start drop anim
 762                         if (
 763 #if INDEPENDENT_ATTACK_FINISHED
 764                                     true
 765 #else
 766                                     ATTACK_FINISHED(actor, slot) <= time + actor.weapon_frametime * 0.5
 767 #endif
 768                            )
 769                         {
 770                                 sound(actor, CH_WEAPON_SINGLE, SND_WEAPON_SWITCH, VOL_BASE, ATTN_NORM);
 771                                 actor.(weaponentity).state = WS_DROP;
 772                                 weapon_thinkf(actor, weaponentity, WFRAME_DONTCHANGE, oldwep.switchdelay_drop, w_clear);
 773                         }
 774                 }
 775         }
 776
 777         // LordHavoc: network timing test code
 778         // if (actor.button0)
 779         //      print(ftos(frametime), " ", ftos(time), " >= ", ftos(ATTACK_FINISHED(actor, slot)), " >= ", ftos(actor.weapon_nextthink), "\n");
 780
 781         int w = actor.weapon;
 782
 783         // call the think code which may fire the weapon
 784         // and do so multiple times to resolve framerate dependency issues if the
 785         // server framerate is very low and the weapon fire rate very high
 786         int c = 0;
 787         while (c < W_TICSPERFRAME)
 788         {
 789                 c += 1;
 790                 if (w && !(actor.weapons & WepSet_FromWeapon(w)))
 791                 {
 792                         if (actor.weapon == actor.switchweapon) W_SwitchWeapon_Force(actor, w_getbestweapon(actor));
 793                         w = 0;
 794                 }
 795
 796                 v_forward = fo;
 797                 v_right = ri;
 798                 v_up = up;
 799
 800                 bool block_weapon = false;
 801                 {
 802                         bool key_pressed = actor.BUTTON_HOOK && !actor.vehicle;
 803                         Weapon off = actor.offhand;
 804                         if (off && !(actor.weapons & WEPSET(HOOK)))
 805                         {
 806                                 if (off.offhand_think) off.offhand_think(off, actor, key_pressed);
 807                         }
 808                         else
 809                         {
 810                                 if (key_pressed && actor.switchweapon != WEP_HOOK.m_id && !actor.hook_switchweapon) W_SwitchWeapon(
 811                                                 WEP_HOOK.m_id);
 812                                 actor.hook_switchweapon = key_pressed;
 813                                 Weapon h = WEP_HOOK;
 814                                 block_weapon = (actor.weapon == h.m_id && (actor.BUTTON_ATCK || key_pressed));
 815                                 h.wr_think(h, actor, weaponentity, block_weapon ? 1 : 0);
 816                         }
 817                 }
 818
 819                 v_forward = fo;
 820                 v_right = ri;
 821                 v_up = up;
 822
 823                 if (!block_weapon)
 824                 {
 825                         if (w)
 826                         {
 827                                 Weapon e = get_weaponinfo(actor.weapon);
 828                                 e.wr_think(e, actor, weaponentity, (actor.BUTTON_ATCK ? 1 : 0) | (actor.BUTTON_ATCK2 ? 2 : 0));
 829                         }
 830                         else
 831                         {
 832                                 Weapon w = get_weaponinfo(actor.weapon);
 833                                 w.wr_gonethink(w);
 834                         }
 835                 }
 836
 837                 if (time + actor.weapon_frametime * 0.5 >= actor.weapon_nextthink)
 838                 {
 839                         if (actor.weapon_think)
 840                         {
 841                                 v_forward = fo;
 842                                 v_right = ri;
 843                                 v_up = up;
 844                                 Weapon wpn = get_weaponinfo(actor.weapon);
 845                                 actor.weapon_think(wpn, actor, weaponentity, (actor.BUTTON_ATCK ? 1 : 0) | (actor.BUTTON_ATCK2 ? 2 : 0));
 846                         }
 847                         else
 848                         {
 849                                 bprint("\{1}^1ERROR: undefined weapon think function for ", actor.netname, "\n");
 850                         }
 851                 }
 852         }
 853 }
 854
 855 void W_AttachToShotorg(entity actor, entity flash, vector offset)
 856 {
 857         .entity weaponentity = weaponentities[0];
 858         flash.owner = actor;
 859         flash.angles_z = random() * 360;
 860
 861         if (gettagindex(actor.(weaponentity), "shot")) setattachment(flash, actor.(weaponentity), "shot");
 862         else setattachment(flash, actor.(weaponentity), "tag_shot");
 863         setorigin(flash, offset);
 864
 865         entity xflash = spawn();
 866         copyentity(flash, xflash);
 867
 868         flash.viewmodelforclient = actor;
 869
 870         if (actor.(weaponentity).oldorigin.x > 0)
 871         {
 872                 setattachment(xflash, actor.exteriorweaponentity, "");
 873                 setorigin(xflash, actor.(weaponentity).oldorigin + offset);
 874         }
 875         else
 876         {
 877                 if (gettagindex(actor.exteriorweaponentity, "shot")) setattachment(xflash, actor.exteriorweaponentity, "shot");
 878                 else setattachment(xflash, actor.exteriorweaponentity, "tag_shot");
 879                 setorigin(xflash, offset);
 880         }
 881 }
 882
 883 void W_DecreaseAmmo(Weapon wep, entity actor, float ammo_use)
 884 {
 885         if (cvar("g_overkill"))
 886         {
 887                 if (actor.ok_use_ammocharge)
 888                 {
 889                         ok_DecreaseCharge(actor, actor.weapon);
 890                         return;  // TODO
 891                 }
 892         }
 893
 894         if ((actor.items & IT_UNLIMITED_WEAPON_AMMO) && !wep.reloading_ammo) return;
 895
 896         // if this weapon is reloadable, decrease its load. Else decrease the player's ammo
 897         if (wep.reloading_ammo)
 898         {
 899                 actor.clip_load -= ammo_use;
 900                 actor.(weapon_load[actor.weapon]) = actor.clip_load;
 901         }
 902         else if (wep.ammo_field != ammo_none)
 903         {
 904                 actor.(wep.ammo_field) -= ammo_use;
 905                 if (actor.(wep.ammo_field) < 0)
 906                 {
 907                         backtrace(sprintf(
 908                                 "W_DecreaseAmmo(%.2f): '%s' subtracted too much %s from '%s', resulting with '%.2f' left... "
 909                                 "Please notify Samual immediately with a copy of this backtrace!\n",
 910                                 ammo_use,
 911                                 wep.netname,
 912                                 GetAmmoPicture(wep.ammo_field),
 913                                 actor.netname,
 914                                 actor.(wep.ammo_field)
 915                                              ));
 916                 }
 917         }
 918 }
 919
 920 // weapon reloading code
 921
 922 .float reload_ammo_amount, reload_ammo_min, reload_time;
 923 .float reload_complain;
 924 .string reload_sound;
 925
 926 void W_ReloadedAndReady(Weapon thiswep, entity actor, .entity weaponentity, int fire)
 927 {
 928         // finish the reloading process, and do the ammo transfer
 929
 930         actor.clip_load = actor.old_clip_load;  // restore the ammo counter, in case we still had ammo in the weapon before reloading
 931
 932         // if the gun uses no ammo, max out weapon load, else decrease ammo as we increase weapon load
 933         if (!actor.reload_ammo_min || actor.items & IT_UNLIMITED_WEAPON_AMMO || actor.ammo_field == ammo_none)
 934         {
 935                 actor.clip_load = actor.reload_ammo_amount;
 936         }
 937         else
 938         {
 939                 // make sure we don't add more ammo than we have
 940                 float load = min(actor.reload_ammo_amount - actor.clip_load, actor.(actor.ammo_field));
 941                 actor.clip_load += load;
 942                 actor.(actor.ammo_field) -= load;
 943         }
 944         actor.(weapon_load[actor.weapon]) = actor.clip_load;
 945
 946         // do not set ATTACK_FINISHED in reload code any more. This causes annoying delays if eg: You start reloading a weapon,
 947         // then quickly switch to another weapon and back. Reloading is canceled, but the reload delay is still there,
 948         // so your weapon is disabled for a few seconds without reason
 949
 950         // ATTACK_FINISHED(actor, slot) -= actor.reload_time - 1;
 951
 952         Weapon wpn = get_weaponinfo(actor.weapon);
 953         w_ready(wpn, actor, weaponentity, (actor.BUTTON_ATCK ? 1 : 0) | (actor.BUTTON_ATCK2 ? 2 : 0));
 954 }
 955
 956 void W_Reload(entity actor, float sent_ammo_min, string sent_sound)
 957 {
 958         .entity weaponentity = weaponentities[0];
 959         // set global values to work with
 960         entity e = get_weaponinfo(actor.weapon);
 961
 962         if (cvar("g_overkill"))
 963                 if (actor.ok_use_ammocharge) return;
 964         // TODO
 965
 966         actor.reload_ammo_min = sent_ammo_min;
 967         actor.reload_ammo_amount = e.reloading_ammo;
 968         actor.reload_time = e.reloading_time;
 969         actor.reload_sound = sent_sound;
 970
 971         // don't reload weapons that don't have the RELOADABLE flag
 972         if (!(e.spawnflags & WEP_FLAG_RELOADABLE))
 973         {
 974                 LOG_TRACE(
 975                         "Warning: Attempted to reload a weapon that does not have the WEP_FLAG_RELOADABLE flag. Fix your code!\n");
 976                 return;
 977         }
 978
 979         // return if reloading is disabled for this weapon
 980         if (!actor.reload_ammo_amount) return;
 981
 982         // our weapon is fully loaded, no need to reload
 983         if (actor.clip_load >= actor.reload_ammo_amount) return;
 984
 985         // no ammo, so nothing to load
 986         if (actor.ammo_field != ammo_none)
 987         {
 988                 if (!actor.(actor.ammo_field) && actor.reload_ammo_min)
 989                 {
 990                         if (!(actor.items & IT_UNLIMITED_WEAPON_AMMO))
 991                         {
 992                                 if (IS_REAL_CLIENT(actor) && actor.reload_complain < time)
 993                                 {
 994                                         play2(actor, SND(UNAVAILABLE));
 995                                         sprint(actor, strcat("You don't have enough ammo to reload the ^2", WEP_NAME(actor.weapon), "\n"));
 996                                         actor.reload_complain = time + 1;
 997                                 }
 998                                 // switch away if the amount of ammo is not enough to keep using this weapon
 999                                 Weapon w = get_weaponinfo(actor.weapon);
1000                                 if (!(w.wr_checkammo1(w) + w.wr_checkammo2(w)))
1001                                 {
1002                                         actor.clip_load = -1;  // reload later
1003                                         W_SwitchToOtherWeapon(actor);
1004                                 }
1005                                 return;
1006                         }
1007                 }
1008         }
1009
1010         if (actor.(weaponentity))
1011         {
1012                 if (actor.(weaponentity).wframe == WFRAME_RELOAD) return;
1013
1014                 // allow switching away while reloading, but this will cause a new reload!
1015                 actor.(weaponentity).state = WS_READY;
1016         }
1017
1018         // now begin the reloading process
1019
1020         _sound(actor, CH_WEAPON_SINGLE, actor.reload_sound, VOL_BASE, ATTEN_NORM);
1021
1022         // do not set ATTACK_FINISHED in reload code any more. This causes annoying delays if eg: You start reloading a weapon,
1023         // then quickly switch to another weapon and back. Reloading is canceled, but the reload delay is still there,
1024         // so your weapon is disabled for a few seconds without reason
1025
1026         // ATTACK_FINISHED(actor, slot) = max(time, ATTACK_FINISHED(actor, slot)) + actor.reload_time + 1;
1027
1028         weapon_thinkf(actor, weaponentity, WFRAME_RELOAD, actor.reload_time, W_ReloadedAndReady);
1029
1030         if (actor.clip_load < 0) actor.clip_load = 0;
1031         actor.old_clip_load = actor.clip_load;
1032         actor.clip_load = actor.(weapon_load[actor.weapon]) = -1;
1033 }
1034
1035 void W_DropEvent(.void(Weapon) event, entity player, float weapon_type, entity weapon_item)
1036 {
1037         Weapon w = get_weaponinfo(weapon_type);
1038         weapon_dropevent_item = weapon_item;
1039         WITH(entity, self, player, w.event(w));
1040 }