qcsrc/server/world.qc

   1 #include "world.qh"
   2
   3 #include <common/constants.qh>
   4 #include <common/deathtypes/all.qh>
   5 #include <common/gamemodes/_mod.qh>
   6 #include <common/gamemodes/sv_rules.qh>
   7 #include <common/items/_mod.qh>
   8 #include <common/mapinfo.qh>
   9 #include <common/mapobjects/target/music.qh>
  10 #include <common/mapobjects/trigger/hurt.qh>
  11 #include <common/mapobjects/trigger/secret.qh>
  12 #include <common/mapobjects/triggers.qh>
  13 #include <common/monsters/_mod.qh>
  14 #include <common/monsters/sv_monsters.qh>
  15 #include <common/net_linked.qh>
  16 #include <common/notifications/all.qh>
  17 #include <common/physics/player.qh>
  18 #include <common/playerstats.qh>
  19 #include <common/state.qh>
  20 #include <common/stats.qh>
  21 #include <common/teams.qh>
  22 #include <common/util.qh>
  23 #include <common/vehicles/all.qh>
  24 #include <common/weapons/_all.qh>
  25 #include <server/anticheat.qh>
  26 #include <server/antilag.qh>
  27 #include <server/bot/api.qh>
  28 #include <server/campaign.qh>
  29 #include <server/cheats.qh>
  30 #include <server/client.qh>
  31 #include <server/command/common.qh>
  32 #include <server/command/getreplies.qh>
  33 #include <server/command/sv_cmd.qh>
  34 #include <server/command/vote.qh>
  35 #include <server/damage.qh>
  36 #include <server/gamelog.qh>
  37 #include <server/hook.qh>
  38 #include <server/intermission.qh>
  39 #include <server/ipban.qh>
  40 #include <server/items/items.qh>
  41 #include <server/main.qh>
  42 #include <server/mapvoting.qh>
  43 #include <server/mutators/_mod.qh>
  44 #include <server/race.qh>
  45 #include <server/scores.qh>
  46 #include <server/scores_rules.qh>
  47 #include <server/spawnpoints.qh>
  48 #include <server/teamplay.qh>
  49 #include <server/weapons/common.qh>
  50 #include <server/weapons/weaponstats.qh>
  51
  52 const float LATENCY_THINKRATE = 10;
  53 .float latency_sum;
  54 .float latency_cnt;
  55 .float latency_time;
  56 entity pingplreport;
  57 void PingPLReport_Think(entity this)
  58 {
  59         float delta;
  60         entity e;
  61
  62         delta = 3 / maxclients;
  63         if(delta < sys_frametime)
  64                 delta = 0;
  65         this.nextthink = time + delta;
  66
  67         e = edict_num(this.cnt + 1);
  68         if(IS_CLIENT(e) && IS_REAL_CLIENT(e))
  69         {
  70                 WriteHeader(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  71                 WriteByte(MSG_BROADCAST, this.cnt);
  72                 WriteShort(MSG_BROADCAST, bound(1, CS(e).ping, 32767));
  73                 WriteByte(MSG_BROADCAST, min(ceil(CS(e).ping_packetloss * 255), 255));
  74                 WriteByte(MSG_BROADCAST, min(ceil(CS(e).ping_movementloss * 255), 255));
  75
  76                 // record latency times for clients throughout the match so we can report it to playerstats
  77                 if(time > (CS(e).latency_time + LATENCY_THINKRATE))
  78                 {
  79                         CS(e).latency_sum += CS(e).ping;
  80                         CS(e).latency_cnt += 1;
  81                         CS(e).latency_time = time;
  82                         //print("sum: ", ftos(CS(e).latency_sum), ", cnt: ", ftos(CS(e).latency_cnt), ", avg: ", ftos(CS(e).latency_sum / CS(e).latency_cnt), ".\n");
  83                 }
  84         }
  85         else
  86         {
  87                 WriteHeader(MSG_BROADCAST, TE_CSQC_PINGPLREPORT);
  88                 WriteByte(MSG_BROADCAST, this.cnt);
  89                 WriteShort(MSG_BROADCAST, 0);
  90                 WriteByte(MSG_BROADCAST, 0);
  91                 WriteByte(MSG_BROADCAST, 0);
  92         }
  93         this.cnt = (this.cnt + 1) % maxclients;
  94 }
  95 void PingPLReport_Spawn()
  96 {
  97         pingplreport = new_pure(pingplreport);
  98         setthink(pingplreport, PingPLReport_Think);
  99         pingplreport.nextthink = time;
 100 }
 101
 102 const float SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS = 1;
 103 float world_initialized;
 104
 105 void SetDefaultAlpha()
 106 {
 107         if (!MUTATOR_CALLHOOK(SetDefaultAlpha))
 108         {
 109                 default_player_alpha = autocvar_g_player_alpha;
 110                 if(default_player_alpha == 0)
 111                         default_player_alpha = 1;
 112                 default_weapon_alpha = default_player_alpha;
 113         }
 114 }
 115
 116 void GotoFirstMap(entity this)
 117 {
 118         float n;
 119         if(autocvar__sv_init)
 120         {
 121                 // cvar_set("_sv_init", "0");
 122                 // we do NOT set this to 0 any more, so someone "accidentally" changing
 123                 // to this "init" map on a dedicated server will cause no permanent
 124                 // harm
 125                 if(autocvar_g_maplist_shuffle)
 126                         ShuffleMaplist();
 127                 n = tokenizebyseparator(autocvar_g_maplist, " ");
 128                 cvar_set("g_maplist_index", ftos(n - 1)); // jump to map 0 in GotoNextMap
 129
 130                 MapInfo_Enumerate();
 131                 MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 132
 133                 if(!DoNextMapOverride(1))
 134                         GotoNextMap(1);
 135
 136                 return;
 137         }
 138
 139         if(time < 5)
 140         {
 141                 this.nextthink = time;
 142         }
 143         else
 144         {
 145                 this.nextthink = time + 1;
 146                 LOG_INFO("Waiting for _sv_init being set to 1 by initialization scripts...");
 147         }
 148 }
 149
 150 void cvar_changes_init()
 151 {
 152         float h;
 153         string k, v, d;
 154         float n, i, adding, pureadding;
 155
 156         strfree(cvar_changes);
 157         strfree(cvar_purechanges);
 158         cvar_purechanges_count = 0;
 159
 160         h = buf_create();
 161         buf_cvarlist(h, "", "_"); // exclude all _ cvars as they are temporary
 162         n = buf_getsize(h);
 163
 164         adding = true;
 165         pureadding = true;
 166
 167         for(i = 0; i < n; ++i)
 168         {
 169                 k = bufstr_get(h, i);
 170
 171 #define BADPREFIX(p) if(substring(k, 0, strlen(p)) == p) continue
 172 #define BADPRESUFFIX(p,s) if(substring(k, 0, strlen(p)) == p && substring(k, -strlen(s), -1) == s) continue
 173 #define BADCVAR(p) if(k == p) continue
 174 #define BADVALUE(p, val) if (k == p && v == val) continue
 175
 176                 // general excludes and namespaces for server admin used cvars
 177                 BADPREFIX("help_"); // PN's server has this listed as changed, let's not rat him out for THAT
 178
 179                 // internal
 180                 BADPREFIX("csqc_");
 181                 BADPREFIX("cvar_check_");
 182                 BADCVAR("gamecfg");
 183                 BADCVAR("g_configversion");
 184                 BADCVAR("halflifebsp");
 185                 BADCVAR("sv_mapformat_is_quake2");
 186                 BADCVAR("sv_mapformat_is_quake3");
 187                 BADPREFIX("sv_world");
 188
 189                 // client
 190                 BADPREFIX("chase_");
 191                 BADPREFIX("cl_");
 192                 BADPREFIX("con_");
 193                 BADPREFIX("scoreboard_");
 194                 BADPREFIX("g_campaign");
 195                 BADPREFIX("g_waypointsprite_");
 196                 BADPREFIX("gl_");
 197                 BADPREFIX("joy");
 198                 BADPREFIX("hud_");
 199                 BADPREFIX("m_");
 200                 BADPREFIX("menu_");
 201                 BADPREFIX("net_slist_");
 202                 BADPREFIX("r_");
 203                 BADPREFIX("sbar_");
 204                 BADPREFIX("scr_");
 205                 BADPREFIX("snd_");
 206                 BADPREFIX("show");
 207                 BADPREFIX("sensitivity");
 208                 BADPREFIX("userbind");
 209                 BADPREFIX("v_");
 210                 BADPREFIX("vid_");
 211                 BADPREFIX("crosshair");
 212                 BADCVAR("mod_q3bsp_lightmapmergepower");
 213                 BADCVAR("mod_q3bsp_nolightmaps");
 214                 BADCVAR("fov");
 215                 BADCVAR("mastervolume");
 216                 BADCVAR("volume");
 217                 BADCVAR("bgmvolume");
 218                 BADCVAR("in_pitch_min");
 219                 BADCVAR("in_pitch_max");
 220
 221                 // private
 222                 BADCVAR("developer");
 223                 BADCVAR("log_dest_udp");
 224                 BADCVAR("net_address");
 225                 BADCVAR("net_address_ipv6");
 226                 BADCVAR("port");
 227                 BADCVAR("savedgamecfg");
 228                 BADCVAR("serverconfig");
 229                 BADCVAR("sv_autoscreenshot");
 230                 BADCVAR("sv_heartbeatperiod");
 231                 BADCVAR("sv_vote_master_password");
 232                 BADCVAR("sys_colortranslation");
 233                 BADCVAR("sys_specialcharactertranslation");
 234                 BADCVAR("timeformat");
 235                 BADCVAR("timestamps");
 236                 BADCVAR("g_require_stats");
 237                 BADPREFIX("developer_");
 238                 BADPREFIX("g_ban_");
 239                 BADPREFIX("g_banned_list");
 240                 BADPREFIX("g_require_stats_");
 241                 BADPREFIX("g_chat_flood_");
 242                 BADPREFIX("g_ghost_items");
 243                 BADPREFIX("g_playerstats_");
 244                 BADPREFIX("g_voice_flood_");
 245                 BADPREFIX("log_file");
 246                 BADPREFIX("quit_");
 247                 BADPREFIX("rcon_");
 248                 BADPREFIX("sv_allowdownloads");
 249                 BADPREFIX("sv_autodemo");
 250                 BADPREFIX("sv_curl_");
 251                 BADPREFIX("sv_eventlog");
 252                 BADPREFIX("sv_logscores_");
 253                 BADPREFIX("sv_master");
 254                 BADPREFIX("sv_weaponstats_");
 255                 BADPREFIX("sv_waypointsprite_");
 256                 BADCVAR("rescan_pending");
 257
 258                 // these can contain player IDs, so better hide
 259                 BADPREFIX("g_forced_team_");
 260                 BADCVAR("sv_muteban_list");
 261                 BADCVAR("sv_voteban_list");
 262                 BADCVAR("sv_allow_customplayermodels_idlist");
 263                 BADCVAR("sv_allow_customplayermodels_speciallist");
 264
 265                 // mapinfo
 266                 BADCVAR("fraglimit");
 267                 BADCVAR("g_arena");
 268                 BADCVAR("g_assault");
 269                 BADCVAR("g_ca");
 270                 BADCVAR("g_ca_teams");
 271                 BADCVAR("g_conquest");
 272                 BADCVAR("g_conquest_teams");
 273                 BADCVAR("g_ctf");
 274                 BADCVAR("g_cts");
 275                 BADCVAR("g_dotc");
 276                 BADCVAR("g_dm");
 277                 BADCVAR("g_domination");
 278                 BADCVAR("g_domination_default_teams");
 279                 BADCVAR("g_duel");
 280                 BADCVAR("g_duel_not_dm_maps");
 281                 BADCVAR("g_freezetag");
 282                 BADCVAR("g_freezetag_teams");
 283                 BADCVAR("g_invasion_teams");
 284                 BADCVAR("g_invasion_type");
 285                 BADCVAR("g_jailbreak");
 286                 BADCVAR("g_jailbreak_teams");
 287                 BADCVAR("g_keepaway");
 288                 BADCVAR("g_keyhunt");
 289                 BADCVAR("g_keyhunt_teams");
 290                 BADCVAR("g_lms");
 291                 BADCVAR("g_nexball");
 292                 BADCVAR("g_onslaught");
 293                 BADCVAR("g_race");
 294                 BADCVAR("g_race_laps_limit");
 295                 BADCVAR("g_race_qualifying_timelimit");
 296                 BADCVAR("g_race_qualifying_timelimit_override");
 297                 BADCVAR("g_runematch");
 298                 BADCVAR("g_shootfromeye");
 299                 BADCVAR("g_snafu");
 300                 BADCVAR("g_survival");
 301                 BADCVAR("g_survival_not_dm_maps");
 302                 BADCVAR("g_tdm");
 303                 BADCVAR("g_tdm_on_dm_maps");
 304                 BADCVAR("g_tdm_teams");
 305                 BADCVAR("g_vip");
 306                 BADCVAR("leadlimit");
 307                 BADCVAR("nextmap");
 308                 BADCVAR("teamplay");
 309                 BADCVAR("timelimit");
 310                 BADCVAR("g_mapinfo_settemp_acl");
 311                 BADCVAR("g_mapinfo_ignore_warnings");
 312                 BADCVAR("g_maplist_ignore_sizes");
 313                 BADCVAR("g_maplist_sizes_count_bots");
 314
 315                 // long
 316                 BADCVAR("hostname");
 317                 BADCVAR("g_maplist");
 318                 BADCVAR("g_maplist_mostrecent");
 319                 BADCVAR("sv_motd");
 320
 321                 v = cvar_string(k);
 322                 d = cvar_defstring(k);
 323                 if(v == d)
 324                         continue;
 325
 326                 if(adding)
 327                 {
 328                         cvar_changes = strcat(cvar_changes, k, " \"", v, "\" // \"", d, "\"\n");
 329                         if(strlen(cvar_changes) > 16384)
 330                         {
 331                                 cvar_changes = "// too many settings have been changed to show them here\n";
 332                                 adding = 0;
 333                         }
 334                 }
 335
 336                 // now check if the changes are actually gameplay relevant
 337
 338                 // does nothing gameplay relevant
 339                 BADCVAR("captureleadlimit_override");
 340                 BADCVAR("condump_stripcolors");
 341                 BADCVAR("gameversion");
 342                 BADCVAR("fs_gamedir");
 343                 BADCVAR("g_allow_oldvortexbeam");
 344                 BADCVAR("g_balance_kill_delay");
 345                 BADCVAR("g_buffs_pickup_anyway");
 346                 BADCVAR("g_buffs_randomize");
 347                 BADCVAR("g_buffs_randomize_teamplay");
 348                 BADCVAR("g_campcheck_distance");
 349                 BADCVAR("g_chatsounds");
 350                 BADCVAR("g_ca_point_leadlimit");
 351                 BADCVAR("g_ca_point_limit");
 352                 BADCVAR("g_ctf_captimerecord_always");
 353                 BADCVAR("g_ctf_flag_glowtrails");
 354                 BADCVAR("g_ctf_dynamiclights");
 355                 BADCVAR("g_ctf_flag_pickup_verbosename");
 356                 BADPRESUFFIX("g_ctf_flag_", "_model");
 357                 BADPRESUFFIX("g_ctf_flag_", "_skin");
 358                 BADCVAR("g_domination_point_leadlimit");
 359                 BADCVAR("g_forced_respawn");
 360                 BADCVAR("g_freezetag_point_leadlimit");
 361                 BADCVAR("g_freezetag_point_limit");
 362                 BADCVAR("g_glowtrails");
 363                 BADCVAR("g_hats");
 364                 BADCVAR("g_casings");
 365                 BADCVAR("g_invasion_point_limit");
 366                 BADCVAR("g_jump_grunt");
 367                 BADCVAR("g_keepaway_ballcarrier_effects");
 368                 BADCVAR("g_keepawayball_effects");
 369                 BADCVAR("g_keyhunt_point_leadlimit");
 370                 BADCVAR("g_nexball_goalleadlimit");
 371                 BADCVAR("g_new_toys_autoreplace");
 372                 BADCVAR("g_new_toys_use_pickupsound");
 373                 BADCVAR("g_physics_predictall");
 374                 BADCVAR("g_piggyback");
 375                 BADCVAR("g_playerclip_collisions");
 376                 BADCVAR("g_spawn_alloweffects");
 377                 BADCVAR("g_tdm_point_leadlimit");
 378                 BADCVAR("g_tdm_point_limit");
 379                 BADCVAR("leadlimit_and_fraglimit");
 380                 BADCVAR("leadlimit_override");
 381                 BADCVAR("pausable");
 382                 BADCVAR("sv_announcer");
 383                 BADCVAR("sv_checkforpacketsduringsleep");
 384                 BADCVAR("sv_damagetext");
 385                 BADCVAR("sv_db_saveasdump");
 386                 BADCVAR("sv_intermission_cdtrack");
 387                 BADCVAR("sv_mapchange_delay");
 388                 BADCVAR("sv_minigames");
 389                 BADCVAR("sv_namechangetimer");
 390                 BADCVAR("sv_precacheplayermodels");
 391                 BADCVAR("sv_radio");
 392                 BADCVAR("sv_stepheight");
 393                 BADCVAR("sv_timeout");
 394                 BADCVAR("sv_weapons_modeloverride");
 395                 BADCVAR("w_prop_interval");
 396                 BADPREFIX("chat_");
 397                 BADPREFIX("crypto_");
 398                 BADPREFIX("gameversion_");
 399                 BADPREFIX("g_chat_");
 400                 BADPREFIX("g_ctf_captimerecord_");
 401                 BADPREFIX("g_hats_");
 402                 BADPREFIX("g_maplist_");
 403                 BADPREFIX("g_mod_");
 404                 BADPREFIX("g_respawn_");
 405                 BADPREFIX("net_");
 406                 BADPREFIX("notification_");
 407                 BADPREFIX("prvm_");
 408                 BADPREFIX("skill_");
 409                 BADPREFIX("sv_allow_");
 410                 BADPREFIX("sv_cullentities_");
 411                 BADPREFIX("sv_maxidle_");
 412                 BADPREFIX("sv_minigames_");
 413                 BADPREFIX("sv_radio_");
 414                 BADPREFIX("sv_timeout_");
 415                 BADPREFIX("sv_vote_");
 416                 BADPREFIX("timelimit_");
 417
 418                 // allowed changes to server admins (please sync this to server.cfg)
 419                 // vi commands:
 420                 //   :/"impure"/,$d
 421                 //   :g!,^\/\/[^ /],d
 422                 //   :%s,//\([^ ]*\).*,BADCVAR("\1");,
 423                 //   :%!sort
 424                 // yes, this does contain some redundant stuff, don't really care
 425                 BADPREFIX("bot_ai_");
 426                 BADCVAR("bot_config_file");
 427                 BADCVAR("bot_number");
 428                 BADCVAR("bot_prefix");
 429                 BADCVAR("bot_suffix");
 430                 BADCVAR("capturelimit_override");
 431                 BADCVAR("fraglimit_override");
 432                 BADCVAR("gametype");
 433                 BADCVAR("g_antilag");
 434                 BADCVAR("g_balance_teams");
 435                 BADCVAR("g_balance_teams_prevent_imbalance");
 436                 BADCVAR("g_balance_teams_scorefactor");
 437                 BADCVAR("g_ban_sync_trusted_servers");
 438                 BADCVAR("g_ban_sync_uri");
 439                 BADCVAR("g_buffs");
 440                 BADCVAR("g_ca_teams_override");
 441                 BADCVAR("g_ctf_fullbrightflags");
 442                 BADCVAR("g_ctf_ignore_frags");
 443                 BADCVAR("g_ctf_leaderboard");
 444                 BADCVAR("g_domination_point_limit");
 445                 BADCVAR("g_domination_teams_override");
 446                 BADCVAR("g_freezetag_teams_override");
 447                 BADCVAR("g_friendlyfire");
 448                 BADCVAR("g_fullbrightitems");
 449                 BADCVAR("g_fullbrightplayers");
 450                 BADCVAR("g_keyhunt_point_limit");
 451                 BADCVAR("g_keyhunt_teams_override");
 452                 BADCVAR("g_lms_lives_override");
 453                 BADCVAR("g_maplist");
 454                 BADCVAR("g_maxplayers");
 455                 BADCVAR("g_mirrordamage");
 456                 BADCVAR("g_nexball_goallimit");
 457                 BADCVAR("g_norecoil");
 458                 BADCVAR("g_physics_clientselect");
 459                 BADCVAR("g_pinata");
 460                 BADCVAR("g_powerups");
 461                 BADCVAR("g_player_brightness");
 462                 BADCVAR("g_rocket_flying");
 463                 BADCVAR("g_rocket_flying_disabledelays");
 464                 BADCVAR("g_spawnshieldtime");
 465                 BADCVAR("g_start_delay");
 466                 BADCVAR("g_superspectate");
 467                 BADCVAR("g_tdm_teams_override");
 468                 BADCVAR("g_warmup");
 469                 BADCVAR("g_weapon_stay"); BADPRESUFFIX("g_", "_weapon_stay");
 470                 BADCVAR("hostname");
 471                 BADCVAR("log_file");
 472                 BADCVAR("maxplayers");
 473                 BADCVAR("minplayers");
 474                 BADCVAR("minplayers_per_team");
 475                 BADCVAR("net_address");
 476                 BADCVAR("port");
 477                 BADCVAR("rcon_password");
 478                 BADCVAR("rcon_restricted_commands");
 479                 BADCVAR("rcon_restricted_password");
 480                 BADCVAR("skill");
 481                 BADCVAR("sv_adminnick");
 482                 BADCVAR("sv_autoscreenshot");
 483                 BADCVAR("sv_autotaunt");
 484                 BADCVAR("sv_curl_defaulturl");
 485                 BADCVAR("sv_defaultcharacter");
 486                 BADCVAR("sv_defaultcharacterskin");
 487                 BADCVAR("sv_defaultplayercolors");
 488                 BADCVAR("sv_defaultplayermodel");
 489                 BADCVAR("sv_defaultplayerskin");
 490                 BADCVAR("sv_maxidle");
 491                 BADCVAR("sv_maxrate");
 492                 BADCVAR("sv_motd");
 493                 BADCVAR("sv_public");
 494                 BADCVAR("sv_ready_restart");
 495                 BADCVAR("sv_showfps");
 496                 BADCVAR("sv_status_privacy");
 497                 BADCVAR("sv_taunt");
 498                 BADCVAR("sv_vote_call");
 499                 BADCVAR("sv_vote_commands");
 500                 BADCVAR("sv_vote_majority_factor");
 501                 BADCVAR("sv_vote_master");
 502                 BADCVAR("sv_vote_master_commands");
 503                 BADCVAR("sv_vote_master_password");
 504                 BADCVAR("sv_vote_simple_majority_factor");
 505                 BADVALUE("sys_ticrate", "0.0166667");
 506                 BADVALUE("sys_ticrate", "0.0333333");
 507                 BADCVAR("teamplay_mode");
 508                 BADCVAR("timelimit_override");
 509                 BADPREFIX("g_warmup_");
 510                 BADPREFIX("sv_info_");
 511                 BADPREFIX("sv_ready_restart_");
 512
 513                 // mutators that announce themselves properly to the server browser
 514                 BADCVAR("g_instagib");
 515                 BADCVAR("g_new_toys");
 516                 BADCVAR("g_nix");
 517                 BADCVAR("g_grappling_hook");
 518                 BADCVAR("g_jetpack");
 519
 520                 // temporary for testing
 521                 // TODO remove before 0.8.3 release
 522                 BADCVAR("g_ca_weaponarena");
 523                 BADCVAR("g_freezetag_weaponarena");
 524                 BADCVAR("g_lms_weaponarena");
 525                 BADCVAR("g_ctf_stalemate_time");
 526
 527 #undef BADPRESUFFIX
 528 #undef BADPREFIX
 529 #undef BADCVAR
 530 #undef BADVALUE
 531
 532                 if(pureadding)
 533                 {
 534                         cvar_purechanges = strcat(cvar_purechanges, k, " \"", v, "\" // \"", d, "\"\n");
 535                         if(strlen(cvar_purechanges) > 16384)
 536                         {
 537                                 cvar_purechanges = "// too many settings have been changed to show them here\n";
 538                                 pureadding = 0;
 539                         }
 540                 }
 541                 ++cvar_purechanges_count;
 542                 // WARNING: this variable is used for the server list
 543                 // NEVER dare to skip this code!
 544                 // Hacks to intentionally appearing as "pure server" even though you DO have
 545                 // modified settings may be punished by removal from the server list.
 546                 // You can do to the variables cvar_changes and cvar_purechanges all you want,
 547                 // though.
 548         }
 549         buf_del(h);
 550         if(cvar_changes == "")
 551                 cvar_changes = "// this server runs at default server settings\n";
 552         else
 553                 cvar_changes = strcat("// this server runs at modified server settings:\n", cvar_changes);
 554         cvar_changes = strzone(cvar_changes);
 555         if(cvar_purechanges == "")
 556                 cvar_purechanges = "// this server runs at default gameplay settings\n";
 557         else
 558                 cvar_purechanges = strcat("// this server runs at modified gameplay settings:\n", cvar_purechanges);
 559         cvar_purechanges = strzone(cvar_purechanges);
 560 }
 561
 562 entity randomseed;
 563 bool RandomSeed_Send(entity this, entity to, int sf)
 564 {
 565         WriteHeader(MSG_ENTITY, ENT_CLIENT_RANDOMSEED);
 566         WriteShort(MSG_ENTITY, this.cnt);
 567         return true;
 568 }
 569 void RandomSeed_Think(entity this)
 570 {
 571         this.cnt = bound(0, floor(random() * 65536), 65535);
 572         this.nextthink = time + 5;
 573
 574         this.SendFlags |= 1;
 575 }
 576 void RandomSeed_Spawn()
 577 {
 578         randomseed = new_pure(randomseed);
 579         setthink(randomseed, RandomSeed_Think);
 580         Net_LinkEntity(randomseed, false, 0, RandomSeed_Send);
 581
 582         getthink(randomseed)(randomseed); // sets random seed and nextthink
 583 }
 584
 585 spawnfunc(__init_dedicated_server)
 586 {
 587         // handler for _init/_init map (only for dedicated server initialization)
 588
 589         world_initialized = -1; // don't complain
 590
 591         delete_fn = remove_unsafely;
 592
 593         entity e = new(GotoFirstMap);
 594         setthink(e, GotoFirstMap);
 595         e.nextthink = time; // this is usually 1 at this point
 596
 597         e = new(info_player_deathmatch);  // safeguard against player joining
 598
 599     // assign reflectively to avoid "assignment to world" warning
 600     for (int i = 0, n = numentityfields(); i < n; ++i) {
 601         string k = entityfieldname(i);
 602         if (k == "classname") {
 603             // safeguard against various stuff ;)
 604             putentityfieldstring(i, this, "worldspawn");
 605             break;
 606         }
 607     }
 608
 609         // needs to be done so early because of the constants they create
 610         static_init();
 611         static_init_late();
 612         static_init_precache();
 613
 614         IL_PUSH(g_spawnpoints, e); // just incase
 615
 616         MapInfo_Enumerate();
 617         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 618 }
 619
 620 void __init_dedicated_server_shutdown() {
 621         MapInfo_Shutdown();
 622 }
 623
 624 STATIC_INIT_EARLY(maxclients)
 625 {
 626         maxclients = 0;
 627         for (entity head = nextent(NULL); head; head = nextent(head)) {
 628                 ++maxclients;
 629         }
 630 }
 631
 632 void GameplayMode_DelayedInit(entity this)
 633 {
 634         if(!scores_initialized)
 635                 ScoreRules_generic();
 636 }
 637
 638 void InitGameplayMode()
 639 {
 640         VoteReset();
 641
 642         // find out good world mins/maxs bounds, either the static bounds found by looking for solid, or the mapinfo specified bounds
 643         get_mi_min_max(1);
 644         // assign reflectively to avoid "assignment to world" warning
 645         int done = 0; for (int i = 0, n = numentityfields(); i < n; ++i) {
 646             string k = entityfieldname(i); vector v = (k == "mins") ? mi_min : (k == "maxs") ? mi_max : '0 0 0';
 647             if (v) {
 648             putentityfieldstring(i, world, sprintf("%v", v));
 649             if (++done == 2) break;
 650         }
 651         }
 652         // currently, NetRadiant's limit is 131072 qu for each side
 653         // distance from one corner of a 131072qu cube to the opposite corner is approx. 227023 qu
 654         // set the distance according to map size but don't go over the limit to avoid issues with float precision
 655         // in case somebody makes extremely large maps
 656         max_shot_distance = min(230000, vlen(world.maxs - world.mins));
 657
 658         MapInfo_LoadMapSettings(mapname);
 659         GameRules_teams(false);
 660
 661         if (!cvar_value_issafe(world.fog))
 662         {
 663                 LOG_INFO("The current map contains a potentially harmful fog setting, ignored");
 664                 world.fog = string_null;
 665         }
 666         if(MapInfo_Map_fog != "")
 667         {
 668                 if(MapInfo_Map_fog == "none")
 669                         world.fog = string_null;
 670                 else
 671                         world.fog = strzone(MapInfo_Map_fog);
 672         }
 673         clientstuff = strzone(MapInfo_Map_clientstuff);
 674
 675         MapInfo_ClearTemps();
 676
 677         gamemode_name = MapInfo_Type_ToText(MapInfo_LoadedGametype);
 678
 679         cache_mutatormsg = strzone("");
 680         cache_lastmutatormsg = strzone("");
 681
 682         InitializeEntity(NULL, GameplayMode_DelayedInit, INITPRIO_GAMETYPE_FALLBACK);
 683 }
 684
 685 bool world_already_spawned;
 686 spawnfunc(worldspawn)
 687 {
 688         server_is_dedicated = boolean(stof(cvar_defstring("is_dedicated")));
 689
 690         bool wantrestart = false;
 691         {
 692                 if (!server_is_dedicated)
 693                 {
 694                         // force unloading of server pk3 files when starting a listen server
 695                         // localcmd("\nfs_rescan\n"); // FIXME: does more harm than good, has unintended side effects. What we really want is to unload temporary pk3s only
 696                         // restore csqc_progname too
 697                         string expect = "csprogs.dat";
 698                         wantrestart = cvar_string("csqc_progname") != expect;
 699                         cvar_set("csqc_progname", expect);
 700                 }
 701                 else
 702                 {
 703                         // Try to use versioned csprogs from pk3
 704                         // Only ever use versioned csprogs.dat files on dedicated servers;
 705                         // we need to reset csqc_progname on clients ourselves, and it's easier if the client's release name is constant
 706                         string pk3csprogs = "csprogs-" WATERMARK ".dat";
 707                         // This always works; fall back to it if a versioned csprogs.dat is suddenly missing
 708                         string select = "csprogs.dat";
 709                         if (fexists(pk3csprogs)) select = pk3csprogs;
 710                         if (cvar_string("csqc_progname") != select)
 711                         {
 712                                 cvar_set("csqc_progname", select);
 713                                 wantrestart = true;
 714                         }
 715                         // Check for updates on startup
 716                         // We do it this way for atomicity so that connecting clients still match the server progs and don't disconnect
 717                         int sentinel = fopen("progs.txt", FILE_READ);
 718                         if (sentinel >= 0)
 719                         {
 720                                 string switchversion = fgets(sentinel);
 721                                 fclose(sentinel);
 722                                 if (switchversion != "" && switchversion != WATERMARK)
 723                                 {
 724                                         LOG_INFOF("Switching progs: " WATERMARK " -> %s", switchversion);
 725                                         // if it doesn't exist, assume either:
 726                                         //   a) the current program was overwritten
 727                                         //   b) this is a client only update
 728                                         string newprogs = sprintf("progs-%s.dat", switchversion);
 729                                         if (fexists(newprogs))
 730                                         {
 731                                                 cvar_set("sv_progs", newprogs);
 732                                                 wantrestart = true;
 733                                         }
 734                                         string newcsprogs = sprintf("csprogs-%s.dat", switchversion);
 735                                         if (fexists(newcsprogs))
 736                                         {
 737                                                 cvar_set("csqc_progname", newcsprogs);
 738                                                 wantrestart = true;
 739                                         }
 740                                 }
 741                         }
 742                 }
 743                 if (wantrestart)
 744                 {
 745                         LOG_INFO("Restart requested");
 746                         changelevel(mapname);
 747                         // let initialization continue, shutdown depends on it
 748                 }
 749         }
 750
 751         if(world_already_spawned)
 752                 error("world already spawned - you may have EXACTLY ONE worldspawn!");
 753         world_already_spawned = true;
 754
 755         delete_fn = remove_safely; // during spawning, watch what you remove!
 756
 757         cvar_changes_init(); // do this very early now so it REALLY matches the server config
 758
 759         // needs to be done so early because of the constants they create
 760         static_init();
 761
 762         ServerProgsDB = db_load(strcat("server.db", autocvar_sessionid));
 763
 764         TemporaryDB = db_create();
 765
 766         // 0 normal
 767         lightstyle(0, "m");
 768
 769         // 1 FLICKER (first variety)
 770         lightstyle(1, "mmnmmommommnonmmonqnmmo");
 771
 772         // 2 SLOW STRONG PULSE
 773         lightstyle(2, "abcdefghijklmnopqrstuvwxyzyxwvutsrqponmlkjihgfedcba");
 774
 775         // 3 CANDLE (first variety)
 776         lightstyle(3, "mmmmmaaaaammmmmaaaaaabcdefgabcdefg");
 777
 778         // 4 FAST STROBE
 779         lightstyle(4, "mamamamamama");
 780
 781         // 5 GENTLE PULSE 1
 782         lightstyle(5,"jklmnopqrstuvwxyzyxwvutsrqponmlkj");
 783
 784         // 6 FLICKER (second variety)
 785         lightstyle(6, "nmonqnmomnmomomno");
 786
 787         // 7 CANDLE (second variety)
 788         lightstyle(7, "mmmaaaabcdefgmmmmaaaammmaamm");
 789
 790         // 8 CANDLE (third variety)
 791         lightstyle(8, "mmmaaammmaaammmabcdefaaaammmmabcdefmmmaaaa");
 792
 793         // 9 SLOW STROBE (fourth variety)
 794         lightstyle(9, "aaaaaaaazzzzzzzz");
 795
 796         // 10 FLUORESCENT FLICKER
 797         lightstyle(10, "mmamammmmammamamaaamammma");
 798
 799         // 11 SLOW PULSE NOT FADE TO BLACK
 800         lightstyle(11, "abcdefghijklmnopqrrqponmlkjihgfedcba");
 801
 802         // styles 32-62 are assigned by the spawnfunc_light program for switchable lights
 803
 804         // 63 testing
 805         lightstyle(63, "a");
 806
 807         if(autocvar_g_campaign)
 808                 CampaignPreInit();
 809
 810         Map_MarkAsRecent(mapname);
 811
 812         PlayerStats_GameReport_Init(); // we need this to be initiated before InitGameplayMode
 813
 814         InitGameplayMode();
 815         static_init_late();
 816         static_init_precache();
 817         readlevelcvars();
 818
 819         GameRules_limit_fallbacks();
 820
 821         if(warmup_limit == 0)
 822                 warmup_limit = (autocvar_timelimit > 0) ? autocvar_timelimit * 60 : autocvar_timelimit;
 823
 824         player_count = 0;
 825         bot_waypoints_for_items = autocvar_g_waypoints_for_items;
 826         if(bot_waypoints_for_items == 1)
 827                 if(this.spawnflags & SPAWNFLAG_NO_WAYPOINTS_FOR_ITEMS)
 828                         bot_waypoints_for_items = 0;
 829
 830         WaypointSprite_Init();
 831
 832         GameLogInit(); // prepare everything
 833         // NOTE for matchid:
 834         // changing the logic generating it is okay. But:
 835         // it HAS to stay <= 64 chars
 836         // character set: ASCII 33-126 without the following characters: : ; ' " \ $
 837         if(autocvar_sv_eventlog)
 838         {
 839                 string s = sprintf("%s.%s.%06d", itos(autocvar_sv_eventlog_files_counter), strftime(false, "%s"), floor(random() * 1000000));
 840                 matchid = strzone(s);
 841
 842                 GameLogEcho(strcat(":gamestart:", GetGametype(), "_", GetMapname(), ":", s));
 843                 s = ":gameinfo:mutators:LIST";
 844
 845                 MUTATOR_CALLHOOK(BuildMutatorsString, s);
 846                 s = M_ARGV(0, string);
 847
 848                 // initialiation stuff, not good in the mutator system
 849                 if(!autocvar_g_use_ammunition)
 850                         s = strcat(s, ":no_use_ammunition");
 851
 852                 // initialiation stuff, not good in the mutator system
 853                 if(autocvar_g_pickup_items == 0)
 854                         s = strcat(s, ":no_pickup_items");
 855                 if(autocvar_g_pickup_items > 0)
 856                         s = strcat(s, ":pickup_items");
 857
 858                 // initialiation stuff, not good in the mutator system
 859                 if(autocvar_g_weaponarena != "0")
 860                         s = strcat(s, ":", autocvar_g_weaponarena, " arena");
 861
 862                 // TODO to mutator system
 863                 if(autocvar_g_norecoil)
 864                         s = strcat(s, ":norecoil");
 865
 866                 // TODO to mutator system
 867                 if(autocvar_g_powerups == 0)
 868                         s = strcat(s, ":no_powerups");
 869                 if(autocvar_g_powerups > 0)
 870                         s = strcat(s, ":powerups");
 871
 872                 GameLogEcho(s);
 873                 GameLogEcho(":gameinfo:end");
 874         }
 875         else
 876                 matchid = strzone(ftos(random()));
 877
 878         cvar_set("nextmap", "");
 879
 880         SetDefaultAlpha();
 881
 882         if(autocvar_g_campaign)
 883                 CampaignPostInit();
 884
 885         Ban_LoadBans();
 886
 887         MapInfo_Enumerate();
 888         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
 889
 890         if(fexists(strcat("scripts/", mapname, ".arena")))
 891                 cvar_settemp("sv_q3acompat_machineshotgunswap", "1");
 892
 893         if(fexists(strcat("scripts/", mapname, ".defi")))
 894                 cvar_settemp("sv_q3defragcompat", "1");
 895
 896         if(whichpack(strcat("maps/", mapname, ".cfg")) != "")
 897         {
 898                 int fd = fopen(strcat("maps/", mapname, ".cfg"), FILE_READ);
 899                 if(fd != -1)
 900                 {
 901                         string s;
 902                         while((s = fgets(fd)))
 903                         {
 904                                 int l = tokenize_console(s);
 905                                 if(l < 2)
 906                                         continue;
 907                                 if(argv(0) == "cd")
 908                                 {
 909                                         string trackname = argv(2);
 910                                         LOG_INFO("Found ^1UNSUPPORTED^7 cd loop command in .cfg file; put this line in mapinfo instead:");
 911                                         LOG_INFO("  cdtrack ", trackname);
 912                                         if (cvar_value_issafe(trackname))
 913                                         {
 914                                                 string newstuff = strcat(clientstuff, "cd loop \"", trackname, "\"\n");
 915                                                 strcpy(clientstuff, newstuff);
 916                                         }
 917                                 }
 918                                 else if(argv(0) == "fog")
 919                                 {
 920                                         LOG_INFO("Found ^1UNSUPPORTED^7 fog command in .cfg file; put this line in worldspawn in the .map/.bsp/.ent file instead:");
 921                                         LOG_INFO("  \"fog\" \"", s, "\"");
 922                                 }
 923                                 else if(argv(0) == "set")
 924                                 {
 925                                         LOG_INFO("Found ^1UNSUPPORTED^7 set command in .cfg file; put this line in mapinfo instead:");
 926                                         LOG_INFO("  clientsettemp_for_type all ", argv(1), " ", argv(2));
 927                                 }
 928                                 else if(argv(0) != "//")
 929                                 {
 930                                         LOG_INFO("Found ^1UNSUPPORTED^7 set command in .cfg file; put this line in mapinfo instead:");
 931                                         LOG_INFO("  clientsettemp_for_type all ", argv(0), " ", argv(1));
 932                                 }
 933                         }
 934                         fclose(fd);
 935                 }
 936         }
 937
 938         WeaponStats_Init();
 939
 940         Nagger_Init();
 941
 942         // set up information replies for clients and server to use
 943         maplist_reply = strzone(getmaplist());
 944         lsmaps_reply = strzone(getlsmaps());
 945         monsterlist_reply = strzone(getmonsterlist());
 946         bool records_available = false;
 947         for(int i = 0; i < 10; ++i)
 948         {
 949                 string s = getrecords(i);
 950                 if (s != "")
 951                 {
 952                         records_reply[i] = strzone(s);
 953                         records_available = true;
 954                 }
 955         }
 956         if (!records_available)
 957                 records_reply[0] = "No records available for the current game mode.\n";
 958         ladder_reply = strzone(getladder());
 959         rankings_reply = strzone(getrankings());
 960
 961         // begin other init
 962         ClientInit_Spawn();
 963         RandomSeed_Spawn();
 964         PingPLReport_Spawn();
 965
 966         CheatInit();
 967
 968         if (!wantrestart) localcmd("\n_sv_hook_gamestart ", GetGametype(), "\n");
 969
 970         // fill sv_curl_serverpackages from .serverpackage files
 971         if (autocvar_sv_curl_serverpackages_auto)
 972         {
 973                 string s = "csprogs-" WATERMARK ".dat";
 974                 // remove automatically managed files from the list to prevent duplicates
 975                 for (int i = 0, n = tokenize_console(cvar_string("sv_curl_serverpackages")); i < n; ++i)
 976                 {
 977                         string pkg = argv(i);
 978                         if (startsWith(pkg, "csprogs-")) continue;
 979                         if (endsWith(pkg, "-serverpackage.txt")) continue;
 980                         if (endsWith(pkg, ".serverpackage")) continue;  // OLD legacy
 981                         s = cons(s, pkg);
 982                 }
 983                 // add automatically managed files to the list
 984                 #define X(match) MACRO_BEGIN \
 985                         int fd = search_begin(match, true, false); \
 986                         if (fd >= 0) \
 987                         { \
 988                                 for (int i = 0, j = search_getsize(fd); i < j; ++i) \
 989                                 { \
 990                                         s = cons(s, search_getfilename(fd, i)); \
 991                                 } \
 992                                 search_end(fd); \
 993                         } \
 994                 MACRO_END
 995                 X("*-serverpackage.txt");
 996                 X("*.serverpackage");
 997                 #undef X
 998                 cvar_set("sv_curl_serverpackages", s);
 999         }
1000
1001         // MOD AUTHORS: change this, and possibly remove a few of the blocks below to ignore certain changes
1002         modname = "Xonotic";
1003         // physics/balance/config changes that count as mod
1004         if(cvar_string("g_mod_physics") != cvar_defstring("g_mod_physics"))
1005                 modname = cvar_string("g_mod_physics");
1006         if(cvar_string("g_mod_balance") != cvar_defstring("g_mod_balance") && cvar_string("g_mod_balance") != "Testing")
1007                 modname = cvar_string("g_mod_balance");
1008         if(cvar_string("g_mod_config") != cvar_defstring("g_mod_config"))
1009                 modname = cvar_string("g_mod_config");
1010         // extra mutators that deserve to count as mod
1011         MUTATOR_CALLHOOK(SetModname, modname);
1012         modname = M_ARGV(0, string);
1013
1014         // save it for later
1015         modname = strzone(modname);
1016
1017         WinningConditionHelper(this); // set worldstatus
1018
1019         world_initialized = 1;
1020         __spawnfunc_spawn_all();
1021 }
1022
1023 spawnfunc(light)
1024 {
1025         //makestatic (this); // Who the f___ did that?
1026         delete(this);
1027 }
1028
1029 bool MoveToRandomLocationWithinBounds(entity e, vector boundmin, vector boundmax, float goodcontents, float badcontents, float badsurfaceflags, int attempts, float maxaboveground, float minviewdistance)
1030 {
1031     float m = e.dphitcontentsmask;
1032     e.dphitcontentsmask = goodcontents | badcontents;
1033
1034     vector org = boundmin;
1035     vector delta = boundmax - boundmin;
1036
1037     vector start, end;
1038     start = end = org;
1039     int j; // used after the loop
1040     for(j = 0; j < attempts; ++j)
1041     {
1042         start.x = org.x + random() * delta.x;
1043         start.y = org.y + random() * delta.y;
1044         start.z = org.z + random() * delta.z;
1045
1046         // rule 1: start inside world bounds, and outside
1047         // solid, and don't start from somewhere where you can
1048         // fall down to evil
1049         tracebox(start, e.mins, e.maxs, start - '0 0 1' * delta.z, MOVE_NORMAL, e);
1050         if (trace_fraction >= 1)
1051             continue;
1052         if (trace_startsolid)
1053             continue;
1054         if (trace_dphitcontents & badcontents)
1055             continue;
1056         if (trace_dphitq3surfaceflags & badsurfaceflags)
1057             continue;
1058
1059         // rule 2: if we are too high, lower the point
1060         if (trace_fraction * delta.z > maxaboveground)
1061             start = trace_endpos + '0 0 1' * maxaboveground;
1062         vector enddown = trace_endpos;
1063
1064         // rule 3: make sure we aren't outside the map. This only works
1065         // for somewhat well formed maps. A good rule of thumb is that
1066         // the map should have a convex outside hull.
1067         // these can be traceLINES as we already verified the starting box
1068         vector mstart = start + 0.5 * (e.mins + e.maxs);
1069         traceline(mstart, mstart + '1 0 0' * delta.x, MOVE_NORMAL, e);
1070         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1071             continue;
1072         traceline(mstart, mstart - '1 0 0' * delta.x, MOVE_NORMAL, e);
1073         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1074             continue;
1075         traceline(mstart, mstart + '0 1 0' * delta.y, MOVE_NORMAL, e);
1076         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1077             continue;
1078         traceline(mstart, mstart - '0 1 0' * delta.y, MOVE_NORMAL, e);
1079         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1080             continue;
1081         traceline(mstart, mstart + '0 0 1' * delta.z, MOVE_NORMAL, e);
1082         if (trace_fraction >= 1 || trace_dphittexturename == "common/caulk")
1083             continue;
1084
1085                 // rule 4: we must "see" some spawnpoint or item
1086             entity sp = NULL;
1087             IL_EACH(g_spawnpoints, checkpvs(mstart, it),
1088             {
1089                 if((traceline(mstart, it.origin, MOVE_NORMAL, e), trace_fraction) >= 1)
1090                 {
1091                         sp = it;
1092                         break;
1093                 }
1094             });
1095                 if(!sp)
1096                 {
1097                         int items_checked = 0;
1098                         IL_EACH(g_items, checkpvs(mstart, it),
1099                         {
1100                                 if((traceline(mstart, it.origin + (it.mins + it.maxs) * 0.5, MOVE_NORMAL, e), trace_fraction) >= 1)
1101                                 {
1102                                         sp = it;
1103                                         break;
1104                                 }
1105
1106                                 ++items_checked;
1107                                 if(items_checked >= attempts)
1108                                         break; // sanity
1109                         });
1110
1111                         if(!sp)
1112                                 continue;
1113                 }
1114
1115         // find a random vector to "look at"
1116         end.x = org.x + random() * delta.x;
1117         end.y = org.y + random() * delta.y;
1118         end.z = org.z + random() * delta.z;
1119         end = start + normalize(end - start) * vlen(delta);
1120
1121         // rule 4: start TO end must not be too short
1122         tracebox(start, e.mins, e.maxs, end, MOVE_NORMAL, e);
1123         if(trace_startsolid)
1124             continue;
1125         if(trace_fraction < minviewdistance / vlen(delta))
1126             continue;
1127
1128         // rule 5: don't want to look at sky
1129         if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_SKY)
1130             continue;
1131
1132         // rule 6: we must not end up in trigger_hurt
1133         if(tracebox_hits_trigger_hurt(start, e.mins, e.maxs, enddown))
1134             continue;
1135
1136         break;
1137     }
1138
1139     e.dphitcontentsmask = m;
1140
1141     if(j < attempts)
1142     {
1143         setorigin(e, start);
1144         e.angles = vectoangles(end - start);
1145         LOG_DEBUG("Needed ", ftos(j + 1), " attempts");
1146         return true;
1147     }
1148     return false;
1149 }
1150
1151 float MoveToRandomMapLocation(entity e, float goodcontents, float badcontents, float badsurfaceflags, float attempts, float maxaboveground, float minviewdistance)
1152 {
1153         return MoveToRandomLocationWithinBounds(e, world.mins, world.maxs, goodcontents, badcontents, badsurfaceflags, attempts, maxaboveground, minviewdistance);
1154 }
1155
1156 /*
1157 ===============================================================================
1158
1159 RULES
1160
1161 ===============================================================================
1162 */
1163
1164 void DumpStats(float final)
1165 {
1166         float file;
1167         string s;
1168         float to_console;
1169         float to_eventlog;
1170         float to_file;
1171         float i;
1172
1173         to_console = autocvar_sv_logscores_console;
1174         to_eventlog = autocvar_sv_eventlog;
1175         to_file = autocvar_sv_logscores_file;
1176
1177         if(!final)
1178         {
1179                 to_console = true; // always print printstats replies
1180                 to_eventlog = false; // but never print them to the event log
1181         }
1182
1183         if(to_eventlog)
1184                 if(autocvar_sv_eventlog_console)
1185                         to_console = false; // otherwise we get the output twice
1186
1187         if(final)
1188                 s = ":scores:";
1189         else
1190                 s = ":status:";
1191         s = strcat(s, GetGametype(), "_", GetMapname(), ":", ftos(rint(time)));
1192
1193         if(to_console)
1194                 LOG_INFO(s);
1195         if(to_eventlog)
1196                 GameLogEcho(s);
1197
1198         file = -1;
1199         if(to_file)
1200         {
1201                 file = fopen(autocvar_sv_logscores_filename, FILE_APPEND);
1202                 if(file == -1)
1203                         to_file = false;
1204                 else
1205                         fputs(file, strcat(s, "\n"));
1206         }
1207
1208         s = strcat(":labels:player:", GetPlayerScoreString(NULL, 0));
1209         if(to_console)
1210                 LOG_INFO(s);
1211         if(to_eventlog)
1212                 GameLogEcho(s);
1213         if(to_file)
1214                 fputs(file, strcat(s, "\n"));
1215
1216         FOREACH_CLIENT(IS_REAL_CLIENT(it) || (IS_BOT_CLIENT(it) && autocvar_sv_logscores_bots), {
1217                 s = strcat(":player:see-labels:", GetPlayerScoreString(it, 0), ":");
1218                 s = strcat(s, ftos(rint(time - CS(it).jointime)), ":");
1219                 if(IS_PLAYER(it) || MUTATOR_CALLHOOK(GetPlayerStatus, it))
1220                         s = strcat(s, ftos(it.team), ":");
1221                 else
1222                         s = strcat(s, "spectator:");
1223
1224                 if(to_console)
1225                         LOG_INFO(s, playername(it.netname, it.team, false));
1226                 if(to_eventlog)
1227                         GameLogEcho(strcat(s, ftos(it.playerid), ":", playername(it.netname, it.team, false)));
1228                 if(to_file)
1229                         fputs(file, strcat(s, playername(it.netname, it.team, false), "\n"));
1230         });
1231
1232         if(teamplay)
1233         {
1234                 s = strcat(":labels:teamscores:", GetTeamScoreString(0, 0));
1235                 if(to_console)
1236                         LOG_INFO(s);
1237                 if(to_eventlog)
1238                         GameLogEcho(s);
1239                 if(to_file)
1240                         fputs(file, strcat(s, "\n"));
1241
1242                 for(i = 1; i < 16; ++i)
1243                 {
1244                         s = strcat(":teamscores:see-labels:", GetTeamScoreString(i, 0));
1245                         s = strcat(s, ":", ftos(i));
1246                         if(to_console)
1247                                 LOG_INFO(s);
1248                         if(to_eventlog)
1249                                 GameLogEcho(s);
1250                         if(to_file)
1251                                 fputs(file, strcat(s, "\n"));
1252                 }
1253         }
1254
1255         if(to_console)
1256                 LOG_INFO(":end");
1257         if(to_eventlog)
1258                 GameLogEcho(":end");
1259         if(to_file)
1260         {
1261                 fputs(file, ":end\n");
1262                 fclose(file);
1263         }
1264 }
1265
1266 /*
1267 go to the next level for deathmatch
1268 only called if a time or frag limit has expired
1269 */
1270 void NextLevel()
1271 {
1272         game_stopped = true;
1273         intermission_running = true; // game over
1274
1275         // enforce a wait time before allowing changelevel
1276         if(player_count > 0)
1277                 intermission_exittime = time + autocvar_sv_mapchange_delay;
1278         else
1279                 intermission_exittime = -1;
1280
1281         /*
1282         WriteByte (MSG_ALL, SVC_CDTRACK);
1283         WriteByte (MSG_ALL, 3);
1284         WriteByte (MSG_ALL, 3);
1285         // done in FixIntermission
1286         */
1287
1288         //pos = FindIntermission ();
1289
1290         VoteReset();
1291
1292         DumpStats(true);
1293
1294         // send statistics
1295         PlayerStats_GameReport(true);
1296         WeaponStats_Shutdown();
1297
1298         Kill_Notification(NOTIF_ALL, NULL, MSG_CENTER, CPID_Null); // kill all centerprints now
1299
1300         if(autocvar_sv_eventlog)
1301                 GameLogEcho(":gameover");
1302
1303         GameLogClose();
1304
1305         FOREACH_CLIENT(IS_PLAYER(it), {
1306                 FixIntermissionClient(it);
1307                 if(it.winning)
1308                         bprint(playername(it.netname, it.team, false), " ^7wins.\n");
1309         });
1310
1311         target_music_kill();
1312
1313         if(autocvar_g_campaign)
1314                 CampaignPreIntermission();
1315
1316         MUTATOR_CALLHOOK(MatchEnd);
1317
1318         localcmd("\nsv_hook_gameend\n");
1319 }
1320
1321
1322 float InitiateSuddenDeath()
1323 {
1324         // Check first whether normal overtimes could be added before initiating suddendeath mode
1325         // - for this timelimit_overtime needs to be >0 of course
1326         // - also check the winning condition calculated in the previous frame and only add normal overtime
1327         //   again, if at the point at which timelimit would be extended again, still no winner was found
1328         if (!autocvar_g_campaign && checkrules_overtimesadded >= 0
1329                 && (checkrules_overtimesadded < autocvar_timelimit_overtimes || autocvar_timelimit_overtimes < 0)
1330                 && autocvar_timelimit_overtime && !(g_race && !g_race_qualifying))
1331         {
1332                 return 1; // need to call InitiateOvertime later
1333         }
1334         else
1335         {
1336                 if(!checkrules_suddendeathend)
1337                 {
1338                         if(autocvar_g_campaign)
1339                                 checkrules_suddendeathend = time; // no suddendeath in campaign
1340                         else
1341                                 checkrules_suddendeathend = time + 60 * autocvar_timelimit_suddendeath;
1342                         if(g_race && !g_race_qualifying)
1343                                 race_StartCompleting();
1344                 }
1345                 return 0;
1346         }
1347 }
1348
1349 void InitiateOvertime() // ONLY call this if InitiateSuddenDeath returned true
1350 {
1351         ++checkrules_overtimesadded;
1352         //add one more overtime by simply extending the timelimit
1353         cvar_set("timelimit", ftos(autocvar_timelimit + autocvar_timelimit_overtime));
1354         Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, CENTER_OVERTIME_TIME, autocvar_timelimit_overtime * 60);
1355 }
1356
1357 float GetWinningCode(float fraglimitreached, float equality)
1358 {
1359         if(autocvar_g_campaign == 1)
1360         {
1361                 if(fraglimitreached)
1362                         return WINNING_YES;
1363                 else
1364                         return WINNING_NO;
1365         }
1366         else
1367         {
1368                 if(equality)
1369                 {
1370                         if(fraglimitreached)
1371                                 return WINNING_STARTSUDDENDEATHOVERTIME;
1372                         else
1373                                 return WINNING_NEVER;
1374                 }
1375                 else
1376                 {
1377                         if(fraglimitreached)
1378                                 return WINNING_YES;
1379                         else
1380                                 return WINNING_NO;
1381                 }
1382         }
1383 }
1384
1385 // set the .winning flag for exactly those players with a given field value
1386 void SetWinners(.float field, float value)
1387 {
1388         FOREACH_CLIENT(IS_PLAYER(it), { it.winning = (it.(field) == value); });
1389 }
1390
1391 // set the .winning flag for those players with a given field value
1392 void AddWinners(.float field, float value)
1393 {
1394         FOREACH_CLIENT(IS_PLAYER(it), {
1395                 if(it.(field) == value)
1396                         it.winning = 1;
1397         });
1398 }
1399
1400 // clear the .winning flags
1401 void ClearWinners()
1402 {
1403         FOREACH_CLIENT(IS_PLAYER(it), { it.winning = 0; });
1404 }
1405
1406 int fragsleft_last;
1407 float WinningCondition_Scores(float limit, float leadlimit)
1408 {
1409         // TODO make everything use THIS winning condition (except LMS)
1410         WinningConditionHelper(NULL);
1411
1412         if(teamplay)
1413         {
1414                 for (int i = 1; i < 5; ++i)
1415                 {
1416                         Team_SetTeamScore(Team_GetTeamFromIndex(i),
1417                                 TeamScore_GetCompareValue(Team_IndexToTeam(i)));
1418                 }
1419         }
1420
1421         ClearWinners();
1422         if(WinningConditionHelper_winner)
1423                 WinningConditionHelper_winner.winning = 1;
1424         if(WinningConditionHelper_winnerteam >= 0)
1425                 SetWinners(team, WinningConditionHelper_winnerteam);
1426
1427         if(WinningConditionHelper_lowerisbetter)
1428         {
1429                 WinningConditionHelper_topscore = -WinningConditionHelper_topscore;
1430                 WinningConditionHelper_secondscore = -WinningConditionHelper_secondscore;
1431                 limit = -limit;
1432         }
1433
1434         if(WinningConditionHelper_zeroisworst)
1435                 leadlimit = 0; // not supported in this mode
1436
1437         if(MUTATOR_CALLHOOK(Scores_CountFragsRemaining))
1438         {
1439                 float fragsleft;
1440                 if (checkrules_suddendeathend && time >= checkrules_suddendeathend)
1441                 {
1442                         fragsleft = 1;
1443                 }
1444                 else
1445                 {
1446                         fragsleft = FLOAT_MAX;
1447                         float leadingfragsleft = FLOAT_MAX;
1448                         if (limit)
1449                                 fragsleft = limit - WinningConditionHelper_topscore;
1450                         if (leadlimit)
1451                                 leadingfragsleft = WinningConditionHelper_secondscore + leadlimit - WinningConditionHelper_topscore;
1452
1453                         if (limit && leadlimit && autocvar_leadlimit_and_fraglimit)
1454                                 fragsleft = max(fragsleft, leadingfragsleft);
1455                         else
1456                                 fragsleft = min(fragsleft, leadingfragsleft);
1457                 }
1458
1459                 if (fragsleft_last != fragsleft) // do not announce same remaining frags multiple times
1460                 {
1461                         if (fragsleft == 1)
1462                                 Send_Notification(NOTIF_ALL, NULL, MSG_ANNCE, ANNCE_REMAINING_FRAG_1);
1463                         else if (fragsleft == 2)
1464                                 Send_Notification(NOTIF_ALL, NULL, MSG_ANNCE, ANNCE_REMAINING_FRAG_2);
1465                         else if (fragsleft == 3)
1466                                 Send_Notification(NOTIF_ALL, NULL, MSG_ANNCE, ANNCE_REMAINING_FRAG_3);
1467
1468                         fragsleft_last = fragsleft;
1469                 }
1470         }
1471
1472         bool fraglimit_reached = (limit && WinningConditionHelper_topscore >= limit);
1473         bool leadlimit_reached = (leadlimit && WinningConditionHelper_topscore - WinningConditionHelper_secondscore >= leadlimit);
1474
1475         bool limit_reached;
1476         // only respect leadlimit_and_fraglimit when both limits are set or the game will never end
1477         if (limit && leadlimit && autocvar_leadlimit_and_fraglimit)
1478                 limit_reached = (fraglimit_reached && leadlimit_reached);
1479         else
1480                 limit_reached = (fraglimit_reached || leadlimit_reached);
1481
1482         return GetWinningCode(
1483                 WinningConditionHelper_topscore && limit_reached,
1484                 WinningConditionHelper_equality
1485         );
1486 }
1487
1488 float WinningCondition_RanOutOfSpawns()
1489 {
1490         if(have_team_spawns <= 0)
1491                 return WINNING_NO;
1492
1493         if(!autocvar_g_spawn_useallspawns)
1494                 return WINNING_NO;
1495
1496         if(!some_spawn_has_been_used)
1497                 return WINNING_NO;
1498
1499         for (int i = 1; i < 5; ++i)
1500         {
1501                 Team_SetTeamScore(Team_GetTeamFromIndex(i), 0);
1502         }
1503
1504         FOREACH_CLIENT(IS_PLAYER(it) && !IS_DEAD(it),
1505         {
1506                 if (Team_IsValidTeam(it.team))
1507                 {
1508                         Team_SetTeamScore(Team_GetTeam(it.team), 1);
1509                 }
1510         });
1511
1512         IL_EACH(g_spawnpoints, true,
1513         {
1514                 if (Team_IsValidTeam(it.team))
1515                 {
1516                         Team_SetTeamScore(Team_GetTeam(it.team), 1);
1517                 }
1518         });
1519
1520         ClearWinners();
1521         float team1_score = Team_GetTeamScore(Team_GetTeamFromIndex(1));
1522         float team2_score = Team_GetTeamScore(Team_GetTeamFromIndex(2));
1523         float team3_score = Team_GetTeamScore(Team_GetTeamFromIndex(3));
1524         float team4_score = Team_GetTeamScore(Team_GetTeamFromIndex(4));
1525         if(team1_score + team2_score + team3_score + team4_score == 0)
1526         {
1527                 checkrules_equality = true;
1528                 return WINNING_YES;
1529         }
1530         else if(team1_score + team2_score + team3_score + team4_score == 1)
1531         {
1532                 float t, i;
1533                 if(team1_score)
1534                         t = 1;
1535                 else if(team2_score)
1536                         t = 2;
1537                 else if(team3_score)
1538                         t = 3;
1539                 else // if(team4_score)
1540                         t = 4;
1541                 entity balance = TeamBalance_CheckAllowedTeams(NULL);
1542                 for(i = 0; i < MAX_TEAMSCORE; ++i)
1543                 {
1544                         for (int j = 1; j <= NUM_TEAMS; ++j)
1545                         {
1546                                 if (t == j)
1547                                 {
1548                                         continue;
1549                                 }
1550                                 if (!TeamBalance_IsTeamAllowed(balance, j))
1551                                 {
1552                                         continue;
1553                                 }
1554                                 TeamScore_AddToTeam(Team_IndexToTeam(j), i, -1000);
1555                         }
1556                 }
1557
1558                 AddWinners(team, t);
1559                 return WINNING_YES;
1560         }
1561         else
1562                 return WINNING_NO;
1563 }
1564
1565 /*
1566 ============
1567 CheckRules_World
1568
1569 Exit deathmatch games upon conditions
1570 ============
1571 */
1572 void CheckRules_World()
1573 {
1574         VoteThink();
1575         MapVote_Think();
1576
1577         SetDefaultAlpha();
1578
1579         if (intermission_running) // someone else quit the game already
1580         {
1581                 if(player_count == 0) // Nobody there? Then let's go to the next map
1582                         MapVote_Start();
1583                         // this will actually check the player count in the next frame
1584                         // again, but this shouldn't hurt
1585                 return;
1586         }
1587
1588         float timelimit = autocvar_timelimit * 60;
1589         float fraglimit = autocvar_fraglimit;
1590         float leadlimit = autocvar_leadlimit;
1591         if (leadlimit < 0) leadlimit = 0;
1592
1593         if(warmup_stage || time <= game_starttime) // NOTE: this is <= to prevent problems in the very tic where the game starts
1594         {
1595                 if(timelimit > 0)
1596                         timelimit = 0; // timelimit is not made for warmup
1597                 if(fraglimit > 0)
1598                         fraglimit = 0; // no fraglimit for now
1599                 leadlimit = 0; // no leadlimit for now
1600         }
1601
1602         if(timelimit > 0)
1603         {
1604                 timelimit += game_starttime;
1605         }
1606         else if (timelimit < 0)
1607         {
1608                 // endmatch
1609                 NextLevel();
1610                 return;
1611         }
1612
1613         float wantovertime;
1614         wantovertime = 0;
1615
1616         if(checkrules_suddendeathend)
1617         {
1618                 if(!checkrules_suddendeathwarning)
1619                 {
1620                         checkrules_suddendeathwarning = true;
1621                         if(g_race && !g_race_qualifying)
1622                                 Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, CENTER_RACE_FINISHLAP);
1623                         else
1624                                 Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, CENTER_OVERTIME_FRAG);
1625                 }
1626         }
1627         else
1628         {
1629                 if (timelimit && time >= timelimit)
1630                 {
1631                         if(g_race && (g_race_qualifying == 2) && timelimit > 0)
1632                         {
1633                                 float totalplayers;
1634                                 float playerswithlaps;
1635                                 float readyplayers;
1636                                 totalplayers = playerswithlaps = readyplayers = 0;
1637                                 FOREACH_CLIENT(IS_PLAYER(it), {
1638                                         ++totalplayers;
1639                                         if(GameRules_scoring_add(it, RACE_FASTEST, 0))
1640                                                 ++playerswithlaps;
1641                                         if(it.ready)
1642                                                 ++readyplayers;
1643                                 });
1644
1645                                 // at least 2 of the players have completed a lap: start the RACE
1646                                 // otherwise, the players should end the qualifying on their own
1647                                 if(readyplayers || playerswithlaps >= 2)
1648                                 {
1649                                         checkrules_suddendeathend = 0;
1650                                         ReadyRestart(); // go to race
1651                                         return;
1652                                 }
1653                                 else
1654                                         wantovertime |= InitiateSuddenDeath();
1655                         }
1656                         else
1657                                 wantovertime |= InitiateSuddenDeath();
1658                 }
1659         }
1660
1661         if (checkrules_suddendeathend && time >= checkrules_suddendeathend)
1662         {
1663                 NextLevel();
1664                 return;
1665         }
1666
1667         int checkrules_status = WinningCondition_RanOutOfSpawns();
1668         if(checkrules_status == WINNING_YES)
1669                 bprint("Hey! Someone ran out of spawns!\n");
1670         else if(MUTATOR_CALLHOOK(CheckRules_World, checkrules_status, timelimit, fraglimit))
1671                 checkrules_status = M_ARGV(0, float);
1672         else
1673                 checkrules_status = WinningCondition_Scores(fraglimit, leadlimit);
1674
1675         if(checkrules_status == WINNING_STARTSUDDENDEATHOVERTIME)
1676         {
1677                 checkrules_status = WINNING_NEVER;
1678                 checkrules_overtimesadded = -1;
1679                 wantovertime |= InitiateSuddenDeath();
1680         }
1681
1682         if(checkrules_status == WINNING_NEVER)
1683                 // equality cases! Nobody wins if the overtime ends in a draw.
1684                 ClearWinners();
1685
1686         if(wantovertime)
1687         {
1688                 if(checkrules_status == WINNING_NEVER)
1689                         InitiateOvertime();
1690                 else
1691                         checkrules_status = WINNING_YES;
1692         }
1693
1694         if(checkrules_suddendeathend)
1695                 if(checkrules_status != WINNING_NEVER || time >= checkrules_suddendeathend)
1696                         checkrules_status = WINNING_YES;
1697
1698         if(checkrules_status == WINNING_YES)
1699         {
1700                 //print("WINNING\n");
1701                 NextLevel();
1702         }
1703 }
1704
1705 float want_weapon(entity weaponinfo, float allguns)
1706 {
1707         int d = 0;
1708         bool allow_mutatorblocked = false;
1709
1710         if(!weaponinfo.m_id)
1711                 return 0;
1712
1713         bool mutator_returnvalue = MUTATOR_CALLHOOK(WantWeapon, weaponinfo, d, allguns, allow_mutatorblocked);
1714         d = M_ARGV(1, float);
1715         allguns = M_ARGV(2, bool);
1716         allow_mutatorblocked = M_ARGV(3, bool);
1717
1718         if(allguns)
1719                 d = boolean((weaponinfo.spawnflags & WEP_FLAG_NORMAL) && !(weaponinfo.spawnflags & (WEP_FLAG_HIDDEN | WEP_FLAG_SPECIALATTACK)));
1720         else if(!mutator_returnvalue)
1721                 d = !(!weaponinfo.weaponstart);
1722
1723         if(!allow_mutatorblocked && (weaponinfo.spawnflags & WEP_FLAG_MUTATORBLOCKED)) // never default mutator blocked guns
1724                 d = 0;
1725
1726         float t = weaponinfo.weaponstartoverride;
1727
1728         //LOG_INFOF("want_weapon: %s - d: %d t: %d\n", weaponinfo.netname, d, t);
1729
1730         // bit order in t:
1731         // 1: want or not
1732         // 2: is default?
1733         // 4: is set by default?
1734         if(t < 0)
1735                 t = 4 | (3 * d);
1736         else
1737                 t |= (2 * d);
1738
1739         return t;
1740 }
1741
1742 /// Weapons the player normally starts with outside weapon arena.
1743 WepSet weapons_start()
1744 {
1745         WepSet ret = '0 0 0';
1746         FOREACH(Weapons, it != WEP_Null, {
1747                 int w = want_weapon(it, false);
1748                 if (w & 1)
1749                         ret |= it.m_wepset;
1750         });
1751         return ret;
1752 }
1753
1754 WepSet weapons_all()
1755 {
1756         WepSet ret = '0 0 0';
1757         FOREACH(Weapons, it != WEP_Null, {
1758                 if (!(it.spawnflags & (WEP_FLAG_MUTATORBLOCKED | WEP_FLAG_SPECIALATTACK)))
1759                         ret |= it.m_wepset;
1760         });
1761         return ret;
1762 }
1763
1764 WepSet weapons_devall()
1765 {
1766         WepSet ret = '0 0 0';
1767         FOREACH(Weapons, it != WEP_Null,
1768         {
1769                 ret |= it.m_wepset;
1770         });
1771         return ret;
1772 }
1773
1774 WepSet weapons_most()
1775 {
1776         WepSet ret = '0 0 0';
1777         FOREACH(Weapons, it != WEP_Null, {
1778                 if ((it.spawnflags & WEP_FLAG_NORMAL) && !(it.spawnflags & (WEP_FLAG_MUTATORBLOCKED | WEP_FLAG_HIDDEN | WEP_FLAG_SPECIALATTACK)))
1779                         ret |= it.m_wepset;
1780         });
1781         return ret;
1782 }
1783
1784 void weaponarena_available_all_update(entity this)
1785 {
1786         if (weaponsInMapAll)
1787         {
1788                 start_weapons = warmup_start_weapons = g_weaponarena_weapons = weapons_start() | (weaponsInMapAll & weapons_all());
1789         }
1790         else
1791         {
1792                 // if no weapons are available on the map, just fall back to all weapons arena
1793                 start_weapons = warmup_start_weapons = g_weaponarena_weapons = weapons_all();
1794         }
1795 }
1796
1797 void weaponarena_available_devall_update(entity this)
1798 {
1799         if (weaponsInMapAll)
1800         {
1801                 start_weapons = warmup_start_weapons = g_weaponarena_weapons = weapons_start() | weaponsInMapAll;
1802         }
1803         else
1804         {
1805                 // if no weapons are available on the map, just fall back to devall weapons arena
1806                 start_weapons = warmup_start_weapons = g_weaponarena_weapons = weapons_devall();
1807         }
1808 }
1809
1810 void weaponarena_available_most_update(entity this)
1811 {
1812         if (weaponsInMapAll)
1813         {
1814                 start_weapons = warmup_start_weapons = g_weaponarena_weapons = weapons_start() | (weaponsInMapAll & weapons_most());
1815         }
1816         else
1817         {
1818                 // if no weapons are available on the map, just fall back to most weapons arena
1819                 start_weapons = warmup_start_weapons = g_weaponarena_weapons = weapons_most();
1820         }
1821 }
1822
1823 void readplayerstartcvars()
1824 {
1825         // initialize starting values for players
1826         start_weapons = '0 0 0';
1827         start_weapons_default = '0 0 0';
1828         start_weapons_defaultmask = '0 0 0';
1829         start_items = 0;
1830         start_ammo_shells = 0;
1831         start_ammo_nails = 0;
1832         start_ammo_rockets = 0;
1833         start_ammo_cells = 0;
1834         start_ammo_plasma = 0;
1835         if (random_start_ammo == NULL)
1836         {
1837                 random_start_ammo = new_pure(random_start_ammo);
1838         }
1839         start_health = cvar("g_balance_health_start");
1840         start_armorvalue = cvar("g_balance_armor_start");
1841
1842         g_weaponarena = 0;
1843         g_weaponarena_weapons = '0 0 0';
1844
1845         string s = cvar_string("g_weaponarena");
1846
1847         MUTATOR_CALLHOOK(SetWeaponArena, s);
1848         s = M_ARGV(0, string);
1849
1850         if (s == "0" || s == "")
1851         {
1852                 // no arena
1853         }
1854         else if (s == "off")
1855         {
1856                 // forcibly turn off weaponarena
1857         }
1858         else if (s == "all" || s == "1")
1859         {
1860                 g_weaponarena = 1;
1861                 g_weaponarena_list = "All Weapons";
1862                 g_weaponarena_weapons = weapons_all();
1863         }
1864         else if (s == "devall")
1865         {
1866                 g_weaponarena = 1;
1867                 g_weaponarena_list = "Dev All Weapons";
1868                 g_weaponarena_weapons = weapons_devall();
1869         }
1870         else if (s == "most")
1871         {
1872                 g_weaponarena = 1;
1873                 g_weaponarena_list = "Most Weapons";
1874                 g_weaponarena_weapons = weapons_most();
1875         }
1876         else if (s == "all_available")
1877         {
1878                 g_weaponarena = 1;
1879                 g_weaponarena_list = "All Available Weapons";
1880
1881                 // this needs to run after weaponsInMapAll is initialized
1882                 InitializeEntity(NULL, weaponarena_available_all_update, INITPRIO_FINDTARGET);
1883         }
1884         else if (s == "devall_available")
1885         {
1886                 g_weaponarena = 1;
1887                 g_weaponarena_list = "Dev All Available Weapons";
1888
1889                 // this needs to run after weaponsInMapAll is initialized
1890                 InitializeEntity(NULL, weaponarena_available_devall_update, INITPRIO_FINDTARGET);
1891         }
1892         else if (s == "most_available")
1893         {
1894                 g_weaponarena = 1;
1895                 g_weaponarena_list = "Most Available Weapons";
1896
1897                 // this needs to run after weaponsInMapAll is initialized
1898                 InitializeEntity(NULL, weaponarena_available_most_update, INITPRIO_FINDTARGET);
1899         }
1900         else if (s == "none")
1901         {
1902                 g_weaponarena = 1;
1903                 g_weaponarena_list = "No Weapons";
1904         }
1905         else
1906         {
1907                 g_weaponarena = 1;
1908                 float t = tokenize_console(s);
1909                 g_weaponarena_list = "";
1910                 for (int j = 0; j < t; ++j)
1911                 {
1912                         s = argv(j);
1913                         Weapon wep = Weapon_from_name(s);
1914                         if(wep != WEP_Null)
1915                         {
1916                                 g_weaponarena_weapons |= (wep.m_wepset);
1917                                 g_weaponarena_list = strcat(g_weaponarena_list, wep.m_name, " & ");
1918                         }
1919                 }
1920                 g_weaponarena_list = strzone(substring(g_weaponarena_list, 0, strlen(g_weaponarena_list) - 3));
1921         }
1922
1923         if (g_weaponarena)
1924         {
1925                 g_weapon_stay = 0; // incompatible
1926                 start_weapons = g_weaponarena_weapons;
1927                 start_items |= IT_UNLIMITED_AMMO | IT_UNLIMITED_SUPERWEAPONS;
1928         }
1929         else
1930         {
1931                 FOREACH(Weapons, it != WEP_Null, {
1932                         int w = want_weapon(it, false);
1933                         WepSet s = it.m_wepset;
1934                         if(w & 1)
1935                                 start_weapons |= s;
1936                         if(w & 2)
1937                                 start_weapons_default |= s;
1938                         if(w & 4)
1939                                 start_weapons_defaultmask |= s;
1940                 });
1941         }
1942
1943         if(cvar("g_balance_superweapons_time") < 0)
1944                 start_items |= IT_UNLIMITED_SUPERWEAPONS;
1945
1946         if(!cvar("g_use_ammunition"))
1947                 start_items |= IT_UNLIMITED_AMMO;
1948
1949         if(start_items & IT_UNLIMITED_AMMO)
1950         {
1951                 start_ammo_shells = 999;
1952                 start_ammo_nails = 999;
1953                 start_ammo_rockets = 999;
1954                 start_ammo_cells = 999;
1955                 start_ammo_plasma = 999;
1956                 start_ammo_fuel = 999;
1957         }
1958         else
1959         {
1960                 start_ammo_shells = cvar("g_start_ammo_shells");
1961                 start_ammo_nails = cvar("g_start_ammo_nails");
1962                 start_ammo_rockets = cvar("g_start_ammo_rockets");
1963                 start_ammo_cells = cvar("g_start_ammo_cells");
1964                 start_ammo_plasma = cvar("g_start_ammo_plasma");
1965                 start_ammo_fuel = cvar("g_start_ammo_fuel");
1966                 random_start_weapons_count = cvar("g_random_start_weapons_count");
1967                 SetResource(random_start_ammo, RES_SHELLS, cvar("g_random_start_shells"));
1968                 SetResource(random_start_ammo, RES_BULLETS, cvar("g_random_start_bullets"));
1969                 SetResource(random_start_ammo, RES_ROCKETS,cvar("g_random_start_rockets"));
1970                 SetResource(random_start_ammo, RES_CELLS, cvar("g_random_start_cells"));
1971                 SetResource(random_start_ammo, RES_PLASMA, cvar("g_random_start_plasma"));
1972         }
1973
1974         warmup_start_ammo_shells = start_ammo_shells;
1975         warmup_start_ammo_nails = start_ammo_nails;
1976         warmup_start_ammo_rockets = start_ammo_rockets;
1977         warmup_start_ammo_cells = start_ammo_cells;
1978         warmup_start_ammo_plasma = start_ammo_plasma;
1979         warmup_start_ammo_fuel = start_ammo_fuel;
1980         warmup_start_health = start_health;
1981         warmup_start_armorvalue = start_armorvalue;
1982         warmup_start_weapons = start_weapons;
1983         warmup_start_weapons_default = start_weapons_default;
1984         warmup_start_weapons_defaultmask = start_weapons_defaultmask;
1985
1986         if (!g_weaponarena)
1987         {
1988                 warmup_start_ammo_shells = cvar("g_warmup_start_ammo_shells");
1989                 warmup_start_ammo_nails = cvar("g_warmup_start_ammo_nails");
1990                 warmup_start_ammo_rockets = cvar("g_warmup_start_ammo_rockets");
1991                 warmup_start_ammo_cells = cvar("g_warmup_start_ammo_cells");
1992                 warmup_start_ammo_plasma = cvar("g_warmup_start_ammo_plasma");
1993                 warmup_start_ammo_fuel = cvar("g_warmup_start_ammo_fuel");
1994                 warmup_start_health = cvar("g_warmup_start_health");
1995                 warmup_start_armorvalue = cvar("g_warmup_start_armor");
1996                 warmup_start_weapons = '0 0 0';
1997                 warmup_start_weapons_default = '0 0 0';
1998                 warmup_start_weapons_defaultmask = '0 0 0';
1999                 FOREACH(Weapons, it != WEP_Null, {
2000                         int w = want_weapon(it, autocvar_g_warmup_allguns);
2001                         WepSet s = it.m_wepset;
2002                         if(w & 1)
2003                                 warmup_start_weapons |= s;
2004                         if(w & 2)
2005                                 warmup_start_weapons_default |= s;
2006                         if(w & 4)
2007                                 warmup_start_weapons_defaultmask |= s;
2008                 });
2009         }
2010
2011         if (autocvar_g_jetpack)
2012                 start_items |= ITEM_Jetpack.m_itemid;
2013
2014         MUTATOR_CALLHOOK(SetStartItems);
2015
2016         if (start_items & ITEM_Jetpack.m_itemid)
2017         {
2018                 start_items |= ITEM_JetpackRegen.m_itemid;
2019                 start_ammo_fuel = max(start_ammo_fuel, cvar("g_balance_fuel_rotstable"));
2020                 warmup_start_ammo_fuel = max(warmup_start_ammo_fuel, cvar("g_balance_fuel_rotstable"));
2021         }
2022
2023         start_ammo_shells = max(0, start_ammo_shells);
2024         start_ammo_nails = max(0, start_ammo_nails);
2025         start_ammo_rockets = max(0, start_ammo_rockets);
2026         start_ammo_cells = max(0, start_ammo_cells);
2027         start_ammo_plasma = max(0, start_ammo_plasma);
2028         start_ammo_fuel = max(0, start_ammo_fuel);
2029         SetResource(random_start_ammo, RES_SHELLS,
2030                 max(0, GetResource(random_start_ammo, RES_SHELLS)));
2031         SetResource(random_start_ammo, RES_BULLETS,
2032                 max(0, GetResource(random_start_ammo, RES_BULLETS)));
2033         SetResource(random_start_ammo, RES_ROCKETS,
2034                 max(0, GetResource(random_start_ammo, RES_ROCKETS)));
2035         SetResource(random_start_ammo, RES_CELLS,
2036                 max(0, GetResource(random_start_ammo, RES_CELLS)));
2037         SetResource(random_start_ammo, RES_PLASMA,
2038                 max(0, GetResource(random_start_ammo, RES_PLASMA)));
2039
2040         warmup_start_ammo_shells = max(0, warmup_start_ammo_shells);
2041         warmup_start_ammo_nails = max(0, warmup_start_ammo_nails);
2042         warmup_start_ammo_rockets = max(0, warmup_start_ammo_rockets);
2043         warmup_start_ammo_cells = max(0, warmup_start_ammo_cells);
2044         warmup_start_ammo_plasma = max(0, warmup_start_ammo_plasma);
2045         warmup_start_ammo_fuel = max(0, warmup_start_ammo_fuel);
2046 }
2047
2048 void readlevelcvars()
2049 {
2050         if(cvar("sv_allow_fullbright"))
2051                 serverflags |= SERVERFLAG_ALLOW_FULLBRIGHT;
2052
2053         sv_ready_restart_after_countdown = cvar("sv_ready_restart_after_countdown");
2054
2055         warmup_stage = cvar("g_warmup");
2056         warmup_limit = cvar("g_warmup_limit");
2057
2058         if(cvar("g_campaign"))
2059                 warmup_stage = 0; // no warmup during campaign
2060
2061         g_pickup_respawntime_weapon = cvar("g_pickup_respawntime_weapon");
2062         g_pickup_respawntime_superweapon = cvar("g_pickup_respawntime_superweapon");
2063         g_pickup_respawntime_ammo = cvar("g_pickup_respawntime_ammo");
2064         g_pickup_respawntime_short = cvar("g_pickup_respawntime_short");
2065         g_pickup_respawntime_medium = cvar("g_pickup_respawntime_medium");
2066         g_pickup_respawntime_long = cvar("g_pickup_respawntime_long");
2067         g_pickup_respawntime_powerup = cvar("g_pickup_respawntime_powerup");
2068         g_pickup_respawntimejitter_weapon = cvar("g_pickup_respawntimejitter_weapon");
2069         g_pickup_respawntimejitter_superweapon = cvar("g_pickup_respawntimejitter_superweapon");
2070         g_pickup_respawntimejitter_ammo = cvar("g_pickup_respawntimejitter_ammo");
2071         g_pickup_respawntimejitter_short = cvar("g_pickup_respawntimejitter_short");
2072         g_pickup_respawntimejitter_medium = cvar("g_pickup_respawntimejitter_medium");
2073         g_pickup_respawntimejitter_long = cvar("g_pickup_respawntimejitter_long");
2074         g_pickup_respawntimejitter_powerup = cvar("g_pickup_respawntimejitter_powerup");
2075
2076         g_pickup_shells = cvar("g_pickup_shells");
2077         g_pickup_shells_max = cvar("g_pickup_shells_max");
2078         g_pickup_nails = cvar("g_pickup_nails");
2079         g_pickup_nails_max = cvar("g_pickup_nails_max");
2080         g_pickup_rockets = cvar("g_pickup_rockets");
2081         g_pickup_rockets_max = cvar("g_pickup_rockets_max");
2082         g_pickup_cells = cvar("g_pickup_cells");
2083         g_pickup_cells_max = cvar("g_pickup_cells_max");
2084         g_pickup_plasma = cvar("g_pickup_plasma");
2085         g_pickup_plasma_max = cvar("g_pickup_plasma_max");
2086         g_pickup_fuel = cvar("g_pickup_fuel");
2087         g_pickup_fuel_jetpack = cvar("g_pickup_fuel_jetpack");
2088         g_pickup_fuel_max = cvar("g_pickup_fuel_max");
2089         g_pickup_armorsmall = cvar("g_pickup_armorsmall");
2090         g_pickup_armorsmall_max = cvar("g_pickup_armorsmall_max");
2091         g_pickup_armorsmall_anyway = cvar("g_pickup_armorsmall_anyway");
2092         g_pickup_armormedium = cvar("g_pickup_armormedium");
2093         g_pickup_armormedium_max = cvar("g_pickup_armormedium_max");
2094         g_pickup_armormedium_anyway = cvar("g_pickup_armormedium_anyway");
2095         g_pickup_armorbig = cvar("g_pickup_armorbig");
2096         g_pickup_armorbig_max = cvar("g_pickup_armorbig_max");
2097         g_pickup_armorbig_anyway = cvar("g_pickup_armorbig_anyway");
2098         g_pickup_armormega = cvar("g_pickup_armormega");
2099         g_pickup_armormega_max = cvar("g_pickup_armormega_max");
2100         g_pickup_armormega_anyway = cvar("g_pickup_armormega_anyway");
2101         g_pickup_healthsmall = cvar("g_pickup_healthsmall");
2102         g_pickup_healthsmall_max = cvar("g_pickup_healthsmall_max");
2103         g_pickup_healthsmall_anyway = cvar("g_pickup_healthsmall_anyway");
2104         g_pickup_healthmedium = cvar("g_pickup_healthmedium");
2105         g_pickup_healthmedium_max = cvar("g_pickup_healthmedium_max");
2106         g_pickup_healthmedium_anyway = cvar("g_pickup_healthmedium_anyway");
2107         g_pickup_healthbig = cvar("g_pickup_healthbig");
2108         g_pickup_healthbig_max = cvar("g_pickup_healthbig_max");
2109         g_pickup_healthbig_anyway = cvar("g_pickup_healthbig_anyway");
2110         g_pickup_healthmega = cvar("g_pickup_healthmega");
2111         g_pickup_healthmega_max = cvar("g_pickup_healthmega_max");
2112         g_pickup_healthmega_anyway = cvar("g_pickup_healthmega_anyway");
2113
2114         g_pickup_ammo_anyway = cvar("g_pickup_ammo_anyway");
2115         g_pickup_weapons_anyway = cvar("g_pickup_weapons_anyway");
2116
2117     g_weapon_stay = cvar(strcat("g_", GetGametype(), "_weapon_stay"));
2118     if(!g_weapon_stay)
2119         g_weapon_stay = cvar("g_weapon_stay");
2120
2121     MUTATOR_CALLHOOK(ReadLevelCvars);
2122
2123         if (!warmup_stage)
2124                 game_starttime = time + cvar("g_start_delay");
2125
2126         FOREACH(Weapons, it != WEP_Null, { it.wr_init(it); });
2127
2128         readplayerstartcvars();
2129 }
2130
2131 void InitializeEntity(entity e, void(entity this) func, int order)
2132 {
2133     entity prev, cur;
2134
2135     if (!e || e.initialize_entity)
2136     {
2137         // make a proxy initializer entity
2138         entity e_old = e;
2139         e = new(initialize_entity);
2140         e.enemy = e_old;
2141     }
2142
2143     e.initialize_entity = func;
2144     e.initialize_entity_order = order;
2145
2146     cur = initialize_entity_first;
2147     prev = NULL;
2148     for (;;)
2149     {
2150         if (!cur || cur.initialize_entity_order > order)
2151         {
2152             // insert between prev and cur
2153             if (prev)
2154                 prev.initialize_entity_next = e;
2155             else
2156                 initialize_entity_first = e;
2157             e.initialize_entity_next = cur;
2158             return;
2159         }
2160         prev = cur;
2161         cur = cur.initialize_entity_next;
2162     }
2163 }
2164 void InitializeEntitiesRun()
2165 {
2166     entity startoflist = initialize_entity_first;
2167     initialize_entity_first = NULL;
2168     delete_fn = remove_except_protected;
2169     for (entity e = startoflist; e; e = e.initialize_entity_next)
2170     {
2171                 e.remove_except_protected_forbidden = 1;
2172     }
2173     for (entity e = startoflist; e; )
2174     {
2175                 e.remove_except_protected_forbidden = 0;
2176         e.initialize_entity_order = 0;
2177         entity next = e.initialize_entity_next;
2178         e.initialize_entity_next = NULL;
2179         var void(entity this) func = e.initialize_entity;
2180         e.initialize_entity = func_null;
2181         if (e.classname == "initialize_entity")
2182         {
2183             entity wrappee = e.enemy;
2184             builtin_remove(e);
2185             e = wrappee;
2186         }
2187         //dprint("Delayed initialization: ", e.classname, "\n");
2188         if (func)
2189         {
2190                 func(e);
2191         }
2192         else
2193         {
2194             eprint(e);
2195             backtrace(strcat("Null function in: ", e.classname, "\n"));
2196         }
2197         e = next;
2198     }
2199     delete_fn = remove_unsafely;
2200 }
2201
2202 // deferred dropping
2203 void DropToFloor_Handler(entity this)
2204 {
2205         WITHSELF(this, builtin_droptofloor());
2206         this.dropped_origin = this.origin;
2207 }
2208
2209 void droptofloor(entity this)
2210 {
2211         InitializeEntity(this, DropToFloor_Handler, INITPRIO_DROPTOFLOOR);
2212 }
2213
2214 bool autocvar_sv_gameplayfix_multiplethinksperframe = true;
2215 void RunThink(entity this)
2216 {
2217         // don't let things stay in the past.
2218         // it is possible to start that way by a trigger with a local time.
2219         if(this.nextthink <= 0 || this.nextthink > time + frametime)
2220                 return;
2221
2222         float oldtime = time; // do we need to save this?
2223
2224         for (int iterations = 0; iterations < 128 && !wasfreed(this); iterations++)
2225         {
2226                 time = max(oldtime, this.nextthink);
2227                 this.nextthink = 0;
2228
2229                 if(getthink(this))
2230                         getthink(this)(this);
2231                 // mods often set nextthink to time to cause a think every frame,
2232                 // we don't want to loop in that case, so exit if the new nextthink is
2233                 // <= the time the qc was told, also exit if it is past the end of the
2234                 // frame
2235                 if(this.nextthink <= time || this.nextthink > oldtime + frametime || !autocvar_sv_gameplayfix_multiplethinksperframe)
2236                         break;
2237         }
2238
2239         time = oldtime;
2240 }
2241
2242 bool autocvar_sv_freezenonclients;
2243 void Physics_Frame()
2244 {
2245         if(autocvar_sv_freezenonclients)
2246                 return;
2247
2248         IL_EACH(g_moveables, true,
2249         {
2250                 if(IS_CLIENT(it) || it.move_movetype == MOVETYPE_PHYSICS)
2251                         continue;
2252
2253                 //set_movetype(it, it.move_movetype);
2254                 // inline the set_movetype function, since this is called a lot
2255                 it.movetype = (it.move_qcphysics) ? MOVETYPE_QCENTITY : it.move_movetype;
2256
2257                 if(it.move_qcphysics && it.move_movetype != MOVETYPE_NONE)
2258                         Movetype_Physics_NoMatchTicrate(it, PHYS_INPUT_TIMELENGTH, false);
2259
2260                 if(it.movetype >= MOVETYPE_USER_FIRST && it.movetype <= MOVETYPE_USER_LAST) // these cases have no think handling
2261                 {
2262                         if(it.move_movetype == MOVETYPE_PUSH || it.move_movetype == MOVETYPE_FAKEPUSH)
2263                                 continue; // these movetypes have no regular think function
2264                         // handle thinking here
2265                         if (getthink(it) && it.nextthink > 0 && it.nextthink <= time + frametime)
2266                                 RunThink(it);
2267                 }
2268         });
2269
2270         if(autocvar_sv_gameplayfix_delayprojectiles >= 0)
2271                 return;
2272
2273         // make a second pass to see if any ents spawned this frame and make
2274         // sure they run their move/think. this is verified by checking .move_time, which will never be 0 if the entity has moved
2275         // MOVETYPE_NONE is also checked as .move_time WILL be 0 with that movetype
2276         IL_EACH(g_moveables, it.move_qcphysics,
2277         {
2278                 if(IS_CLIENT(it) || it.move_time || it.move_movetype == MOVETYPE_NONE || it.move_movetype == MOVETYPE_PHYSICS)
2279                         continue;
2280                 Movetype_Physics_NoMatchTicrate(it, PHYS_INPUT_TIMELENGTH, false);
2281         });
2282 }
2283
2284 void systems_update();
2285 void EndFrame()
2286 {
2287         anticheat_endframe();
2288
2289         Physics_Frame();
2290
2291         FOREACH_CLIENT(IS_REAL_CLIENT(it), {
2292                 entity e = IS_SPEC(it) ? it.enemy : it;
2293                 if (e.typehitsound) {
2294                         STAT(TYPEHIT_TIME, it) = time;
2295                 } else if (e.killsound) {
2296                         STAT(KILL_TIME, it) = time;
2297                 } else if (e.damage_dealt) {
2298                         STAT(HIT_TIME, it) = time;
2299                         STAT(DAMAGE_DEALT_TOTAL, it) += ceil(e.damage_dealt);
2300                 }
2301         });
2302         // add 1 frametime because after this, engine SV_Physics
2303         // increases time by a frametime and then networks the frame
2304         // add another frametime because client shows everything with
2305         // 1 frame of lag (cl_nolerp 0). The last +1 however should not be
2306         // needed!
2307         float altime = time + frametime * (1 + autocvar_g_antilag_nudge);
2308         FOREACH_CLIENT(true, {
2309                 it.typehitsound = false;
2310                 it.damage_dealt = 0;
2311                 it.killsound = false;
2312                 antilag_record(it, CS(it), altime);
2313         });
2314         IL_EACH(g_monsters, true,
2315         {
2316                 antilag_record(it, it, altime);
2317         });
2318         IL_EACH(g_projectiles, it.classname == "nade",
2319         {
2320                 antilag_record(it, it, altime);
2321         });
2322         systems_update();
2323         IL_ENDFRAME();
2324 }
2325
2326
2327 /*
2328  * RedirectionThink:
2329  * returns true if redirecting
2330  */
2331 float redirection_timeout;
2332 float redirection_nextthink;
2333 float RedirectionThink()
2334 {
2335         float clients_found;
2336
2337         if(redirection_target == "")
2338                 return false;
2339
2340         if(!redirection_timeout)
2341         {
2342                 cvar_set("sv_public", "-2");
2343                 redirection_timeout = time + 0.6; // this will only try twice... should be able to keep more clients
2344                 if(redirection_target == "self")
2345                         bprint("^3SERVER NOTICE:^7 restarting the server\n");
2346                 else
2347                         bprint("^3SERVER NOTICE:^7 redirecting everyone to ", redirection_target, "\n");
2348         }
2349
2350         if(time < redirection_nextthink)
2351                 return true;
2352
2353         redirection_nextthink = time + 1;
2354
2355         clients_found = 0;
2356         FOREACH_CLIENT(IS_REAL_CLIENT(it), {
2357                 // TODO add timer
2358                 LOG_INFO("Redirecting: sending connect command to ", it.netname);
2359                 if(redirection_target == "self")
2360                         stuffcmd(it, "\ndisconnect; defer ", ftos(autocvar_quit_and_redirect_timer), " reconnect\n");
2361                 else
2362                         stuffcmd(it, strcat("\ndisconnect; defer ", ftos(autocvar_quit_and_redirect_timer), " \"connect ", redirection_target, "\"\n"));
2363                 ++clients_found;
2364         });
2365
2366         LOG_INFO("Redirecting: ", ftos(clients_found), " clients left.");
2367
2368         if(time > redirection_timeout || clients_found == 0)
2369                 localcmd("\nwait; wait; wait; quit\n");
2370
2371         return true;
2372 }
2373
2374 void RestoreGame()
2375 {
2376         // Loaded from a save game
2377         // some things then break, so let's work around them...
2378
2379         // Progs DB (capture records)
2380         ServerProgsDB = db_load(strcat("server.db", autocvar_sessionid));
2381
2382         // Mapinfo
2383         MapInfo_Shutdown();
2384         MapInfo_Enumerate();
2385         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 1);
2386         WeaponStats_Init();
2387
2388         TargetMusic_RestoreGame();
2389 }
2390
2391 void Shutdown()
2392 {
2393         game_stopped = 2;
2394
2395         if(world_initialized > 0)
2396         {
2397                 world_initialized = 0;
2398
2399                 // if a timeout is active, reset the slowmo value to normal
2400                 if(timeout_status == TIMEOUT_ACTIVE)
2401                         cvar_set("slowmo", ftos(orig_slowmo));
2402
2403                 LOG_TRACE("Saving persistent data...");
2404                 Ban_SaveBans();
2405
2406                 // playerstats with unfinished match
2407                 PlayerStats_GameReport(false);
2408
2409                 if(!cheatcount_total)
2410                 {
2411                         if(autocvar_sv_db_saveasdump)
2412                                 db_dump(ServerProgsDB, strcat("server.db", autocvar_sessionid));
2413                         else
2414                                 db_save(ServerProgsDB, strcat("server.db", autocvar_sessionid));
2415                 }
2416                 if(autocvar_developer > 0)
2417                 {
2418                         if(autocvar_sv_db_saveasdump)
2419                                 db_dump(TemporaryDB, "server-temp.db");
2420                         else
2421                                 db_save(TemporaryDB, "server-temp.db");
2422                 }
2423                 CheatShutdown(); // must be after cheatcount check
2424                 db_close(ServerProgsDB);
2425                 db_close(TemporaryDB);
2426                 LOG_TRACE("Saving persistent data... done!");
2427                 // tell the bot system the game is ending now
2428                 bot_endgame();
2429
2430                 WeaponStats_Shutdown();
2431                 MapInfo_Shutdown();
2432         }
2433         else if(world_initialized == 0)
2434         {
2435                 LOG_INFO("NOTE: crashed before even initializing the world, not saving persistent data");
2436         }
2437         else
2438         {
2439                 __init_dedicated_server_shutdown();
2440         }
2441 }