qcsrc/server/weapons/weaponsystem.qc

   1 #include "weaponsystem.qh"
   2
   3 #include "selection.qh"
   4
   5 #include "../command/common.qh"
   6 #include "../mutators/all.qh"
   7 #include "../round_handler.qh"
   8 #include "../t_items.qh"
   9 #include "../../common/animdecide.qh"
  10 #include "../../common/constants.qh"
  11 #include "../../common/monsters/all.qh"
  12 #include "../../common/notifications.qh"
  13 #include "../../common/util.qh"
  14 #include "../../common/weapons/all.qh"
  15 #include "../../lib/csqcmodel/sv_model.qh"
  16
  17 vector shotorg_adjustfromclient(vector vecs, float y_is_right, float algn)
  18 {
  19         switch (algn)
  20         {
  21                 default: case 3: break; // right alignment
  22                 case 4: vecs.y = -vecs.y;
  23                         break;              // left
  24                 case 1: case 2: vecs.y = 0;
  25                         vecs.z -= 2;
  26                         break;              // center
  27         }
  28
  29         return vecs;
  30 }
  31
  32 vector shotorg_adjust_values(vector vecs, bool y_is_right, bool visual, int algn)
  33 {
  34         string s;
  35
  36         if (visual)
  37         {
  38                 vecs = shotorg_adjustfromclient(vecs, y_is_right, algn);
  39         }
  40         else if (autocvar_g_shootfromeye)
  41         {
  42                 vecs.y = vecs.z = 0;
  43         }
  44         else if (autocvar_g_shootfromcenter)
  45         {
  46                 vecs.y = 0;
  47                 vecs.z -= 2;
  48         }
  49         else if ((s = autocvar_g_shootfromfixedorigin) != "")
  50         {
  51                 vector v = stov(s);
  52                 if (y_is_right) v.y = -v.y;
  53                 if (v.x != 0) vecs.x = v.x;
  54                 vecs.y = v.y;
  55                 vecs.z = v.z;
  56         }
  57         else  // just do the same as top
  58         {
  59                 vecs = shotorg_adjustfromclient(vecs, y_is_right, algn);
  60         }
  61
  62         return vecs;
  63 }
  64
  65 vector shotorg_adjust(vector vecs, bool y_is_right, bool visual, int algn)
  66 {
  67         return shotorg_adjust_values(vecs, y_is_right, visual, algn);
  68 }
  69
  70 .int state;
  71
  72 .float weapon_frametime;
  73
  74 float W_WeaponRateFactor()
  75 {
  76         float t = 1.0 / g_weaponratefactor;
  77
  78         MUTATOR_CALLHOOK(WeaponRateFactor, t);
  79         t = weapon_rate;
  80
  81         return t;
  82 }
  83
  84 float W_WeaponSpeedFactor()
  85 {
  86         float t = 1.0 * g_weaponspeedfactor;
  87
  88         MUTATOR_CALLHOOK(WeaponSpeedFactor, t);
  89         t = ret_float;
  90
  91         return t;
  92 }
  93
  94
  95 void weapon_thinkf(entity actor, int slot, float fr, float t,
  96     void(Weapon thiswep, entity actor, int slot, int fire) func);
  97
  98 bool CL_Weaponentity_CustomizeEntityForClient()
  99 {
 100         SELFPARAM();
 101         this.viewmodelforclient = this.owner;
 102         if (IS_SPEC(other) && other.enemy == this.owner) this.viewmodelforclient = other;
 103         return true;
 104 }
 105
 106 /*
 107  * supported formats:
 108  *
 109  * 1. simple animated model, muzzle flash handling on h_ model:
 110  *    h_tuba.dpm, h_tuba.dpm.framegroups - invisible model controlling the animation
 111  *      tags:
 112  *        shot = muzzle end (shot origin, also used for muzzle flashes)
 113  *        shell = casings ejection point (must be on the right hand side of the gun)
 114  *        weapon = attachment for v_tuba.md3
 115  *    v_tuba.md3 - first and third person model
 116  *    g_tuba.md3 - pickup model
 117  *
 118  * 2. simple animated model, muzzle flash handling on v_ model:
 119  *    h_tuba.dpm, h_tuba.dpm.framegroups - invisible model controlling the animation
 120  *      tags:
 121  *        weapon = attachment for v_tuba.md3
 122  *    v_tuba.md3 - first and third person model
 123  *      tags:
 124  *        shot = muzzle end (shot origin, also used for muzzle flashes)
 125  *        shell = casings ejection point (must be on the right hand side of the gun)
 126  *    g_tuba.md3 - pickup model
 127  *
 128  * 3. fully animated model, muzzle flash handling on h_ model:
 129  *    h_tuba.dpm, h_tuba.dpm.framegroups - animated first person model
 130  *      tags:
 131  *        shot = muzzle end (shot origin, also used for muzzle flashes)
 132  *        shell = casings ejection point (must be on the right hand side of the gun)
 133  *        handle = corresponding to the origin of v_tuba.md3 (used for muzzle flashes)
 134  *    v_tuba.md3 - third person model
 135  *    g_tuba.md3 - pickup model
 136  *
 137  * 4. fully animated model, muzzle flash handling on v_ model:
 138  *    h_tuba.dpm, h_tuba.dpm.framegroups - animated first person model
 139  *      tags:
 140  *        shot = muzzle end (shot origin)
 141  *        shell = casings ejection point (must be on the right hand side of the gun)
 142  *    v_tuba.md3 - third person model
 143  *      tags:
 144  *        shot = muzzle end (for muzzle flashes)
 145  *    g_tuba.md3 - pickup model
 146  */
 147
 148 // writes:
 149 //   this.origin, this.angles
 150 //   this.weaponentity
 151 //   this.movedir, this.view_ofs
 152 //   attachment stuff
 153 //   anim stuff
 154 // to free:
 155 //   call again with ""
 156 //   remove the ent
 157 void CL_WeaponEntity_SetModel(entity this, int slot, string name)
 158 {
 159         if (name != "")
 160         {
 161                 // if there is a child entity, hide it until we're sure we use it
 162                 if (this.weaponentity[slot]) this.weaponentity[slot].model = "";
 163                 _setmodel(this, W_Model(strcat("v_", name, ".md3")));
 164                 int v_shot_idx = gettagindex(this, "shot");  // used later
 165                 if (!v_shot_idx) v_shot_idx = gettagindex(this, "tag_shot");
 166
 167                 _setmodel(this, W_Model(strcat("h_", name, ".iqm")));
 168                 // preset some defaults that work great for renamed zym files (which don't need an animinfo)
 169                 this.anim_fire1  = animfixfps(this, '0 1 0.01', '0 0 0');
 170                 this.anim_fire2  = animfixfps(this, '1 1 0.01', '0 0 0');
 171                 this.anim_idle   = animfixfps(this, '2 1 0.01', '0 0 0');
 172                 this.anim_reload = animfixfps(this, '3 1 0.01', '0 0 0');
 173
 174                 // if we have a "weapon" tag, let's attach the v_ model to it ("invisible hand" style model)
 175                 // if we don't, this is a "real" animated model
 176                 if (gettagindex(this, "weapon"))
 177                 {
 178                         if (!this.weaponentity[slot]) this.weaponentity[slot] = new(weaponentity);
 179                         _setmodel(this.weaponentity[slot], W_Model(strcat("v_", name, ".md3")));
 180                         setattachment(this.weaponentity[slot], this, "weapon");
 181                 }
 182                 else if (gettagindex(this, "tag_weapon"))
 183                 {
 184                         if (!this.weaponentity[slot]) this.weaponentity[slot] = new(weaponentity);
 185                         _setmodel(this.weaponentity[slot], W_Model(strcat("v_", name, ".md3")));
 186                         setattachment(this.weaponentity[slot], this, "tag_weapon");
 187                 }
 188                 else
 189                 {
 190                         if (this.weaponentity[slot]) remove(this.weaponentity[slot]);
 191                         this.weaponentity[slot] = NULL;
 192                 }
 193
 194                 setorigin(this, '0 0 0');
 195                 this.angles = '0 0 0';
 196                 this.frame = 0;
 197                 this.viewmodelforclient = NULL;
 198
 199                 float idx;
 200
 201                 if (v_shot_idx)  // v_ model attached to invisible h_ model
 202                 {
 203                         this.movedir = gettaginfo(this.weaponentity[slot], v_shot_idx);
 204                 }
 205                 else
 206                 {
 207                         idx = gettagindex(this, "shot");
 208                         if (!idx) idx = gettagindex(this, "tag_shot");
 209                         if (idx)
 210                         {
 211                                 this.movedir = gettaginfo(this, idx);
 212                         }
 213                         else
 214                         {
 215                                 LOG_INFO("WARNING: weapon model ", this.model,
 216                                         " does not support the 'shot' tag, will display shots TOTALLY wrong\n");
 217                                 this.movedir = '0 0 0';
 218                         }
 219                 }
 220
 221                 if (this.weaponentity[slot])  // v_ model attached to invisible h_ model
 222                 {
 223                         idx = gettagindex(this.weaponentity[slot], "shell");
 224                         if (!idx) idx = gettagindex(this.weaponentity[slot], "tag_shell");
 225                         if (idx) this.spawnorigin = gettaginfo(this.weaponentity[slot], idx);
 226                 }
 227                 else
 228                 {
 229                         idx = 0;
 230                 }
 231                 if (!idx)
 232                 {
 233                         idx = gettagindex(this, "shell");
 234                         if (!idx) idx = gettagindex(this, "tag_shell");
 235                         if (idx)
 236                         {
 237                                 this.spawnorigin = gettaginfo(this, idx);
 238                         }
 239                         else
 240                         {
 241                                 LOG_INFO("WARNING: weapon model ", this.model,
 242                                         " does not support the 'shell' tag, will display casings wrong\n");
 243                                 this.spawnorigin = this.movedir;
 244                         }
 245                 }
 246
 247                 if (v_shot_idx)
 248                 {
 249                         this.oldorigin = '0 0 0';  // use regular attachment
 250                 }
 251                 else
 252                 {
 253                         if (this.weaponentity[slot])
 254                         {
 255                                 idx = gettagindex(this, "weapon");
 256                                 if (!idx) idx = gettagindex(this, "tag_weapon");
 257                         }
 258                         else
 259                         {
 260                                 idx = gettagindex(this, "handle");
 261                                 if (!idx) idx = gettagindex(this, "tag_handle");
 262                         }
 263                         if (idx)
 264                         {
 265                                 this.oldorigin = this.movedir - gettaginfo(this, idx);
 266                         }
 267                         else
 268                         {
 269                                 LOG_INFO("WARNING: weapon model ", this.model,
 270                                         " does not support the 'handle' tag and neither does the v_ model support the 'shot' tag, will display muzzle flashes TOTALLY wrong\n");
 271                                 this.oldorigin = '0 0 0';  // there is no way to recover from this
 272                         }
 273                 }
 274
 275                 this.viewmodelforclient = this.owner;
 276         }
 277         else
 278         {
 279                 this.model = "";
 280                 if (this.weaponentity[slot]) remove(this.weaponentity[slot]);
 281                 this.weaponentity[slot] = NULL;
 282                 this.movedir = '0 0 0';
 283                 this.spawnorigin = '0 0 0';
 284                 this.oldorigin = '0 0 0';
 285                 this.anim_fire1  = '0 1 0.01';
 286                 this.anim_fire2  = '0 1 0.01';
 287                 this.anim_idle   = '0 1 0.01';
 288                 this.anim_reload = '0 1 0.01';
 289         }
 290
 291         this.view_ofs = '0 0 0';
 292
 293         if (this.movedir.x >= 0)
 294         {
 295                 vector v0 = this.movedir;
 296                 this.movedir = shotorg_adjust(v0, false, false, this.owner.cvar_cl_gunalign);
 297                 this.view_ofs = shotorg_adjust(v0, false, true, this.owner.cvar_cl_gunalign) - v0;
 298         }
 299         this.owner.stat_shotorg = compressShotOrigin(this.movedir);
 300         this.movedir = decompressShotOrigin(this.owner.stat_shotorg); // make them match perfectly
 301
 302         this.spawnorigin += this.view_ofs;                            // offset the casings origin by the same amount
 303
 304         // check if an instant weapon switch occurred
 305         setorigin(this, this.view_ofs);
 306         // reset animstate now
 307         this.wframe = WFRAME_IDLE;
 308         setanim(this, this.anim_idle, true, false, true);
 309 }
 310
 311 vector CL_Weapon_GetShotOrg(float wpn)
 312 {
 313         entity wi = get_weaponinfo(wpn);
 314         entity e = spawn();
 315         CL_WeaponEntity_SetModel(e, 0, wi.mdl);
 316         vector ret = e.movedir;
 317         CL_WeaponEntity_SetModel(e, 0, "");
 318         remove(e);
 319         return ret;
 320 }
 321
 322 void CL_Weaponentity_Think()
 323 {
 324         SELFPARAM();
 325         this.nextthink = time;
 326         if (intermission_running) this.frame = this.anim_idle.x;
 327         int slot = 0; // TODO: unhardcode
 328         if (this.owner.weaponentity[slot] != this)
 329         {
 330                 if (this.weaponentity[slot]) remove(this.weaponentity[slot]);
 331                 remove(this);
 332                 return;
 333         }
 334         if (this.owner.deadflag != DEAD_NO)
 335         {
 336                 this.model = "";
 337                 if (this.weaponentity[slot]) this.weaponentity[slot].model = "";
 338                 return;
 339         }
 340         if (this.weaponname != this.owner.weaponname || this.dmg != this.owner.modelindex
 341             || this.deadflag != this.owner.deadflag)
 342         {
 343                 this.weaponname = this.owner.weaponname;
 344                 this.dmg = this.owner.modelindex;
 345                 this.deadflag = this.owner.deadflag;
 346
 347                 CL_WeaponEntity_SetModel(this, slot, this.owner.weaponname);
 348         }
 349
 350         int tb = (this.effects & (EF_TELEPORT_BIT | EF_RESTARTANIM_BIT));
 351         this.effects = this.owner.effects & EFMASK_CHEAP;
 352         this.effects &= ~EF_LOWPRECISION;
 353         this.effects &= ~EF_FULLBRIGHT;  // can mask team color, so get rid of it
 354         this.effects &= ~EF_TELEPORT_BIT;
 355         this.effects &= ~EF_RESTARTANIM_BIT;
 356         this.effects |= tb;
 357
 358         if (this.owner.alpha == default_player_alpha) this.alpha = default_weapon_alpha;
 359         else if (this.owner.alpha != 0) this.alpha = this.owner.alpha;
 360         else this.alpha = 1;
 361
 362         this.glowmod = this.owner.weaponentity_glowmod;
 363         this.colormap = this.owner.colormap;
 364         if (this.weaponentity[slot])
 365         {
 366                 this.weaponentity[slot].effects = this.effects;
 367                 this.weaponentity[slot].alpha = this.alpha;
 368                 this.weaponentity[slot].colormap = this.colormap;
 369                 this.weaponentity[slot].glowmod = this.glowmod;
 370         }
 371
 372         this.angles = '0 0 0';
 373
 374         float f = (this.owner.weapon_nextthink - time);
 375         if (this.state == WS_RAISE && !intermission_running)
 376         {
 377                 entity newwep = get_weaponinfo(this.owner.switchweapon);
 378                 f = f * g_weaponratefactor / max(f, newwep.switchdelay_raise);
 379                 this.angles_x = -90 * f * f;
 380         }
 381         else if (this.state == WS_DROP && !intermission_running)
 382         {
 383                 entity oldwep = get_weaponinfo(this.owner.weapon);
 384                 f = 1 - f * g_weaponratefactor / max(f, oldwep.switchdelay_drop);
 385                 this.angles_x = -90 * f * f;
 386         }
 387         else if (this.state == WS_CLEAR)
 388         {
 389                 f = 1;
 390                 this.angles_x = -90 * f * f;
 391         }
 392 }
 393
 394 void CL_ExteriorWeaponentity_Think()
 395 {
 396         SELFPARAM();
 397         this.nextthink = time;
 398         if (this.owner.exteriorweaponentity != this)
 399         {
 400                 remove(this);
 401                 return;
 402         }
 403         if (this.owner.deadflag != DEAD_NO)
 404         {
 405                 this.model = "";
 406                 return;
 407         }
 408         if (this.weaponname != this.owner.weaponname || this.dmg != this.owner.modelindex
 409             || this.deadflag != this.owner.deadflag)
 410         {
 411                 this.weaponname = this.owner.weaponname;
 412                 this.dmg = this.owner.modelindex;
 413                 this.deadflag = this.owner.deadflag;
 414                 if (this.owner.weaponname != "") _setmodel(this, W_Model(strcat("v_", this.owner.weaponname, ".md3")));
 415                 else this.model = "";
 416
 417                 int tag_found;
 418                 if ((tag_found = gettagindex(this.owner, "tag_weapon")))
 419                 {
 420                         this.tag_index = tag_found;
 421                         this.tag_entity = this.owner;
 422                 }
 423                 else
 424                 {
 425                         setattachment(this, this.owner, "bip01 r hand");
 426                 }
 427         }
 428         this.effects = this.owner.effects;
 429         this.effects |= EF_LOWPRECISION;
 430         this.effects = this.effects & EFMASK_CHEAP;  // eat performance
 431         if (this.owner.alpha == default_player_alpha) this.alpha = default_weapon_alpha;
 432         else if (this.owner.alpha != 0) this.alpha = this.owner.alpha;
 433         else this.alpha = 1;
 434
 435         this.glowmod = this.owner.weaponentity_glowmod;
 436         this.colormap = this.owner.colormap;
 437
 438         CSQCMODEL_AUTOUPDATE(this);
 439 }
 440
 441 // spawning weaponentity for client
 442 void CL_SpawnWeaponentity(entity e, int slot)
 443 {
 444         entity view = e.weaponentity[slot] = new(weaponentity);
 445         make_pure(view);
 446         view.solid = SOLID_NOT;
 447         view.owner = e;
 448         setmodel(view, MDL_Null);  // precision set when changed
 449         setorigin(view, '0 0 0');
 450         view.angles = '0 0 0';
 451         view.viewmodelforclient = e;
 452         view.flags = 0;
 453         view.think = CL_Weaponentity_Think;
 454         view.customizeentityforclient = CL_Weaponentity_CustomizeEntityForClient;
 455         view.nextthink = time;
 456
 457         if (slot == 0)
 458         {
 459                 entity exterior = e.exteriorweaponentity = new(exteriorweaponentity);
 460                 make_pure(exterior);
 461                 exterior.solid = SOLID_NOT;
 462                 exterior.exteriorweaponentity = exterior;
 463                 exterior.owner = e;
 464                 setorigin(exterior, '0 0 0');
 465                 exterior.angles = '0 0 0';
 466                 exterior.think = CL_ExteriorWeaponentity_Think;
 467                 exterior.nextthink = time;
 468
 469                 CSQCMODEL_AUTOINIT(exterior);
 470         }
 471 }
 472
 473 // Weapon subs
 474 void w_clear(Weapon thiswep, entity actor, int slot, int fire)
 475 {
 476         if (actor.weapon != -1)
 477         {
 478                 actor.weapon = 0;
 479                 actor.switchingweapon = 0;
 480         }
 481         if (actor.weaponentity[slot])
 482         {
 483                 actor.weaponentity[slot].state = WS_CLEAR;
 484                 actor.weaponentity[slot].effects = 0;
 485         }
 486 }
 487
 488 void w_ready(Weapon thiswep, entity actor, int slot, int fire)
 489 {
 490         if (actor.weaponentity[slot]) actor.weaponentity[slot].state = WS_READY;
 491         weapon_thinkf(actor, slot, WFRAME_IDLE, 1000000, w_ready);
 492 }
 493
 494 .float prevdryfire;
 495 .float prevwarntime;
 496 bool weapon_prepareattack_checkammo(Weapon thiswep, entity actor, bool secondary)
 497 {
 498         if ((actor.items & IT_UNLIMITED_WEAPON_AMMO)) return true;
 499         bool ammo = false;
 500         if (secondary) WITH(entity, self, actor, ammo = thiswep.wr_checkammo2(thiswep));
 501         else WITH(entity, self, actor, ammo = thiswep.wr_checkammo1(thiswep));
 502         if (ammo) return true;
 503         // always keep the Mine Layer if we placed mines, so that we can detonate them
 504         if (thiswep == WEP_MINE_LAYER)
 505                 for (entity mine; (mine = find(mine, classname, "mine")); )
 506                         if (mine.owner == actor) return false;
 507
 508         if (thiswep == WEP_SHOTGUN)
 509                 if (!secondary && WEP_CVAR(shotgun, secondary) == 1) return false;             // no clicking, just allow
 510
 511         if (thiswep == get_weaponinfo(actor.switchweapon) && time - actor.prevdryfire > 1) // only play once BEFORE starting to switch weapons
 512         {
 513                 sound(actor, CH_WEAPON_A, SND_DRYFIRE, VOL_BASE, ATTEN_NORM);
 514                 actor.prevdryfire = time;
 515         }
 516
 517         // check if the other firing mode has enough ammo
 518         bool ammo_other = false;
 519         if (secondary) WITH(entity, self, actor, ammo_other = thiswep.wr_checkammo1(thiswep));
 520         else WITH(entity, self, actor, ammo_other = thiswep.wr_checkammo2(thiswep));
 521         if (ammo_other)
 522         {
 523                 if (time - actor.prevwarntime > 1)
 524                 {
 525                         Send_Notification(
 526                                 NOTIF_ONE,
 527                                 actor,
 528                                 MSG_MULTI,
 529                                 ITEM_WEAPON_PRIMORSEC,
 530                                 thiswep.m_id,
 531                                 secondary,
 532                                 (1 - secondary)
 533                                          );
 534                 }
 535                 actor.prevwarntime = time;
 536         }
 537         else  // this weapon is totally unable to fire, switch to another one
 538         {
 539                 W_SwitchToOtherWeapon(actor);
 540         }
 541
 542         return false;
 543 }
 544
 545 .float race_penalty;
 546 bool weapon_prepareattack_check(Weapon thiswep, entity actor, int slot, bool secondary, float attacktime)
 547 {
 548         if (!weapon_prepareattack_checkammo(thiswep, actor, secondary)) return false;
 549
 550         // if sv_ready_restart_after_countdown is set, don't allow the player to shoot
 551         // if all players readied up and the countdown is running
 552         if (time < game_starttime || time < actor.race_penalty) return false;
 553
 554         if (timeout_status == TIMEOUT_ACTIVE)  // don't allow the player to shoot while game is paused
 555                 return false;
 556
 557         // do not even think about shooting if switching
 558         if (actor.switchweapon != actor.weapon) return false;
 559
 560         if (attacktime >= 0)
 561         {
 562                 // don't fire if previous attack is not finished
 563                 if (ATTACK_FINISHED(actor, slot) > time + actor.weapon_frametime * 0.5) return false;
 564                 // don't fire while changing weapon
 565                 if (actor.weaponentity[slot].state != WS_READY) return false;
 566         }
 567         return true;
 568 }
 569
 570 void weapon_prepareattack_do(entity actor, int slot, bool secondary, float attacktime)
 571 {
 572         actor.weaponentity[slot].state = WS_INUSE;
 573
 574         actor.spawnshieldtime = min(actor.spawnshieldtime, time);  // kill spawn shield when you fire
 575
 576         // if the weapon hasn't been firing continuously, reset the timer
 577         if (attacktime >= 0)
 578         {
 579                 if (ATTACK_FINISHED(actor, slot) < time - actor.weapon_frametime * 1.5)
 580                 {
 581                         ATTACK_FINISHED(actor, slot) = time;
 582                         // dprint("resetting attack finished to ", ftos(time), "\n");
 583                 }
 584                 ATTACK_FINISHED(actor, slot) = ATTACK_FINISHED(actor, slot) + attacktime * W_WeaponRateFactor();
 585         }
 586         actor.bulletcounter += 1;
 587         // dprint("attack finished ", ftos(ATTACK_FINISHED(actor, slot)), "\n");
 588 }
 589
 590 bool weapon_prepareattack(Weapon thiswep, entity actor, int slot, bool secondary, float attacktime)
 591 {
 592         if (weapon_prepareattack_check(thiswep, actor, slot, secondary, attacktime))
 593         {
 594                 weapon_prepareattack_do(actor, slot, secondary, attacktime);
 595                 return true;
 596         }
 597         return false;
 598 }
 599
 600 void weapon_thinkf(entity actor, int slot, float fr, float t,
 601         void(Weapon thiswep, entity actor, int slot, int fire) func)
 602 {
 603         bool restartanim;
 604         if (fr == WFRAME_DONTCHANGE)
 605         {
 606                 fr = actor.weaponentity[slot].wframe;
 607                 restartanim = false;
 608         }
 609         else if (fr == WFRAME_IDLE)
 610         {
 611                 restartanim = false;
 612         }
 613         else
 614         {
 615                 restartanim = true;
 616         }
 617
 618         vector of = v_forward;
 619         vector or = v_right;
 620         vector ou = v_up;
 621
 622         if (actor.weaponentity[slot])
 623         {
 624                 actor.weaponentity[slot].wframe = fr;
 625                 vector a = '0 0 0';
 626                 if (fr == WFRAME_IDLE) a = actor.weaponentity[slot].anim_idle;
 627                 else if (fr == WFRAME_FIRE1) a = actor.weaponentity[slot].anim_fire1;
 628                 else if (fr == WFRAME_FIRE2) a = actor.weaponentity[slot].anim_fire2;
 629                 else  // if (fr == WFRAME_RELOAD)
 630                         a = actor.weaponentity[slot].anim_reload;
 631                 a.z *= g_weaponratefactor;
 632                 setanim(actor.weaponentity[slot], a, restartanim == false, restartanim, restartanim);
 633         }
 634
 635         v_forward = of;
 636         v_right = or;
 637         v_up = ou;
 638
 639         if (actor.weapon_think == w_ready && func != w_ready && actor.weaponentity[slot].state == WS_RAISE) backtrace(
 640                         "Tried to override initial weapon think function - should this really happen?");
 641
 642         t *= W_WeaponRateFactor();
 643
 644         // VorteX: haste can be added here
 645         if (actor.weapon_think == w_ready)
 646         {
 647                 actor.weapon_nextthink = time;
 648                 // dprint("started firing at ", ftos(time), "\n");
 649         }
 650         if (actor.weapon_nextthink < time - actor.weapon_frametime * 1.5
 651             || actor.weapon_nextthink > time + actor.weapon_frametime * 1.5)
 652         {
 653                 actor.weapon_nextthink = time;
 654                 // dprint("reset weapon animation timer at ", ftos(time), "\n");
 655         }
 656         actor.weapon_nextthink = actor.weapon_nextthink + t;
 657         actor.weapon_think = func;
 658         // dprint("next ", ftos(actor.weapon_nextthink), "\n");
 659
 660         if ((fr == WFRAME_FIRE1 || fr == WFRAME_FIRE2) && t)
 661         {
 662                 if ((actor.weapon == WEP_SHOCKWAVE.m_id || actor.weapon == WEP_SHOTGUN.m_id)
 663                     && fr == WFRAME_FIRE2) animdecide_setaction(actor, ANIMACTION_MELEE, restartanim);
 664                 else animdecide_setaction(actor, ANIMACTION_SHOOT, restartanim);
 665         }
 666         else
 667         {
 668                 if (actor.anim_upper_action == ANIMACTION_SHOOT
 669                     || actor.anim_upper_action == ANIMACTION_MELEE) actor.anim_upper_action = 0;
 670         }
 671 }
 672
 673 bool forbidWeaponUse(entity player)
 674 {
 675         if (time < game_starttime && !autocvar_sv_ready_restart_after_countdown) return true;
 676         if (round_handler_IsActive() && !round_handler_IsRoundStarted()) return true;
 677         if (player.player_blocked) return true;
 678         if (player.frozen) return true;
 679         if (player.weapon_blocked) return true;
 680         return false;
 681 }
 682
 683 .bool hook_switchweapon;
 684
 685 void W_WeaponFrame(entity actor)
 686 {
 687         int slot = 0; // TODO: unhardcode
 688         if (frametime) actor.weapon_frametime = frametime;
 689
 690         if (!actor.weaponentity[slot] || actor.health < 1) return;  // Dead player can't use weapons and injure impulse commands
 691
 692         if (forbidWeaponUse(actor))
 693         {
 694                 if (actor.weaponentity[slot].state != WS_CLEAR)
 695                 {
 696                         Weapon wpn = get_weaponinfo(actor.weapon);
 697                         w_ready(wpn, actor, 0, (actor.BUTTON_ATCK ? 1 : 0) | (actor.BUTTON_ATCK2 ? 2 : 0));
 698                         return;
 699                 }
 700         }
 701
 702         if (!actor.switchweapon)
 703         {
 704                 actor.weapon = 0;
 705                 actor.switchingweapon = 0;
 706                 actor.weaponentity[slot].state = WS_CLEAR;
 707                 actor.weaponname = "";
 708                 // actor.items &= ~IT_AMMO;
 709                 return;
 710         }
 711
 712         makevectors(actor.v_angle);
 713         vector fo = v_forward;  // save them in case the weapon think functions change it
 714         vector ri = v_right;
 715         vector up = v_up;
 716
 717         // Change weapon
 718         if (actor.weapon != actor.switchweapon)
 719         {
 720                 if (actor.weaponentity[slot].state == WS_CLEAR)
 721                 {
 722                         // end switching!
 723                         actor.switchingweapon = actor.switchweapon;
 724                         entity newwep = get_weaponinfo(actor.switchweapon);
 725
 726                         // the two weapon entities will notice this has changed and update their models
 727                         actor.weapon = actor.switchweapon;
 728                         actor.weaponname = newwep.mdl;
 729                         actor.bulletcounter = 0;
 730                         actor.ammo_field = newwep.ammo_field;
 731                         Weapon w = get_weaponinfo(actor.switchweapon);
 732                         w.wr_setup(w);
 733                         actor.weaponentity[slot].state = WS_RAISE;
 734
 735                         // set our clip load to the load of the weapon we switched to, if it's reloadable
 736                         if (newwep.spawnflags & WEP_FLAG_RELOADABLE && newwep.reloading_ammo)  // prevent accessing undefined cvars
 737                         {
 738                                 actor.clip_load = actor.(weapon_load[actor.switchweapon]);
 739                                 actor.clip_size = newwep.reloading_ammo;
 740                         }
 741                         else
 742                         {
 743                                 actor.clip_load = actor.clip_size = 0;
 744                         }
 745
 746                         weapon_thinkf(actor, slot, WFRAME_IDLE, newwep.switchdelay_raise, w_ready);
 747                 }
 748                 else if (actor.weaponentity[slot].state == WS_DROP)
 749                 {
 750                         // in dropping phase we can switch at any time
 751                         actor.switchingweapon = actor.switchweapon;
 752                 }
 753                 else if (actor.weaponentity[slot].state == WS_READY)
 754                 {
 755                         // start switching!
 756                         actor.switchingweapon = actor.switchweapon;
 757                         entity oldwep = get_weaponinfo(actor.weapon);
 758
 759                         // set up weapon switch think in the future, and start drop anim
 760                         if (
 761 #if INDEPENDENT_ATTACK_FINISHED
 762                                     true
 763 #else
 764                                     ATTACK_FINISHED(actor, slot) <= time + actor.weapon_frametime * 0.5
 765 #endif
 766                            )
 767                         {
 768                                 sound(actor, CH_WEAPON_SINGLE, SND_WEAPON_SWITCH, VOL_BASE, ATTN_NORM);
 769                                 actor.weaponentity[slot].state = WS_DROP;
 770                                 weapon_thinkf(actor, slot, WFRAME_DONTCHANGE, oldwep.switchdelay_drop, w_clear);
 771                         }
 772                 }
 773         }
 774
 775         // LordHavoc: network timing test code
 776         // if (actor.button0)
 777         //      print(ftos(frametime), " ", ftos(time), " >= ", ftos(ATTACK_FINISHED(actor, slot)), " >= ", ftos(actor.weapon_nextthink), "\n");
 778
 779         int w = actor.weapon;
 780
 781         // call the think code which may fire the weapon
 782         // and do so multiple times to resolve framerate dependency issues if the
 783         // server framerate is very low and the weapon fire rate very high
 784         int c = 0;
 785         while (c < W_TICSPERFRAME)
 786         {
 787                 c += 1;
 788                 if (w && !(actor.weapons & WepSet_FromWeapon(w)))
 789                 {
 790                         if (actor.weapon == actor.switchweapon) W_SwitchWeapon_Force(actor, w_getbestweapon(actor));
 791                         w = 0;
 792                 }
 793
 794                 v_forward = fo;
 795                 v_right = ri;
 796                 v_up = up;
 797
 798                 bool block_weapon = false;
 799                 {
 800                         bool key_pressed = actor.BUTTON_HOOK && !actor.vehicle;
 801                         Weapon off = actor.offhand;
 802                         if (off && !(actor.weapons & WEPSET(HOOK)))
 803                         {
 804                                 if (off.offhand_think) off.offhand_think(off, actor, key_pressed);
 805                         }
 806                         else
 807                         {
 808                                 if (key_pressed && actor.switchweapon != WEP_HOOK.m_id && !actor.hook_switchweapon) W_SwitchWeapon(
 809                                                 WEP_HOOK.m_id);
 810                                 actor.hook_switchweapon = key_pressed;
 811                                 Weapon h = WEP_HOOK;
 812                                 block_weapon = (actor.weapon == h.m_id && (actor.BUTTON_ATCK || key_pressed));
 813                                 h.wr_think(h, actor, 0, block_weapon ? 1 : 0);
 814                         }
 815                 }
 816
 817                 if (!block_weapon)
 818                 {
 819                         if (w)
 820                         {
 821                                 Weapon e = get_weaponinfo(actor.weapon);
 822                                 e.wr_think(e, actor, 0, (actor.BUTTON_ATCK ? 1 : 0) | (actor.BUTTON_ATCK2 ? 2 : 0));
 823                         }
 824                         else
 825                         {
 826                                 Weapon w = get_weaponinfo(actor.weapon);
 827                                 w.wr_gonethink(w);
 828                         }
 829                 }
 830
 831                 if (time + actor.weapon_frametime * 0.5 >= actor.weapon_nextthink)
 832                 {
 833                         if (actor.weapon_think)
 834                         {
 835                                 v_forward = fo;
 836                                 v_right = ri;
 837                                 v_up = up;
 838                                 Weapon wpn = get_weaponinfo(actor.weapon);
 839                                 actor.weapon_think(wpn, actor, 0, (actor.BUTTON_ATCK ? 1 : 0) | (actor.BUTTON_ATCK2 ? 2 : 0));
 840                         }
 841                         else
 842                         {
 843                                 bprint("\{1}^1ERROR: undefined weapon think function for ", actor.netname, "\n");
 844                         }
 845                 }
 846         }
 847 }
 848
 849 void W_AttachToShotorg(entity actor, entity flash, vector offset)
 850 {
 851         int slot = 0;
 852         flash.owner = actor;
 853         flash.angles_z = random() * 360;
 854
 855         if (gettagindex(actor.weaponentity[slot], "shot")) setattachment(flash, actor.weaponentity[slot], "shot");
 856         else setattachment(flash, actor.weaponentity[slot], "tag_shot");
 857         setorigin(flash, offset);
 858
 859         entity xflash = spawn();
 860         copyentity(flash, xflash);
 861
 862         flash.viewmodelforclient = actor;
 863
 864         if (actor.weaponentity[slot].oldorigin.x > 0)
 865         {
 866                 setattachment(xflash, actor.exteriorweaponentity, "");
 867                 setorigin(xflash, actor.weaponentity[slot].oldorigin + offset);
 868         }
 869         else
 870         {
 871                 if (gettagindex(actor.exteriorweaponentity, "shot")) setattachment(xflash, actor.exteriorweaponentity, "shot");
 872                 else setattachment(xflash, actor.exteriorweaponentity, "tag_shot");
 873                 setorigin(xflash, offset);
 874         }
 875 }
 876
 877 void W_DecreaseAmmo(Weapon wep, entity actor, float ammo_use)
 878 {
 879         if (cvar("g_overkill"))
 880         {
 881                 if (actor.ok_use_ammocharge)
 882                 {
 883                         ok_DecreaseCharge(actor, actor.weapon);
 884                         return;  // TODO
 885                 }
 886         }
 887
 888         if ((actor.items & IT_UNLIMITED_WEAPON_AMMO) && !wep.reloading_ammo) return;
 889
 890         // if this weapon is reloadable, decrease its load. Else decrease the player's ammo
 891         if (wep.reloading_ammo)
 892         {
 893                 actor.clip_load -= ammo_use;
 894                 actor.(weapon_load[actor.weapon]) = actor.clip_load;
 895         }
 896         else if (wep.ammo_field != ammo_none)
 897         {
 898                 actor.(wep.ammo_field) -= ammo_use;
 899                 if (actor.(wep.ammo_field) < 0)
 900                 {
 901                         backtrace(sprintf(
 902                                 "W_DecreaseAmmo(%.2f): '%s' subtracted too much %s from '%s', resulting with '%.2f' left... "
 903                                 "Please notify Samual immediately with a copy of this backtrace!\n",
 904                                 ammo_use,
 905                                 wep.netname,
 906                                 GetAmmoPicture(wep.ammo_field),
 907                                 actor.netname,
 908                                 actor.(wep.ammo_field)
 909                                              ));
 910                 }
 911         }
 912 }
 913
 914 // weapon reloading code
 915
 916 .float reload_ammo_amount, reload_ammo_min, reload_time;
 917 .float reload_complain;
 918 .string reload_sound;
 919
 920 void W_ReloadedAndReady(Weapon thiswep, entity actor, int slot, int fire)
 921 {
 922         // finish the reloading process, and do the ammo transfer
 923
 924         actor.clip_load = actor.old_clip_load;  // restore the ammo counter, in case we still had ammo in the weapon before reloading
 925
 926         // if the gun uses no ammo, max out weapon load, else decrease ammo as we increase weapon load
 927         if (!actor.reload_ammo_min || actor.items & IT_UNLIMITED_WEAPON_AMMO || actor.ammo_field == ammo_none)
 928         {
 929                 actor.clip_load = actor.reload_ammo_amount;
 930         }
 931         else
 932         {
 933                 // make sure we don't add more ammo than we have
 934                 float load = min(actor.reload_ammo_amount - actor.clip_load, actor.(actor.ammo_field));
 935                 actor.clip_load += load;
 936                 actor.(actor.ammo_field) -= load;
 937         }
 938         actor.(weapon_load[actor.weapon]) = actor.clip_load;
 939
 940         // do not set ATTACK_FINISHED in reload code any more. This causes annoying delays if eg: You start reloading a weapon,
 941         // then quickly switch to another weapon and back. Reloading is canceled, but the reload delay is still there,
 942         // so your weapon is disabled for a few seconds without reason
 943
 944         // ATTACK_FINISHED(actor, slot) -= actor.reload_time - 1;
 945
 946         Weapon wpn = get_weaponinfo(actor.weapon);
 947         w_ready(wpn, actor, slot, (actor.BUTTON_ATCK ? 1 : 0) | (actor.BUTTON_ATCK2 ? 2 : 0));
 948 }
 949
 950 void W_Reload(entity actor, float sent_ammo_min, string sent_sound)
 951 {
 952         int slot = 0;
 953         // set global values to work with
 954         entity e = get_weaponinfo(actor.weapon);
 955
 956         if (cvar("g_overkill"))
 957                 if (actor.ok_use_ammocharge) return;
 958         // TODO
 959
 960         actor.reload_ammo_min = sent_ammo_min;
 961         actor.reload_ammo_amount = e.reloading_ammo;
 962         actor.reload_time = e.reloading_time;
 963         actor.reload_sound = sent_sound;
 964
 965         // don't reload weapons that don't have the RELOADABLE flag
 966         if (!(e.spawnflags & WEP_FLAG_RELOADABLE))
 967         {
 968                 LOG_TRACE(
 969                         "Warning: Attempted to reload a weapon that does not have the WEP_FLAG_RELOADABLE flag. Fix your code!\n");
 970                 return;
 971         }
 972
 973         // return if reloading is disabled for this weapon
 974         if (!actor.reload_ammo_amount) return;
 975
 976         // our weapon is fully loaded, no need to reload
 977         if (actor.clip_load >= actor.reload_ammo_amount) return;
 978
 979         // no ammo, so nothing to load
 980         if (actor.ammo_field != ammo_none)
 981         {
 982                 if (!actor.(actor.ammo_field) && actor.reload_ammo_min)
 983                 {
 984                         if (!(actor.items & IT_UNLIMITED_WEAPON_AMMO))
 985                         {
 986                                 if (IS_REAL_CLIENT(actor) && actor.reload_complain < time)
 987                                 {
 988                                         play2(actor, SND(UNAVAILABLE));
 989                                         sprint(actor, strcat("You don't have enough ammo to reload the ^2", WEP_NAME(actor.weapon), "\n"));
 990                                         actor.reload_complain = time + 1;
 991                                 }
 992                                 // switch away if the amount of ammo is not enough to keep using this weapon
 993                                 Weapon w = get_weaponinfo(actor.weapon);
 994                                 if (!(w.wr_checkammo1(w) + w.wr_checkammo2(w)))
 995                                 {
 996                                         actor.clip_load = -1;  // reload later
 997                                         W_SwitchToOtherWeapon(actor);
 998                                 }
 999                                 return;
1000                         }
1001                 }
1002         }
1003
1004         if (actor.weaponentity[slot])
1005         {
1006                 if (actor.weaponentity[slot].wframe == WFRAME_RELOAD) return;
1007
1008                 // allow switching away while reloading, but this will cause a new reload!
1009                 actor.weaponentity[slot].state = WS_READY;
1010         }
1011
1012         // now begin the reloading process
1013
1014         _sound(actor, CH_WEAPON_SINGLE, actor.reload_sound, VOL_BASE, ATTEN_NORM);
1015
1016         // do not set ATTACK_FINISHED in reload code any more. This causes annoying delays if eg: You start reloading a weapon,
1017         // then quickly switch to another weapon and back. Reloading is canceled, but the reload delay is still there,
1018         // so your weapon is disabled for a few seconds without reason
1019
1020         // ATTACK_FINISHED(actor, slot) = max(time, ATTACK_FINISHED(actor, slot)) + actor.reload_time + 1;
1021
1022         weapon_thinkf(actor, slot, WFRAME_RELOAD, actor.reload_time, W_ReloadedAndReady);
1023
1024         if (actor.clip_load < 0) actor.clip_load = 0;
1025         actor.old_clip_load = actor.clip_load;
1026         actor.clip_load = actor.(weapon_load[actor.weapon]) = -1;
1027 }
1028
1029 void W_DropEvent(.void(Weapon) event, entity player, float weapon_type, entity weapon_item)
1030 {
1031         Weapon w = get_weaponinfo(weapon_type);
1032         weapon_dropevent_item = weapon_item;
1033         WITH(entity, self, player, w.event(w));
1034 }