qcsrc/warpzonelib/common.qc

   1 float trace_dphitcontents;
   2 .float dphitcontents;
   3
   4 void WarpZone_Accumulator_Clear(entity acc)
   5 {
   6         acc.warpzone_transform = '0 0 0';
   7         acc.warpzone_shift = '0 0 0';
   8 }
   9 void WarpZone_Accumulator_AddTransform(entity acc, vector t, vector s)
  10 {
  11         vector tr, st;
  12         tr = AnglesTransform_Multiply(t, acc.warpzone_transform);
  13         st = AnglesTransform_Multiply_GetPostShift(t, s, acc.warpzone_transform, acc.warpzone_shift);
  14         acc.warpzone_transform = tr;
  15         acc.warpzone_shift = st;
  16 }
  17 void WarpZone_Accumulator_Add(entity acc, entity wz)
  18 {
  19         vector t, st;
  20         t = AnglesTransform_Multiply(wz.warpzone_transform, acc.warpzone_transform);
  21         st = AnglesTransform_Multiply_GetPostShift(wz.warpzone_transform, wz.warpzone_shift, acc.warpzone_transform, acc.warpzone_shift);
  22         acc.warpzone_transform = t;
  23         acc.warpzone_shift = st;
  24 }
  25
  26 .vector(vector, vector) camera_transform;
  27 var float autocvar_cl_warpzone_usetrace = 1;
  28 vector WarpZone_camera_transform(vector org, vector ang)
  29 {
  30         vector vf, vr, vu;
  31         vf = v_forward;
  32         vr = v_right;
  33         vu = v_up;
  34         org = WarpZone_TransformOrigin(self, org);
  35         vf = WarpZone_TransformVelocity(self, vf);
  36         vr = WarpZone_TransformVelocity(self, vr);
  37         vu = WarpZone_TransformVelocity(self, vu);
  38         if(autocvar_cl_warpzone_usetrace)
  39                 traceline(self.warpzone_targetorigin, org, MOVE_NOMONSTERS, world);
  40         else
  41                 trace_endpos = self.warpzone_targetorigin;
  42         v_forward = vf;
  43         v_right = vr;
  44         v_up = vu;
  45         return org;
  46 }
  47
  48 void WarpZone_SetUp(entity e, vector my_org, vector my_ang, vector other_org, vector other_ang)
  49 {
  50         e.warpzone_transform = AnglesTransform_Divide(other_ang, AnglesTransform_TurnDirectionFR(my_ang));
  51         e.warpzone_shift = AnglesTransform_PrePostShift_GetPostShift(my_org, e.warpzone_transform, other_org);
  52         e.warpzone_origin = my_org;
  53         e.warpzone_targetorigin = other_org;
  54         e.warpzone_angles = my_ang;
  55         e.warpzone_targetangles = other_ang;
  56         fixedmakevectors(my_ang); e.warpzone_forward = v_forward;
  57         fixedmakevectors(other_ang); e.warpzone_targetforward = v_forward;
  58         e.camera_transform = WarpZone_camera_transform;
  59 }
  60
  61 vector WarpZone_Camera_camera_transform(vector org, vector ang)
  62 {
  63         // a fixed camera view
  64         trace_endpos = self.warpzone_origin;
  65         makevectors(self.warpzone_angles);
  66         return self.warpzone_origin;
  67 }
  68
  69 void WarpZone_Camera_SetUp(entity e, vector my_org, vector my_ang) // we assume that e.oldorigin and e.avelocity point to view origin and direction
  70 {
  71         e.warpzone_origin = my_org;
  72         e.warpzone_angles = my_ang;
  73         e.camera_transform = WarpZone_Camera_camera_transform;
  74 }
  75
  76 .entity enemy;
  77
  78 vector WarpZoneLib_BoxTouchesBrush_mins;
  79 vector WarpZoneLib_BoxTouchesBrush_maxs;
  80 entity WarpZoneLib_BoxTouchesBrush_ent;
  81 entity WarpZoneLib_BoxTouchesBrush_ignore;
  82 float WarpZoneLib_BoxTouchesBrush_Recurse()
  83 {
  84         float s;
  85         entity se;
  86         float f;
  87
  88         tracebox('0 0 0', WarpZoneLib_BoxTouchesBrush_mins, WarpZoneLib_BoxTouchesBrush_maxs, '0 0 0', MOVE_NOMONSTERS, WarpZoneLib_BoxTouchesBrush_ignore);
  89 #ifdef CSQC
  90         if (trace_networkentity)
  91         {
  92                 dprint("hit a network ent, cannot continue WarpZoneLib_BoxTouchesBrush\n");
  93                 // we cannot continue, as a player blocks us...
  94                 // so, abort
  95                 return 0;
  96         }
  97 #endif
  98         if not(trace_ent)
  99                 return 0;
 100         if (trace_ent == WarpZoneLib_BoxTouchesBrush_ent)
 101                 return 1;
 102
 103         se = trace_ent;
 104         s = se.solid;
 105         se.solid = SOLID_NOT;
 106         f = WarpZoneLib_BoxTouchesBrush_Recurse();
 107         se.solid = s;
 108
 109         return f;
 110 }
 111
 112 float WarpZoneLib_BoxTouchesBrush(vector mi, vector ma, entity e, entity ig)
 113 {
 114     float f, s;
 115
 116     if(!e.modelindex || e.warpzone_isboxy)
 117         return 1;
 118
 119     s = e.solid;
 120     e.solid = SOLID_BSP;
 121     WarpZoneLib_BoxTouchesBrush_mins = mi;
 122     WarpZoneLib_BoxTouchesBrush_maxs = ma;
 123     WarpZoneLib_BoxTouchesBrush_ent = e;
 124     WarpZoneLib_BoxTouchesBrush_ignore = ig;
 125     f = WarpZoneLib_BoxTouchesBrush_Recurse();
 126     e.solid = s;
 127
 128     return f;
 129 }
 130
 131 entity WarpZone_Find(vector mi, vector ma)
 132 {
 133         // if we are near any warpzone planes - MOVE AWAY (work around nearclip)
 134         entity e;
 135         for(e = world; (e = find(e, classname, "trigger_warpzone")); )
 136                 if(WarpZoneLib_BoxTouchesBrush(mi, ma, e, world))
 137                         return e;
 138         return world;
 139 }
 140
 141 void WarpZone_MakeAllSolid()
 142 {
 143         entity e;
 144         for(e = world; (e = find(e, classname, "trigger_warpzone")); )
 145                 e.solid = SOLID_BSP;
 146 }
 147
 148 void WarpZone_MakeAllOther()
 149 {
 150         entity e;
 151         for(e = world; (e = find(e, classname, "trigger_warpzone")); )
 152                 e.solid = SOLID_TRIGGER;
 153 }
 154
 155 void WarpZone_Trace_InitTransform()
 156 {
 157         if(!WarpZone_trace_transform)
 158         {
 159                 WarpZone_trace_transform = spawn();
 160                 WarpZone_trace_transform.classname = "warpzone_trace_transform";
 161         }
 162         WarpZone_Accumulator_Clear(WarpZone_trace_transform);
 163 }
 164 void WarpZone_Trace_AddTransform(entity wz)
 165 {
 166         WarpZone_Accumulator_Add(WarpZone_trace_transform, wz);
 167 }
 168
 169 void WarpZone_TraceBox_ThroughZone(vector org, vector mi, vector ma, vector end, float nomonsters, entity forent, entity zone, WarpZone_trace_callback_t cb)
 170 {
 171         float nomonsters_adjusted;
 172         float frac, sol, i;
 173         float contentshack;
 174         vector o0, e0;
 175         entity wz;
 176         vector vf, vr, vu;
 177
 178         WarpZone_Trace_InitTransform();
 179         if(!warpzone_warpzones_exist)
 180         {
 181                 if(nomonsters == MOVE_NOTHING)
 182                 {
 183                         trace_endpos = end;
 184                         trace_fraction = 1;
 185                         if(cb)
 186                                 cb(org, trace_endpos, end);
 187                         return;
 188                 }
 189                 else
 190                 {
 191                         tracebox(org, mi, ma, end, nomonsters, forent);
 192                         if(cb)
 193                                 cb(org, trace_endpos, end);
 194                         return;
 195                 }
 196         }
 197
 198         vf = v_forward;
 199         vr = v_right;
 200         vu = v_up;
 201         o0 = org;
 202         e0 = end;
 203
 204         switch(nomonsters)
 205         {
 206                 case MOVE_WORLDONLY:
 207                 case MOVE_NOTHING:
 208                         nomonsters_adjusted = MOVE_NOMONSTERS;
 209                         break;
 210                 default:
 211                         nomonsters_adjusted = nomonsters;
 212                         break;
 213         }
 214         if((contentshack = (forent.dphitcontentsmask && !(forent.dphitcontentsmask & DPCONTENTS_SOLID))))
 215                 forent.dphitcontentsmask |= DPCONTENTS_SOLID;
 216
 217         // if starting in warpzone, first transform
 218         wz = WarpZone_Find(org + mi, org + ma);
 219         if(wz)
 220         {
 221                 if(zone && wz != zone)
 222                 {
 223                         // we are in ANOTHER warpzone. This is bad. Make a zero length trace and return.
 224                         sol = 1;
 225                         trace_fraction = 0;
 226                         trace_endpos = org;
 227                         goto fail;
 228                 }
 229                 WarpZone_Trace_AddTransform(wz);
 230                 org = WarpZone_TransformOrigin(wz, trace_endpos);
 231                 end = WarpZone_TransformOrigin(wz, end);
 232         }
 233         WarpZone_MakeAllSolid();
 234         sol = -1;
 235         frac = 0;
 236         i = 16;
 237         for(;;)
 238         {
 239                 if(--i < 1)
 240                 {
 241                         dprint("Too many warpzones in sequence, aborting trace.\n");
 242                         trace_ent = world;
 243                         break;
 244                 }
 245                 tracebox(org, mi, ma, end, nomonsters_adjusted, forent);
 246                 if(cb)
 247                         cb(org, trace_endpos, end);
 248                 if(sol < 0)
 249                         sol = trace_startsolid;
 250
 251                 frac = trace_fraction = frac + (1 - frac) * trace_fraction;
 252                 if(trace_fraction >= 1)
 253                         break;
 254                 if(trace_ent.classname != "trigger_warpzone")
 255                 {
 256                         if((nomonsters == MOVE_NOTHING) || ((nomonsters == MOVE_WORLDONLY) && trace_ent) || (contentshack && (trace_dphitcontents & forent.dphitcontentsmask) == DPCONTENTS_SOLID))
 257                         {
 258                                 // continue the trace, ignoring this hit (we only care for warpzones)
 259                                 org = trace_endpos + normalize(end - org);
 260                                 continue;
 261                                 // we cannot do an inverted trace here, as we do care for further warpzones inside that "solid" to be found
 262                                 // otherwise, players could block entrances that way
 263                         }
 264                         break;
 265                 }
 266                 if(trace_ent == wz)
 267                 {
 268                         dprint("I transformed into the same zone again, wtf, aborting the trace\n");
 269                         trace_ent = world;
 270                         break;
 271                 }
 272                 wz = trace_ent;
 273                 if(zone && wz != zone)
 274                         break;
 275                 WarpZone_Trace_AddTransform(wz);
 276                 // we hit a warpzone... so, let's perform the trace after the warp again
 277                 org = WarpZone_TransformOrigin(wz, trace_endpos);
 278                 end = WarpZone_TransformOrigin(wz, end);
 279         }
 280         WarpZone_MakeAllOther();
 281 :fail
 282         if(contentshack)
 283                 forent.dphitcontentsmask &~= DPCONTENTS_SOLID;
 284         trace_startsolid = sol;
 285         v_forward = vf;
 286         v_right = vr;
 287         v_up = vu;
 288 }
 289
 290 void WarpZone_TraceBox(vector org, vector mi, vector ma, vector end, float nomonsters, entity forent)
 291 {
 292         WarpZone_TraceBox_ThroughZone(org, mi, ma, end, nomonsters, forent, world, WarpZone_trace_callback_t_null);
 293 }
 294
 295 void WarpZone_TraceLine(vector org, vector end, float nomonsters, entity forent)
 296 {
 297         WarpZone_TraceBox(org, '0 0 0', '0 0 0', end, nomonsters, forent);
 298 }
 299
 300 void WarpZone_TraceToss_ThroughZone(entity e, entity forent, entity zone, WarpZone_trace_callback_t cb)
 301 {
 302         float g, dt, i;
 303         vector vf, vr, vu, v0, o0;
 304         entity wz;
 305
 306         WarpZone_Trace_InitTransform();
 307         WarpZone_tracetoss_time = 0;
 308         if(!warpzone_warpzones_exist)
 309         {
 310                 tracetoss(e, forent);
 311                 if(cb)
 312                         cb(e.origin, trace_endpos, trace_endpos);
 313                 dt = vlen(e.origin - o0) / vlen(e.velocity);
 314                 WarpZone_tracetoss_time += dt;
 315                 return;
 316         }
 317
 318         vf = v_forward;
 319         vr = v_right;
 320         vu = v_up;
 321         o0 = e.origin;
 322         v0 = e.velocity;
 323
 324         // if starting in warpzone, first transform
 325         wz = WarpZone_Find(e.origin + e.mins, e.origin + e.maxs);
 326         if(wz)
 327         {
 328                 if(zone && wz != zone)
 329                 {
 330                         // we are in ANOTHER warpzone. This is bad. Make a zero length trace and return.
 331
 332                         WarpZone_tracetoss_time = 0;
 333                         trace_endpos = o0;
 334                         goto fail;
 335                 }
 336                 WarpZone_Trace_AddTransform(wz);
 337                 setorigin(e, WarpZone_TransformOrigin(wz, e.origin));
 338                 e.velocity = WarpZone_TransformVelocity(wz, e.velocity);
 339         }
 340         WarpZone_MakeAllSolid();
 341         g = cvar("sv_gravity") * e.gravity;
 342         i = 16;
 343         for(;;)
 344         {
 345                 if(--i < 1)
 346                 {
 347                         dprint("Too many warpzones in sequence, aborting trace.\n");
 348                         trace_ent = world;
 349                         break;
 350                 }
 351                 tracetoss(e, forent);
 352                 if(cb)
 353                         cb(e.origin, trace_endpos, trace_endpos);
 354                 e.origin = trace_endpos;
 355                 dt = vlen(e.origin - o0) / vlen(e.velocity);
 356                 WarpZone_tracetoss_time += dt;
 357                 e.velocity_z -= WarpZone_tracetoss_time * g;
 358                 if(trace_fraction >= 1)
 359                         break;
 360                 if(trace_ent.classname != "trigger_warpzone")
 361                         break;
 362                 if(trace_ent == wz)
 363                 {
 364                         dprint("I transformed into the same zone again, wtf, aborting the trace\n");
 365                         trace_ent = world;
 366                         break;
 367                 }
 368                 wz = trace_ent;
 369                 if(zone && wz != zone)
 370                         break;
 371                 WarpZone_Trace_AddTransform(wz);
 372                 // we hit a warpzone... so, let's perform the trace after the warp again
 373                 e.origin = WarpZone_TransformOrigin(wz, e.origin);
 374                 e.velocity = WarpZone_TransformVelocity(wz, e.velocity);
 375         }
 376         WarpZone_MakeAllOther();
 377 :fail
 378         WarpZone_tracetoss_velocity = e.velocity;
 379         v_forward = vf;
 380         v_right = vr;
 381         v_up = vu;
 382         // restore old entity data (caller just uses trace_endpos, WarpZone_tracetoss_velocity and the transform)
 383         e.velocity = v0;
 384         e.origin = o0;
 385 }
 386
 387 void WarpZone_TraceToss(entity e, entity forent)
 388 {
 389         WarpZone_TraceToss_ThroughZone(e, forent, world, WarpZone_trace_callback_t_null);
 390 }
 391
 392 entity WarpZone_TrailParticles_trace_callback_own;
 393 float WarpZone_TrailParticles_trace_callback_eff;
 394 void WarpZone_TrailParticles_trace_callback(vector from, vector endpos, vector to)
 395 {
 396         trailparticles(WarpZone_TrailParticles_trace_callback_own, WarpZone_TrailParticles_trace_callback_eff, from, endpos);
 397 }
 398
 399 void WarpZone_TrailParticles(entity own, float eff, vector org, vector end)
 400 {
 401         WarpZone_TrailParticles_trace_callback_own = own;
 402         WarpZone_TrailParticles_trace_callback_eff = eff;
 403         WarpZone_TraceBox_ThroughZone(org, '0 0 0', '0 0 0', end, MOVE_NOMONSTERS, world, world, WarpZone_TrailParticles_trace_callback);
 404 }
 405
 406 float WarpZone_PlaneDist(entity wz, vector v)
 407 {
 408         return (v - wz.warpzone_origin) * wz.warpzone_forward;
 409 }
 410
 411 float WarpZone_TargetPlaneDist(entity wz, vector v)
 412 {
 413         return (v - wz.warpzone_targetorigin) * wz.warpzone_targetforward;
 414 }
 415
 416 vector WarpZone_TransformOrigin(entity wz, vector v)
 417 {
 418         return wz.warpzone_shift + AnglesTransform_Apply(wz.warpzone_transform, v);
 419 }
 420
 421 vector WarpZone_TransformVelocity(entity wz, vector v)
 422 {
 423         return AnglesTransform_Apply(wz.warpzone_transform, v);
 424 }
 425
 426 vector WarpZone_TransformAngles(entity wz, vector v)
 427 {
 428         return AnglesTransform_ApplyToAngles(wz.warpzone_transform, v);
 429 }
 430
 431 vector WarpZone_TransformVAngles(entity wz, vector ang)
 432 {
 433 #ifdef KEEP_ROLL
 434         float roll;
 435         roll = ang_z;
 436         ang_z = 0;
 437 #endif
 438
 439         ang = AnglesTransform_ApplyToVAngles(wz.warpzone_transform, ang);
 440
 441 #ifdef KEEP_ROLL
 442         ang = AnglesTransform_Normalize(ang, TRUE);
 443         ang = AnglesTransform_CancelRoll(ang);
 444         ang_z = roll;
 445 #else
 446         ang = AnglesTransform_Normalize(ang, FALSE);
 447 #endif
 448
 449         return ang;
 450 }
 451
 452 vector WarpZone_UnTransformOrigin(entity wz, vector v)
 453 {
 454         return AnglesTransform_Apply(AnglesTransform_Invert(wz.warpzone_transform), v - wz.warpzone_shift);
 455 }
 456
 457 vector WarpZone_UnTransformVelocity(entity wz, vector v)
 458 {
 459         return AnglesTransform_Apply(AnglesTransform_Invert(wz.warpzone_transform), v);
 460 }
 461
 462 vector WarpZone_UnTransformAngles(entity wz, vector v)
 463 {
 464         return AnglesTransform_ApplyToAngles(AnglesTransform_Invert(wz.warpzone_transform), v);
 465 }
 466
 467 vector WarpZone_UnTransformVAngles(entity wz, vector ang)
 468 {
 469         float roll;
 470
 471         roll = ang_z;
 472         ang_z = 0;
 473
 474         ang = AnglesTransform_ApplyToVAngles(AnglesTransform_Invert(wz.warpzone_transform), ang);
 475         ang = AnglesTransform_Normalize(ang, TRUE);
 476         ang = AnglesTransform_CancelRoll(ang);
 477
 478         ang_z = roll;
 479         return ang;
 480 }
 481
 482 vector WarpZoneLib_NearestPointOnBox(vector mi, vector ma, vector org)
 483 {
 484         vector nearest;
 485         nearest_x = bound(mi_x, org_x, ma_x);
 486         nearest_y = bound(mi_y, org_y, ma_y);
 487         nearest_z = bound(mi_z, org_z, ma_z);
 488         return nearest;
 489 }
 490
 491 .float WarpZone_findradius_hit;
 492 .entity WarpZone_findradius_next;
 493 void WarpZone_FindRadius_Recurse(vector org, float rad,        vector org0,               vector transform, vector shift, float needlineofsight)
 494 //                               blast origin of current search   original blast origin   how to untransform (victim to blast system)
 495 {
 496         vector org_new;
 497         vector org0_new;
 498         vector shift_new, transform_new;
 499         vector p;
 500         entity e, e0;
 501         entity wz;
 502         if(rad <= 0)
 503                 return;
 504         e0 = findradius(org, rad);
 505         wz = world;
 506
 507         for(e = e0; e; e = e.chain)
 508         {
 509                 p = WarpZoneLib_NearestPointOnBox(e.origin + e.mins, e.origin + e.maxs, org0);
 510                 if(needlineofsight)
 511                 {
 512                         traceline(org, p, MOVE_NOMONSTERS, e);
 513                         if(trace_fraction < 1)
 514                                 continue;
 515                 }
 516                 if(!e.WarpZone_findradius_hit || vlen(e.WarpZone_findradius_dist) > vlen(org0 - p))
 517                 {
 518                         e.WarpZone_findradius_nearest = p;
 519                         e.WarpZone_findradius_dist = org0 - p;
 520                         e.WarpZone_findradius_findorigin = org;
 521                         e.WarpZone_findradius_findradius = rad;
 522                         if(e.classname == "warpzone_refsys")
 523                         {
 524                                 // ignore, especially: do not overwrite the refsys parameters
 525                         }
 526                         else if(e.classname == "trigger_warpzone")
 527                         {
 528                                 e.WarpZone_findradius_next = wz;
 529                                 wz = e;
 530                                 e.WarpZone_findradius_hit = 1;
 531                                 e.enemy.WarpZone_findradius_dist = '0 0 0'; // we don't want to go through this zone ever again
 532                                 e.enemy.WarpZone_findradius_hit = 1;
 533                         }
 534                         else
 535                         {
 536                                 e.warpzone_transform = transform;
 537                                 e.warpzone_shift = shift;
 538                                 e.WarpZone_findradius_hit = 1;
 539                         }
 540                 }
 541         }
 542         for(e = wz; e; e = e.WarpZone_findradius_next)
 543         {
 544                 org0_new = WarpZone_TransformOrigin(e, org);
 545                 traceline(e.warpzone_targetorigin, org0_new, MOVE_NOMONSTERS, e);
 546                 org_new = trace_endpos;
 547
 548                 transform_new = AnglesTransform_Multiply(e.warpzone_transform, transform);
 549                 shift_new = AnglesTransform_Multiply_GetPostShift(e.warpzone_transform, e.warpzone_shift, transform, shift);
 550                 WarpZone_FindRadius_Recurse(
 551                         org_new,
 552                         bound(0, rad - vlen(org_new - org0_new), rad - 8),
 553                         org0_new,
 554                         transform_new, shift_new,
 555                         needlineofsight);
 556                 e.WarpZone_findradius_hit = 0;
 557                 e.enemy.WarpZone_findradius_hit = 0;
 558         }
 559 }
 560 entity WarpZone_FindRadius(vector org, float rad, float needlineofsight)
 561 {
 562         entity e0, e;
 563         WarpZone_FindRadius_Recurse(org, rad, org, '0 0 0', '0 0 0', needlineofsight);
 564         e0 = findchainfloat(WarpZone_findradius_hit, 1);
 565         for(e = e0; e; e = e.chain)
 566                 e.WarpZone_findradius_hit = 0;
 567         return e0;
 568 }
 569
 570 .entity WarpZone_refsys;
 571 void WarpZone_RefSys_GC()
 572 {
 573         // garbage collect unused reference systems
 574         self.nextthink = time + 1;
 575         if(self.owner.WarpZone_refsys != self)
 576                 remove(self);
 577 }
 578 void WarpZone_RefSys_Add(entity me, entity wz)
 579 {
 580         if(me.WarpZone_refsys.owner != me)
 581         {
 582                 me.WarpZone_refsys = spawn();
 583                 me.WarpZone_refsys.classname = "warpzone_refsys";
 584                 me.WarpZone_refsys.owner = me;
 585                 me.WarpZone_refsys.think = WarpZone_RefSys_GC;
 586                 me.WarpZone_refsys.nextthink = time + 1;
 587                 WarpZone_Accumulator_Clear(me.WarpZone_refsys);
 588         }
 589         if(wz)
 590                 WarpZone_Accumulator_Add(me.WarpZone_refsys, wz);
 591 }
 592 .vector WarpZone_refsys_incremental_shift;
 593 .vector WarpZone_refsys_incremental_transform;
 594 void WarpZone_RefSys_AddIncrementally(entity me, entity ref)
 595 {
 596         vector t, s;
 597         if(me.WarpZone_refsys_incremental_transform == ref.WarpZone_refsys.warpzone_transform)
 598         if(me.WarpZone_refsys_incremental_shift == ref.WarpZone_refsys.warpzone_shift)
 599                 return;
 600         if(me.WarpZone_refsys.owner != me)
 601         {
 602                 me.WarpZone_refsys = spawn();
 603                 me.WarpZone_refsys.classname = "warpzone_refsys";
 604                 me.WarpZone_refsys.owner = me;
 605                 me.WarpZone_refsys.think = WarpZone_RefSys_GC;
 606                 me.WarpZone_refsys.nextthink = time + 1;
 607                 WarpZone_Accumulator_Clear(me.WarpZone_refsys);
 608         }
 609         t = AnglesTransform_Invert(me.WarpZone_refsys_incremental_transform);
 610         s = AnglesTransform_PrePostShift_GetPostShift(me.WarpZone_refsys_incremental_shift, t, '0 0 0');
 611         WarpZone_Accumulator_AddTransform(me.WarpZone_refsys, t, s);
 612         WarpZone_Accumulator_Add(me.WarpZone_refsys, ref);
 613         me.WarpZone_refsys_incremental_shift = ref.WarpZone_refsys.warpzone_shift;
 614         me.WarpZone_refsys_incremental_transform = ref.WarpZone_refsys.warpzone_transform;
 615 }
 616 void WarpZone_RefSys_BeginAddingIncrementally(entity me, entity ref)
 617 {
 618         me.WarpZone_refsys_incremental_shift = ref.WarpZone_refsys.warpzone_shift;
 619         me.WarpZone_refsys_incremental_transform = ref.WarpZone_refsys.warpzone_transform;
 620 }
 621 vector WarpZone_RefSys_TransformOrigin(entity from, entity to, vector org)
 622 {
 623         if(from.WarpZone_refsys)
 624                 org = WarpZone_UnTransformOrigin(from.WarpZone_refsys, org);
 625         if(to.WarpZone_refsys)
 626                 org = WarpZone_TransformOrigin(to.WarpZone_refsys, org);
 627         return org;
 628 }
 629 vector WarpZone_RefSys_TransformVelocity(entity from, entity to, vector vel)
 630 {
 631         if(from.WarpZone_refsys)
 632                 vel = WarpZone_UnTransformVelocity(from.WarpZone_refsys, vel);
 633         if(to.WarpZone_refsys)
 634                 vel = WarpZone_TransformVelocity(to.WarpZone_refsys, vel);
 635         return vel;
 636 }
 637 vector WarpZone_RefSys_TransformAngles(entity from, entity to, vector ang)
 638 {
 639         if(from.WarpZone_refsys)
 640                 ang = WarpZone_UnTransformAngles(from.WarpZone_refsys, ang);
 641         if(to.WarpZone_refsys)
 642                 ang = WarpZone_TransformAngles(to.WarpZone_refsys, ang);
 643         return ang;
 644 }
 645 vector WarpZone_RefSys_TransformVAngles(entity from, entity to, vector ang)
 646 {
 647         if(from.WarpZone_refsys)
 648                 ang = WarpZone_UnTransformVAngles(from.WarpZone_refsys, ang);
 649         if(to.WarpZone_refsys)
 650                 ang = WarpZone_TransformVAngles(to.WarpZone_refsys, ang);
 651         return ang;
 652 }
 653 entity WarpZone_RefSys_SpawnSameRefSys(entity me)
 654 {
 655         entity e;
 656         e = spawn();
 657         if(me.WarpZone_refsys)
 658         {
 659                 e.WarpZone_refsys = spawn();
 660                 e.WarpZone_refsys.classname = "warpzone_refsys";
 661                 e.WarpZone_refsys.owner = e;
 662                 e.WarpZone_refsys.think = WarpZone_RefSys_GC;
 663                 e.WarpZone_refsys.nextthink = time + 1;
 664                 e.WarpZone_refsys.warpzone_shift = me.WarpZone_refsys.warpzone_shift;
 665                 e.WarpZone_refsys.warpzone_transform = me.WarpZone_refsys.warpzone_transform;
 666         }
 667         return e;
 668 }