qcsrc/warpzonelib/client.qc

   1 void WarpZone_Fade_PreDraw()
   2 {
   3         if(self.warpzone_fadestart)
   4         {
   5                 vector org;
   6                 org = R_SetView3fv(VF_ORIGIN);
   7                 self.alpha = bound(0, (self.warpzone_fadeend - vlen(org - self.origin - 0.5 * (self.mins + self.maxs))) / (self.warpzone_fadeend - self.warpzone_fadestart), 1);
   8         }
   9         else
  10                 self.alpha = 1;
  11         //print(sprintf("%v <-> %v\n", view_origin, self.origin + 0.5 * (self.mins + self.maxs)));
  12         if(self.alpha <= 0)
  13                 self.drawmask = 0;
  14         else
  15                 self.drawmask = MASK_NORMAL;
  16 }
  17
  18 void WarpZone_Read(float isnew)
  19 {
  20         float f;
  21
  22         warpzone_warpzones_exist = 1;
  23         if not(self.enemy)
  24         {
  25                 self.enemy = spawn();
  26                 self.enemy.classname = "warpzone_from";
  27         }
  28         self.classname = "trigger_warpzone";
  29
  30         f = ReadByte();
  31         self.warpzone_isboxy = (f & 1);
  32         if(f & 4)
  33         {
  34                 self.origin_x = ReadCoord();
  35                 self.origin_y = ReadCoord();
  36                 self.origin_z = ReadCoord();
  37         }
  38         else
  39                 self.origin = '0 0 0';
  40         self.modelindex = ReadShort();
  41         self.mins_x = ReadCoord();
  42         self.mins_y = ReadCoord();
  43         self.mins_z = ReadCoord();
  44         self.maxs_x = ReadCoord();
  45         self.maxs_y = ReadCoord();
  46         self.maxs_z = ReadCoord();
  47         self.scale = ReadByte() / 16;
  48         self.enemy.oldorigin_x = ReadCoord();
  49         self.enemy.oldorigin_y = ReadCoord();
  50         self.enemy.oldorigin_z = ReadCoord();
  51         self.enemy.avelocity_x = ReadCoord();
  52         self.enemy.avelocity_y = ReadCoord();
  53         self.enemy.avelocity_z = ReadCoord();
  54         self.oldorigin_x = ReadCoord();
  55         self.oldorigin_y = ReadCoord();
  56         self.oldorigin_z = ReadCoord();
  57         self.avelocity_x = ReadCoord();
  58         self.avelocity_y = ReadCoord();
  59         self.avelocity_z = ReadCoord();
  60
  61         if(f & 2)
  62         {
  63                 self.warpzone_fadestart = ReadShort();
  64                 self.warpzone_fadeend = max(self.warpzone_fadestart + 1, ReadShort());
  65         }
  66         else
  67         {
  68                 self.warpzone_fadestart = 0;
  69                 self.warpzone_fadeend = 0;
  70         }
  71
  72         // common stuff
  73         WarpZone_SetUp(self, self.enemy.oldorigin, self.enemy.avelocity, self.oldorigin, self.avelocity);
  74
  75         // link me
  76         //setmodel(self, self.model);
  77         setorigin(self, self.origin);
  78         setsize(self, self.mins, self.maxs);
  79
  80         // how to draw
  81         // engine currently wants this
  82         if(self.warpzone_fadestart)
  83                 self.predraw = WarpZone_Fade_PreDraw;
  84         else
  85                 self.drawmask = MASK_NORMAL;
  86 }
  87
  88 void WarpZone_Camera_Read(float isnew)
  89 {
  90         float f;
  91         warpzone_cameras_exist = 1;
  92         self.classname = "func_warpzone_camera";
  93
  94         f = ReadByte();
  95         if(f & 4)
  96         {
  97                 self.origin_x = ReadCoord();
  98                 self.origin_y = ReadCoord();
  99                 self.origin_z = ReadCoord();
 100         }
 101         else
 102                 self.origin = '0 0 0';
 103         self.modelindex = ReadShort();
 104         self.mins_x = ReadCoord();
 105         self.mins_y = ReadCoord();
 106         self.mins_z = ReadCoord();
 107         self.maxs_x = ReadCoord();
 108         self.maxs_y = ReadCoord();
 109         self.maxs_z = ReadCoord();
 110         self.scale = ReadByte() / 16;
 111         self.oldorigin_x = ReadCoord();
 112         self.oldorigin_y = ReadCoord();
 113         self.oldorigin_z = ReadCoord();
 114         self.avelocity_x = ReadCoord();
 115         self.avelocity_y = ReadCoord();
 116         self.avelocity_z = ReadCoord();
 117
 118         if(f & 2)
 119         {
 120                 self.warpzone_fadestart = ReadShort();
 121                 self.warpzone_fadeend = max(self.warpzone_fadestart + 1, ReadShort());
 122         }
 123         else
 124         {
 125                 self.warpzone_fadestart = 0;
 126                 self.warpzone_fadeend = 0;
 127         }
 128
 129         // common stuff
 130         WarpZone_Camera_SetUp(self, self.oldorigin, self.avelocity);
 131
 132         // engine currently wants this
 133         self.drawmask = MASK_NORMAL;
 134
 135         // link me
 136         //setmodel(self, self.model);
 137         setorigin(self, self.origin);
 138         setsize(self, self.mins, self.maxs);
 139
 140         // how to draw
 141         // engine currently wants this
 142         if(self.warpzone_fadestart)
 143                 self.predraw = WarpZone_Fade_PreDraw;
 144         else
 145                 self.drawmask = MASK_NORMAL;
 146 }
 147
 148 void CL_RotateMoves(vector ang) = #638;
 149 void WarpZone_Teleported_Read(float isnew)
 150 {
 151         vector v;
 152         self.classname = "warpzone_teleported";
 153         v_x = ReadCoord();
 154         v_y = ReadCoord();
 155         v_z = ReadCoord();
 156         if(!isnew)
 157                 return;
 158         self.warpzone_transform = v;
 159         R_SetView3fv(VF_CL_VIEWANGLES, WarpZone_TransformVAngles(self, R_SetView3fv(VF_CL_VIEWANGLES)));
 160         if(checkextension("DP_CSQC_ROTATEMOVES"))
 161                 CL_RotateMoves(v);
 162                 //CL_RotateMoves('0 90 0');
 163 }
 164
 165 float warpzone_fixingview;
 166 float warpzone_fixingview_drawexteriormodel;
 167 //float warpzone_fixingview_sidespeed;
 168 //float warpzone_fixingview_forwardspeed;
 169 void WarpZone_Inside()
 170 {
 171         if(warpzone_fixingview)
 172                 return;
 173         warpzone_fixingview = 1;
 174         warpzone_fixingview_drawexteriormodel = cvar("r_drawexteriormodel");
 175         //warpzone_fixingview_sidespeed = cvar("cl_sidespeed");
 176         //warpzone_fixingview_forwardspeed = cvar("cl_forwardspeed");
 177         cvar_set("r_drawexteriormodel", "0");
 178         //cvar_set("cl_sidespeed", ftos(warpzone_fixingview_sidespeed / 100)); // just keep a bit of it in case player gets stuck
 179         //cvar_set("cl_forwardspeed", ftos(warpzone_fixingview_forwardspeed / 100)); // just keep a bit of it in case player gets stuck
 180 }
 181
 182 void WarpZone_Outside()
 183 {
 184         if(!warpzone_fixingview)
 185                 return;
 186         warpzone_fixingview = 0;
 187         cvar_set("r_drawexteriormodel", ftos(warpzone_fixingview_drawexteriormodel));
 188         //cvar_set("cl_sidespeed", ftos(warpzone_fixingview_sidespeed));
 189         //cvar_set("cl_forwardspeed", ftos(warpzone_fixingview_forwardspeed));
 190 }
 191
 192 vector WarpZone_FixNearClip(vector o, vector c0, vector c1, vector c2, vector c3)
 193 {
 194         vector mi, ma;
 195         entity e;
 196         float pd;
 197
 198         mi_x = min5(o_x, c0_x, c1_x, c2_x, c3_x);
 199         ma_x = max5(o_x, c0_x, c1_x, c2_x, c3_x);
 200         mi_y = min5(o_y, c0_y, c1_y, c2_y, c3_y);
 201         ma_y = max5(o_y, c0_y, c1_y, c2_y, c3_y);
 202         mi_z = min5(o_z, c0_z, c1_z, c2_z, c3_z);
 203         ma_z = max5(o_z, c0_z, c1_z, c2_z, c3_z);
 204
 205         e = WarpZone_Find(mi, ma);
 206         if(e)
 207         {
 208                 if(WarpZone_PlaneDist(e, o) < 0)
 209                         return '0 0 0';
 210                         // can't really be, though, but if it is, this is not my warpzone, but a random different one in the same mins/maxs
 211                 pd = min4(
 212                                 WarpZone_PlaneDist(e, c0),
 213                                 WarpZone_PlaneDist(e, c1),
 214                                 WarpZone_PlaneDist(e, c2),
 215                                 WarpZone_PlaneDist(e, c3)
 216                         );
 217                 if(pd < 0)
 218                         return e.warpzone_forward * -pd;
 219         }
 220
 221         return '0 0 0';
 222 }
 223
 224 float warpzone_saved;
 225 vector warpzone_saved_origin;
 226 vector warpzone_saved_angles;
 227 vector warpzone_saved_cl_viewangles;
 228 #ifndef KEEP_ROLL
 229 var float autocvar_cl_rollkillspeed = 10;
 230 #endif
 231 void WarpZone_FixView()
 232 {
 233         float f;
 234         vector o;
 235         entity e;
 236         vector corner0, corner1, corner2, corner3, nearclip;
 237
 238         warpzone_saved = 0;
 239         warpzone_saved_origin = warpzone_fixview_origin;
 240         warpzone_saved_angles = warpzone_fixview_angles;
 241         warpzone_saved_cl_viewangles = warpzone_fixview_cl_viewangles;
 242
 243         nearclip = '0 0 1' * (cvar("r_nearclip") * 1.125);
 244         corner0 = cs_unproject('0 0 0' + nearclip);
 245         corner1 = cs_unproject('1 0 0' * cvar("vid_conwidth") + nearclip);
 246         corner2 = cs_unproject('0 1 0' * cvar("vid_conheight") + nearclip);
 247         corner3 = cs_unproject('1 0 0' * cvar("vid_conwidth") + '0 1 0' * cvar("vid_conheight") + nearclip);
 248
 249 #ifndef KEEP_ROLL
 250         if(warpzone_fixview_angles_z != 0 || warpzone_fixview_cl_viewangles_z != 0)
 251         {
 252                 if(autocvar_cl_rollkillspeed)
 253                         f = max(0, (1 - frametime * autocvar_cl_rollkillspeed));
 254                 else
 255                         f = 0;
 256                 warpzone_fixview_angles_z *= f;
 257                 warpzone_fixview_cl_viewangles_z *= f;
 258                 warpzone_saved_angles_z *= f; // PERMANENTLY apply that change!
 259                 warpzone_saved_cl_viewangles_z *= f; // PERMANENTLY apply that change!
 260                 warpzone_saved = 2;
 261                 R_SetView(VF_CL_VIEWANGLES_Z, warpzone_fixview_angles_z);
 262         }
 263 #endif
 264
 265         e = WarpZone_Find(warpzone_fixview_origin, warpzone_fixview_origin);
 266         if(e)
 267         {
 268                 warpzone_saved = 1;
 269                 warpzone_fixview_origin = WarpZone_TransformOrigin(e, warpzone_fixview_origin);
 270                 corner0 = WarpZone_TransformOrigin(e, corner0);
 271                 corner1 = WarpZone_TransformOrigin(e, corner1);
 272                 corner2 = WarpZone_TransformOrigin(e, corner2);
 273                 corner3 = WarpZone_TransformOrigin(e, corner3);
 274                 warpzone_fixview_angles = WarpZone_TransformVAngles(e, warpzone_fixview_angles);
 275                 warpzone_fixview_cl_viewangles = WarpZone_TransformVAngles(e, warpzone_fixview_cl_viewangles);
 276                 WarpZone_Inside();
 277         }
 278         else
 279                 WarpZone_Outside();
 280
 281         // if we are near any warpzone planes - MOVE AWAY (work around nearclip)
 282         o = WarpZone_FixNearClip(warpzone_fixview_origin, corner0, corner1, corner2, corner3);
 283         if(o != '0 0 0')
 284         {
 285                 warpzone_saved = 1;
 286                 warpzone_fixview_origin += o;
 287         }
 288
 289         if(warpzone_saved == 1)
 290         {
 291                 R_SetView(VF_ORIGIN, warpzone_fixview_origin);
 292                 R_SetView(VF_ANGLES, warpzone_fixview_cl_viewangles);
 293         }
 294 }
 295 void WarpZone_UnFixView()
 296 {
 297         if(warpzone_saved)
 298         {
 299                 warpzone_fixview_origin = warpzone_saved_origin;
 300                 warpzone_fixview_angles = warpzone_saved_angles;
 301                 warpzone_fixview_cl_viewangles = warpzone_saved_cl_viewangles;
 302                 R_SetView(VF_ORIGIN, warpzone_fixview_origin);
 303                 R_SetView(VF_ANGLES, warpzone_fixview_angles);
 304                 R_SetView(VF_CL_VIEWANGLES, warpzone_fixview_cl_viewangles);
 305         }
 306 }
 307
 308 void WarpZone_Init()
 309 {
 310 }
 311
 312 void WarpZone_Shutdown()
 313 {
 314         WarpZone_Outside();
 315 }