qcsrc/warpzonelib/client.qc

   1 void WarpZone_Read(float isnew)
   2 {
   3         if not(self.enemy)
   4         {
   5                 self.enemy = spawn();
   6                 self.enemy.classname = "warpzone_from";
   7         }
   8         self.classname = "trigger_warpzone";
   9
  10         self.warpzone_isboxy = ReadByte();
  11         self.origin_x = ReadCoord();
  12         self.origin_y = ReadCoord();
  13         self.origin_z = ReadCoord();
  14         self.modelindex = ReadShort();
  15         self.mins_x = ReadCoord();
  16         self.mins_y = ReadCoord();
  17         self.mins_z = ReadCoord();
  18         self.maxs_x = ReadCoord();
  19         self.maxs_y = ReadCoord();
  20         self.maxs_z = ReadCoord();
  21         self.scale = ReadByte() / 16;
  22         self.enemy.oldorigin_x = ReadCoord();
  23         self.enemy.oldorigin_y = ReadCoord();
  24         self.enemy.oldorigin_z = ReadCoord();
  25         self.enemy.avelocity_x = ReadCoord();
  26         self.enemy.avelocity_y = ReadCoord();
  27         self.enemy.avelocity_z = ReadCoord();
  28         self.oldorigin_x = ReadCoord();
  29         self.oldorigin_y = ReadCoord();
  30         self.oldorigin_z = ReadCoord();
  31         self.avelocity_x = ReadCoord();
  32         self.avelocity_y = ReadCoord();
  33         self.avelocity_z = ReadCoord();
  34
  35         // common stuff
  36         WarpZone_SetUp(self, self.enemy.oldorigin, self.enemy.avelocity, self.oldorigin, self.avelocity);
  37
  38         // engine currently wants this
  39         self.drawmask = MASK_NORMAL;
  40
  41         // link me
  42         //setmodel(self, self.model);
  43         setorigin(self, self.origin);
  44         setsize(self, self.mins, self.maxs);
  45 }
  46
  47 void WarpZone_Camera_Read(float isnew)
  48 {
  49         self.classname = "func_warpzone_camera";
  50         self.origin_x = ReadCoord();
  51         self.origin_y = ReadCoord();
  52         self.origin_z = ReadCoord();
  53         self.modelindex = ReadShort();
  54         self.mins_x = ReadCoord();
  55         self.mins_y = ReadCoord();
  56         self.mins_z = ReadCoord();
  57         self.maxs_x = ReadCoord();
  58         self.maxs_y = ReadCoord();
  59         self.maxs_z = ReadCoord();
  60         self.scale = ReadByte() / 16;
  61         self.oldorigin_x = ReadCoord();
  62         self.oldorigin_y = ReadCoord();
  63         self.oldorigin_z = ReadCoord();
  64         self.avelocity_x = ReadCoord();
  65         self.avelocity_y = ReadCoord();
  66         self.avelocity_z = ReadCoord();
  67
  68         // common stuff
  69         WarpZone_Camera_SetUp(self, self.oldorigin, self.avelocity);
  70
  71         // engine currently wants this
  72         self.drawmask = MASK_NORMAL;
  73
  74         // link me
  75         //setmodel(self, self.model);
  76         setorigin(self, self.origin);
  77         setsize(self, self.mins, self.maxs);
  78 }
  79
  80 float warpzone_fixingview;
  81 float warpzone_fixingview_drawexteriormodel;
  82 //float warpzone_fixingview_sidespeed;
  83 //float warpzone_fixingview_forwardspeed;
  84 void WarpZone_Inside()
  85 {
  86         if(warpzone_fixingview)
  87                 return;
  88         warpzone_fixingview = 1;
  89         warpzone_fixingview_drawexteriormodel = cvar("r_drawexteriormodel");
  90         //warpzone_fixingview_sidespeed = cvar("cl_sidespeed");
  91         //warpzone_fixingview_forwardspeed = cvar("cl_forwardspeed");
  92         cvar_set("r_drawexteriormodel", "0");
  93         //cvar_set("cl_sidespeed", ftos(warpzone_fixingview_sidespeed / 100)); // just keep a bit of it in case player gets stuck
  94         //cvar_set("cl_forwardspeed", ftos(warpzone_fixingview_forwardspeed / 100)); // just keep a bit of it in case player gets stuck
  95 }
  96
  97 void WarpZone_Outside()
  98 {
  99         if(!warpzone_fixingview)
 100                 return;
 101         warpzone_fixingview = 0;
 102         cvar_set("r_drawexteriormodel", ftos(warpzone_fixingview_drawexteriormodel));
 103         //cvar_set("cl_sidespeed", ftos(warpzone_fixingview_sidespeed));
 104         //cvar_set("cl_forwardspeed", ftos(warpzone_fixingview_forwardspeed));
 105 }
 106
 107 vector WarpZone_FixNearClip(vector o, vector c0, vector c1, vector c2, vector c3)
 108 {
 109         float nearclipdistance;
 110         vector mi, ma;
 111         entity e;
 112         float pd;
 113
 114         mi_x = min5(o_x, c0_x, c1_x, c2_x, c3_x);
 115         ma_x = max5(o_x, c0_x, c1_x, c2_x, c3_x);
 116         mi_y = min5(o_y, c0_y, c1_y, c2_y, c3_y);
 117         ma_y = max5(o_y, c0_y, c1_y, c2_y, c3_y);
 118         mi_z = min5(o_z, c0_z, c1_z, c2_z, c3_z);
 119         ma_z = max5(o_z, c0_z, c1_z, c2_z, c3_z);
 120
 121         e = WarpZone_Find(mi, ma);
 122         if(e)
 123         {
 124                 if(WarpZone_PlaneDist(e, o) < 0)
 125                         return '0 0 0';
 126                         // can't really be, though, but if it is, this is not my warpzone, but a random different one in the same mins/maxs
 127                 pd = min4(
 128                                 WarpZone_PlaneDist(e, c0),
 129                                 WarpZone_PlaneDist(e, c1),
 130                                 WarpZone_PlaneDist(e, c2),
 131                                 WarpZone_PlaneDist(e, c3)
 132                         );
 133                 if(pd < 0)
 134                         return e.warpzone_forward * -pd;
 135         }
 136
 137         return '0 0 0';
 138 }
 139
 140 float warpzone_saved;
 141 vector warpzone_saved_origin;
 142 vector warpzone_saved_angles;
 143 vector warpzone_saved_cl_viewangles;
 144 #ifndef KEEP_ROLL
 145 var float autocvar_cl_rollkillspeed = 10;
 146 #endif
 147 void WarpZone_FixView()
 148 {
 149         float pd, f;
 150         vector o;
 151         entity e;
 152         vector corner0, corner1, corner2, corner3, nearclip;
 153
 154         warpzone_saved = 0;
 155         warpzone_saved_origin = warpzone_fixview_origin;
 156         warpzone_saved_angles = warpzone_fixview_angles;
 157         warpzone_saved_cl_viewangles = warpzone_fixview_cl_viewangles;
 158
 159         nearclip = '0 0 1' * (cvar("r_nearclip") * 1.125);
 160         corner0 = cs_unproject('0 0 0' + nearclip);
 161         corner1 = cs_unproject('1 0 0' * cvar("vid_conwidth") + nearclip);
 162         corner2 = cs_unproject('0 1 0' * cvar("vid_conheight") + nearclip);
 163         corner3 = cs_unproject('1 0 0' * cvar("vid_conwidth") + '0 1 0' * cvar("vid_conheight") + nearclip);
 164
 165 #ifndef KEEP_ROLL
 166         if(warpzone_fixview_angles_z != 0 || warpzone_fixview_cl_viewangles_z != 0)
 167         {
 168                 if(autocvar_cl_rollkillspeed)
 169                         f = max(0, (1 - frametime * autocvar_cl_rollkillspeed));
 170                 else
 171                         f = 0;
 172                 warpzone_fixview_angles_z *= f;
 173                 warpzone_fixview_cl_viewangles_z *= f;
 174                 warpzone_saved_angles_z *= f; // PERMANENTLY apply that change!
 175                 warpzone_saved_cl_viewangles_z *= f; // PERMANENTLY apply that change!
 176                 warpzone_saved = 2;
 177                 R_SetView(VF_CL_VIEWANGLES_Z, warpzone_fixview_angles_z);
 178         }
 179 #endif
 180
 181         e = WarpZone_Find(warpzone_fixview_origin, warpzone_fixview_origin);
 182         if(e)
 183         {
 184                 warpzone_saved = 1;
 185                 warpzone_fixview_origin = WarpZone_TransformOrigin(e, warpzone_fixview_origin);
 186                 corner0 = WarpZone_TransformOrigin(e, corner0);
 187                 corner1 = WarpZone_TransformOrigin(e, corner1);
 188                 corner2 = WarpZone_TransformOrigin(e, corner2);
 189                 corner3 = WarpZone_TransformOrigin(e, corner3);
 190                 warpzone_fixview_angles = WarpZone_TransformVAngles(e, warpzone_fixview_angles);
 191                 warpzone_fixview_cl_viewangles = WarpZone_TransformVAngles(e, warpzone_fixview_cl_viewangles);
 192                 WarpZone_Inside();
 193         }
 194         else
 195                 WarpZone_Outside();
 196
 197         // if we are near any warpzone planes - MOVE AWAY (work around nearclip)
 198         o = WarpZone_FixNearClip(warpzone_fixview_origin, corner0, corner1, corner2, corner3);
 199         if(o != '0 0 0')
 200         {
 201                 warpzone_saved = 1;
 202                 warpzone_fixview_origin += o;
 203         }
 204
 205         if(warpzone_saved == 1)
 206         {
 207                 R_SetView(VF_ORIGIN, warpzone_fixview_origin);
 208                 R_SetView(VF_ANGLES, warpzone_fixview_cl_viewangles);
 209         }
 210 }
 211 void WarpZone_UnFixView()
 212 {
 213         if(warpzone_saved)
 214         {
 215                 warpzone_fixview_origin = warpzone_saved_origin;
 216                 warpzone_fixview_angles = warpzone_saved_angles;
 217                 warpzone_fixview_cl_viewangles = warpzone_saved_cl_viewangles;
 218                 R_SetView(VF_ORIGIN, warpzone_fixview_origin);
 219                 R_SetView(VF_ANGLES, warpzone_fixview_angles);
 220                 R_SetView(VF_CL_VIEWANGLES, warpzone_fixview_cl_viewangles);
 221         }
 222 }
 223
 224 void WarpZone_Init()
 225 {
 226 }
 227
 228 void WarpZone_Shutdown()
 229 {
 230         WarpZone_Outside();
 231 }