qcsrc/common/gamemodes/gamemode/keyhunt/sv_keyhunt.qc

   1 #include "sv_keyhunt.qh"
   2
   3 float autocvar_g_balance_keyhunt_damageforcescale;
   4 float autocvar_g_balance_keyhunt_delay_collect;
   5 float autocvar_g_balance_keyhunt_delay_damage_return;
   6 float autocvar_g_balance_keyhunt_delay_return;
   7 float autocvar_g_balance_keyhunt_delay_round;
   8 float autocvar_g_balance_keyhunt_delay_tracking;
   9 float autocvar_g_balance_keyhunt_return_when_unreachable;
  10 float autocvar_g_balance_keyhunt_dropvelocity;
  11 float autocvar_g_balance_keyhunt_maxdist;
  12 float autocvar_g_balance_keyhunt_protecttime;
  13
  14 int autocvar_g_balance_keyhunt_score_capture;
  15 int autocvar_g_balance_keyhunt_score_carrierfrag;
  16 int autocvar_g_balance_keyhunt_score_collect;
  17 int autocvar_g_balance_keyhunt_score_destroyed;
  18 int autocvar_g_balance_keyhunt_score_destroyed_ownfactor;
  19 int autocvar_g_balance_keyhunt_score_push;
  20 float autocvar_g_balance_keyhunt_throwvelocity;
  21
  22 //int autocvar_g_keyhunt_teams;
  23 int autocvar_g_keyhunt_teams_override;
  24
  25 // #define KH_PLAYER_USE_ATTACHMENT
  26 // #define KH_PLAYER_USE_CARRIEDMODEL
  27
  28 #ifdef KH_PLAYER_USE_ATTACHMENT
  29 const vector KH_PLAYER_ATTACHMENT_DIST_ROTATED = '0 -4 0';
  30 const vector KH_PLAYER_ATTACHMENT_DIST = '4 0 0';
  31 const vector KH_PLAYER_ATTACHMENT = '0 0 0';
  32 const vector KH_PLAYER_ATTACHMENT_ANGLES = '0 0 0';
  33 const string KH_PLAYER_ATTACHMENT_BONE = "";
  34 #else
  35 const float KH_KEY_ZSHIFT = 22;
  36 const float KH_KEY_XYDIST = 24;
  37 const float KH_KEY_XYSPEED = 45;
  38 #endif
  39 const float KH_KEY_WP_ZSHIFT = 20;
  40
  41 const vector KH_KEY_MIN = '-10 -10 -46';
  42 const vector KH_KEY_MAX = '10 10 3';
  43 const float KH_KEY_BRIGHTNESS = 2;
  44
  45 bool kh_no_radar_circles;
  46
  47 // kh_state
  48 //     bits  0- 4: team of key 1, or 0 for no such key, or 30 for dropped, or 31 for self
  49 //     bits  5- 9: team of key 2, or 0 for no such key, or 30 for dropped, or 31 for self
  50 //     bits 10-14: team of key 3, or 0 for no such key, or 30 for dropped, or 31 for self
  51 //     bits 15-19: team of key 4, or 0 for no such key, or 30 for dropped, or 31 for self
  52 .float siren_time;  //  time delay the siren
  53 //.float stuff_time;  //  time delay to stuffcmd a cvar
  54
  55 int kh_Team_ByID(int t)
  56 {
  57         if(t == 0) return NUM_TEAM_1;
  58         if(t == 1) return NUM_TEAM_2;
  59         if(t == 2) return NUM_TEAM_3;
  60         if(t == 3) return NUM_TEAM_4;
  61         return 0;
  62 }
  63
  64 entity kh_controller;
  65 //bool kh_tracking_enabled;
  66 int kh_teams;
  67 int kh_interferemsg_team;
  68 float kh_interferemsg_time;
  69 .entity kh_next, kh_prev; // linked list
  70 .float kh_droptime;
  71 .int kh_dropperteam;
  72 .entity kh_previous_owner;
  73 .int kh_previous_owner_playerid;
  74
  75 int kh_key_dropped, kh_key_carried;
  76
  77 int kh_Key_AllOwnedByWhichTeam();
  78
  79 const int ST_KH_CAPS = 1;
  80 void kh_ScoreRules(int teams)
  81 {
  82         GameRules_scoring(teams, SFL_SORT_PRIO_PRIMARY, SFL_SORT_PRIO_PRIMARY, {
  83         field_team(ST_KH_CAPS, "caps", SFL_SORT_PRIO_SECONDARY);
  84         field(SP_KH_CAPS, "caps", SFL_SORT_PRIO_SECONDARY);
  85         field(SP_KH_PUSHES, "pushes", 0);
  86         field(SP_KH_DESTROYS, "destroyed", SFL_LOWER_IS_BETTER);
  87         field(SP_KH_PICKUPS, "pickups", 0);
  88         field(SP_KH_KCKILLS, "kckills", 0);
  89         field(SP_KH_LOSSES, "losses", SFL_LOWER_IS_BETTER);
  90         });
  91 }
  92
  93 bool kh_KeyCarrier_waypointsprite_visible_for_player(entity this, entity player, entity view)  // runs all the time
  94 {
  95         if(!IS_PLAYER(view) || DIFF_TEAM(this, view))
  96                 if(!kh_tracking_enabled)
  97                         return false;
  98
  99         return true;
 100 }
 101
 102 bool kh_Key_waypointsprite_visible_for_player(entity this, entity player, entity view)
 103 {
 104         if(!kh_tracking_enabled)
 105                 return false;
 106         if(!this.owner)
 107                 return true;
 108         if(!this.owner.owner)
 109                 return true;
 110         return false;  // draw only when key is not owned
 111 }
 112
 113 void kh_update_state()
 114 {
 115         entity key;
 116         int f;
 117         int s = 0;
 118         FOR_EACH_KH_KEY(key)
 119         {
 120                 if(key.owner)
 121                         f = key.team;
 122                 else
 123                         f = 30;
 124                 s |= (32 ** key.count) * f;
 125         }
 126
 127         FOREACH_CLIENT(true, { STAT(KH_KEYS, it) = s; });
 128
 129         FOR_EACH_KH_KEY(key)
 130         {
 131                 if(key.owner)
 132                         STAT(KH_KEYS, key.owner) |= (32 ** key.count) * 31;
 133         }
 134         //print(ftos((nextent(NULL)).kh_state), "\n");
 135 }
 136
 137
 138
 139
 140 var kh_Think_t kh_Controller_Thinkfunc;
 141 void kh_Controller_SetThink(float t, kh_Think_t func)  // runs occasionaly
 142 {
 143         kh_Controller_Thinkfunc = func;
 144         kh_controller.cnt = ceil(t);
 145         if(t == 0)
 146                 kh_controller.nextthink = time; // force
 147 }
 148 void kh_WaitForPlayers();
 149 void kh_Controller_Think(entity this)  // called a lot
 150 {
 151         if(game_stopped)
 152                 return;
 153         if(this.cnt > 0)
 154         {
 155                 if(getthink(this) != kh_WaitForPlayers)
 156                         this.cnt -= 1;
 157         }
 158         else if(this.cnt == 0)
 159         {
 160                 this.cnt -= 1;
 161                 kh_Controller_Thinkfunc();
 162         }
 163         this.nextthink = time + 1;
 164 }
 165
 166 // frags f: take from cvar * f
 167 // frags 0: no frags
 168 void kh_Scores_Event(entity player, entity key, string what, float frags_player, float frags_owner)  // update the score when a key is captured
 169 {
 170         string s;
 171         if(game_stopped)
 172                 return;
 173
 174         if(frags_player)
 175                 UpdateFrags(player, frags_player);
 176
 177         if(key && key.owner && frags_owner)
 178                 UpdateFrags(key.owner, frags_owner);
 179
 180         if(!autocvar_sv_eventlog)  //output extra info to the console or text file
 181                 return;
 182
 183         s = strcat(":keyhunt:", what, ":", ftos(player.playerid), ":", ftos(frags_player));
 184
 185         if(key && key.owner)
 186                 s = strcat(s, ":", ftos(key.owner.playerid));
 187         else
 188                 s = strcat(s, ":0");
 189
 190         s = strcat(s, ":", ftos(frags_owner), ":");
 191
 192         if(key)
 193                 s = strcat(s, key.netname);
 194
 195         GameLogEcho(s);
 196 }
 197
 198 vector kh_AttachedOrigin(entity e)  // runs when a team captures the flag, it can run 2 or 3 times.
 199 {
 200         if(e.tag_entity)
 201         {
 202                 makevectors(e.tag_entity.angles);
 203                 return e.tag_entity.origin + e.origin.x * v_forward - e.origin.y * v_right + e.origin.z * v_up;
 204         }
 205         else
 206                 return e.origin;
 207 }
 208
 209 void kh_Key_Attach(entity key)  // runs when a player picks up a key and several times when a key is assigned to a player at the start of a round
 210 {
 211 #ifdef KH_PLAYER_USE_ATTACHMENT
 212         entity first = key.owner.kh_next;
 213         if(key == first)
 214         {
 215                 setattachment(key, key.owner, KH_PLAYER_ATTACHMENT_BONE);
 216                 if(key.kh_next)
 217                 {
 218                         setattachment(key.kh_next, key, "");
 219                         setorigin(key, key.kh_next.origin - 0.5 * KH_PLAYER_ATTACHMENT_DIST);
 220                         setorigin(key.kh_next, KH_PLAYER_ATTACHMENT_DIST_ROTATED);
 221                         key.kh_next.angles = '0 0 0';
 222                 }
 223                 else
 224                         setorigin(key, KH_PLAYER_ATTACHMENT);
 225                 key.angles = KH_PLAYER_ATTACHMENT_ANGLES;
 226         }
 227         else
 228         {
 229                 setattachment(key, key.kh_prev, "");
 230                 if(key.kh_next)
 231                         setattachment(key.kh_next, key, "");
 232                 setorigin(key, KH_PLAYER_ATTACHMENT_DIST_ROTATED);
 233                 setorigin(first, first.origin - 0.5 * KH_PLAYER_ATTACHMENT_DIST);
 234                 key.angles = '0 0 0';
 235         }
 236 #else
 237         setattachment(key, key.owner, "");
 238         setorigin(key, '0 0 1' * KH_KEY_ZSHIFT);  // fixing x, y in think
 239         key.angles_y -= key.owner.angles.y;
 240 #endif
 241         key.flags = 0;
 242         if(IL_CONTAINS(g_items, key))
 243                 IL_REMOVE(g_items, key);
 244         key.solid = SOLID_NOT;
 245         set_movetype(key, MOVETYPE_NONE);
 246         key.team = key.owner.team;
 247         key.nextthink = time;
 248         key.damageforcescale = 0;
 249         key.takedamage = DAMAGE_NO;
 250         key.modelindex = kh_key_carried;
 251         navigation_dynamicgoal_unset(key);
 252 }
 253
 254 void kh_Key_Detach(entity key) // runs every time a key is dropped or lost. Runs several times times when all the keys are captured
 255 {
 256 #ifdef KH_PLAYER_USE_ATTACHMENT
 257         entity first = key.owner.kh_next;
 258         if(key == first)
 259         {
 260                 if(key.kh_next)
 261                 {
 262                         setattachment(key.kh_next, key.owner, KH_PLAYER_ATTACHMENT_BONE);
 263                         setorigin(key.kh_next, key.origin + 0.5 * KH_PLAYER_ATTACHMENT_DIST);
 264                         key.kh_next.angles = KH_PLAYER_ATTACHMENT_ANGLES;
 265                 }
 266         }
 267         else
 268         {
 269                 if(key.kh_next)
 270                         setattachment(key.kh_next, key.kh_prev, "");
 271                 setorigin(first, first.origin + 0.5 * KH_PLAYER_ATTACHMENT_DIST);
 272         }
 273         // in any case:
 274         setattachment(key, NULL, "");
 275         setorigin(key, key.owner.origin + '0 0 1' * (STAT(PL_MIN, key.owner).z - KH_KEY_MIN_z));
 276         key.angles = key.owner.angles;
 277 #else
 278         setorigin(key, key.owner.origin + key.origin.z * '0 0 1');
 279         setattachment(key, NULL, "");
 280         key.angles_y += key.owner.angles.y;
 281 #endif
 282         key.flags = FL_ITEM;
 283         if(!IL_CONTAINS(g_items, key))
 284                 IL_PUSH(g_items, key);
 285         key.solid = SOLID_TRIGGER;
 286         set_movetype(key, MOVETYPE_TOSS);
 287         key.pain_finished = time + autocvar_g_balance_keyhunt_delay_return;
 288         key.damageforcescale = autocvar_g_balance_keyhunt_damageforcescale;
 289         key.takedamage = DAMAGE_YES;
 290         // let key.team stay
 291         key.modelindex = kh_key_dropped;
 292         navigation_dynamicgoal_set(key, key.owner);
 293         key.kh_previous_owner = key.owner;
 294         key.kh_previous_owner_playerid = key.owner.playerid;
 295 }
 296
 297 void kh_Key_AssignTo(entity key, entity player)  // runs every time a key is picked up or assigned. Runs prior to kh_key_attach
 298 {
 299         if(key.owner == player)
 300                 return;
 301
 302         int ownerteam0 = kh_Key_AllOwnedByWhichTeam();
 303
 304         if(key.owner)
 305         {
 306                 kh_Key_Detach(key);
 307
 308                 // remove from linked list
 309                 if(key.kh_next)
 310                         key.kh_next.kh_prev = key.kh_prev;
 311                 key.kh_prev.kh_next = key.kh_next;
 312                 key.kh_next = NULL;
 313                 key.kh_prev = NULL;
 314
 315                 if(key.owner.kh_next == NULL)
 316                 {
 317                         // No longer a key carrier
 318                         if(!kh_no_radar_circles)
 319                                 WaypointSprite_Ping(key.owner.waypointsprite_attachedforcarrier);
 320                         WaypointSprite_DetachCarrier(key.owner);
 321                 }
 322         }
 323
 324         key.owner = player;
 325
 326         if(player)
 327         {
 328                 // insert into linked list
 329                 key.kh_next = player.kh_next;
 330                 key.kh_prev = player;
 331                 player.kh_next = key;
 332                 if(key.kh_next)
 333                         key.kh_next.kh_prev = key;
 334
 335                 kh_Key_Attach(key);
 336
 337                 if(key.kh_next == NULL)
 338                 {
 339                         // player is now a key carrier
 340                         entity wp = WaypointSprite_AttachCarrier(WP_Null, player, RADARICON_FLAGCARRIER);
 341                         wp.colormod = colormapPaletteColor(player.team - 1, 0);
 342                         player.waypointsprite_attachedforcarrier.waypointsprite_visible_for_player = kh_KeyCarrier_waypointsprite_visible_for_player;
 343                         WaypointSprite_UpdateRule(player.waypointsprite_attachedforcarrier, player.team, SPRITERULE_TEAMPLAY);
 344                         if(player.team == NUM_TEAM_1)
 345                                 WaypointSprite_UpdateSprites(player.waypointsprite_attachedforcarrier, WP_KeyCarrierRed, WP_KeyCarrierFriend, WP_KeyCarrierRed);
 346                         else if(player.team == NUM_TEAM_2)
 347                                 WaypointSprite_UpdateSprites(player.waypointsprite_attachedforcarrier, WP_KeyCarrierBlue, WP_KeyCarrierFriend, WP_KeyCarrierBlue);
 348                         else if(player.team == NUM_TEAM_3)
 349                                 WaypointSprite_UpdateSprites(player.waypointsprite_attachedforcarrier, WP_KeyCarrierYellow, WP_KeyCarrierFriend, WP_KeyCarrierYellow);
 350                         else if(player.team == NUM_TEAM_4)
 351                                 WaypointSprite_UpdateSprites(player.waypointsprite_attachedforcarrier, WP_KeyCarrierPink, WP_KeyCarrierFriend, WP_KeyCarrierPink);
 352                         if(!kh_no_radar_circles)
 353                                 WaypointSprite_Ping(player.waypointsprite_attachedforcarrier);
 354                 }
 355         }
 356
 357         // moved that here, also update if there's no player
 358         kh_update_state();
 359
 360         key.pusher = NULL;
 361
 362         int ownerteam = kh_Key_AllOwnedByWhichTeam();
 363         if(ownerteam != ownerteam0)
 364         {
 365                 entity k;
 366                 if(ownerteam != -1)
 367                 {
 368                         kh_interferemsg_time = time + 0.2;
 369                         kh_interferemsg_team = player.team;
 370
 371                         // audit all key carrier sprites, update them to "Run here"
 372                         FOR_EACH_KH_KEY(k)
 373                         {
 374                                 if (!k.owner) continue;
 375                                 entity first = WP_Null;
 376                                 FOREACH(Waypoints, it.netname == k.owner.waypointsprite_attachedforcarrier.model1, { first = it; break; });
 377                                 entity third = WP_Null;
 378                                 FOREACH(Waypoints, it.netname == k.owner.waypointsprite_attachedforcarrier.model3, { third = it; break; });
 379                                 WaypointSprite_UpdateSprites(k.owner.waypointsprite_attachedforcarrier, first, WP_KeyCarrierFinish, third);
 380                         }
 381                 }
 382                 else
 383                 {
 384                         kh_interferemsg_time = 0;
 385
 386                         // audit all key carrier sprites, update them to "Key Carrier"
 387                         FOR_EACH_KH_KEY(k)
 388                         {
 389                                 if (!k.owner) continue;
 390                                 entity first = WP_Null;
 391                                 FOREACH(Waypoints, it.netname == k.owner.waypointsprite_attachedforcarrier.model1, { first = it; break; });
 392                                 entity third = WP_Null;
 393                                 FOREACH(Waypoints, it.netname == k.owner.waypointsprite_attachedforcarrier.model3, { third = it; break; });
 394                                 WaypointSprite_UpdateSprites(k.owner.waypointsprite_attachedforcarrier, first, WP_KeyCarrierFriend, third);
 395                         }
 396                 }
 397         }
 398 }
 399
 400 void kh_Key_Damage(entity this, entity inflictor, entity attacker, float damage, int deathtype, .entity weaponentity, vector hitloc, vector force)
 401 {
 402         if(this.owner)
 403                 return;
 404         if(ITEM_DAMAGE_NEEDKILL(deathtype))
 405         {
 406                 this.pain_finished = bound(time, time + autocvar_g_balance_keyhunt_delay_damage_return, this.pain_finished);
 407                 return;
 408         }
 409         if(force == '0 0 0')
 410                 return;
 411         if(time > this.pushltime)
 412                 if(IS_PLAYER(attacker))
 413                         this.team = attacker.team;
 414 }
 415
 416 void kh_Key_Collect(entity key, entity player)  //a player picks up a dropped key
 417 {
 418         sound(player, CH_TRIGGER, SND_KH_COLLECT, VOL_BASE, ATTEN_NORM);
 419
 420         if(key.kh_dropperteam != player.team)
 421         {
 422                 kh_Scores_Event(player, key, "collect", autocvar_g_balance_keyhunt_score_collect, 0);
 423                 GameRules_scoring_add(player, KH_PICKUPS, 1);
 424         }
 425         key.kh_dropperteam = 0;
 426         int realteam = kh_Team_ByID(key.count);
 427         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, APP_TEAM_NUM(realteam, INFO_KEYHUNT_PICKUP), player.netname);
 428
 429         kh_Key_AssignTo(key, player); // this also updates .kh_state
 430 }
 431
 432 void kh_Key_Touch(entity this, entity toucher)  // runs many, many times when a key has been dropped and can be picked up
 433 {
 434         if(game_stopped)
 435                 return;
 436
 437         if(this.owner) // already carried
 438                 return;
 439
 440         if(ITEM_TOUCH_NEEDKILL())
 441         {
 442                 this.pain_finished = bound(time, time + autocvar_g_balance_keyhunt_delay_damage_return, this.pain_finished);
 443                 return;
 444         }
 445
 446         if (!IS_PLAYER(toucher))
 447                 return;
 448         if(IS_DEAD(toucher))
 449                 return;
 450         if(toucher == this.enemy)
 451                 if(time < this.kh_droptime + autocvar_g_balance_keyhunt_delay_collect)
 452                         return;  // you just dropped it!
 453         kh_Key_Collect(this, toucher);
 454 }
 455
 456 void kh_Key_Remove(entity key)  // runs after when all the keys have been collected or when a key has been dropped for more than X seconds
 457 {
 458         entity o = key.owner;
 459         kh_Key_AssignTo(key, NULL);
 460         if(o) // it was attached
 461                 WaypointSprite_Kill(key.waypointsprite_attachedforcarrier);
 462         else // it was dropped
 463                 WaypointSprite_DetachCarrier(key);
 464
 465         // remove key from key list
 466         if (kh_worldkeylist == key)
 467                 kh_worldkeylist = kh_worldkeylist.kh_worldkeynext;
 468         else
 469         {
 470                 o = kh_worldkeylist;
 471                 while (o)
 472                 {
 473                         if (o.kh_worldkeynext == key)
 474                         {
 475                                 o.kh_worldkeynext = o.kh_worldkeynext.kh_worldkeynext;
 476                                 break;
 477                         }
 478                         o = o.kh_worldkeynext;
 479                 }
 480         }
 481
 482         delete(key);
 483
 484         kh_update_state();
 485 }
 486
 487 void kh_FinishRound()  // runs when a team captures the keys
 488 {
 489         // prepare next round
 490         kh_interferemsg_time = 0;
 491         entity key;
 492
 493         kh_no_radar_circles = true;
 494         FOR_EACH_KH_KEY(key)
 495                 kh_Key_Remove(key);
 496         kh_no_radar_circles = false;
 497
 498         Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, CENTER_KEYHUNT_ROUNDSTART, autocvar_g_balance_keyhunt_delay_round);
 499         kh_Controller_SetThink(autocvar_g_balance_keyhunt_delay_round, kh_StartRound);
 500 }
 501
 502 void nades_GiveBonus(entity player, float score);
 503
 504 void kh_WinnerTeam(int winner_team)  // runs when a team wins
 505 {
 506         // all key carriers get some points
 507         entity key;
 508         float score = (NumTeams(kh_teams) - 1) * autocvar_g_balance_keyhunt_score_capture;
 509         DistributeEvenly_Init(score, NumTeams(kh_teams));
 510         // twice the score for 3 team games, three times the score for 4 team games!
 511         // note: for a win by destroying the key, this should NOT be applied
 512         FOR_EACH_KH_KEY(key)
 513         {
 514                 float f = DistributeEvenly_Get(1);
 515                 kh_Scores_Event(key.owner, key, "capture", f, 0);
 516                 GameRules_scoring_add_team(key.owner, KH_CAPS, 1);
 517                 nades_GiveBonus(key.owner, autocvar_g_nades_bonus_score_high);
 518         }
 519
 520         bool first = true;
 521         string keyowner = "";
 522         FOR_EACH_KH_KEY(key)
 523                 if(key.owner.kh_next == key)
 524                 {
 525                         if(!first)
 526                                 keyowner = strcat(keyowner, ", ");
 527                         keyowner = key.owner.netname;
 528                         first = false;
 529                 }
 530
 531         Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, APP_TEAM_NUM(winner_team, CENTER_ROUND_TEAM_WIN));
 532         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, APP_TEAM_NUM(winner_team, INFO_KEYHUNT_CAPTURE), keyowner);
 533
 534         first = true;
 535         vector firstorigin = '0 0 0', lastorigin = '0 0 0', midpoint = '0 0 0';
 536         FOR_EACH_KH_KEY(key)
 537         {
 538                 vector thisorigin = kh_AttachedOrigin(key);
 539                 //dprint("Key origin: ", vtos(thisorigin), "\n");
 540                 midpoint += thisorigin;
 541
 542                 if(!first)
 543                         te_lightning2(NULL, lastorigin, thisorigin);
 544                 lastorigin = thisorigin;
 545                 if(first)
 546                         firstorigin = thisorigin;
 547                 first = false;
 548         }
 549         if(NumTeams(kh_teams) > 2)
 550         {
 551                 te_lightning2(NULL, lastorigin, firstorigin);
 552         }
 553         midpoint = midpoint * (1 / NumTeams(kh_teams));
 554         te_customflash(midpoint, 1000, 1, Team_ColorRGB(winner_team) * 0.5 + '0.5 0.5 0.5');  // make the color >=0.5 in each component
 555
 556         play2all(SND(KH_CAPTURE));
 557         kh_FinishRound();
 558 }
 559
 560 void kh_LoserTeam(int loser_team, entity lostkey)  // runs when a player pushes a flag carrier off the map
 561 {
 562         float f;
 563         entity attacker = NULL;
 564         if(lostkey.pusher)
 565                 if(lostkey.pusher.team != loser_team)
 566                         if(IS_PLAYER(lostkey.pusher))
 567                                 attacker = lostkey.pusher;
 568
 569         if(attacker)
 570         {
 571                 if(lostkey.kh_previous_owner)
 572                         kh_Scores_Event(lostkey.kh_previous_owner, NULL, "pushed", 0, -autocvar_g_balance_keyhunt_score_push);
 573                         // don't actually GIVE him the -nn points, just log
 574                 kh_Scores_Event(attacker, NULL, "push", autocvar_g_balance_keyhunt_score_push, 0);
 575                 GameRules_scoring_add(attacker, KH_PUSHES, 1);
 576                 //centerprint(attacker, "Your push is the best!"); // does this really need to exist?
 577         }
 578         else
 579         {
 580                 int players = 0;
 581                 float of = autocvar_g_balance_keyhunt_score_destroyed_ownfactor;
 582
 583                 FOREACH_CLIENT(IS_PLAYER(it) && it.team != loser_team, { ++players; });
 584
 585                 entity key;
 586                 int keys = 0;
 587                 FOR_EACH_KH_KEY(key)
 588                         if(key.owner && key.team != loser_team)
 589                                 ++keys;
 590
 591                 if(lostkey.kh_previous_owner)
 592                         kh_Scores_Event(lostkey.kh_previous_owner, NULL, "destroyed", 0, -autocvar_g_balance_keyhunt_score_destroyed);
 593                         // don't actually GIVE him the -nn points, just log
 594
 595                 if(lostkey.kh_previous_owner.playerid == lostkey.kh_previous_owner_playerid)
 596                         GameRules_scoring_add(lostkey.kh_previous_owner, KH_DESTROYS, 1);
 597
 598                 DistributeEvenly_Init(autocvar_g_balance_keyhunt_score_destroyed, keys * of + players);
 599
 600                 FOR_EACH_KH_KEY(key)
 601                         if(key.owner && key.team != loser_team)
 602                         {
 603                                 f = DistributeEvenly_Get(of);
 604                                 kh_Scores_Event(key.owner, NULL, "destroyed_holdingkey", f, 0);
 605                         }
 606
 607                 int fragsleft = DistributeEvenly_Get(players);
 608
 609                 // Now distribute these among all other teams...
 610                 int j = NumTeams(kh_teams) - 1;
 611                 for(int i = 0; i < NumTeams(kh_teams); ++i)
 612                 {
 613                         int thisteam = kh_Team_ByID(i);
 614                         if(thisteam == loser_team) // bad boy, no cookie - this WILL happen
 615                                 continue;
 616
 617                         players = 0;
 618                         FOREACH_CLIENT(IS_PLAYER(it) && it.team == thisteam, { ++players; });
 619
 620                         DistributeEvenly_Init(fragsleft, j);
 621                         fragsleft = DistributeEvenly_Get(j - 1);
 622                         DistributeEvenly_Init(DistributeEvenly_Get(1), players);
 623
 624                         FOREACH_CLIENT(IS_PLAYER(it) && it.team == thisteam, {
 625                                 f = DistributeEvenly_Get(1);
 626                                 kh_Scores_Event(it, NULL, "destroyed", f, 0);
 627                         });
 628
 629                         --j;
 630                 }
 631         }
 632
 633         int realteam = kh_Team_ByID(lostkey.count);
 634         Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, APP_TEAM_NUM(loser_team, CENTER_ROUND_TEAM_LOSS));
 635         if(attacker)
 636                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, APP_TEAM_NUM(realteam, INFO_KEYHUNT_PUSHED), attacker.netname, lostkey.kh_previous_owner.netname);
 637         else
 638                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, APP_TEAM_NUM(realteam, INFO_KEYHUNT_DESTROYED), lostkey.kh_previous_owner.netname);
 639
 640         play2all(SND(KH_DESTROY));
 641         te_tarexplosion(lostkey.origin);
 642
 643         kh_FinishRound();
 644 }
 645
 646 void kh_Key_Think(entity this)  // runs all the time
 647 {
 648         if(game_stopped)
 649                 return;
 650
 651         if(this.owner)
 652         {
 653 #ifndef KH_PLAYER_USE_ATTACHMENT
 654                 makevectors('0 1 0' * (this.cnt + (time % 360) * KH_KEY_XYSPEED));
 655                 setorigin(this, v_forward * KH_KEY_XYDIST + '0 0 1' * this.origin.z);
 656 #endif
 657         }
 658
 659         // if in nodrop or time over, end the round
 660         if(!this.owner)
 661                 if(time > this.pain_finished)
 662                         kh_LoserTeam(this.team, this);
 663
 664         if(this.owner)
 665         if(kh_Key_AllOwnedByWhichTeam() != -1)
 666         {
 667                 if(this.siren_time < time)
 668                 {
 669                         sound(this.owner, CH_TRIGGER, SND_KH_ALARM, VOL_BASE, ATTEN_NORM);  // play a simple alarm
 670                         this.siren_time = time + 2.5;  // repeat every 2.5 seconds
 671                 }
 672
 673                 entity key;
 674                 vector p = this.owner.origin;
 675                 FOR_EACH_KH_KEY(key)
 676                         if(vdist(key.owner.origin - p, >, autocvar_g_balance_keyhunt_maxdist))
 677                                 goto not_winning;
 678                 kh_WinnerTeam(this.team);
 679 LABEL(not_winning)
 680         }
 681
 682         if(kh_interferemsg_time && time > kh_interferemsg_time)
 683         {
 684                 kh_interferemsg_time = 0;
 685                 FOREACH_CLIENT(IS_PLAYER(it), {
 686                         if(it.team == kh_interferemsg_team)
 687                         {
 688                                 if(it.kh_next)
 689                                         Send_Notification(NOTIF_ONE, it, MSG_CENTER, CENTER_KEYHUNT_MEET);
 690                                 else
 691                                         Send_Notification(NOTIF_ONE, it, MSG_CENTER, CENTER_KEYHUNT_HELP);
 692                         }
 693                         else
 694                                 Send_Notification(NOTIF_ONE, it, MSG_CENTER, APP_TEAM_NUM(kh_interferemsg_team, CENTER_KEYHUNT_INTERFERE));
 695                 });
 696         }
 697
 698         this.nextthink = time + 0.05;
 699 }
 700
 701 void key_reset(entity this)
 702 {
 703         kh_Key_AssignTo(this, NULL);
 704         kh_Key_Remove(this);
 705 }
 706
 707 const string STR_ITEM_KH_KEY = "item_kh_key";
 708 void kh_Key_Spawn(entity initial_owner, float _angle, float i)  // runs every time a new flag is created, ie after all the keys have been collected
 709 {
 710         entity key = spawn();
 711         key.count = i;
 712         key.classname = STR_ITEM_KH_KEY;
 713         settouch(key, kh_Key_Touch);
 714         setthink(key, kh_Key_Think);
 715         key.nextthink = time;
 716         key.items = IT_KEY1 | IT_KEY2;
 717         key.cnt = _angle;
 718         key.angles = '0 360 0' * random();
 719         key.event_damage = kh_Key_Damage;
 720         key.takedamage = DAMAGE_YES;
 721         key.damagedbytriggers = autocvar_g_balance_keyhunt_return_when_unreachable;
 722         key.damagedbycontents = autocvar_g_balance_keyhunt_return_when_unreachable;
 723         key.modelindex = kh_key_dropped;
 724         key.model = "key";
 725         key.kh_dropperteam = 0;
 726         key.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP | DPCONTENTS_BOTCLIP;
 727         setsize(key, KH_KEY_MIN, KH_KEY_MAX);
 728         key.colormod = Team_ColorRGB(initial_owner.team) * KH_KEY_BRIGHTNESS;
 729         key.reset = key_reset;
 730         navigation_dynamicgoal_init(key, false);
 731
 732         switch(initial_owner.team)
 733         {
 734                 case NUM_TEAM_1:
 735                         key.netname = "^1red key";
 736                         break;
 737                 case NUM_TEAM_2:
 738                         key.netname = "^4blue key";
 739                         break;
 740                 case NUM_TEAM_3:
 741                         key.netname = "^3yellow key";
 742                         break;
 743                 case NUM_TEAM_4:
 744                         key.netname = "^6pink key";
 745                         break;
 746                 default:
 747                         key.netname = "NETGIER key";
 748                         break;
 749         }
 750
 751         // link into key list
 752         key.kh_worldkeynext = kh_worldkeylist;
 753         kh_worldkeylist = key;
 754
 755         Send_Notification(NOTIF_ONE, initial_owner, MSG_CENTER, APP_TEAM_NUM(initial_owner.team, CENTER_KEYHUNT_START));
 756
 757         WaypointSprite_Spawn(WP_KeyDropped, 0, 0, key, '0 0 1' * KH_KEY_WP_ZSHIFT, NULL, key.team, key, waypointsprite_attachedforcarrier, false, RADARICON_FLAG);
 758         key.waypointsprite_attachedforcarrier.waypointsprite_visible_for_player = kh_Key_waypointsprite_visible_for_player;
 759
 760         kh_Key_AssignTo(key, initial_owner);
 761 }
 762
 763 // -1 when no team completely owns all keys yet
 764 int kh_Key_AllOwnedByWhichTeam()  // constantly called. check to see if all the keys are owned by the same team
 765 {
 766         entity key;
 767         int teem = -1;
 768         int keys = NumTeams(kh_teams);
 769         FOR_EACH_KH_KEY(key)
 770         {
 771                 if(!key.owner)
 772                         return -1;
 773                 if(teem == -1)
 774                         teem = key.team;
 775                 else if(teem != key.team)
 776                         return -1;
 777                 --keys;
 778         }
 779         if(keys != 0)
 780                 return -1;
 781         return teem;
 782 }
 783
 784 void kh_Key_DropOne(entity key)
 785 {
 786         // prevent collecting this one for some time
 787         entity player = key.owner;
 788
 789         key.kh_droptime = time;
 790         key.enemy = player;
 791
 792         kh_Scores_Event(player, key, "dropkey", 0, 0);
 793         GameRules_scoring_add(player, KH_LOSSES, 1);
 794         int realteam = kh_Team_ByID(key.count);
 795         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, APP_TEAM_NUM(realteam, INFO_KEYHUNT_DROP), player.netname);
 796
 797         kh_Key_AssignTo(key, NULL);
 798         makevectors(player.v_angle);
 799         key.velocity = W_CalculateProjectileVelocity(player, player.velocity, autocvar_g_balance_keyhunt_throwvelocity * v_forward, false);
 800         key.pusher = NULL;
 801         key.pushltime = time + autocvar_g_balance_keyhunt_protecttime;
 802         key.kh_dropperteam = key.team;
 803
 804         sound(player, CH_TRIGGER, SND_KH_DROP, VOL_BASE, ATTEN_NORM);
 805 }
 806
 807 void kh_Key_DropAll(entity player, float suicide) // runs whenever a player dies
 808 {
 809         if(player.kh_next)
 810         {
 811                 entity mypusher = NULL;
 812                 if(player.pusher)
 813                         if(time < player.pushltime)
 814                                 mypusher = player.pusher;
 815
 816                 entity key;
 817                 while((key = player.kh_next))
 818                 {
 819                         kh_Scores_Event(player, key, "losekey", 0, 0);
 820                         GameRules_scoring_add(player, KH_LOSSES, 1);
 821                         int realteam = kh_Team_ByID(key.count);
 822                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, APP_TEAM_NUM(realteam, INFO_KEYHUNT_LOST), player.netname);
 823                         kh_Key_AssignTo(key, NULL);
 824                         makevectors('-1 0 0' * (45 + 45 * random()) + '0 360 0' * random());
 825                         key.velocity = W_CalculateProjectileVelocity(player, player.velocity, autocvar_g_balance_keyhunt_dropvelocity * v_forward, false);
 826                         key.pusher = mypusher;
 827                         key.pushltime = time + autocvar_g_balance_keyhunt_protecttime;
 828                         if(suicide)
 829                                 key.kh_dropperteam = player.team;
 830                 }
 831                 sound(player, CH_TRIGGER, SND_KH_DROP, VOL_BASE, ATTEN_NORM);
 832         }
 833 }
 834
 835 int kh_GetMissingTeams()
 836 {
 837         int missing_teams = 0;
 838         for(int i = 0; i < NumTeams(kh_teams); ++i)
 839         {
 840                 int teem = kh_Team_ByID(i);
 841                 int players = 0;
 842                 FOREACH_CLIENT(IS_PLAYER(it), {
 843                         if(!IS_DEAD(it) && !PHYS_INPUT_BUTTON_CHAT(it) && it.team == teem)
 844                                 ++players;
 845                 });
 846                 if (!players)
 847                         missing_teams |= (2 ** i);
 848         }
 849         return missing_teams;
 850 }
 851
 852 void kh_WaitForPlayers()  // delay start of the round until enough players are present
 853 {
 854         static int prev_missing_teams_mask;
 855         if(time < game_starttime)
 856         {
 857                 if (prev_missing_teams_mask > 0)
 858                         Kill_Notification(NOTIF_ALL, NULL, MSG_CENTER, CPID_MISSING_TEAMS);
 859                 prev_missing_teams_mask = -1;
 860                 kh_Controller_SetThink(game_starttime - time + 0.1, kh_WaitForPlayers);
 861                 return;
 862         }
 863
 864         int missing_teams_mask = kh_GetMissingTeams();
 865         if(!missing_teams_mask)
 866         {
 867                 if(prev_missing_teams_mask > 0)
 868                         Kill_Notification(NOTIF_ALL, NULL, MSG_CENTER, CPID_MISSING_TEAMS);
 869                 prev_missing_teams_mask = -1;
 870                 Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, CENTER_KEYHUNT_ROUNDSTART, autocvar_g_balance_keyhunt_delay_round);
 871                 kh_Controller_SetThink(autocvar_g_balance_keyhunt_delay_round, kh_StartRound);
 872         }
 873         else
 874         {
 875                 if(player_count == 0)
 876                 {
 877                         if(prev_missing_teams_mask > 0)
 878                                 Kill_Notification(NOTIF_ALL, NULL, MSG_CENTER, CPID_MISSING_TEAMS);
 879                         prev_missing_teams_mask = -1;
 880                 }
 881                 else
 882                 {
 883                         if(prev_missing_teams_mask != missing_teams_mask)
 884                         {
 885                                 Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, CENTER_MISSING_TEAMS, missing_teams_mask);
 886                                 prev_missing_teams_mask = missing_teams_mask;
 887                         }
 888                 }
 889                 kh_Controller_SetThink(1, kh_WaitForPlayers);
 890         }
 891 }
 892
 893 void kh_EnableTrackingDevice()  // runs after each round
 894 {
 895         Kill_Notification(NOTIF_ALL, NULL, MSG_CENTER, CPID_KEYHUNT);
 896         Kill_Notification(NOTIF_ALL, NULL, MSG_CENTER, CPID_KEYHUNT_OTHER);
 897
 898         kh_tracking_enabled = true;
 899 }
 900
 901 void kh_StartRound()  // runs at the start of each round
 902 {
 903         if(time < game_starttime)
 904         {
 905                 kh_Controller_SetThink(game_starttime - time + 0.1, kh_WaitForPlayers);
 906                 return;
 907         }
 908
 909         if(kh_GetMissingTeams())
 910         {
 911                 kh_Controller_SetThink(1, kh_WaitForPlayers);
 912                 return;
 913         }
 914
 915         Kill_Notification(NOTIF_ALL, NULL, MSG_CENTER, CPID_KEYHUNT);
 916         Kill_Notification(NOTIF_ALL, NULL, MSG_CENTER, CPID_KEYHUNT_OTHER);
 917
 918         for(int i = 0; i < NumTeams(kh_teams); ++i)
 919         {
 920                 int teem = kh_Team_ByID(i);
 921                 int players = 0;
 922                 entity my_player = NULL;
 923                 FOREACH_CLIENT(IS_PLAYER(it), {
 924                         if(!IS_DEAD(it) && !PHYS_INPUT_BUTTON_CHAT(it) && it.team == teem)
 925                         {
 926                                 ++players;
 927                                 if(random() * players <= 1)
 928                                         my_player = it;
 929                         }
 930                 });
 931                 kh_Key_Spawn(my_player, 360 * i / NumTeams(kh_teams), i);
 932         }
 933
 934         kh_tracking_enabled = false;
 935         Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, CENTER_KEYHUNT_SCAN, autocvar_g_balance_keyhunt_delay_tracking);
 936         kh_Controller_SetThink(autocvar_g_balance_keyhunt_delay_tracking, kh_EnableTrackingDevice);
 937 }
 938
 939 float kh_HandleFrags(entity attacker, entity targ, float f)  // adds to the player score
 940 {
 941         if(attacker == targ)
 942                 return f;
 943
 944         if(targ.kh_next)
 945         {
 946                 if(attacker.team == targ.team)
 947                 {
 948                         int nk = 0;
 949                         for(entity k = targ.kh_next; k != NULL; k = k.kh_next)
 950                                 ++nk;
 951                         kh_Scores_Event(attacker, targ.kh_next, "carrierfrag", -nk * autocvar_g_balance_keyhunt_score_collect, 0);
 952                 }
 953                 else
 954                 {
 955                         kh_Scores_Event(attacker, targ.kh_next, "carrierfrag", autocvar_g_balance_keyhunt_score_carrierfrag-1, 0);
 956                         GameRules_scoring_add(attacker, KH_KCKILLS, 1);
 957                         // the frag gets added later
 958                 }
 959         }
 960
 961         return f;
 962 }
 963
 964 void kh_Initialize()  // sets up th KH environment
 965 {
 966         // setup variables
 967         kh_teams = autocvar_g_keyhunt_teams_override;
 968         if(kh_teams < 2)
 969                 kh_teams = cvar("g_keyhunt_teams"); // read the cvar directly as it gets written earlier in the same frame
 970         kh_teams = BITS(bound(2, kh_teams, 4));
 971
 972         // make a KH entity for controlling the game
 973         kh_controller = spawn();
 974         setthink(kh_controller, kh_Controller_Think);
 975         kh_Controller_SetThink(0, kh_WaitForPlayers);
 976
 977         setmodel(kh_controller, MDL_KH_KEY);
 978         kh_key_dropped = kh_controller.modelindex;
 979         /*
 980         dprint(vtos(kh_controller.mins));
 981         dprint(vtos(kh_controller.maxs));
 982         dprint("\n");
 983         */
 984 #ifdef KH_PLAYER_USE_CARRIEDMODEL
 985         setmodel(kh_controller, MDL_KH_KEY_CARRIED);
 986         kh_key_carried = kh_controller.modelindex;
 987 #else
 988         kh_key_carried = kh_key_dropped;
 989 #endif
 990
 991         kh_controller.model = "";
 992         kh_controller.modelindex = 0;
 993
 994         kh_ScoreRules(kh_teams);
 995 }
 996
 997 void kh_finalize()
 998 {
 999         // to be called before intermission
1000         kh_FinishRound();
1001         delete(kh_controller);
1002         kh_controller = NULL;
1003 }
1004
1005 // legacy bot role
1006
1007 void(entity this) havocbot_role_kh_carrier;
1008 void(entity this) havocbot_role_kh_defense;
1009 void(entity this) havocbot_role_kh_offense;
1010 void(entity this) havocbot_role_kh_freelancer;
1011
1012
1013 void havocbot_goalrating_kh(entity this, float ratingscale_team, float ratingscale_dropped, float ratingscale_enemy)
1014 {
1015         entity head;
1016         for (head = kh_worldkeylist; head; head = head.kh_worldkeynext)
1017         {
1018                 if(head.owner == this)
1019                         continue;
1020                 if(!kh_tracking_enabled)
1021                 {
1022                         // if it's carried by our team we know about it
1023                         // otherwise we have to see it to know about it
1024                         if(!head.owner || head.team != this.team)
1025                         {
1026                                 traceline(this.origin + this.view_ofs, head.origin, MOVE_NOMONSTERS, this);
1027                                 if (trace_fraction < 1 && trace_ent != head)
1028                                         continue; // skip what I can't see
1029                         }
1030                 }
1031                 if(!head.owner)
1032                         navigation_routerating(this, head, ratingscale_dropped * 10000, 100000);
1033                 else if(head.team == this.team)
1034                         navigation_routerating(this, head.owner, ratingscale_team * 10000, 100000);
1035                 else
1036                         navigation_routerating(this, head.owner, ratingscale_enemy * 10000, 100000);
1037         }
1038
1039         havocbot_goalrating_items(this, 1, this.origin, 10000);
1040 }
1041
1042 void havocbot_role_kh_carrier(entity this)
1043 {
1044         if(IS_DEAD(this))
1045                 return;
1046
1047         if (!(this.kh_next))
1048         {
1049                 LOG_TRACE("changing role to freelancer");
1050                 this.havocbot_role = havocbot_role_kh_freelancer;
1051                 this.havocbot_role_timeout = 0;
1052                 return;
1053         }
1054
1055         if (navigation_goalrating_timeout(this))
1056         {
1057                 navigation_goalrating_start(this);
1058
1059                 if(kh_Key_AllOwnedByWhichTeam() == this.team)
1060                         havocbot_goalrating_kh(this, 10, 0.1, 0.05); // bring home
1061                 else
1062                         havocbot_goalrating_kh(this, 4, 4, 0.5); // play defensively
1063
1064                 navigation_goalrating_end(this);
1065
1066                 navigation_goalrating_timeout_set(this);
1067         }
1068 }
1069
1070 void havocbot_role_kh_defense(entity this)
1071 {
1072         if(IS_DEAD(this))
1073                 return;
1074
1075         if (this.kh_next)
1076         {
1077                 LOG_TRACE("changing role to carrier");
1078                 this.havocbot_role = havocbot_role_kh_carrier;
1079                 this.havocbot_role_timeout = 0;
1080                 return;
1081         }
1082
1083         if (!this.havocbot_role_timeout)
1084                 this.havocbot_role_timeout = time + random() * 10 + 20;
1085         if (time > this.havocbot_role_timeout)
1086         {
1087                 LOG_TRACE("changing role to freelancer");
1088                 this.havocbot_role = havocbot_role_kh_freelancer;
1089                 this.havocbot_role_timeout = 0;
1090                 return;
1091         }
1092
1093         if (navigation_goalrating_timeout(this))
1094         {
1095                 float key_owner_team;
1096                 navigation_goalrating_start(this);
1097
1098                 key_owner_team = kh_Key_AllOwnedByWhichTeam();
1099                 if(key_owner_team == this.team)
1100                         havocbot_goalrating_kh(this, 10, 0.1, 0.05); // defend key carriers
1101                 else if(key_owner_team == -1)
1102                         havocbot_goalrating_kh(this, 4, 1, 0.05); // play defensively
1103                 else
1104                         havocbot_goalrating_kh(this, 0.1, 0.1, 5); // ATTACK ANYWAY
1105
1106                 navigation_goalrating_end(this);
1107
1108                 navigation_goalrating_timeout_set(this);
1109         }
1110 }
1111
1112 void havocbot_role_kh_offense(entity this)
1113 {
1114         if(IS_DEAD(this))
1115                 return;
1116
1117         if (this.kh_next)
1118         {
1119                 LOG_TRACE("changing role to carrier");
1120                 this.havocbot_role = havocbot_role_kh_carrier;
1121                 this.havocbot_role_timeout = 0;
1122                 return;
1123         }
1124
1125         if (!this.havocbot_role_timeout)
1126                 this.havocbot_role_timeout = time + random() * 10 + 20;
1127         if (time > this.havocbot_role_timeout)
1128         {
1129                 LOG_TRACE("changing role to freelancer");
1130                 this.havocbot_role = havocbot_role_kh_freelancer;
1131                 this.havocbot_role_timeout = 0;
1132                 return;
1133         }
1134
1135         if (navigation_goalrating_timeout(this))
1136         {
1137                 float key_owner_team;
1138
1139                 navigation_goalrating_start(this);
1140
1141                 key_owner_team = kh_Key_AllOwnedByWhichTeam();
1142                 if(key_owner_team == this.team)
1143                         havocbot_goalrating_kh(this, 10, 0.1, 0.05); // defend anyway
1144                 else if(key_owner_team == -1)
1145                         havocbot_goalrating_kh(this, 0.1, 1, 2); // play offensively
1146                 else
1147                         havocbot_goalrating_kh(this, 0.1, 0.1, 5); // ATTACK! EMERGENCY!
1148
1149                 navigation_goalrating_end(this);
1150
1151                 navigation_goalrating_timeout_set(this);
1152         }
1153 }
1154
1155 void havocbot_role_kh_freelancer(entity this)
1156 {
1157         if(IS_DEAD(this))
1158                 return;
1159
1160         if (this.kh_next)
1161         {
1162                 LOG_TRACE("changing role to carrier");
1163                 this.havocbot_role = havocbot_role_kh_carrier;
1164                 this.havocbot_role_timeout = 0;
1165                 return;
1166         }
1167
1168         if (!this.havocbot_role_timeout)
1169                 this.havocbot_role_timeout = time + random() * 10 + 10;
1170         if (time > this.havocbot_role_timeout)
1171         {
1172                 if (random() < 0.5)
1173                 {
1174                         LOG_TRACE("changing role to offense");
1175                         this.havocbot_role = havocbot_role_kh_offense;
1176                 }
1177                 else
1178                 {
1179                         LOG_TRACE("changing role to defense");
1180                         this.havocbot_role = havocbot_role_kh_defense;
1181                 }
1182                 this.havocbot_role_timeout = 0;
1183                 return;
1184         }
1185
1186         if (navigation_goalrating_timeout(this))
1187         {
1188                 navigation_goalrating_start(this);
1189
1190                 int key_owner_team = kh_Key_AllOwnedByWhichTeam();
1191                 if(key_owner_team == this.team)
1192                         havocbot_goalrating_kh(this, 10, 0.1, 0.05); // defend anyway
1193                 else if(key_owner_team == -1)
1194                         havocbot_goalrating_kh(this, 1, 10, 2); // prefer dropped keys
1195                 else
1196                         havocbot_goalrating_kh(this, 0.1, 0.1, 5); // ATTACK ANYWAY
1197
1198                 navigation_goalrating_end(this);
1199
1200                 navigation_goalrating_timeout_set(this);
1201         }
1202 }
1203
1204
1205 // register this as a mutator
1206
1207 MUTATOR_HOOKFUNCTION(kh, ClientDisconnect)
1208 {
1209         entity player = M_ARGV(0, entity);
1210
1211         kh_Key_DropAll(player, true);
1212 }
1213
1214 MUTATOR_HOOKFUNCTION(kh, MakePlayerObserver)
1215 {
1216         entity player = M_ARGV(0, entity);
1217
1218         kh_Key_DropAll(player, true);
1219 }
1220
1221 MUTATOR_HOOKFUNCTION(kh, PlayerDies)
1222 {
1223         entity frag_attacker = M_ARGV(1, entity);
1224         entity frag_target = M_ARGV(2, entity);
1225
1226         if(frag_target == frag_attacker)
1227                 kh_Key_DropAll(frag_target, true);
1228         else if(IS_PLAYER(frag_attacker))
1229                 kh_Key_DropAll(frag_target, false);
1230         else
1231                 kh_Key_DropAll(frag_target, true);
1232 }
1233
1234 MUTATOR_HOOKFUNCTION(kh, GiveFragsForKill, CBC_ORDER_FIRST)
1235 {
1236         entity frag_attacker = M_ARGV(0, entity);
1237         entity frag_target = M_ARGV(1, entity);
1238         float frag_score = M_ARGV(2, float);
1239         M_ARGV(2, float) = kh_HandleFrags(frag_attacker, frag_target, frag_score);
1240 }
1241
1242 MUTATOR_HOOKFUNCTION(kh, MatchEnd)
1243 {
1244         kh_finalize();
1245 }
1246
1247 MUTATOR_HOOKFUNCTION(kh, TeamBalance_CheckAllowedTeams, CBC_ORDER_EXCLUSIVE)
1248 {
1249         M_ARGV(0, float) = kh_teams;
1250         return true;
1251 }
1252
1253 MUTATOR_HOOKFUNCTION(kh, SpectateCopy)
1254 {
1255         entity spectatee = M_ARGV(0, entity);
1256         entity client = M_ARGV(1, entity);
1257
1258         STAT(KH_KEYS, client) = STAT(KH_KEYS, spectatee);
1259 }
1260
1261 MUTATOR_HOOKFUNCTION(kh, PlayerUseKey)
1262 {
1263         entity player = M_ARGV(0, entity);
1264
1265         if(MUTATOR_RETURNVALUE == 0)
1266         {
1267                 entity k = player.kh_next;
1268                 if(k)
1269                 {
1270                         kh_Key_DropOne(k);
1271                         return true;
1272                 }
1273         }
1274 }
1275
1276 MUTATOR_HOOKFUNCTION(kh, HavocBot_ChooseRole)
1277 {
1278     entity bot = M_ARGV(0, entity);
1279
1280         if(IS_DEAD(bot))
1281                 return true;
1282
1283         float r = random() * 3;
1284         if (r < 1)
1285                 bot.havocbot_role = havocbot_role_kh_offense;
1286         else if (r < 2)
1287                 bot.havocbot_role = havocbot_role_kh_defense;
1288         else
1289                 bot.havocbot_role = havocbot_role_kh_freelancer;
1290
1291         return true;
1292 }
1293
1294 MUTATOR_HOOKFUNCTION(kh, LogDeath_AppendItemCodes)
1295 {
1296         entity player = M_ARGV(0, entity);
1297         if(player.kh_next)
1298                 M_ARGV(1, string) = strcat(M_ARGV(1, string), "K"); // item codes
1299 }
1300
1301 MUTATOR_HOOKFUNCTION(kh, DropSpecialItems)
1302 {
1303         entity frag_target = M_ARGV(0, entity);
1304
1305         kh_Key_DropAll(frag_target, false);
1306 }
1307
1308 MUTATOR_HOOKFUNCTION(kh, reset_map_global)
1309 {
1310         kh_WaitForPlayers(); // takes care of killing the "missing teams" message
1311 }