qcsrc/warpzonelib/client.qc

   1 void WarpZone_Fade_PreDraw()
   2 {
   3         if(self.warpzone_fadestart)
   4                 self.alpha = (self.warpzone_fadeend - vlen(view_origin - self.origin - 0.5 * (self.mins + self.maxs))) / (self.warpzone_fadeend - self.warpzone_fadestart);
   5         else
   6                 self.alpha = 1;
   7         if(self.alpha <= 0)
   8                 self.drawmask = 0;
   9         else
  10                 self.drawmask = MASK_NORMAL;
  11 }
  12
  13 void WarpZone_Read(float isnew)
  14 {
  15         float f;
  16
  17         ++warpzone_warpzones_exist;
  18         if not(self.enemy)
  19         {
  20                 self.enemy = spawn();
  21                 self.enemy.classname = "warpzone_from";
  22         }
  23         self.classname = "trigger_warpzone";
  24
  25         f = ReadByte();
  26         self.warpzone_isboxy = (f & 1);
  27         if(f & 4)
  28         {
  29                 self.origin_x = ReadCoord();
  30                 self.origin_y = ReadCoord();
  31                 self.origin_z = ReadCoord();
  32         }
  33         else
  34                 self.origin = '0 0 0';
  35         self.modelindex = ReadShort();
  36         self.mins_x = ReadCoord();
  37         self.mins_y = ReadCoord();
  38         self.mins_z = ReadCoord();
  39         self.maxs_x = ReadCoord();
  40         self.maxs_y = ReadCoord();
  41         self.maxs_z = ReadCoord();
  42         self.scale = ReadByte() / 16;
  43         self.enemy.oldorigin_x = ReadCoord();
  44         self.enemy.oldorigin_y = ReadCoord();
  45         self.enemy.oldorigin_z = ReadCoord();
  46         self.enemy.avelocity_x = ReadCoord();
  47         self.enemy.avelocity_y = ReadCoord();
  48         self.enemy.avelocity_z = ReadCoord();
  49         self.oldorigin_x = ReadCoord();
  50         self.oldorigin_y = ReadCoord();
  51         self.oldorigin_z = ReadCoord();
  52         self.avelocity_x = ReadCoord();
  53         self.avelocity_y = ReadCoord();
  54         self.avelocity_z = ReadCoord();
  55
  56         if(f & 2)
  57         {
  58                 self.warpzone_fadestart = ReadShort();
  59                 self.warpzone_fadeend = max(self.warpzone_fadestart + 1, ReadShort());
  60         }
  61         else
  62         {
  63                 self.warpzone_fadestart = 0;
  64                 self.warpzone_fadeend = 0;
  65         }
  66
  67         // common stuff
  68         WarpZone_SetUp(self, self.enemy.oldorigin, self.enemy.avelocity, self.oldorigin, self.avelocity);
  69
  70         // link me
  71         //setmodel(self, self.model);
  72         setorigin(self, self.origin);
  73         setsize(self, self.mins, self.maxs);
  74
  75         // how to draw
  76         // engine currently wants this
  77         if(self.warpzone_fadestart)
  78                 self.predraw = WarpZone_Fade_PreDraw;
  79         else
  80                 self.drawmask = MASK_NORMAL;
  81 }
  82
  83 void WarpZone_Camera_Read(float isnew)
  84 {
  85         float f;
  86         ++warpzone_cameras_exist;
  87         self.classname = "func_warpzone_camera";
  88
  89         f = ReadByte();
  90         if(f & 4)
  91         {
  92                 self.origin_x = ReadCoord();
  93                 self.origin_y = ReadCoord();
  94                 self.origin_z = ReadCoord();
  95         }
  96         else
  97                 self.origin = '0 0 0';
  98         self.modelindex = ReadShort();
  99         self.mins_x = ReadCoord();
 100         self.mins_y = ReadCoord();
 101         self.mins_z = ReadCoord();
 102         self.maxs_x = ReadCoord();
 103         self.maxs_y = ReadCoord();
 104         self.maxs_z = ReadCoord();
 105         self.scale = ReadByte() / 16;
 106         self.oldorigin_x = ReadCoord();
 107         self.oldorigin_y = ReadCoord();
 108         self.oldorigin_z = ReadCoord();
 109         self.avelocity_x = ReadCoord();
 110         self.avelocity_y = ReadCoord();
 111         self.avelocity_z = ReadCoord();
 112
 113         if(f & 2)
 114         {
 115                 self.warpzone_fadestart = ReadShort();
 116                 self.warpzone_fadeend = max(self.warpzone_fadestart + 1, ReadShort());
 117         }
 118         else
 119         {
 120                 self.warpzone_fadestart = 0;
 121                 self.warpzone_fadeend = 0;
 122         }
 123
 124         // common stuff
 125         WarpZone_Camera_SetUp(self, self.oldorigin, self.avelocity);
 126
 127         // engine currently wants this
 128         self.drawmask = MASK_NORMAL;
 129
 130         // link me
 131         //setmodel(self, self.model);
 132         setorigin(self, self.origin);
 133         setsize(self, self.mins, self.maxs);
 134
 135         // how to draw
 136         // engine currently wants this
 137         if(self.warpzone_fadestart)
 138                 self.predraw = WarpZone_Fade_PreDraw;
 139         else
 140                 self.drawmask = MASK_NORMAL;
 141 }
 142
 143 float warpzone_fixingview;
 144 float warpzone_fixingview_drawexteriormodel;
 145 //float warpzone_fixingview_sidespeed;
 146 //float warpzone_fixingview_forwardspeed;
 147 void WarpZone_Inside()
 148 {
 149         if(warpzone_fixingview)
 150                 return;
 151         warpzone_fixingview = 1;
 152         warpzone_fixingview_drawexteriormodel = cvar("r_drawexteriormodel");
 153         //warpzone_fixingview_sidespeed = cvar("cl_sidespeed");
 154         //warpzone_fixingview_forwardspeed = cvar("cl_forwardspeed");
 155         cvar_set("r_drawexteriormodel", "0");
 156         //cvar_set("cl_sidespeed", ftos(warpzone_fixingview_sidespeed / 100)); // just keep a bit of it in case player gets stuck
 157         //cvar_set("cl_forwardspeed", ftos(warpzone_fixingview_forwardspeed / 100)); // just keep a bit of it in case player gets stuck
 158 }
 159
 160 void WarpZone_Outside()
 161 {
 162         if(!warpzone_fixingview)
 163                 return;
 164         warpzone_fixingview = 0;
 165         cvar_set("r_drawexteriormodel", ftos(warpzone_fixingview_drawexteriormodel));
 166         //cvar_set("cl_sidespeed", ftos(warpzone_fixingview_sidespeed));
 167         //cvar_set("cl_forwardspeed", ftos(warpzone_fixingview_forwardspeed));
 168 }
 169
 170 vector WarpZone_FixNearClip(vector o, vector c0, vector c1, vector c2, vector c3)
 171 {
 172         float nearclipdistance;
 173         vector mi, ma;
 174         entity e;
 175         float pd;
 176
 177         mi_x = min5(o_x, c0_x, c1_x, c2_x, c3_x);
 178         ma_x = max5(o_x, c0_x, c1_x, c2_x, c3_x);
 179         mi_y = min5(o_y, c0_y, c1_y, c2_y, c3_y);
 180         ma_y = max5(o_y, c0_y, c1_y, c2_y, c3_y);
 181         mi_z = min5(o_z, c0_z, c1_z, c2_z, c3_z);
 182         ma_z = max5(o_z, c0_z, c1_z, c2_z, c3_z);
 183
 184         e = WarpZone_Find(mi, ma);
 185         if(e)
 186         {
 187                 if(WarpZone_PlaneDist(e, o) < 0)
 188                         return '0 0 0';
 189                         // can't really be, though, but if it is, this is not my warpzone, but a random different one in the same mins/maxs
 190                 pd = min4(
 191                                 WarpZone_PlaneDist(e, c0),
 192                                 WarpZone_PlaneDist(e, c1),
 193                                 WarpZone_PlaneDist(e, c2),
 194                                 WarpZone_PlaneDist(e, c3)
 195                         );
 196                 if(pd < 0)
 197                         return e.warpzone_forward * -pd;
 198         }
 199
 200         return '0 0 0';
 201 }
 202
 203 float warpzone_saved;
 204 vector warpzone_saved_origin;
 205 vector warpzone_saved_angles;
 206 vector warpzone_saved_cl_viewangles;
 207 #ifndef KEEP_ROLL
 208 var float autocvar_cl_rollkillspeed = 10;
 209 #endif
 210 void WarpZone_FixView()
 211 {
 212         float pd, f;
 213         vector o;
 214         entity e;
 215         vector corner0, corner1, corner2, corner3, nearclip;
 216
 217         warpzone_saved = 0;
 218         warpzone_saved_origin = warpzone_fixview_origin;
 219         warpzone_saved_angles = warpzone_fixview_angles;
 220         warpzone_saved_cl_viewangles = warpzone_fixview_cl_viewangles;
 221
 222         nearclip = '0 0 1' * (cvar("r_nearclip") * 1.125);
 223         corner0 = cs_unproject('0 0 0' + nearclip);
 224         corner1 = cs_unproject('1 0 0' * cvar("vid_conwidth") + nearclip);
 225         corner2 = cs_unproject('0 1 0' * cvar("vid_conheight") + nearclip);
 226         corner3 = cs_unproject('1 0 0' * cvar("vid_conwidth") + '0 1 0' * cvar("vid_conheight") + nearclip);
 227
 228 #ifndef KEEP_ROLL
 229         if(warpzone_fixview_angles_z != 0 || warpzone_fixview_cl_viewangles_z != 0)
 230         {
 231                 if(autocvar_cl_rollkillspeed)
 232                         f = max(0, (1 - frametime * autocvar_cl_rollkillspeed));
 233                 else
 234                         f = 0;
 235                 warpzone_fixview_angles_z *= f;
 236                 warpzone_fixview_cl_viewangles_z *= f;
 237                 warpzone_saved_angles_z *= f; // PERMANENTLY apply that change!
 238                 warpzone_saved_cl_viewangles_z *= f; // PERMANENTLY apply that change!
 239                 warpzone_saved = 2;
 240                 R_SetView(VF_CL_VIEWANGLES_Z, warpzone_fixview_angles_z);
 241         }
 242 #endif
 243
 244         e = WarpZone_Find(warpzone_fixview_origin, warpzone_fixview_origin);
 245         if(e)
 246         {
 247                 warpzone_saved = 1;
 248                 warpzone_fixview_origin = WarpZone_TransformOrigin(e, warpzone_fixview_origin);
 249                 corner0 = WarpZone_TransformOrigin(e, corner0);
 250                 corner1 = WarpZone_TransformOrigin(e, corner1);
 251                 corner2 = WarpZone_TransformOrigin(e, corner2);
 252                 corner3 = WarpZone_TransformOrigin(e, corner3);
 253                 warpzone_fixview_angles = WarpZone_TransformVAngles(e, warpzone_fixview_angles);
 254                 warpzone_fixview_cl_viewangles = WarpZone_TransformVAngles(e, warpzone_fixview_cl_viewangles);
 255                 WarpZone_Inside();
 256         }
 257         else
 258                 WarpZone_Outside();
 259
 260         // if we are near any warpzone planes - MOVE AWAY (work around nearclip)
 261         o = WarpZone_FixNearClip(warpzone_fixview_origin, corner0, corner1, corner2, corner3);
 262         if(o != '0 0 0')
 263         {
 264                 warpzone_saved = 1;
 265                 warpzone_fixview_origin += o;
 266         }
 267
 268         if(warpzone_saved == 1)
 269         {
 270                 R_SetView(VF_ORIGIN, warpzone_fixview_origin);
 271                 R_SetView(VF_ANGLES, warpzone_fixview_cl_viewangles);
 272         }
 273 }
 274 void WarpZone_UnFixView()
 275 {
 276         if(warpzone_saved)
 277         {
 278                 warpzone_fixview_origin = warpzone_saved_origin;
 279                 warpzone_fixview_angles = warpzone_saved_angles;
 280                 warpzone_fixview_cl_viewangles = warpzone_saved_cl_viewangles;
 281                 R_SetView(VF_ORIGIN, warpzone_fixview_origin);
 282                 R_SetView(VF_ANGLES, warpzone_fixview_angles);
 283                 R_SetView(VF_CL_VIEWANGLES, warpzone_fixview_cl_viewangles);
 284         }
 285 }
 286
 287 void WarpZone_Init()
 288 {
 289 }
 290
 291 void WarpZone_Shutdown()
 292 {
 293         WarpZone_Outside();
 294 }