qcsrc/common/notifications/all.qh

   1 #pragma once
   2
   3 #include <common/command/_mod.qh>
   4
   5 #include <common/constants.qh>
   6 #include <common/teams.qh>
   7 #include <common/util.qh>
   8 #include <common/sounds/sound.qh>
   9 #include <common/weapons/all.qh>
  10
  11 // Operator for bold notifications
  12 #define BOLD_OPERATOR "^BOLD"
  13
  14 /** main types/groups of notifications */
  15 ENUMCLASS(MSG)
  16         /** "Global" AND "personal" announcer messages */
  17         CASE(MSG, ANNCE)
  18         /** "Global" information messages */
  19         CASE(MSG, INFO)
  20         /** "Personal" centerprint messages */
  21         CASE(MSG, CENTER)
  22         /** Subcall MSG_INFO and/or MSG_CENTER notifications */
  23         CASE(MSG, MULTI)
  24         /** Choose which subcall wrapper to activate */
  25         CASE(MSG, CHOICE)
  26         /** Kill centerprint message @deprecated */
  27         CASE(MSG, CENTER_KILL)
  28 ENUMCLASS_END(MSG)
  29
  30 string Get_Notif_TypeName(MSG net_type)
  31 {
  32         switch (net_type)
  33         {
  34                 case MSG_ANNCE: return "MSG_ANNCE";
  35                 case MSG_INFO: return "MSG_INFO";
  36                 case MSG_CENTER: return "MSG_CENTER";
  37                 case MSG_MULTI: return "MSG_MULTI";
  38                 case MSG_CHOICE: return "MSG_CHOICE";
  39                 case MSG_CENTER_KILL: return "MSG_CENTER_KILL";
  40         }
  41         LOG_WARNF("Get_Notif_TypeName(%d): Improper net type!", ORDINAL(net_type));
  42         return "";
  43 }
  44
  45 ENUMCLASS(CPID)
  46         CASE(CPID, ASSAULT_ROLE)
  47         CASE(CPID, ROUND)
  48         CASE(CPID, CAMPCHECK)
  49         CASE(CPID, CTF_CAPSHIELD)
  50         CASE(CPID, CTF_LOWPRIO)
  51         CASE(CPID, CTF_PASS)
  52         CASE(CPID, STALEMATE)
  53         CASE(CPID, NADES)
  54         CASE(CPID, IDLING)
  55         CASE(CPID, ITEM)
  56         CASE(CPID, PREVENT_JOIN)
  57         CASE(CPID, KEEPAWAY)
  58         CASE(CPID, KEEPAWAY_WARN)
  59         CASE(CPID, KEYHUNT)
  60         CASE(CPID, KEYHUNT_OTHER)
  61         CASE(CPID, LMS)
  62         CASE(CPID, MISSING_TEAMS)
  63         CASE(CPID, MISSING_PLAYERS)
  64         CASE(CPID, INSTAGIB_FINDAMMO)
  65         CASE(CPID, MOTD)
  66         CASE(CPID, NIX)
  67         CASE(CPID, ONSLAUGHT)
  68         CASE(CPID, ONS_CAPSHIELD)
  69         CASE(CPID, OVERTIME)
  70         CASE(CPID, POWERUP)
  71         CASE(CPID, RACE_FINISHLAP)
  72         CASE(CPID, TEAMCHANGE)
  73         CASE(CPID, TIMEOUT)
  74         CASE(CPID, TIMEIN)
  75         CASE(CPID, VEHICLES)
  76         CASE(CPID, VEHICLES_OTHER)
  77         /** always last */
  78         CASE(CPID, LAST)
  79 ENUMCLASS_END(CPID)
  80
  81 USING(Notification, entity);
  82
  83 // used for notification system multi-team identifiers
  84 #define APP_TEAM_NUM(num, prefix) ((num == NUM_TEAM_1) ? prefix##_RED : ((num == NUM_TEAM_2) ? prefix##_BLUE : ((num == NUM_TEAM_3) ? prefix##_YELLOW : prefix##_PINK)))
  85 #define APP_NUM(num, prefix) ((num) ? APP_TEAM_NUM(num, prefix) : prefix##_NEUTRAL)
  86
  87 #define EIGHT_VARS_TO_VARARGS_VARLIST \
  88         VARITEM(1, 0, s1) \
  89         VARITEM(2, 0, XPD(s1, s2)) \
  90         VARITEM(3, 0, XPD(s1, s2, s3)) \
  91         VARITEM(4, 0, XPD(s1, s2, s3, s4)) \
  92         VARITEM(0, 1, f1) \
  93         VARITEM(1, 1, XPD(s1, f1)) \
  94         VARITEM(2, 1, XPD(s1, s2, f1)) \
  95         VARITEM(3, 1, XPD(s1, s2, s3, f1)) \
  96         VARITEM(4, 1, XPD(s1, s2, s3, s4, f1)) \
  97         VARITEM(0, 2, XPD(f1, f2)) \
  98         VARITEM(1, 2, XPD(s1, f1, f2)) \
  99         VARITEM(2, 2, XPD(s1, s2, f1, f2)) \
 100         VARITEM(3, 2, XPD(s1, s2, s3, f1, f2)) \
 101         VARITEM(4, 2, XPD(s1, s2, s3, s4, f1, f2)) \
 102         VARITEM(0, 3, XPD(f1, f2, f3)) \
 103         VARITEM(1, 3, XPD(s1, f1, f2, f3)) \
 104         VARITEM(2, 3, XPD(s1, s2, f1, f2, f3)) \
 105         VARITEM(3, 3, XPD(s1, s2, s3, f1, f2, f3)) \
 106         VARITEM(4, 3, XPD(s1, s2, s3, s4, f1, f2, f3)) \
 107         VARITEM(0, 4, XPD(f1, f2, f3, f4)) \
 108         VARITEM(1, 4, XPD(s1, f1, f2, f3, f4)) \
 109         VARITEM(2, 4, XPD(s1, s2, f1, f2, f3, f4)) \
 110         VARITEM(3, 4, XPD(s1, s2, s3, f1, f2, f3, f4)) \
 111         VARITEM(4, 4, XPD(s1, s2, s3, s4, f1, f2, f3, f4))
 112
 113 void Destroy_All_Notifications();
 114 void Create_Notification_Entity(entity notif,
 115         float var_default,
 116         float var_cvar,
 117         MSG typeId,
 118         string namestring,
 119         int teamnum);
 120 void Create_Notification_Entity_Annce(entity notif,
 121                                                                                 float var_cvar,
 122                                                                                 string namestring,
 123                                                                                 /* MSG_ANNCE */
 124                                                                                 float channel,
 125                                                                                 string snd,
 126                                                                                 float vol,
 127                                                                                 float position);
 128
 129 void Create_Notification_Entity_InfoCenter(entity notif,
 130                                                                                         float var_cvar,
 131                                                                                         string namestring,
 132                                                                                         int strnum,
 133                                                                                         int flnum,
 134                                                                                         /* MSG_INFO & MSG_CENTER */
 135                                                                                         string args,
 136                                                                                         string hudargs,
 137                                                                                         string icon,
 138                                                                                         CPID cpid,
 139                                                                                         string durcnt,
 140                                                                                         string normal,
 141                                                                                         string gentle);
 142
 143 void Create_Notification_Entity_Multi(entity notif,
 144                                                                                 float var_cvar,
 145                                                                                 string namestring,
 146                                                                                 /* MSG_MULTI */
 147                                                                                 Notification anncename,
 148                                                                                 Notification infoname,
 149                                                                                 Notification centername);
 150
 151 void Create_Notification_Entity_Choice(entity notif,
 152                                                                                 float var_cvar,
 153                                                                                 string namestring,
 154                                                                                 /* MSG_CHOICE */
 155                                                                                 float challow_def,
 156                                                                                 float challow_var,
 157                                                                                 MSG chtype,
 158                                                                                 Notification optiona,
 159                                                                                 Notification optionb);
 160
 161 void Dump_Notifications(int fh, bool alsoprint);
 162
 163 #define DEFAULT_FILENAME "notifications_dump.cfg"
 164 // NOTE: dumpeffectinfo, dumpnotifs, dumpturrets and dumpweapons use similar code
 165 GENERIC_COMMAND(dumpnotifs, "Dump all notifications into " DEFAULT_FILENAME, false)
 166 {
 167         switch (request)
 168         {
 169                 case CMD_REQUEST_COMMAND:
 170                 {
 171                         #ifdef GAMEQC
 172                         string filename = argv(1);
 173                         bool alsoprint = false;
 174                         if (filename == "")
 175                         {
 176                                 filename = DEFAULT_FILENAME;
 177                                 alsoprint = false;
 178                         }
 179                         else if (filename == "-")
 180                         {
 181                                 filename = DEFAULT_FILENAME;
 182                                 alsoprint = true;
 183                         }
 184                         int fh = fopen(filename, FILE_WRITE);
 185                         if (fh >= 0)
 186                         {
 187                                 Dump_Notifications(fh, alsoprint);
 188                                 LOG_INFOF("Dumping notifications... File located in ^2data/data/%s^7.", filename);
 189                                 fclose(fh);
 190                         }
 191                         else
 192                         {
 193                                 LOG_INFOF("^1Error: ^7Could not open file '%s'!", filename);
 194                         }
 195                         #else
 196                         LOG_INFO("Notification dump command only works with cl_cmd and sv_cmd.");
 197                         #endif
 198                         return;
 199                 }
 200                 default:
 201                 case CMD_REQUEST_USAGE:
 202                 {
 203                         LOG_HELP("Usage:^3 ", GetProgramCommandPrefix(), " dumpnotifs [<filename>]");
 204                         LOG_HELPF("  Where <filename> is the file to write (default is %s),", DEFAULT_FILENAME);
 205                         LOG_HELP("  if supplied with '-' output to console as well as default,");
 206                         LOG_HELP("  if left blank, it will only write to default.");
 207                         return;
 208                 }
 209         }
 210 }
 211 #undef DEFAULT_FILENAME
 212
 213 #ifdef NOTIFICATIONS_DEBUG
 214 bool autocvar_notification_debug = false;
 215 void Debug_Notification(string input)
 216 {
 217         switch (autocvar_notification_debug)
 218         {
 219                 case 1: { LOG_TRACE(input); break; }
 220                 case 2: { LOG_INFO(input); break; }
 221         }
 222 }
 223 #endif
 224
 225 void Local_Notification(MSG net_type, Notification net_name, ...count);
 226 /** glue for networking, forwards to `Local_Notification` */
 227 void Local_Notification_WOVA(
 228         MSG net_type, Notification net_name,
 229         float stringcount, float floatcount,
 230         string s1, string s2, string s3, string s4,
 231         float f1, float f2, float f3, float f4);
 232
 233 #ifdef CSQC
 234 string prev_soundfile;
 235 float prev_soundtime;
 236 #endif
 237
 238 #ifdef SVQC
 239 IntrusiveList g_notifications;
 240 STATIC_INIT(g_notifications) { g_notifications = IL_NEW(); }
 241 #endif
 242
 243 #ifdef SVQC
 244 ENUMCLASS(NOTIF)
 245         /** send to one client and their spectators */
 246         CASE(NOTIF, ONE)
 247         /** send ONLY to one client */
 248         CASE(NOTIF, ONE_ONLY)
 249         /** send only to X team and their spectators */
 250         CASE(NOTIF, TEAM)
 251         /** send only to X team and their spectators, except for Y person and their spectators */
 252         CASE(NOTIF, TEAM_EXCEPT)
 253         /** send to everyone */
 254         CASE(NOTIF, ALL)
 255         /** send to everyone except X person and their spectators */
 256         CASE(NOTIF, ALL_EXCEPT)
 257 ENUMCLASS_END(NOTIF)
 258
 259 string Get_Notif_BroadcastName(NOTIF broadcast)
 260 {
 261         switch (broadcast)
 262         {
 263                 case NOTIF_ONE: return "NOTIF_ONE";
 264                 case NOTIF_ONE_ONLY: return "NOTIF_ONE_ONLY";
 265                 case NOTIF_ALL_EXCEPT: return "NOTIF_ALL_EXCEPT";
 266                 case NOTIF_ALL: return "NOTIF_ALL";
 267                 case NOTIF_TEAM: return "NOTIF_TEAM";
 268                 case NOTIF_TEAM_EXCEPT: return "NOTIF_TEAM_EXCEPT";
 269         }
 270         LOG_WARNF("Get_Notif_BroadcastName(%d): Improper broadcast!", broadcast);
 271         return "";
 272 }
 273
 274 void Kill_Notification(
 275         NOTIF broadcast, entity client,
 276         MSG net_type, CPID net_name);
 277 void Send_Notification(
 278         NOTIF broadcast, entity client,
 279         MSG net_type, Notification net_name,
 280         ...count);
 281 void Send_Notification_WOVA(
 282         NOTIF broadcast, entity client,
 283         MSG net_type, Notification net_name,
 284         float stringcount, float floatcount,
 285         string s1, string s2, string s3, string s4,
 286         float f1, float f2, float f3, float f4);
 287 void Send_Notification_WOCOVA(
 288         NOTIF broadcast, entity client,
 289         MSG net_type, Notification net_name,
 290         string s1, string s2, string s3, string s4,
 291         float f1, float f2, float f3, float f4);
 292 #endif
 293
 294 // ===========================
 295 //  Special CVAR Declarations
 296 // ===========================
 297
 298 // MAKE SURE THIS IS ALWAYS SYNCHRONIZED WITH THE DUMP
 299 // NOTIFICATIONS FUNCTION IN THE .QC FILE!
 300
 301 #define NOTIF_ADD_AUTOCVAR(name,defaultvalue) float autocvar_notification_##name = defaultvalue;
 302
 303 float autocvar_notification_show_location = false;
 304 string autocvar_notification_show_location_string = ""; //_(" at the %s");
 305 float autocvar_notification_show_sprees = true;
 306 float autocvar_notification_show_sprees_info = 3; // 0 = off, 1 = target only, 2 = attacker only, 3 = target and attacker
 307 float autocvar_notification_show_sprees_info_newline = true;
 308 float autocvar_notification_show_sprees_info_specialonly = true;
 309 float autocvar_notification_errors_are_fatal = true;
 310 #ifdef SVQC
 311 float autocvar_notification_lifetime_runtime = 0.5;
 312 float autocvar_notification_lifetime_mapload = 10;
 313 #endif
 314
 315 #ifdef SVQC
 316 void Notification_GetCvars(entity this, entity store);
 317 float autocvar_notification_server_allows_location = 1; // 0 = no, 1 = yes
 318 #else
 319 float autocvar_notification_item_centerprinttime = 1.5;
 320
 321 // 0 = no, 1 = yes, 2 = forced on for all MSG_INFO notifs
 322 // DISABLED IN CODE, BUT ENABLED IN CONFIG FOR COMPATIBILITY WITH OLD CLIENTS
 323 float autocvar_notification_allow_chatboxprint = 0;
 324
 325 float autocvar_notification_show_sprees_center = true;
 326 float autocvar_notification_show_sprees_center_specialonly = true;
 327 #endif
 328
 329
 330 // ============================
 331 //  Notification Argument List
 332 // ============================
 333 /*
 334  These arguments get replaced with the Local_Notification_sprintf
 335  and other such functions found in all.qc to supply data
 336  from networked notifications to their usage in sprintf... It
 337  allows for more dynamic data to be inferred by the local
 338  notification parser, so that the server does not have to network
 339  anything too crazy on a per-client/per-situation basis.
 340
 341  Pay attention to the CSQC/SVQC relations, some of these are redefined
 342  in slightly different ways for different programs, this is because the
 343  server does a more conservative approach to the notifs than the client.
 344
 345  All arguments are swapped into strings, so be sure that your
 346  sprintf usage matches with proper %s placement.
 347
 348  Argument descriptions:
 349         s1-s4: string arguments to be literally swapped into sprintf
 350         s2loc: s2 string of locations of deaths or other events
 351         s3loc: s3 string of locations of deaths or other events
 352         f1-f4: float arguments expanded into strings to be swapped into sprintf
 353         f1p2dec: f1 float to string with 2 decimal places
 354         f2p2dec: f2 float to string with 2 decimal places
 355         f2primsec: f2 float primary or secondary selection for weapons
 356         f3primsec: f3 float primary or secondary selection for weapons
 357         f1secs: count_seconds of f1
 358         f1points: point or points depending on f1
 359         f1ord: count_ordinal of f1
 360         f1time: process_time of f1
 361         f1race_time: mmssth of f1
 362         f2race_time: mmssth of f2
 363         race_col: color of race time/position (i.e. good or bad)
 364         race_diff: show time difference between f2 and f3
 365         missing_teams: show which teams still need players
 366         pass_key: find the keybind for "passing" or "dropping" in CTF game mode
 367         nade_key: find the keybind for nade throwing
 368         frag_ping: show the ping of a player
 369         frag_stats: show health/armor/ping of a player
 370         frag_pos: show score status and position in the match of a player
 371         spree_cen: centerprint notif for kill spree/how many kills they have
 372         spree_inf: info notif for kill spree/how many kills they have
 373         spree_end: placed at the end of murder messages to show ending of sprees
 374         spree_lost: placed at the end of suicide messages to show losing of sprees
 375         item_wepname: return full name of a weapon from weaponid
 376         item_wepammo: ammo display for weapon from f1 and f2
 377         item_centime: amount of time to display weapon message in centerprint
 378         item_buffname: return full name of a buff from buffid
 379         death_team: show the full name of the team a player is switching from
 380         minigame1_name: return human readable name of a minigame from its id(s1)
 381         minigame1_d: return descriptor name of a minigame from its id(s1)
 382 */
 383
 384 const float NOTIF_MAX_ARGS = 7;
 385 const float NOTIF_MAX_HUDARGS = 2;
 386 const float NOTIF_MAX_DURCNT = 2;
 387
 388 string arg_slot[NOTIF_MAX_ARGS];
 389
 390 const float ARG_CS_SV_HA = 1; // enabled on CSQC, SVQC, and Hudargs
 391 const float ARG_CS_SV_DC = 2; // enabled on CSQC, SVQC, and durcnt centerprint
 392 const float ARG_CS_SV = 3; // enabled on CSQC and SVQC
 393 const float ARG_CS = 4; // unique result to CSQC
 394 const float ARG_SV = 5; // unique result to SVQC
 395 const float ARG_DC = 6; // unique result to durcnt/centerprint
 396
 397 // todo possible idea.... declare how many floats/strings each arg needs, and then dynamically increment the input
 398 // this way, we don't need to have duplicates like i.e. s2loc and s3loc?
 399
 400 string BUFF_NAME(int i);
 401
 402 #define NOTIF_ARGUMENT_LIST \
 403         ARG_CASE(ARG_CS_SV_HA,  "s1",            s1) \
 404         ARG_CASE(ARG_CS_SV_HA,  "s2",            s2) \
 405         ARG_CASE(ARG_CS_SV_HA,  "s3",            s3) \
 406         ARG_CASE(ARG_CS_SV_HA,  "s4",            s4) \
 407         ARG_CASE(ARG_CS_SV,     "s2loc",         ((autocvar_notification_show_location && (s2 != "")) ? sprintf(( ((tmp_s = autocvar_notification_show_location_string) != "") ? tmp_s : _(" (near %s)") ), s2) : "")) \
 408         ARG_CASE(ARG_CS_SV,     "s3loc",         ((autocvar_notification_show_location && (s3 != "")) ? sprintf(( ((tmp_s = autocvar_notification_show_location_string) != "") ? tmp_s : _(" (near %s)") ), s3) : "")) \
 409         ARG_CASE(ARG_CS_SV_DC,  "f1",            ftos(f1)) \
 410         ARG_CASE(ARG_CS_SV_DC,  "f2",            ftos(f2)) \
 411         ARG_CASE(ARG_CS_SV,     "f3",            ftos(f3)) \
 412         ARG_CASE(ARG_CS_SV,     "f4",            ftos(f4)) \
 413         ARG_CASE(ARG_CS_SV,     "f1dtime",       ftos_decimals(TIME_DECODE(f1), 2)) \
 414         ARG_CASE(ARG_CS_SV,     "f2dtime",       ftos_decimals(TIME_DECODE(f2), 2)) \
 415         ARG_CASE(ARG_CS,        "f2primsec",     (f2 ? _("secondary") : _("primary"))) \
 416         ARG_CASE(ARG_CS,        "f3primsec",     (f3 ? _("secondary") : _("primary"))) \
 417         ARG_CASE(ARG_CS,        "f1secs",        count_seconds(f1)) \
 418         ARG_CASE(ARG_CS,        "f1points",      (f1 == 1 ? _("point") : _("points"))) \
 419         ARG_CASE(ARG_CS_SV,     "f1ord",         count_ordinal(f1)) \
 420         ARG_CASE(ARG_CS_SV,     "f1time",        process_time(2, f1)) \
 421         ARG_CASE(ARG_CS_SV_HA,  "f1race_time",   mmssth(f1)) \
 422         ARG_CASE(ARG_CS_SV_HA,  "f2race_time",   mmssth(f2)) \
 423         ARG_CASE(ARG_CS_SV_HA,  "f3race_time",   mmssth(f3)) \
 424         ARG_CASE(ARG_CS_SV,     "race_col",      CCR(((f1 == 1) ? "^F1" : "^F2"))) \
 425         ARG_CASE(ARG_CS_SV,     "race_diff",     ((f2 > f3) ? sprintf(CCR("^1[+%s]"), mmssth(f2 - f3)) : sprintf(CCR("^2[-%s]"), mmssth(f3 - f2)))) \
 426         ARG_CASE(ARG_CS,        "missing_teams", notif_arg_missing_teams(f1)) \
 427         ARG_CASE(ARG_CS,        "pass_key",      getcommandkey(_("drop flag"), "+use")) \
 428         ARG_CASE(ARG_CS,        "nade_key",      getcommandkey(_("throw nade"), "dropweapon")) \
 429         ARG_CASE(ARG_CS,        "join_key",      getcommandkey(_("jump"), "+jump")) \
 430         ARG_CASE(ARG_CS,        "frag_ping",     notif_arg_frag_ping(true, f2)) \
 431         ARG_CASE(ARG_CS,        "frag_stats",    notif_arg_frag_stats(f2, f3, f4)) \
 432         /*ARG_CASE(ARG_CS,      "frag_pos",      ((Should_Print_Score_Pos(f1)) ? sprintf("\n^BG%s", Read_Score_Pos(f1)) : ""))*/ \
 433         ARG_CASE(ARG_CS,        "spree_cen",     (autocvar_notification_show_sprees ? notif_arg_spree_cen(f1) : "")) \
 434         ARG_CASE(ARG_CS_SV,     "spree_inf",     (autocvar_notification_show_sprees ? notif_arg_spree_inf(1, input, s2, f2) : "")) \
 435         ARG_CASE(ARG_CS_SV,     "spree_end",     (autocvar_notification_show_sprees ? notif_arg_spree_inf(-1, "", "", f1) : "")) \
 436         ARG_CASE(ARG_CS_SV,     "spree_lost",    (autocvar_notification_show_sprees ? notif_arg_spree_inf(-2, "", "", f1) : "")) \
 437         ARG_CASE(ARG_CS_SV,     "item_wepname",  REGISTRY_GET(Weapons, f1).m_name) \
 438         ARG_CASE(ARG_CS_SV,     "item_buffname", BUFF_NAME(f1)) \
 439         ARG_CASE(ARG_CS_SV,     "f3buffname",    BUFF_NAME(f3)) \
 440         ARG_CASE(ARG_CS_SV,     "item_wepammo",  (f2 > 0 ? notif_arg_item_wepammo(f1, f2) : "")) \
 441         ARG_CASE(ARG_DC,        "item_centime",  ftos(autocvar_notification_item_centerprinttime)) \
 442         ARG_CASE(ARG_SV,        "death_team",    Team_ColoredFullName(f1)) \
 443         ARG_CASE(ARG_CS,        "death_team",    Team_ColoredFullName(f1 - 1)) \
 444         ARG_CASE(ARG_CS_SV_HA,  "minigame1_name",find(NULL,netname,s1).descriptor.message) \
 445         ARG_CASE(ARG_CS_SV_HA,  "minigame1_d",   find(NULL,netname,s1).descriptor.netname)
 446
 447 #define NOTIF_HIT_MAX(count,funcname) MACRO_BEGIN \
 448         if(sel_num == count) { backtrace(sprintf("%s: Hit maximum arguments!\n", funcname)); break; } \
 449 MACRO_END
 450
 451 #define NOTIF_HIT_UNKNOWN(token,funcname) { backtrace(sprintf("%s: Hit unknown token in selected string! '%s'\n", funcname, selected)); break; }
 452
 453 #define KILL_SPREE_LIST \
 454         SPREE_ITEM(3, 03, _("TRIPLE FRAG! "), _("%s^K1 made a TRIPLE FRAG! %s^BG"), _("%s^K1 made a TRIPLE SCORE! %s^BG")) \
 455         SPREE_ITEM(5, 05, _("RAGE! "), _("%s^K1 unlocked RAGE! %s^BG"), _("%s^K1 made FIVE SCORES IN A ROW! %s^BG")) \
 456         SPREE_ITEM(10, 10, _("MASSACRE! "), _("%s^K1 started a MASSACRE! %s^BG"), _("%s^K1 made TEN SCORES IN A ROW! %s^BG")) \
 457         SPREE_ITEM(15, 15, _("MAYHEM! "), _("%s^K1 executed MAYHEM! %s^BG"), _("%s^K1 made FIFTEEN SCORES IN A ROW! %s^BG")) \
 458         SPREE_ITEM(20, 20, _("BERSERKER! "), _("%s^K1 is a BERSERKER! %s^BG"), _("%s^K1 made TWENTY SCORES IN A ROW! %s^BG")) \
 459         SPREE_ITEM(25, 25, _("CARNAGE! "), _("%s^K1 inflicts CARNAGE! %s^BG"), _("%s^K1 made TWENTY FIVE SCORES IN A ROW! %s^BG")) \
 460         SPREE_ITEM(30, 30, _("ARMAGEDDON! "), _("%s^K1 unleashes ARMAGEDDON! %s^BG"), _("%s^K1 made THIRTY SCORES IN A ROW! %s^BG"))
 461
 462 #ifdef CSQC
 463 string notif_arg_frag_ping(bool newline, float fping)
 464 {
 465         string s = newline ? "\n" : " ";
 466         if (fping < 0)
 467                 return sprintf(CCR(_("%s(^F1Bot^BG)")), s);
 468         else
 469                 return sprintf(CCR(_("%s(Ping ^F1%d^BG)")), s, fping);
 470 }
 471
 472 string notif_arg_frag_stats(float fhealth, float farmor, float fping)
 473 {
 474         string s = notif_arg_frag_ping(false, fping);
 475         if (fhealth > 1)
 476                 return sprintf(CCR(_("\n(Health ^1%d^BG / Armor ^2%d^BG)%s")), fhealth, farmor, s);
 477         else
 478                 return sprintf(CCR(_("\n(^F4Dead^BG)%s")), s);
 479 }
 480
 481 string notif_arg_missing_teams(float f1)
 482 {
 483         return strcat(
 484                 ((f1 & BIT(0)) ? strcat(Team_ColoredFullName(NUM_TEAM_1), (f1 >> 1) ? ", " : "") : ""),
 485                 ((f1 & BIT(1)) ? strcat(Team_ColoredFullName(NUM_TEAM_2), (f1 >> 2) ? ", " : "") : ""),
 486                 ((f1 & BIT(2)) ? strcat(Team_ColoredFullName(NUM_TEAM_3), (f1 >> 3) ? ", " : "") : ""),
 487                 ((f1 & BIT(3)) ?        Team_ColoredFullName(NUM_TEAM_4)                         : "")
 488         );
 489 }
 490
 491 string notif_arg_spree_cen(float spree)
 492 {
 493         // 0 = off, 1 = target (but only for first victim) and attacker
 494         if(autocvar_notification_show_sprees_center)
 495         {
 496                 if(spree > 1)
 497                 {
 498                         #define SPREE_ITEM(counta,countb,center,normal,gentle) \
 499                                 case counta: { return normal_or_gentle(center, sprintf(_("%d score spree! "), spree)); }
 500
 501                         switch(spree)
 502                         {
 503                                 KILL_SPREE_LIST
 504                                 default:
 505                                 {
 506                                         if (!autocvar_notification_show_sprees_center_specialonly)
 507                                         {
 508                                                 return
 509                                                         sprintf(
 510                                                                 normal_or_gentle(
 511                                                                         _("%d frag spree! "),
 512                                                                         _("%d score spree! ")
 513                                                                 ),
 514                                                                 spree);
 515                                         }
 516                                         else { return ""; } // don't show spree information if it isn't an achievement
 517                                 }
 518                         }
 519
 520                         #undef SPREE_ITEM
 521                 }
 522                 else if(spree == -1) // first blood
 523                 {
 524                         return normal_or_gentle(_("First blood! "), _("First score! "));
 525                 }
 526                 else if(spree == -2) // first victim
 527                 {
 528                         return normal_or_gentle(_("First victim! "), _("First casualty! "));
 529                 }
 530         }
 531         return "";
 532 }
 533 #endif
 534
 535 string notif_arg_spree_inf(float type, string input, string player, float spree)
 536 {
 537         switch(type)
 538         {
 539                 case 1: // attacker kill spree
 540                 {
 541                         // 0 = off, 1 = target only, 2 = attacker only, 3 = target and attacker
 542                         // this conditional (& 2) is true for 2 and 3
 543                         if(autocvar_notification_show_sprees_info & 2)
 544                         {
 545                                 #ifdef CSQC
 546                                 string spree_newline =
 547                                         ( autocvar_notification_show_sprees_info_newline ?
 548                                                 ((substring(input, 0, 1) == "\{3}") ? "\n\{3}" : "\n") : "" );
 549                                 #else
 550                                 string spree_newline =
 551                                         (autocvar_notification_show_sprees_info_newline ? "\n" : "");
 552                                 #endif
 553
 554                                 if(spree > 1)
 555                                 {
 556                                         #define SPREE_ITEM(counta,countb,center,normal,gentle) \
 557                                                 case counta: { return sprintf(CCR(normal_or_gentle(normal, gentle)), player, spree_newline); }
 558
 559                                         switch(spree)
 560                                         {
 561                                                 KILL_SPREE_LIST
 562                                                 default:
 563                                                 {
 564                                                         if (!autocvar_notification_show_sprees_info_specialonly)
 565                                                         {
 566                                                                 return
 567                                                                         sprintf(
 568                                                                                 CCR(normal_or_gentle(
 569                                                                                         _("%s^K1 has %d frags in a row! %s^BG"),
 570                                                                                         _("%s^K1 made %d scores in a row! %s^BG")
 571                                                                                 )),
 572                                                                                 player,
 573                                                                                 spree,
 574                                                                                 spree_newline
 575                                                                         );
 576                                                         }
 577                                                         else { return ""; } // don't show spree information if it isn't an achievement
 578                                                 }
 579                                         }
 580
 581                                         #undef SPREE_ITEM
 582                                 }
 583                                 else if(spree == -1) // firstblood
 584                                 {
 585                                         return
 586                                                 sprintf(
 587                                                         CCR(normal_or_gentle(
 588                                                                 _("%s^K1 drew first blood! %s^BG"),
 589                                                                 _("%s^K1 got the first score! %s^BG")
 590                                                         )),
 591                                                         player,
 592                                                         spree_newline
 593                                                 );
 594                                 }
 595                         }
 596                         break;
 597                 }
 598
 599                 case -1: // kill spree ended
 600                 {
 601                         if((spree > 1) && (autocvar_notification_show_sprees_info & 1))
 602                         {
 603                                 return
 604                                         sprintf(normal_or_gentle(
 605                                                 _(", ending their %d frag spree"),
 606                                                 _(", ending their %d score spree")
 607                                                 ),
 608                                                 spree
 609                                         );
 610                         }
 611                         break;
 612                 }
 613
 614                 case -2: // kill spree lost
 615                 {
 616                         if((spree > 1) && (autocvar_notification_show_sprees_info & 1))
 617                         {
 618                                 return
 619                                         sprintf(normal_or_gentle(
 620                                                 _(", losing their %d frag spree"),
 621                                                 _(", losing their %d score spree")
 622                                                 ),
 623                                                 spree
 624                                         );
 625                         }
 626                         break;
 627                 }
 628         }
 629         return "";
 630 }
 631
 632 string notif_arg_item_wepammo(float f1, float f2)
 633 {
 634         string ammoitems = "";
 635         Weapon wep = REGISTRY_GET(Weapons, f1);
 636         // TODO: registry handles
 637         switch (wep.ammo_type)
 638         {
 639                 case RES_SHELLS:  ammoitems = ITEM_Shells.m_name;      break;
 640                 case RES_BULLETS: ammoitems = ITEM_Bullets.m_name;     break;
 641                 case RES_ROCKETS: ammoitems = ITEM_Rockets.m_name;     break;
 642                 case RES_CELLS:   ammoitems = ITEM_Cells.m_name;       break;
 643                 case RES_PLASMA:  ammoitems = ITEM_Plasma.m_name;      break;
 644                 case RES_FUEL:    ammoitems = ITEM_JetpackFuel.m_name; break;
 645                 default: return ""; // doesn't use ammo
 646         }
 647         return sprintf(_(" with %d %s"), f2, ammoitems);
 648 }
 649
 650
 651 // ====================================
 652 //  Initialization/Create Declarations
 653 // ====================================
 654
 655 // common notification entity values
 656 .int nent_default;
 657 .bool nent_enabled;
 658 .MSG nent_type;
 659 .string nent_name;
 660 .int nent_stringcount;
 661 .int nent_floatcount;
 662 .int nent_teamnum;
 663
 664 // MSG_ANNCE entity values
 665 .int nent_channel;
 666 .string nent_snd;
 667 .float nent_vol;
 668 .float nent_position;
 669
 670 // MSG_INFO and MSG_CENTER entity values
 671 .string nent_args; // used by both
 672 .string nent_hudargs; // used by info
 673 .string nent_icon; // used by info
 674 .CPID nent_cpid; // used by center
 675 .string nent_durcnt; // used by center
 676 .string nent_string; // used by both
 677
 678 // MSG_MULTI entity values
 679 .entity nent_msgannce;
 680 .entity nent_msginfo;
 681 .entity nent_msgcenter;
 682
 683 // MSG_CHOICE entity values
 684 .float nent_challow_def;
 685 .float nent_challow_var;
 686 .entity nent_optiona;
 687 .entity nent_optionb;
 688
 689 // networked notification entity values
 690 #ifdef SVQC
 691 .NOTIF nent_broadcast;
 692 #endif
 693 .entity nent_client;
 694 .MSG nent_net_type;
 695 .float nent_net_name;
 696 .string nent_strings[4];
 697 .float nent_floats[4];
 698
 699 #define ACVNN(name) autocvar_notification_##name
 700
 701 REGISTRY(Notifications, BITS(11))
 702 REGISTER_REGISTRY(Notifications)
 703 REGISTRY_SORT(Notifications);
 704
 705 REGISTRY_DEFINE_GET(Notifications, NULL)
 706 STATIC_INIT(Notifications) { FOREACH(Notifications, true, it.m_id = i); }
 707 REGISTRY_CHECK(Notifications)
 708
 709 const int NOTIF_CHOICE_MAX = 20;
 710 // NOTE: a team choice is actually made of 4 choices (one per team) with the same nent_choice_idx
 711 // thus they are counted as 1 in nent_choice_count
 712 int nent_choice_count = 0;
 713 .int nent_choice_idx;
 714 .int msg_choice_choices[NOTIF_CHOICE_MAX]; // set on each player containing MSG_CHOICE choices
 715 // initialization error detection
 716 bool notif_error;
 717 bool notif_global_error;
 718
 719 STATIC_INIT_LATE(Notif_Choices)
 720 {
 721         if (nent_choice_count > NOTIF_CHOICE_MAX)
 722                 LOG_FATALF("Too many MSG_CHOICE notifications (%d), hit NOTIF_CHOICE_MAX (%d) limit",
 723                         nent_choice_count, NOTIF_CHOICE_MAX);
 724 }
 725
 726 string Get_Notif_CvarName(Notification notif)
 727 {
 728         if(!notif.nent_teamnum)
 729                 return notif.nent_name;
 730         return substring(notif.nent_name, 0, -strlen(Static_Team_ColorName(notif.nent_teamnum)) - 2);
 731 }
 732
 733 Notification Get_Notif_Ent(MSG net_type, int net_name)
 734 {
 735         Notification it = REGISTRY_GET(Notifications, net_name);
 736         if (it.nent_type != net_type) {
 737                 LOG_WARNF("Get_Notif_Ent(%s (%d), %s (%d)): Improper net type '%s'!",
 738                         Get_Notif_TypeName(net_type), net_type,
 739                         it.registered_id, net_name,
 740                         Get_Notif_TypeName(it.nent_type)
 741                 );
 742                 return NULL;
 743         }
 744         return it;
 745 }
 746
 747 #define MSG_ANNCE_NOTIF_TEAM(teamnum, name, cvarname, defaultvalue, sound, channel, volume, position) \
 748         MSG_ANNCE_NOTIF_(teamnum, ANNCE_##name, ANNCE_##cvarname, defaultvalue, sound, channel, volume, position)
 749
 750 #define MSG_ANNCE_NOTIF(name, defaultvalue, sound, channel, volume, position) \
 751         NOTIF_ADD_AUTOCVAR(ANNCE_##name, defaultvalue) \
 752         MSG_ANNCE_NOTIF_(0, ANNCE_##name, ANNCE_##name, defaultvalue, sound, channel, volume, position)
 753
 754 #define MSG_ANNCE_NOTIF_(teamnum, name, cvarname, defaultvalue, sound, channel, volume, position) \
 755         REGISTER(Notifications, name, m_id, new_pure(msg_annce_notification)) { \
 756                 Create_Notification_Entity      (this, defaultvalue, ACVNN(cvarname), MSG_ANNCE, strtoupper(#name), teamnum); \
 757                 Create_Notification_Entity_Annce(this, ACVNN(cvarname), strtoupper(#name), \
 758                         channel,   /* channel  */ \
 759                         sound,     /* snd      */ \
 760                         volume,    /* vol      */ \
 761                         position); /* position */ \
 762         }
 763
 764 #define MSG_INFO_NOTIF_TEAM(teamnum, name, cvarname, defaultvalue, strnum, flnum, args, hudargs, icon, normal, gentle) \
 765         MSG_INFO_NOTIF_(teamnum, INFO_##name, INFO_##cvarname, defaultvalue, strnum, flnum, args, hudargs, icon, normal, gentle)
 766
 767 #define MSG_INFO_NOTIF(name, defaultvalue, strnum, flnum, args, hudargs, icon, normal, gentle) \
 768         NOTIF_ADD_AUTOCVAR(INFO_##name, defaultvalue) \
 769         MSG_INFO_NOTIF_(0, INFO_##name, INFO_##name, defaultvalue, strnum, flnum, args, hudargs, icon, normal, gentle)
 770
 771 #define MSG_INFO_NOTIF_(teamnum, name, cvarname, defaultvalue, strnum, flnum, args, hudargs, icon, normal, gentle) \
 772         REGISTER(Notifications, name, m_id, new_pure(msg_info_notification)) { \
 773                 Create_Notification_Entity           (this, defaultvalue, ACVNN(cvarname), MSG_INFO, strtoupper(#name), teamnum); \
 774                 Create_Notification_Entity_InfoCenter(this, ACVNN(cvarname), strtoupper(#name), strnum, flnum, \
 775                         args,     /* args    */ \
 776                         hudargs,  /* hudargs */ \
 777                         icon,     /* icon    */ \
 778                         CPID_Null,/* cpid    */ \
 779                         "",       /* durcnt  */ \
 780                         normal,   /* normal  */ \
 781                         gentle);  /* gentle  */ \
 782         }
 783
 784 .string nent_iconargs;
 785 #define MULTIICON_INFO(name, defaultvalue, strnum, flnum, args, hudargs, iconargs, icon, normal, gentle) \
 786         MULTIICON_INFO_(INFO_##name, defaultvalue, strnum, flnum, args, hudargs, iconargs, icon, normal, gentle)
 787 #define MULTIICON_INFO_(name, defaultvalue, strnum, flnum, args, hudargs, iconargs, icon, normal, gentle) \
 788         NOTIF_ADD_AUTOCVAR(name, defaultvalue) \
 789         REGISTER(Notifications, name, m_id, new_pure(msg_info_notification)) { \
 790                 Create_Notification_Entity           (this, defaultvalue, ACVNN(name), MSG_INFO, strtoupper(#name), 0); \
 791                 Create_Notification_Entity_InfoCenter(this, ACVNN(name), strtoupper(#name), strnum, flnum, \
 792                         args,     /* args    */ \
 793                         hudargs,  /* hudargs */ \
 794                         icon,     /* icon    */ \
 795                         CPID_Null,/* cpid    */ \
 796                         "",       /* durcnt  */ \
 797                         normal,   /* normal  */ \
 798                         gentle);  /* gentle  */ \
 799                 this.nent_iconargs = iconargs; \
 800         }
 801
 802 #define MSG_CENTER_NOTIF_TEAM(teamnum, name, cvarname, defaultvalue, strnum, flnum, args, cpid, durcnt, normal, gentle) \
 803         MSG_CENTER_NOTIF_(teamnum, CENTER_##name, CENTER_##cvarname, defaultvalue, strnum, flnum, args, cpid, durcnt, normal, gentle)
 804
 805 #define MSG_CENTER_NOTIF(name, defaultvalue, strnum, flnum, args, cpid, durcnt, normal, gentle) \
 806         NOTIF_ADD_AUTOCVAR(CENTER_##name, defaultvalue) \
 807         MSG_CENTER_NOTIF_(0, CENTER_##name, CENTER_##name, defaultvalue, strnum, flnum, args, cpid, durcnt, normal, gentle)
 808
 809 #define MSG_CENTER_NOTIF_(teamnum, name, cvarname, defaultvalue, strnum, flnum, args, cpid, durcnt, normal, gentle) \
 810         REGISTER(Notifications, name, m_id, new_pure(msg_center_notification)) { \
 811                 Create_Notification_Entity           (this, defaultvalue, ACVNN(cvarname), MSG_CENTER, strtoupper(#name), teamnum); \
 812                 Create_Notification_Entity_InfoCenter(this, ACVNN(cvarname), strtoupper(#name), strnum, flnum, \
 813                         args,    /* args    */ \
 814                         "",      /* hudargs */ \
 815                         "",      /* icon    */ \
 816                         cpid,    /* cpid    */ \
 817                         durcnt,  /* durcnt  */ \
 818                         normal,  /* normal  */ \
 819                         gentle); /* gentle  */ \
 820         }
 821
 822 #define MSG_MULTI_NOTIF(name, defaultvalue, anncename, infoname, centername) \
 823         NOTIF_ADD_AUTOCVAR(name, defaultvalue) \
 824         REGISTER(Notifications, name, m_id, new_pure(msg_multi_notification)) { \
 825                 Create_Notification_Entity      (this, defaultvalue, ACVNN(name), MSG_MULTI, strtoupper(#name), 0); \
 826                 Create_Notification_Entity_Multi(this, ACVNN(name), strtoupper(#name), \
 827                         anncename,   /* anncename  */ \
 828                         infoname,    /* infoname   */ \
 829                         centername); /* centername */ \
 830         }
 831
 832 #define MSG_CHOICE_NOTIF_TEAM(teamnum, name, cvarname, defaultvalue, challow, chtype, optiona, optionb) \
 833         MSG_CHOICE_NOTIF_(teamnum, CHOICE_##name, CHOICE_##cvarname, defaultvalue, challow, chtype, optiona, optionb)
 834
 835 #define MSG_CHOICE_NOTIF(name, defaultvalue, challow, chtype, optiona, optionb) \
 836         NOTIF_ADD_AUTOCVAR(CHOICE_##name, defaultvalue) \
 837         NOTIF_ADD_AUTOCVAR(CHOICE_##name##_ALLOWED, challow) \
 838         MSG_CHOICE_NOTIF_(0, CHOICE_##name, CHOICE_##name, defaultvalue, challow, chtype, optiona, optionb)
 839
 840 #define MSG_CHOICE_NOTIF_(teamnum, name, cvarname, defaultvalue, challow, chtype, optiona, optionb) \
 841         REGISTER(Notifications, name, m_id, new_pure(msg_choice_notification)) { \
 842                 this.nent_choice_idx = nent_choice_count; \
 843                 if (!teamnum || teamnum == NUM_TEAM_4) \
 844                         nent_choice_count++; \
 845                 Create_Notification_Entity       (this, defaultvalue, ACVNN(cvarname), MSG_CHOICE, strtoupper(#name), teamnum); \
 846                 Create_Notification_Entity_Choice(this, ACVNN(cvarname), strtoupper(#name), \
 847                         challow,                                 /* challow_def */ \
 848                         autocvar_notification_##cvarname##_ALLOWED,  /* challow_var */ \
 849                         chtype,                                  /* chtype      */ \
 850                         optiona,                                 /* optiona     */ \
 851                         optionb);                                /* optionb     */ \
 852         }
 853
 854 REGISTRY_BEGIN(Notifications)
 855 {
 856         notif_global_error = false;
 857 }
 858
 859 REGISTRY_END(Notifications)
 860 {
 861         if (!notif_global_error) return;
 862         // shit happened... stop the loading of the program now if this is unacceptable
 863         if (autocvar_notification_errors_are_fatal)
 864                 LOG_FATAL("Notification initialization failed! Read above and fix the errors!");
 865         else
 866                 LOG_SEVERE("Notification initialization failed! Read above and fix the errors!");
 867 }
 868
 869 #ifdef CSQC
 870 .int cvar_value;
 871 void ReplicateVars(bool would_destroy)
 872 {
 873         if (!would_destroy)
 874                 FOREACH(Notifications, it.nent_type == MSG_CHOICE && (!it.nent_teamnum || it.nent_teamnum == NUM_TEAM_1), {
 875                         string cvarname = strcat("notification_", Get_Notif_CvarName(it));
 876                         // NOTE: REPLICATE_SIMPLE can return;
 877                         REPLICATE_SIMPLE(it.cvar_value, cvarname);
 878                 });
 879 }
 880 #endif
 881
 882 #include "all.inc"