qcsrc/server/bot/default/bot.qc

   1 #include "bot.qh"
   2
   3 #include <common/constants.qh>
   4 #include <common/mapinfo.qh>
   5 #include <common/net_linked.qh>
   6 #include <common/physics/player.qh>
   7 #include <common/stats.qh>
   8 #include <common/teams.qh>
   9 #include <common/util.qh>
  10 #include <common/weapons/_all.qh>
  11 #include <lib/csqcmodel/sv_model.qh>
  12 #include <lib/warpzone/common.qh>
  13 #include <lib/warpzone/util_server.qh>
  14 #include <server/antilag.qh>
  15 #include <server/bot/default/aim.qh>
  16 #include <server/bot/default/cvars.qh>
  17 #include <server/bot/default/havocbot/havocbot.qh>
  18 #include <server/bot/default/havocbot/scripting.qh>
  19 #include <server/bot/default/navigation.qh>
  20 #include <server/bot/default/scripting.qh>
  21 #include <server/bot/default/waypoints.qh>
  22 #include <server/campaign.qh>
  23 #include <server/client.qh>
  24 #include <server/damage.qh>
  25 #include <server/items/items.qh>
  26 #include <server/mutators/_mod.qh>
  27 #include <server/race.qh>
  28 #include <server/scores_rules.qh>
  29 #include <server/teamplay.qh>
  30 #include <server/weapons/accuracy.qh>
  31 #include <server/weapons/selection.qh>
  32 #include <server/world.qh>
  33
  34 STATIC_INIT(bot) { bot_calculate_stepheightvec(); }
  35
  36 // TODO: remove this function! its only purpose is to update these fields since bot_setnameandstuff is called before ClientState
  37 void bot_setclientfields(entity this)
  38 {
  39         CS_CVAR(this).cvar_cl_accuracy_data_share = 1;  // share the bots weapon accuracy data with the world
  40         CS_CVAR(this).cvar_cl_accuracy_data_receive = 0;  // don't receive any weapon accuracy data
  41 }
  42
  43 entity bot_spawn()
  44 {
  45         entity bot = spawnclient();
  46         if (bot)
  47         {
  48                 setItemGroupCount();
  49                 currentbots = currentbots + 1;
  50                 bot_setnameandstuff(bot);
  51                 ClientConnect(bot);
  52                 bot_setclientfields(bot);
  53                 PutClientInServer(bot);
  54         }
  55         return bot;
  56 }
  57
  58 void bot_think(entity this)
  59 {
  60         if (this.bot_nextthink > time)
  61                 return;
  62
  63         this.flags &= ~FL_GODMODE;
  64         if(autocvar_bot_god)
  65                 this.flags |= FL_GODMODE;
  66
  67         this.bot_nextthink = max(time, this.bot_nextthink) + max(0.01, autocvar_bot_ai_thinkinterval * (0.5 ** this.bot_aiskill) * min(14 / (skill + 14), 1));
  68
  69         if (!IS_PLAYER(this) || (autocvar_g_campaign && !campaign_bots_may_start))
  70         {
  71                 if (IS_PLAYER(this))
  72                 {
  73                         .entity weaponentity = weaponentities[0];
  74                         if(this.(weaponentity).m_weapon == WEP_Null)
  75                                 W_NextWeapon(this, 0, weaponentity);
  76                 }
  77                 CS(this).movement = '0 0 0';
  78                 this.bot_nextthink = time + 0.5;
  79                 return;
  80         }
  81
  82         if (this.fixangle)
  83         {
  84                 this.v_angle = this.angles;
  85                 this.v_angle_z = 0;
  86                 this.fixangle = false;
  87         }
  88
  89         this.dmg_take = 0;
  90         this.dmg_save = 0;
  91         this.dmg_inflictor = NULL;
  92
  93         // calculate an aiming latency based on the skill setting
  94         // (simulated network latency + naturally delayed reflexes)
  95         //this.ping = 0.7 - bound(0, 0.05 * skill, 0.5); // moved the reflexes to bot_aimdir (under the name 'think')
  96         // minimum ping 20+10 random
  97         CS(this).ping = bound(0,0.07 - bound(0, (skill + this.bot_pingskill) * 0.005,0.05)+random()*0.01,0.65); // Now holds real lag to server, and higer skill players take a less laggy server
  98         // skill 10 = ping 0.2 (adrenaline)
  99         // skill 0 = ping 0.7 (slightly drunk)
 100
 101         // clear buttons
 102         PHYS_INPUT_BUTTON_ATCK(this) = false;
 103         // keep jump button pressed for a short while, useful with ramp jumps
 104         PHYS_INPUT_BUTTON_JUMP(this) = (!IS_DEAD(this) && time < this.bot_jump_time + 0.2);
 105         PHYS_INPUT_BUTTON_ATCK2(this) = false;
 106         PHYS_INPUT_BUTTON_ZOOM(this) = false;
 107         PHYS_INPUT_BUTTON_CROUCH(this) = false;
 108         PHYS_INPUT_BUTTON_HOOK(this) = false;
 109         PHYS_INPUT_BUTTON_INFO(this) = false;
 110         PHYS_INPUT_BUTTON_DRAG(this) = false;
 111         PHYS_INPUT_BUTTON_CHAT(this) = false;
 112         PHYS_INPUT_BUTTON_USE(this) = false;
 113
 114         if (time < game_starttime)
 115         {
 116                 .entity weaponentity = weaponentities[0];
 117                 if(this.(weaponentity).m_weapon == WEP_Null)
 118                         W_NextWeapon(this, 0, weaponentity);
 119                 // block the bot during the countdown to game start
 120                 CS(this).movement = '0 0 0';
 121                 this.bot_nextthink = game_starttime;
 122                 return;
 123         }
 124
 125         // if dead, just wait until we can respawn
 126         if (IS_DEAD(this) || IS_OBSERVER(this))
 127         {
 128                 if (bot_waypoint_queue_owner == this)
 129                         bot_waypoint_queue_owner = NULL;
 130                 this.aistatus = 0;
 131                 CS(this).movement = '0 0 0';
 132                 if (IS_OBSERVER(this))
 133                         return;
 134                 if (IS_DEAD(this))
 135                 {
 136                         if (!navigation_goalrating_timeout(this))
 137                                 navigation_goalrating_timeout_force(this);
 138                         // jump must not be pressed for at least one frame in order for
 139                         // PlayerThink to detect the key down event
 140                         if (this.deadflag == DEAD_DYING)
 141                                 PHYS_INPUT_BUTTON_JUMP(this) = false;
 142                         else if (this.deadflag == DEAD_DEAD)
 143                                 PHYS_INPUT_BUTTON_JUMP(this) = true; // press jump to respawn
 144                 }
 145         }
 146         else if(this.aistatus & AI_STATUS_STUCK)
 147                 navigation_unstuck(this);
 148
 149         // now call the current bot AI (havocbot for example)
 150         this.bot_ai(this);
 151 }
 152
 153 void bot_setnameandstuff(entity this)
 154 {
 155         string readfile, s;
 156         int file, tokens, prio;
 157
 158         file = fopen(autocvar_bot_config_file, FILE_READ);
 159
 160         if(file < 0)
 161         {
 162                 LOG_INFOF("Error: Can not open the bot configuration file '%s'", autocvar_bot_config_file);
 163                 readfile = "";
 164         }
 165         else
 166         {
 167                 entity balance = TeamBalance_CheckAllowedTeams(NULL);
 168                 TeamBalance_GetTeamCounts(balance, NULL);
 169                 int smallest_team = -1;
 170                 int smallest_count = -1;
 171                 if (teamplay)
 172                 {
 173                         for (int i = 1; i <= AvailableTeams(); ++i)
 174                         {
 175                                 // NOTE if (autocvar_g_campaign && autocvar_g_campaign_forceteam == i)
 176                                 // TeamBalance_GetNumberOfPlayers(balance, i); returns the number of players + 1
 177                                 // since it keeps a spot for the real player in the desired team
 178                                 int count = TeamBalance_GetNumberOfPlayers(balance, i);
 179                                 if (smallest_count < 0 || count < smallest_count)
 180                                 {
 181                                         smallest_team = i;
 182                                         smallest_count = count;
 183                                 }
 184                         }
 185                 }
 186                 TeamBalance_Destroy(balance);
 187                 RandomSelection_Init();
 188                 while((readfile = fgets(file)))
 189                 {
 190                         if(substring(readfile, 0, 2) == "//")
 191                                 continue;
 192                         if(substring(readfile, 0, 1) == "#")
 193                                 continue;
 194                         // NOTE if the line is empty tokenizebyseparator(readfile, "\t")
 195                         // will create 1 empty token because there's no separator (bug?)
 196                         if (readfile == "")
 197                                 continue;
 198                         tokens = tokenizebyseparator(readfile, "\t");
 199                         if(tokens == 0)
 200                                 continue;
 201                         s = argv(0);
 202                         prio = 0;
 203                         bool conflict = false;
 204                         FOREACH_CLIENT(IS_BOT_CLIENT(it), {
 205                                 if (s == it.cleanname)
 206                                 {
 207                                         conflict = true;
 208                                         break;
 209                                 }
 210                         });
 211                         if (!conflict)
 212                                 prio += 1;
 213                         if (teamplay && !(autocvar_bot_vs_human && AvailableTeams() == 2))
 214                         {
 215                                 int forced_team = stof(argv(5));
 216                                 if (!Team_IsValidIndex(forced_team))
 217                                         forced_team = 0;
 218                                 if (!forced_team || forced_team == smallest_team)
 219                                         prio += 2;
 220                         }
 221                         RandomSelection_AddString(readfile, 1, prio);
 222                 }
 223                 readfile = RandomSelection_chosen_string;
 224                 fclose(file);
 225         }
 226
 227         string bot_name, bot_model, bot_skin, bot_shirt, bot_pants;
 228
 229         tokens = tokenizebyseparator(readfile, "\t");
 230         if(argv(0) != "") bot_name = argv(0);
 231         else bot_name = "Bot";
 232
 233         if(argv(1) != "") bot_model = argv(1);
 234         else bot_model = "";
 235
 236         if(argv(2) != "") bot_skin = argv(2);
 237         else bot_skin = "0";
 238
 239         if(argv(3) != "" && stof(argv(3)) >= 0) bot_shirt = argv(3);
 240         else bot_shirt = ftos(floor(random() * 15));
 241
 242         if(argv(4) != "" && stof(argv(4)) >= 0) bot_pants = argv(4);
 243         else bot_pants = ftos(floor(random() * 15));
 244
 245         if (teamplay && !(autocvar_bot_vs_human && AvailableTeams() == 2))
 246         {
 247                 this.bot_forced_team = stof(argv(5));
 248                 if (!Team_IsValidIndex(this.bot_forced_team))
 249                         this.bot_forced_team = 0;
 250         }
 251         else
 252                 this.bot_forced_team = 0;
 253
 254         prio = 6;
 255
 256         #define READSKILL(f, w, r) MACRO_BEGIN \
 257                 if(argv(prio) != "") \
 258                         this.f = stof(argv(prio)) * w; \
 259                 else \
 260                         this.f = (!autocvar_g_campaign) * (2 * random() - 1) * r * w; \
 261                 prio++; \
 262         MACRO_END
 263         //print(bot_name, ": ping=", argv(9), "\n");
 264
 265         READSKILL(havocbot_keyboardskill, 0.5, 0.5); // keyboard skill
 266         READSKILL(bot_moveskill, 2, 0); // move skill
 267         READSKILL(bot_dodgeskill, 2, 0); // dodge skill
 268
 269         READSKILL(bot_pingskill, 0.5, 0); // ping skill
 270
 271         READSKILL(bot_weaponskill, 2, 0); // weapon skill
 272         READSKILL(bot_aggresskill, 1, 0); // aggre skill
 273         READSKILL(bot_rangepreference, 1, 0); // read skill
 274
 275         READSKILL(bot_aimskill, 2, 0); // aim skill
 276         READSKILL(bot_offsetskill, 2, 0.5); // offset skill
 277         READSKILL(bot_mouseskill, 1, 0.5); // mouse skill
 278
 279         READSKILL(bot_thinkskill, 1, 0.5); // think skill
 280         READSKILL(bot_aiskill, 2, 0); // "ai" skill
 281
 282         if (file >= 0 && argv(prio) != "")
 283                 LOG_INFOF("^1Warning^7: too many parameters for bot %s, please check format of %s", bot_name, autocvar_bot_config_file);
 284
 285         this.bot_config_loaded = true;
 286
 287         // this is really only a default, TeamBalance_JoinBestTeam is called later
 288         setcolor(this, stof(bot_shirt) * 16 + stof(bot_pants));
 289         this.bot_preferredcolors = this.clientcolors;
 290
 291         string prefix = (autocvar_g_campaign ? "" : autocvar_bot_prefix);
 292         string suffix = (autocvar_g_campaign ? "" : autocvar_bot_suffix);
 293         string name = (autocvar_bot_usemodelnames ? bot_model : bot_name);
 294
 295         if (name == "")
 296         {
 297                 name = ftos(etof(this));
 298                 this.netname = this.netname_freeme = strzone(strcat(prefix, name, suffix));
 299         }
 300         else
 301         {
 302                 // number bots with identical names
 303                 int j = 0;
 304                 FOREACH_CLIENT(IS_BOT_CLIENT(it), {
 305                         if(it.cleanname == name)
 306                                 ++j;
 307                 });
 308                 if (j)
 309                         this.netname = this.netname_freeme = strzone(strcat(prefix, name, "(", ftos(j), ")", suffix));
 310                 else
 311                         this.netname = this.netname_freeme = strzone(strcat(prefix, name, suffix));
 312         }
 313         this.cleanname = strzone(name);
 314
 315         // pick the model and skin
 316         if(substring(bot_model, -4, 1) != ".")
 317                 bot_model = strcat(bot_model, ".iqm");
 318         this.playermodel = this.playermodel_freeme = strzone(strcat("models/player/", bot_model));
 319         this.playerskin = this.playerskin_freeme = strzone(bot_skin);
 320 }
 321
 322 void bot_custom_weapon_priority_setup()
 323 {
 324         static string bot_priority_far_prev;
 325         static string bot_priority_mid_prev;
 326         static string bot_priority_close_prev;
 327         static string bot_priority_distances_prev;
 328         float tokens, i, w;
 329
 330         bot_custom_weapon = false;
 331
 332         if(     autocvar_bot_ai_custom_weapon_priority_far == "" ||
 333                 autocvar_bot_ai_custom_weapon_priority_mid == "" ||
 334                 autocvar_bot_ai_custom_weapon_priority_close == "" ||
 335                 autocvar_bot_ai_custom_weapon_priority_distances == ""
 336         )
 337                 return;
 338
 339         if (bot_priority_distances_prev != autocvar_bot_ai_custom_weapon_priority_distances)
 340         {
 341                 strcpy(bot_priority_distances_prev, autocvar_bot_ai_custom_weapon_priority_distances);
 342                 tokens = tokenizebyseparator(autocvar_bot_ai_custom_weapon_priority_distances," ");
 343
 344                 if (tokens!=2)
 345                         return;
 346
 347                 bot_distance_far = stof(argv(0));
 348                 bot_distance_close = stof(argv(1));
 349
 350                 if(bot_distance_far < bot_distance_close){
 351                         bot_distance_far = stof(argv(1));
 352                         bot_distance_close = stof(argv(0));
 353                 }
 354         }
 355
 356         int c;
 357
 358         #define PARSE_WEAPON_PRIORITIES(dist) MACRO_BEGIN \
 359                 if (bot_priority_##dist##_prev != autocvar_bot_ai_custom_weapon_priority_##dist) { \
 360                         strcpy(bot_priority_##dist##_prev, autocvar_bot_ai_custom_weapon_priority_##dist); \
 361                         tokens = tokenizebyseparator(W_NumberWeaponOrder(autocvar_bot_ai_custom_weapon_priority_##dist)," "); \
 362                         bot_weapons_##dist[0] = -1; \
 363                         c = 0; \
 364                         for(i = 0; i < tokens && c < REGISTRY_COUNT(Weapons); ++i) { \
 365                                 w = stof(argv(i)); \
 366                                 if (w >= WEP_FIRST && w <= WEP_LAST) { \
 367                                         bot_weapons_##dist[c] = w; \
 368                                         ++c; \
 369                                 } \
 370                         } \
 371                         if (c < REGISTRY_COUNT(Weapons)) \
 372                                 bot_weapons_##dist[c] = -1; \
 373                 } \
 374         MACRO_END
 375
 376         PARSE_WEAPON_PRIORITIES(far);
 377         PARSE_WEAPON_PRIORITIES(mid);
 378         PARSE_WEAPON_PRIORITIES(close);
 379
 380         bot_custom_weapon = true;
 381 }
 382
 383 void bot_endgame()
 384 {
 385         bot_relinkplayerlist();
 386         entity e = bot_list;
 387         while (e)
 388         {
 389                 setcolor(e, e.bot_preferredcolors);
 390                 e = e.nextbot;
 391         }
 392         // if dynamic waypoints are ever implemented, save them here
 393 }
 394
 395 void bot_relinkplayerlist()
 396 {
 397         player_count = 0;
 398         currentbots = 0;
 399         bot_list = NULL;
 400
 401         entity prevbot = NULL;
 402         FOREACH_CLIENT(true,
 403         {
 404                 ++player_count;
 405
 406                 if(IS_BOT_CLIENT(it))
 407                 {
 408                         if (!IS_OBSERVER(it) && !bot_ispaused(it))
 409                         {
 410                                 if(prevbot)
 411                                         prevbot.nextbot = it;
 412                                 else
 413                                         bot_list = it;
 414                                 prevbot = it;
 415                         }
 416                         ++currentbots;
 417                 }
 418         });
 419         if(prevbot)
 420                 prevbot.nextbot = NULL;
 421         bot_strategytoken = bot_list;
 422         bot_strategytoken_taken = true;
 423 }
 424
 425 void bot_clientdisconnect(entity this)
 426 {
 427         if (!IS_BOT_CLIENT(this))
 428                 return;
 429         bot_clearqueue(this);
 430         strfree(this.cleanname);
 431         strfree(this.netname_freeme);
 432         strfree(this.playermodel_freeme);
 433         strfree(this.playerskin_freeme);
 434         if(this.bot_cmd_current)
 435                 delete(this.bot_cmd_current);
 436         if(bot_waypoint_queue_owner == this)
 437                 bot_waypoint_queue_owner = NULL;
 438 }
 439
 440 void bot_clientconnect(entity this)
 441 {
 442         if (!IS_BOT_CLIENT(this)) return;
 443         this.bot_preferredcolors = this.clientcolors;
 444         this.bot_nextthink = time - random();
 445         this.lag_func = bot_lagfunc;
 446         this.isbot = true;
 447         this.createdtime = this.bot_nextthink;
 448
 449         if(!this.bot_config_loaded) // This is needed so team overrider doesn't break between matches
 450         {
 451                 bot_setnameandstuff(this);
 452                 bot_setclientfields(this);
 453         }
 454
 455         havocbot_setupbot(this);
 456 }
 457
 458 void bot_removefromlargestteam()
 459 {
 460         entity balance = TeamBalance_CheckAllowedTeams(NULL);
 461         TeamBalance_GetTeamCounts(balance, NULL);
 462
 463         entity best = NULL;
 464         float besttime = 0;
 465         int bestcount = 0;
 466
 467         int bcount = 0;
 468         FOREACH_CLIENT(it.isbot,
 469         {
 470                 ++bcount;
 471
 472                 if(!best)
 473                 {
 474                         best = it;
 475                         besttime = it.createdtime;
 476                 }
 477
 478                 int thiscount = 0;
 479
 480                 if (Team_IsValidTeam(it.team))
 481                 {
 482                         thiscount = TeamBalance_GetNumberOfPlayers(balance,
 483                                 Team_TeamToIndex(it.team));
 484                 }
 485
 486                 if(thiscount > bestcount)
 487                 {
 488                         bestcount = thiscount;
 489                         besttime = it.createdtime;
 490                         best = it;
 491                 }
 492                 else if(thiscount == bestcount && besttime < it.createdtime)
 493                 {
 494                         besttime = it.createdtime;
 495                         best = it;
 496                 }
 497         });
 498         TeamBalance_Destroy(balance);
 499         if(!bcount)
 500                 return; // no bots to remove
 501         currentbots = currentbots - 1;
 502         dropclient(best);
 503 }
 504
 505 void bot_removenewest()
 506 {
 507         if(teamplay)
 508         {
 509                 bot_removefromlargestteam();
 510                 return;
 511         }
 512
 513         float besttime = 0;
 514         entity best = NULL;
 515         int bcount = 0;
 516
 517         FOREACH_CLIENT(it.isbot,
 518         {
 519                 ++bcount;
 520
 521                 if(!best)
 522                 {
 523                         best = it;
 524                         besttime = it.createdtime;
 525                 }
 526
 527                 if(besttime < it.createdtime)
 528                 {
 529                         besttime = it.createdtime;
 530                         best = it;
 531                 }
 532         });
 533
 534         if(!bcount)
 535                 return; // no bots to remove
 536
 537         currentbots = currentbots - 1;
 538         dropclient(best);
 539 }
 540
 541 void autoskill(float factor)
 542 {
 543         int bestbot = -1;
 544         int bestplayer = -1;
 545         FOREACH_CLIENT(IS_PLAYER(it), {
 546                 if(IS_REAL_CLIENT(it))
 547                         bestplayer = max(bestplayer, it.totalfrags - it.totalfrags_lastcheck);
 548                 else
 549                         bestbot = max(bestbot, it.totalfrags - it.totalfrags_lastcheck);
 550         });
 551
 552         string msg = strcat("autoskill: best player got ", ftos(bestplayer), ", ""best bot got ", ftos(bestbot), "; ");
 553         if(bestbot < 0 || bestplayer < 0)
 554         {
 555                 msg = strcat(msg, "not doing anything");
 556                 // don't return, let it reset all counters below
 557         }
 558         else if(bestbot <= bestplayer * factor - 2)
 559         {
 560                 if(autocvar_skill < 17)
 561                 {
 562                         msg = strcat(msg, "2 frags difference, increasing skill");
 563                         cvar_set("skill", ftos(autocvar_skill + 1));
 564                         bprint("^2BOT SKILL UP!^7 Now at level ", ftos(autocvar_skill), "\n");
 565                 }
 566         }
 567         else if(bestbot >= bestplayer * factor + 2)
 568         {
 569                 if(autocvar_skill > 0)
 570                 {
 571                         msg = strcat(msg, "2 frags difference, decreasing skill");
 572                         cvar_set("skill", ftos(autocvar_skill - 1));
 573                         bprint("^1BOT SKILL DOWN!^7 Now at level ", ftos(autocvar_skill), "\n");
 574                 }
 575         }
 576         else
 577         {
 578                 msg = strcat(msg, "not doing anything");
 579                 return;
 580                 // don't reset counters, wait for them to accumulate
 581         }
 582         LOG_DEBUG(msg);
 583
 584         FOREACH_CLIENT(IS_PLAYER(it), { it.totalfrags_lastcheck = it.totalfrags; });
 585 }
 586
 587 void bot_calculate_stepheightvec()
 588 {
 589         stepheightvec = autocvar_sv_stepheight * '0 0 1';
 590         jumpheight_vec = (autocvar_sv_jumpvelocity ** 2) / (2 * autocvar_sv_gravity) * '0 0 1';
 591         jumpstepheightvec = stepheightvec + jumpheight_vec * 0.85; // reduce it a bit to make the jumps easy
 592         jumpheight_time = autocvar_sv_jumpvelocity / autocvar_sv_gravity;
 593 }
 594
 595 bool bot_fixcount(bool multiple_per_frame)
 596 {
 597         int activerealplayers = 0;
 598         int realplayers = 0;
 599         if (MUTATOR_CALLHOOK(Bot_FixCount, activerealplayers, realplayers)) {
 600                 activerealplayers = M_ARGV(0, int);
 601                 realplayers = M_ARGV(1, int);
 602         } else {
 603                 FOREACH_CLIENT(IS_REAL_CLIENT(it), {
 604                         if(IS_PLAYER(it))
 605                                 ++activerealplayers;
 606                         ++realplayers;
 607                 });
 608         }
 609
 610         int bots;
 611         // But don't remove bots immediately on level change, as the real players
 612         // usually haven't rejoined yet
 613         bots_would_leave = false;
 614         if (teamplay && autocvar_bot_vs_human && AvailableTeams() == 2)
 615                 bots = min(ceil(fabs(autocvar_bot_vs_human) * activerealplayers), maxclients - realplayers);
 616         else if ((realplayers || autocvar_bot_join_empty || (currentbots > 0 && time < 5)))
 617         {
 618                 int minplayers = max(0, floor(autocvar_minplayers));
 619                 if (teamplay)
 620                         minplayers = max(0, floor(autocvar_minplayers_per_team) * AvailableTeams());
 621                 int minbots = max(0, floor(autocvar_bot_number));
 622
 623                 // add bots to reach minplayers if needed
 624                 bots = max(minbots, minplayers - activerealplayers);
 625                 // cap bots to the max players allowed by the server
 626                 int player_limit = GetPlayerLimit();
 627                 if(player_limit)
 628                         bots = min(bots, max(player_limit - activerealplayers, 0));
 629                 bots = min(bots, maxclients - realplayers);
 630
 631                 if(bots > minbots)
 632                         bots_would_leave = true;
 633         }
 634         else
 635         {
 636                 // if there are no players, remove bots
 637                 bots = 0;
 638         }
 639
 640         // only add one bot per frame to avoid utter chaos
 641         if(time > botframe_nextthink)
 642         {
 643                 while (currentbots < bots)
 644                 {
 645                         if (bot_spawn() == NULL)
 646                         {
 647                                 bprint("Can not add bot, server full.\n");
 648                                 return false;
 649                         }
 650                         if (!multiple_per_frame)
 651                         {
 652                                 break;
 653                         }
 654                 }
 655                 while (currentbots > bots && bots >= 0)
 656                         bot_removenewest();
 657         }
 658
 659         return true;
 660 }
 661
 662 void bot_serverframe()
 663 {
 664         if (intermission_running && currentbots > 0)
 665         {
 666                 // after the end of the match all bots stay unless all human players disconnect
 667                 int realplayers = 0;
 668                 FOREACH_CLIENT(IS_REAL_CLIENT(it), { ++realplayers; });
 669                 if (!realplayers)
 670                 {
 671                         FOREACH_CLIENT(IS_BOT_CLIENT(it), { dropclient(it); });
 672                         currentbots = 0;
 673                 }
 674                 return;
 675         }
 676
 677         if (game_stopped)
 678                 return;
 679
 680         // Added 0.5 to avoid possible addition + immediate removal of bots that would make them appear as
 681         // spectators in the scoreboard and never go away. This issue happens at time 2 if map is changed
 682         // with the gotomap command, minplayers is > 1 and human clients join as players very soon
 683         // either intentionally or automatically (sv_spectate 0)
 684         if (time < 2.5)
 685         {
 686                 currentbots = -1;
 687                 return;
 688         }
 689
 690         if (currentbots == -1)
 691         {
 692                 // count bots already in the server from the previous match
 693                 currentbots = 0;
 694                 FOREACH_CLIENT(IS_BOT_CLIENT(it), { ++currentbots; });
 695         }
 696
 697         if(autocvar_skill != skill)
 698         {
 699                 float wpcost_update = false;
 700                 if(skill >= autocvar_bot_ai_bunnyhop_skilloffset && autocvar_skill < autocvar_bot_ai_bunnyhop_skilloffset)
 701                         wpcost_update = true;
 702                 if(skill < autocvar_bot_ai_bunnyhop_skilloffset && autocvar_skill >= autocvar_bot_ai_bunnyhop_skilloffset)
 703                         wpcost_update = true;
 704
 705                 skill = autocvar_skill;
 706                 if (wpcost_update)
 707                         waypoint_updatecost_foralllinks();
 708         }
 709
 710         bot_calculate_stepheightvec();
 711         bot_navigation_movemode = ((autocvar_bot_navigation_ignoreplayers) ? MOVE_NOMONSTERS : MOVE_NORMAL);
 712
 713         if(time > autoskill_nextthink)
 714         {
 715                 float a;
 716                 a = autocvar_skill_auto;
 717                 if(a)
 718                         autoskill(a);
 719                 autoskill_nextthink = time + 5;
 720         }
 721
 722         if(time > botframe_nextthink)
 723         {
 724                 if(!bot_fixcount(false))
 725                         botframe_nextthink = time + 10;
 726         }
 727
 728         if(botframe_spawnedwaypoints)
 729         {
 730                 if(autocvar_waypoint_benchmark)
 731                         localcmd("quit\n");
 732         }
 733
 734         if (currentbots > 0 || waypointeditor_enabled || autocvar_g_waypointeditor_auto)
 735         if (botframe_spawnedwaypoints)
 736         {
 737                 if(botframe_cachedwaypointlinks)
 738                 {
 739                         if(!botframe_loadedforcedlinks)
 740                                 waypoint_load_hardwiredlinks();
 741                 }
 742                 else
 743                 {
 744                         // TODO: Make this check cleaner
 745                         IL_EACH(g_waypoints, time - it.nextthink > 10,
 746                         {
 747                                 waypoint_save_links();
 748                                 break;
 749                         });
 750                 }
 751         }
 752         else
 753         {
 754                 botframe_spawnedwaypoints = true;
 755                 waypoint_loadall();
 756                 waypoint_load_links();
 757         }
 758
 759         if (bot_list)
 760         {
 761                 // cycle the goal token from one bot to the next each frame
 762                 // (this prevents them from all doing spawnfunc_waypoint searches on the same
 763                 //  frame, which causes choppy framerates)
 764                 if (bot_strategytoken_taken)
 765                 {
 766                         // give goal token to the first bot without goals; if all bots don't have
 767                         // any goal (or are dead/frozen) simply give it to the next one
 768                         bot_strategytoken_taken = false;
 769                         entity bot_strategytoken_save = bot_strategytoken;
 770                         while (true)
 771                         {
 772                                 if (bot_strategytoken)
 773                                         bot_strategytoken = bot_strategytoken.nextbot;
 774                                 if (!bot_strategytoken)
 775                                         bot_strategytoken = bot_list;
 776
 777                                 if (!(IS_DEAD(bot_strategytoken) || STAT(FROZEN, bot_strategytoken))
 778                                         && !bot_strategytoken.goalcurrent)
 779                                         break;
 780
 781                                 if (!bot_strategytoken_save) // break loop if all the bots are dead or frozen
 782                                         break;
 783                                 if (bot_strategytoken == bot_strategytoken_save)
 784                                         bot_strategytoken_save = NULL; // looped through all the bots
 785                         }
 786                 }
 787
 788                 if (botframe_nextdangertime < time)
 789                 {
 790                         float interval;
 791                         interval = autocvar_bot_ai_dangerdetectioninterval;
 792                         if (botframe_nextdangertime < time - interval * 1.5)
 793                                 botframe_nextdangertime = time;
 794                         botframe_nextdangertime = botframe_nextdangertime + interval;
 795                         botframe_updatedangerousobjects(autocvar_bot_ai_dangerdetectionupdates);
 796                 }
 797         }
 798
 799         if (waypointeditor_enabled)
 800                 botframe_showwaypointlinks();
 801
 802         if (autocvar_g_waypointeditor_auto)
 803                 botframe_autowaypoints();
 804
 805         if (currentbots > 0)
 806                 bot_custom_weapon_priority_setup();
 807 }