qcsrc/server/w_crylink.qc

   1 #ifdef REGISTER_WEAPON
   2 REGISTER_WEAPON(CRYLINK, w_crylink, IT_CELLS, 6, WEP_FLAG_NORMAL | WEP_TYPE_SPLASH, BOT_PICKUP_RATING_MID, "crylink", "crylink", "Crylink");
   3 #else
   4 #ifdef SVQC
   5 .float gravity;
   6 .float crylink_waitrelease;
   7 .entity crylink_lastgroup;
   8
   9 .entity queuenext;
  10 .entity queueprev;
  11
  12 void W_Crylink_Dequeue_Raw(entity own, entity prev, entity me, entity next)
  13 {
  14         if(me == own.crylink_lastgroup)
  15                 own.crylink_lastgroup = ((me == next) ? world : next);
  16         prev.queuenext = next;
  17         next.queueprev = prev;
  18 }
  19
  20 void W_Crylink_Dequeue(entity e)
  21 {
  22         W_Crylink_Dequeue_Raw(e.realowner, e.queueprev, e, e.queuenext);
  23 }
  24
  25 // force projectile to explode
  26 void W_Crylink_LinkExplode (entity e, entity e2)
  27 {
  28         float a;
  29         a = bound(0, 1 - (time - e.fade_time) * e.fade_rate, 1);
  30
  31         if(e == e.realowner.crylink_lastgroup)
  32                 e.realowner.crylink_lastgroup = world;
  33
  34         RadiusDamage (e, e.realowner, cvar("g_balance_crylink_primary_damage") * a, cvar("g_balance_crylink_primary_edgedamage") * a, cvar("g_balance_crylink_primary_radius"), world, cvar("g_balance_crylink_primary_force") * a, e.projectiledeathtype, other);
  35
  36         if(e.queuenext != e2)
  37                 W_Crylink_LinkExplode(e.queuenext, e2);
  38
  39         remove (e);
  40 }
  41
  42 // adjust towards center
  43 // returns the origin where they will meet... and the time till the meeting is
  44 // stored in w_crylink_linkjoin_time.
  45 // could possibly network this origin and time, and display a special particle
  46 // effect when projectiles meet there :P
  47 // jspeed: MINIMUM jing speed
  48 // jtime: MAXIMUM jing time (0: none)
  49 float w_crylink_linkjoin_time;
  50 vector W_Crylink_LinkJoin(entity e, float jspeed, float jtime)
  51 {
  52         vector avg_origin, avg_velocity;
  53         vector targ_origin;
  54         float avg_dist, n;
  55         entity p;
  56
  57         w_crylink_linkjoin_time = 0;
  58
  59         avg_origin = e.origin;
  60         avg_velocity = e.velocity;
  61         n = 1;
  62         for(p = e; (p = p.queuenext) != e; )
  63         {
  64                 avg_origin += WarpZone_RefSys_TransformOrigin(p, e, p.origin);
  65                 avg_velocity += WarpZone_RefSys_TransformVelocity(p, e, p.velocity);
  66                 ++n;
  67         }
  68         avg_origin *= (1.0 / n);
  69         avg_velocity *= (1.0 / n);
  70
  71         if(n < 2)
  72                 return avg_origin; // nothing to do
  73
  74         // yes, mathematically we can do this in ONE step, but beware of 32bit floats...
  75         avg_dist = pow(vlen(e.origin - avg_origin), 2);
  76         for(p = e; (p = p.queuenext) != e; )
  77                 avg_dist += pow(vlen(WarpZone_RefSys_TransformOrigin(p, e, p.origin) - avg_origin), 2);
  78         avg_dist *= (1.0 / n);
  79         avg_dist = sqrt(avg_dist);
  80
  81         if(avg_dist == 0)
  82                 return avg_origin; // no change needed
  83
  84         if(jspeed == 0 && jtime == 0)
  85         {
  86                 e.velocity = avg_velocity;
  87                 UpdateCSQCProjectile(e);
  88                 for(p = e; (p = p.queuenext) != e; )
  89                 {
  90                         p.velocity = WarpZone_RefSys_TransformVelocity(e, p, avg_velocity);
  91                         UpdateCSQCProjectile(p);
  92                 }
  93         }
  94         else
  95         {
  96                 if(jtime)
  97                 {
  98                         if(jspeed)
  99                                 w_crylink_linkjoin_time = min(jtime, avg_dist / jspeed);
 100                         else
 101                                 w_crylink_linkjoin_time = jtime;
 102                 }
 103                 else
 104                         w_crylink_linkjoin_time = avg_dist / jspeed;
 105                 targ_origin = avg_origin + w_crylink_linkjoin_time * avg_velocity;
 106
 107                 e.velocity = (targ_origin - e.origin) * (1.0 / w_crylink_linkjoin_time);
 108                 UpdateCSQCProjectile(e);
 109                 for(p = e; (p = p.queuenext) != e; )
 110                 {
 111                         p.velocity = WarpZone_RefSys_TransformVelocity(e, p, (targ_origin - WarpZone_RefSys_TransformOrigin(p, e, p.origin)) * (1.0 / w_crylink_linkjoin_time));
 112                         UpdateCSQCProjectile(p);
 113                 }
 114
 115                 // analysis:
 116                 //   jspeed -> +infinity:
 117                 //      w_crylink_linkjoin_time -> +0
 118                 //      targ_origin -> avg_origin
 119                 //      p->velocity -> HUEG towards center
 120                 //   jspeed -> 0:
 121                 //      w_crylink_linkjoin_time -> +/- infinity
 122                 //      targ_origin -> avg_velocity * +/- infinity
 123                 //      p->velocity -> avg_velocity
 124                 //   jspeed -> -infinity:
 125                 //      w_crylink_linkjoin_time -> -0
 126                 //      targ_origin -> avg_origin
 127                 //      p->velocity -> HUEG away from center
 128         }
 129
 130         return targ_origin;
 131 }
 132
 133 void W_Crylink_LinkJoinEffect_Think()
 134 {
 135         // is there at least 2 projectiles very close?
 136         entity e, p;
 137         float n;
 138         e = self.owner.crylink_lastgroup;
 139         n = 0;
 140         if(e)
 141         {
 142                 if(vlen(e.origin - self.origin) < vlen(e.velocity) * frametime)
 143                         ++n;
 144                 for(p = e; (p = p.queuenext) != e; )
 145                 {
 146                         if(vlen(p.origin - self.origin) < vlen(p.velocity) * frametime)
 147                                 ++n;
 148                 }
 149                 if(n >= 2)
 150                 {
 151
 152                         if(cvar("g_balance_crylink_primary_joinexplode"))
 153                         {
 154                                 n = n / cvar("g_balance_crylink_primary_shots");
 155                                 RadiusDamage (e, e.realowner, cvar("g_balance_crylink_primary_joinexplode_damage") * n,
 156                                                                 cvar("g_balance_crylink_primary_joinexplode_edgedamage") * n,
 157                                                                 cvar("g_balance_crylink_primary_joinexplode_radius") * n, world,
 158                                                                 cvar("g_balance_crylink_primary_joinexplode_force") * n, e.projectiledeathtype, other);
 159                         }
 160
 161                         // they seem to touch...
 162                         // TODO make a specific particle effect for this
 163                         pointparticles(particleeffectnum("crylink_linkjoin"), self.origin, '0 0 0', 1);
 164                 }
 165         }
 166         remove(self);
 167 }
 168
 169 // NO bounce protection, as bounces are limited!
 170 void W_Crylink_Touch (void)
 171 {
 172         float finalhit;
 173         float f;
 174         //PROJECTILE_TOUCH;
 175         local entity savenext, saveprev, saveown;
 176         saveown = self.realowner;
 177         savenext = self.queuenext;
 178         saveprev = self.queueprev;
 179         if(WarpZone_Projectile_Touch())
 180         {
 181                 if(wasfreed(self))
 182                         W_Crylink_Dequeue_Raw(saveown, saveprev, self, savenext);
 183                 return;
 184         }
 185
 186         float a;
 187         a = bound(0, 1 - (time - self.fade_time) * self.fade_rate, 1);
 188
 189         finalhit = ((self.cnt <= 0) || (other.takedamage != DAMAGE_NO));
 190         if(finalhit)
 191                 f = 1;
 192         else
 193                 f = cvar("g_balance_crylink_primary_bouncedamagefactor");
 194         if(a)
 195                 f *= a;
 196         if (RadiusDamage (self, self.realowner, cvar("g_balance_crylink_primary_damage") * f, cvar("g_balance_crylink_primary_edgedamage") * f, cvar("g_balance_crylink_primary_radius"), world, cvar("g_balance_crylink_primary_force") * f, self.projectiledeathtype, other) && cvar("g_balance_crylink_primary_linkexplode"))
 197         {
 198                 W_Crylink_LinkExplode(self.queuenext, self);
 199                 remove (self);
 200                 return;
 201         }
 202         else if(finalhit)
 203         {
 204                 // just unlink
 205                 W_Crylink_Dequeue(self);
 206                 remove(self);
 207                 return;
 208         }
 209         self.cnt = self.cnt - 1;
 210         self.angles = vectoangles(self.velocity);
 211         self.owner = world;
 212         self.projectiledeathtype |= HITTYPE_BOUNCE;
 213         // commented out as it causes a little hitch...
 214         //if(proj.cnt == 0)
 215         //      CSQCProjectile(proj, TRUE, PROJECTILE_CRYLINK, TRUE);
 216 }
 217
 218 void W_Crylink_Touch2 (void)
 219 {
 220         float finalhit;
 221         float f;
 222         //PROJECTILE_TOUCH;
 223         local entity savenext, saveprev, saveown;
 224         savenext = self.queuenext;
 225         saveprev = self.queueprev;
 226         saveown = self.realowner;
 227         if(WarpZone_Projectile_Touch())
 228         {
 229                 if(wasfreed(self))
 230                         W_Crylink_Dequeue_Raw(saveown, saveprev, self, savenext);
 231                 return;
 232         }
 233
 234         float a;
 235         a = 1 - (time - self.fade_time) * self.fade_rate;
 236
 237         finalhit = ((self.cnt <= 0) || (other.takedamage != DAMAGE_NO));
 238         if(finalhit)
 239                 f = 1;
 240         else
 241                 f = cvar("g_balance_crylink_secondary_bouncedamagefactor");
 242         if(a)
 243                 f *= a;
 244         if (RadiusDamage (self, self.realowner, cvar("g_balance_crylink_secondary_damage") * f, cvar("g_balance_crylink_secondary_edgedamage") * f, cvar("g_balance_crylink_secondary_radius"), world, cvar("g_balance_crylink_secondary_force") * f, self.projectiledeathtype, other) && cvar("g_balance_crylink_secondary_linkexplode"))
 245         {
 246                 W_Crylink_LinkExplode(self.queuenext, self);
 247                 remove (self);
 248                 return;
 249         }
 250         else if(finalhit)
 251         {
 252                 // just unlink
 253                 W_Crylink_Dequeue(self);
 254                 remove(self);
 255                 return;
 256         }
 257         self.cnt = self.cnt - 1;
 258         self.angles = vectoangles(self.velocity);
 259         self.owner = world;
 260         self.projectiledeathtype |= HITTYPE_BOUNCE;
 261         // commented out as it causes a little hitch...
 262         //if(proj.cnt == 0)
 263         //      CSQCProjectile(proj, TRUE, PROJECTILE_CRYLINK, TRUE);
 264 }
 265
 266 void W_Crylink_Fadethink (void)
 267 {
 268         W_Crylink_Dequeue(self);
 269         remove(self);
 270 }
 271
 272 void W_Crylink_Attack (void)
 273 {
 274         local float counter, shots;
 275         local entity proj, prevproj, firstproj;
 276         local vector s;
 277         vector forward, right, up;
 278
 279         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
 280                 self.ammo_cells = self.ammo_cells - cvar("g_balance_crylink_primary_ammo");
 281
 282         W_SetupShot (self, FALSE, 2, "weapons/crylink_fire.wav", (cvar("g_balance_crylink_primary_damage")*cvar("g_balance_crylink_primary_shots")));
 283         forward = v_forward;
 284         right = v_right;
 285         up = v_up;
 286
 287         shots = cvar("g_balance_crylink_primary_shots");
 288         pointparticles(particleeffectnum("crylink_muzzleflash"), w_shotorg, w_shotdir * 1000, shots);
 289         proj = world;
 290         while (counter < shots)
 291         {
 292                 proj = spawn ();
 293                 proj.realowner = proj.owner = self;
 294                 proj.classname = "spike";
 295                 proj.bot_dodge = TRUE;
 296                 proj.bot_dodgerating = cvar("g_balance_crylink_primary_damage");
 297                 if(counter == 0) { // first projectile, store in firstproj for now
 298                         firstproj = proj;
 299                 }
 300                 else if(counter == shots - 1) { // last projectile, link up with first projectile
 301                         prevproj.queuenext = proj;
 302                         firstproj.queueprev = proj;
 303                         proj.queuenext = firstproj;
 304                         proj.queueprev = prevproj;
 305                 }
 306                 else { // else link up with previous projectile
 307                         prevproj.queuenext = proj;
 308                         proj.queueprev = prevproj;
 309                 }
 310
 311                 prevproj = proj;
 312
 313                 proj.movetype = MOVETYPE_BOUNCEMISSILE;
 314                 PROJECTILE_MAKETRIGGER(proj);
 315                 proj.projectiledeathtype = WEP_CRYLINK;
 316                 //proj.gravity = 0.001;
 317
 318                 setorigin (proj, w_shotorg);
 319                 setsize(proj, '0 0 0', '0 0 0');
 320
 321
 322                 s = '0 0 0';
 323                 if (counter == 0)
 324                         s = '0 0 0';
 325                 else
 326                 {
 327                         makevectors('0 360 0' * (0.75 + (counter - 0.5) / (shots - 1)));
 328                         s_y = v_forward_x;
 329                         s_z = v_forward_y;
 330                 }
 331                 s = s * cvar("g_balance_crylink_primary_spread") * g_weaponspreadfactor;
 332                 W_SetupProjectileVelocityEx(proj, w_shotdir + right * s_y + up * s_z, v_up, cvar("g_balance_crylink_primary_speed"), 0, 0, 0);
 333                 proj.touch = W_Crylink_Touch;
 334
 335                 proj.think = W_Crylink_Fadethink;
 336                 if(counter == 0)
 337                 {
 338                         proj.fade_time = time + cvar("g_balance_crylink_primary_middle_lifetime");
 339                         self.fade_rate = 1 / cvar("g_balance_crylink_primary_middle_fadetime");
 340                         proj.nextthink = time + cvar("g_balance_crylink_primary_middle_lifetime") + cvar("g_balance_crylink_primary_middle_fadetime");
 341                 }
 342                 else
 343                 {
 344                         proj.fade_time = time + cvar("g_balance_crylink_primary_other_lifetime");
 345                         self.fade_rate = 1 / cvar("g_balance_crylink_primary_other_fadetime");
 346                         proj.nextthink = time + cvar("g_balance_crylink_primary_other_lifetime") + cvar("g_balance_crylink_primary_other_fadetime");
 347                 }
 348                 proj.cnt = cvar("g_balance_crylink_primary_bounces");
 349                 //proj.scale = 1 + 1 * proj.cnt;
 350
 351                 proj.angles = vectoangles (proj.velocity);
 352
 353                 //proj.glow_size = 20;
 354
 355                 proj.flags = FL_PROJECTILE;
 356
 357                 CSQCProjectile(proj, TRUE, (proj.cnt ? PROJECTILE_CRYLINK_BOUNCING : PROJECTILE_CRYLINK), TRUE);
 358
 359                 other = proj; MUTATOR_CALLHOOK(EditProjectile);
 360
 361                 counter = counter + 1;
 362         }
 363         self.crylink_lastgroup = proj;
 364 }
 365
 366 void W_Crylink_Attack2 (void)
 367 {
 368         local float counter, shots;
 369         local entity proj, prevproj, firstproj;
 370
 371         if not(self.items & IT_UNLIMITED_WEAPON_AMMO)
 372                 self.ammo_cells = self.ammo_cells - cvar("g_balance_crylink_secondary_ammo");
 373
 374         W_SetupShot (self, FALSE, 2, "weapons/crylink_fire2.wav", (cvar("g_balance_crylink_secondary_damage")*cvar("g_balance_crylink_secondary_shots")));
 375
 376         shots = cvar("g_balance_crylink_secondary_shots");
 377         pointparticles(particleeffectnum("crylink_muzzleflash"), w_shotorg, w_shotdir * 1000, shots);
 378         proj = world;
 379         while (counter < shots)
 380         {
 381                 proj = spawn ();
 382                 proj.realowner = proj.owner = self;
 383                 proj.classname = "spike";
 384                 proj.bot_dodge = TRUE;
 385                 proj.bot_dodgerating = cvar("g_balance_crylink_secondary_damage");
 386                 if(counter == 0) { // first projectile, store in firstproj for now
 387                         firstproj = proj;
 388                 }
 389                 else if(counter == shots - 1) { // last projectile, link up with first projectile
 390                         prevproj.queuenext = proj;
 391                         firstproj.queueprev = proj;
 392                         proj.queuenext = firstproj;
 393                         proj.queueprev = prevproj;
 394                 }
 395                 else { // else link up with previous projectile
 396                         prevproj.queuenext = proj;
 397                         proj.queueprev = prevproj;
 398                 }
 399
 400                 prevproj = proj;
 401
 402                 proj.movetype = MOVETYPE_BOUNCEMISSILE;
 403                 PROJECTILE_MAKETRIGGER(proj);
 404                 proj.projectiledeathtype = WEP_CRYLINK | HITTYPE_SECONDARY;
 405                 //proj.gravity = 0.001;
 406
 407                 setorigin (proj, w_shotorg);
 408                 setsize(proj, '0 0 0', '0 0 0');
 409
 410                 W_SetupProjectileVelocityEx(proj, (w_shotdir + (((counter + 0.5) / shots) * 2 - 1) * v_right * cvar("g_balance_crylink_secondary_spread") * g_weaponspreadfactor), v_up, cvar("g_balance_crylink_secondary_speed"), 0, 0, 0);
 411                 proj.touch = W_Crylink_Touch2;
 412                 proj.think = W_Crylink_Fadethink;
 413                 if(counter == (shots - 1) / 2)
 414                 {
 415                         proj.fade_time = time + cvar("g_balance_crylink_secondary_middle_lifetime");
 416                         self.fade_rate = 1 / cvar("g_balance_crylink_secondary_middle_fadetime");
 417                         proj.nextthink = time + cvar("g_balance_crylink_secondary_middle_lifetime") + cvar("g_balance_crylink_secondary_middle_fadetime");
 418                 }
 419                 else
 420                 {
 421                         proj.fade_time = time + cvar("g_balance_crylink_secondary_line_lifetime");
 422                         self.fade_rate = 1 / cvar("g_balance_crylink_secondary_line_fadetime");
 423                         proj.nextthink = time + cvar("g_balance_crylink_secondary_line_lifetime") + cvar("g_balance_crylink_secondary_line_fadetime");
 424                 }
 425                 proj.cnt = cvar("g_balance_crylink_secondary_bounces");
 426                 //proj.scale = 1 + 1 * proj.cnt;
 427
 428                 proj.angles = vectoangles (proj.velocity);
 429
 430                 //proj.glow_size = 20;
 431
 432                 proj.flags = FL_PROJECTILE;
 433
 434                 CSQCProjectile(proj, TRUE, (proj.cnt ? PROJECTILE_CRYLINK_BOUNCING : PROJECTILE_CRYLINK), TRUE);
 435
 436                 other = proj; MUTATOR_CALLHOOK(EditProjectile);
 437
 438                 counter = counter + 1;
 439         }
 440         self.crylink_lastgroup = proj;
 441 }
 442
 443 void spawnfunc_weapon_crylink (void)
 444 {
 445         weapon_defaultspawnfunc(WEP_CRYLINK);
 446 }
 447
 448 float w_crylink(float req)
 449 {
 450         if (req == WR_AIM)
 451         {
 452                 if (random() > 0.15)
 453                         self.BUTTON_ATCK = bot_aim(cvar("g_balance_crylink_primary_speed"), 0, cvar("g_balance_crylink_primary_middle_lifetime"), FALSE);
 454                 else
 455                         self.BUTTON_ATCK2 = bot_aim(cvar("g_balance_crylink_secondary_speed"), 0, cvar("g_balance_crylink_secondary_middle_lifetime"), FALSE);
 456         }
 457         else if (req == WR_THINK)
 458         {
 459                 if (self.BUTTON_ATCK)
 460                 {
 461                         if (!self.crylink_waitrelease)
 462                         if (weapon_prepareattack(0, cvar("g_balance_crylink_primary_refire")))
 463                         {
 464                                 W_Crylink_Attack();
 465                                 weapon_thinkf(WFRAME_FIRE1, cvar("g_balance_crylink_primary_animtime"), w_ready);
 466                                 if(cvar("g_balance_crylink_primary_joinspeed") != 0 || cvar("g_balance_crylink_primary_jointime") != 0)
 467                                         self.crylink_waitrelease = 1;
 468                         }
 469                 }
 470                 else if(self.BUTTON_ATCK2 && cvar("g_balance_crylink_secondary"))
 471                 {
 472                         if (!self.crylink_waitrelease)
 473                         if (weapon_prepareattack(1, cvar("g_balance_crylink_secondary_refire")))
 474                         {
 475                                 W_Crylink_Attack2();
 476                                 weapon_thinkf(WFRAME_FIRE2, cvar("g_balance_crylink_secondary_animtime"), w_ready);
 477                                 if(cvar("g_balance_crylink_secondary_joinspeed") != 0 || cvar("g_balance_crylink_secondary_jointime") != 0)
 478                                         self.crylink_waitrelease = 2;
 479                         }
 480                 }
 481                 else
 482                 {
 483                         if (self.crylink_waitrelease)
 484                         {
 485                                 // fired and released now!
 486                                 if(self.crylink_lastgroup)
 487                                 {
 488                                         vector pos;
 489                                         if(self.crylink_waitrelease == 1)
 490                                         {
 491                                                 pos = W_Crylink_LinkJoin(self.crylink_lastgroup, cvar("g_balance_crylink_primary_joinspeed"), cvar("g_balance_crylink_primary_jointime"));
 492                                         }
 493                                         else
 494                                         {
 495                                                 pos = W_Crylink_LinkJoin(self.crylink_lastgroup, cvar("g_balance_crylink_secondary_joinspeed"), cvar("g_balance_crylink_secondary_jointime"));
 496                                         }
 497
 498                                         entity linkjoineffect;
 499                                         linkjoineffect = spawn();
 500                                         linkjoineffect.classname = "linkjoineffect";
 501                                         linkjoineffect.think = W_Crylink_LinkJoinEffect_Think;
 502                                         linkjoineffect.nextthink = time + w_crylink_linkjoin_time;
 503                                         linkjoineffect.owner = self;
 504                                         setorigin(linkjoineffect, pos);
 505                                 }
 506                                 self.crylink_waitrelease = 0;
 507                                 if(!w_crylink(WR_CHECKAMMO1) && !w_crylink(WR_CHECKAMMO2))
 508                                 {
 509                                         // ran out of ammo!
 510                                         self.cnt = WEP_CRYLINK;
 511                                         self.switchweapon = w_getbestweapon(self);
 512                                 }
 513                         }
 514                 }
 515         }
 516         else if (req == WR_PRECACHE)
 517         {
 518                 precache_model ("models/weapons/g_crylink.md3");
 519                 precache_model ("models/weapons/v_crylink.md3");
 520                 precache_model ("models/weapons/h_crylink.iqm");
 521                 precache_sound ("weapons/crylink_fire.wav");
 522                 precache_sound ("weapons/crylink_fire2.wav");
 523                 precache_sound ("weapons/crylink_linkjoin.wav");
 524         }
 525         else if (req == WR_SETUP)
 526                 weapon_setup(WEP_CRYLINK);
 527         else if (req == WR_CHECKAMMO1)
 528         {
 529                 // don't "run out of ammo" and switch weapons while waiting for release
 530                 if(self.crylink_lastgroup && self.crylink_waitrelease)
 531                         return TRUE;
 532                 return self.ammo_cells >= cvar("g_balance_crylink_primary_ammo");
 533         }
 534         else if (req == WR_CHECKAMMO2)
 535         {
 536                 // don't "run out of ammo" and switch weapons while waiting for release
 537                 if(self.crylink_lastgroup && self.crylink_waitrelease)
 538                         return TRUE;
 539                 return self.ammo_cells >= cvar("g_balance_crylink_secondary_ammo");
 540         }
 541         return TRUE;
 542 };
 543 #endif
 544 #ifdef CSQC
 545 float w_crylink(float req)
 546 {
 547         if(req == WR_IMPACTEFFECT)
 548         {
 549                 vector org2;
 550                 org2 = w_org + w_backoff * 2;
 551                 if(w_deathtype & HITTYPE_SECONDARY)
 552                 {
 553                         pointparticles(particleeffectnum("crylink_impact"), org2, '0 0 0', 1);
 554                         if(!w_issilent)
 555                                 sound(self, CHAN_PROJECTILE, "weapons/crylink_impact2.wav", VOL_BASE, ATTN_NORM);
 556                 }
 557                 else
 558                 {
 559                         pointparticles(particleeffectnum("crylink_impactbig"), org2, '0 0 0', 1);
 560                         if(!w_issilent)
 561                                 sound(self, CHAN_PROJECTILE, "weapons/crylink_impact.wav", VOL_BASE, ATTN_NORM);
 562                 }
 563         }
 564         else if(req == WR_PRECACHE)
 565         {
 566                 precache_sound("weapons/crylink_impact2.wav");
 567                 precache_sound("weapons/crylink_impact.wav");
 568         }
 569         else if (req == WR_SUICIDEMESSAGE)
 570         {
 571                 w_deathtypestring = "%s succeeded at self-destructing themself with the Crylink";
 572         }
 573         else if (req == WR_KILLMESSAGE)
 574         {
 575                 if(w_deathtype & HITTYPE_BOUNCE)
 576                         w_deathtypestring = "%s could not hide from %s's Crylink"; // unchecked: SPLASH (SECONDARY can't be)
 577                 else if(w_deathtype & HITTYPE_SPLASH)
 578                         w_deathtypestring = "%s was too close to %s's Crylink"; // unchecked: SECONDARY
 579                 else
 580                         w_deathtypestring = "%s took a close look at %s's Crylink"; // unchecked: SECONDARY
 581         }
 582         return TRUE;
 583 }
 584 #endif
 585 #endif