qcsrc/server/bot/default/havocbot/havocbot.qc

   1 #include "havocbot.qh"
   2
   3 #include <server/defs.qh>
   4 #include <server/miscfunctions.qh>
   5 #include "../cvars.qh"
   6
   7 #include "../aim.qh"
   8 #include "../bot.qh"
   9 #include "../navigation.qh"
  10 #include "../scripting.qh"
  11 #include "../waypoints.qh"
  12
  13 #include <common/constants.qh>
  14 #include <common/impulses/all.qh>
  15 #include <common/net_linked.qh>
  16 #include <common/physics/player.qh>
  17 #include <common/state.qh>
  18 #include <common/items/_mod.qh>
  19 #include <common/wepent.qh>
  20
  21 #include <common/triggers/teleporters.qh>
  22 #include <common/triggers/trigger/jumppads.qh>
  23
  24 #include <lib/warpzone/common.qh>
  25
  26 .float speed;
  27
  28 void havocbot_ai(entity this)
  29 {
  30         if(this.draggedby)
  31                 return;
  32
  33         if(bot_execute_commands(this))
  34                 return;
  35
  36         if (bot_strategytoken == this && !bot_strategytoken_taken)
  37         {
  38                 if(this.havocbot_blockhead)
  39                 {
  40                         this.havocbot_blockhead = false;
  41                 }
  42                 else
  43                 {
  44                         if (!this.jumppadcount && !STAT(FROZEN, this))
  45                                 this.havocbot_role(this); // little too far down the rabbit hole
  46                 }
  47
  48                 // if we don't have a goal and we're under water look for a waypoint near the "shore" and push it
  49                 if(!(IS_DEAD(this) || STAT(FROZEN, this)))
  50                 if(!this.goalcurrent)
  51                 if(this.waterlevel == WATERLEVEL_SWIMMING || (this.aistatus & AI_STATUS_OUT_WATER))
  52                 {
  53                         // Look for the closest waypoint out of water
  54                         entity newgoal = NULL;
  55                         IL_EACH(g_waypoints, vdist(it.origin - this.origin, <=, 10000),
  56                         {
  57                                 if(it.origin.z < this.origin.z)
  58                                         continue;
  59
  60                                 if(it.origin.z - this.origin.z - this.view_ofs.z > 100)
  61                                         continue;
  62
  63                                 if (pointcontents(it.origin + it.maxs + '0 0 1') != CONTENT_EMPTY)
  64                                         continue;
  65
  66                                 traceline(this.origin + this.view_ofs, ((it.absmin + it.absmax) * 0.5), true, this);
  67
  68                                 if(trace_fraction < 1)
  69                                         continue;
  70
  71                                 if(!newgoal || vlen2(it.origin - this.origin) < vlen2(newgoal.origin - this.origin))
  72                                         newgoal = it;
  73                         });
  74
  75                         if(newgoal)
  76                         {
  77                         //      te_wizspike(newgoal.origin);
  78                                 navigation_pushroute(this, newgoal);
  79                         }
  80                 }
  81
  82                 // token has been used this frame
  83                 bot_strategytoken_taken = true;
  84         }
  85
  86         if(IS_DEAD(this) || STAT(FROZEN, this))
  87         {
  88                 if (this.goalcurrent)
  89                         navigation_clearroute(this);
  90                 return;
  91         }
  92
  93         havocbot_chooseenemy(this);
  94
  95         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
  96         {
  97                 .entity weaponentity = weaponentities[slot];
  98                 if(this.(weaponentity).m_weapon != WEP_Null || slot == 0)
  99                 if(this.(weaponentity).bot_chooseweapontime < time)
 100                 {
 101                         this.(weaponentity).bot_chooseweapontime = time + autocvar_bot_ai_chooseweaponinterval;
 102                         havocbot_chooseweapon(this, weaponentity);
 103                 }
 104         }
 105         havocbot_aim(this);
 106         lag_update(this);
 107         if (this.bot_aimtarg)
 108         {
 109                 this.aistatus |= AI_STATUS_ATTACKING;
 110                 this.aistatus &= ~AI_STATUS_ROAMING;
 111
 112                 if(this.weapons)
 113                 {
 114                         if (autocvar_bot_nofire || IS_INDEPENDENT_PLAYER(this))
 115                         {
 116                                 PHYS_INPUT_BUTTON_ATCK(this) = false;
 117                                 PHYS_INPUT_BUTTON_ATCK2(this) = false;
 118                         }
 119                         else
 120                         {
 121                                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 122                                 {
 123                                         .entity weaponentity = weaponentities[slot];
 124                                         Weapon w = this.(weaponentity).m_weapon;
 125                                         if(w == WEP_Null && slot != 0)
 126                                                 continue;
 127                                         w.wr_aim(w, this, weaponentity);
 128                                         if(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_ATCK2(this)) // TODO: what if we didn't fire this weapon, but the previous?
 129                                                 this.(weaponentity).lastfiredweapon = this.(weaponentity).m_weapon.m_id;
 130                                 }
 131                         }
 132                 }
 133                 else
 134                 {
 135                         if(IS_PLAYER(this.bot_aimtarg))
 136                                 bot_aimdir(this, this.bot_aimtarg.origin + this.bot_aimtarg.view_ofs - this.origin - this.view_ofs , -1);
 137                 }
 138         }
 139         else if (this.goalcurrent)
 140         {
 141                 this.aistatus |= AI_STATUS_ROAMING;
 142                 this.aistatus &= ~AI_STATUS_ATTACKING;
 143
 144                 vector now, next;
 145                 float aimdistance,skillblend,distanceblend,blend;
 146
 147                 vector v = get_closer_dest(this.goalcurrent, this.origin);
 148                 if(this.goalcurrent.wpisbox)
 149                 {
 150                         // avoid a glitch when bot is teleported but teleport waypoint isn't removed yet
 151                         if(this.goalstack02 && this.goalcurrent.wpflags & WAYPOINTFLAG_TELEPORT
 152                         && this.lastteleporttime > 0 && time - this.lastteleporttime < 0.15)
 153                                 v = (this.goalstack02.absmin + this.goalstack02.absmax) * 0.5;
 154                         // aim to teleport origin if bot is inside teleport waypoint but hasn't touched the real teleport yet
 155                         else if(boxesoverlap(this.goalcurrent.absmin, this.goalcurrent.absmax, this.origin, this.origin))
 156                                 v = this.goalcurrent.origin;
 157                 }
 158                 next = now = v - (this.origin + this.view_ofs);
 159                 aimdistance = vlen(now);
 160
 161                 //dprint(this.goalstack01.classname,etos(this.goalstack01),"\n");
 162                 if(
 163                         this.goalstack01 != this && this.goalstack01 && !wasfreed(this.goalstack01) && ((this.aistatus & AI_STATUS_RUNNING) == 0) &&
 164                         !(this.goalcurrent.wpflags & WAYPOINTFLAG_TELEPORT)
 165                 )
 166                         next = ((this.goalstack01.absmin + this.goalstack01.absmax) * 0.5) - (this.origin + this.view_ofs);
 167
 168                 skillblend=bound(0,(skill+this.bot_moveskill-2.5)*0.5,1); //lower skill player can't preturn
 169                 distanceblend=bound(0,aimdistance/autocvar_bot_ai_keyboard_distance,1);
 170                 blend = skillblend * (1-distanceblend);
 171                 //v = (now * (distanceblend) + next * (1-distanceblend)) * (skillblend) + now * (1-skillblend);
 172                 //v = now * (distanceblend) * (skillblend) + next * (1-distanceblend) * (skillblend) + now * (1-skillblend);
 173                 //v = now * ((1-skillblend) + (distanceblend) * (skillblend)) + next * (1-distanceblend) * (skillblend);
 174                 v = now + blend * (next - now);
 175                 //dprint(etos(this), " ");
 176                 //dprint(vtos(now), ":", vtos(next), "=", vtos(v), " (blend ", ftos(blend), ")\n");
 177                 //v = now * (distanceblend) + next * (1-distanceblend);
 178                 if (this.waterlevel < WATERLEVEL_SWIMMING)
 179                         v.z = 0;
 180                 //dprint("walk at:", vtos(v), "\n");
 181                 //te_lightning2(NULL, this.origin, this.goalcurrent.origin);
 182                 bot_aimdir(this, v, -1);
 183         }
 184         havocbot_movetogoal(this);
 185
 186         // if the bot is not attacking, consider reloading weapons
 187         if (!(this.aistatus & AI_STATUS_ATTACKING))
 188         {
 189                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 190                 {
 191                         .entity weaponentity = weaponentities[slot];
 192
 193                         if(this.(weaponentity).m_weapon == WEP_Null && slot != 0)
 194                                 continue;
 195
 196                         // we are currently holding a weapon that's not fully loaded, reload it
 197                         if(skill >= 2) // bots can only reload the held weapon on purpose past this skill
 198                         if(this.(weaponentity).clip_load < this.(weaponentity).clip_size)
 199                                 CS(this).impulse = IMP_weapon_reload.impulse; // not sure if this is done right
 200
 201                         // if we're not reloading a weapon, switch to any weapon in our invnetory that's not fully loaded to reload it next
 202                         // the code above executes next frame, starting the reloading then
 203                         if(skill >= 5) // bots can only look for unloaded weapons past this skill
 204                         if(this.(weaponentity).clip_load >= 0) // only if we're not reloading a weapon already
 205                         {
 206                                 FOREACH(Weapons, it != WEP_Null, {
 207                                         if((this.weapons & (it.m_wepset)) && (it.spawnflags & WEP_FLAG_RELOADABLE) && (this.(weaponentity).weapon_load[it.m_id] < it.reloading_ammo))
 208                                         {
 209                                                 this.(weaponentity).m_switchweapon = it;
 210                                                 break;
 211                                         }
 212                                 });
 213                         }
 214                 }
 215         }
 216 }
 217
 218 void havocbot_keyboard_movement(entity this, vector destorg)
 219 {
 220         vector keyboard;
 221
 222         if (time > this.havocbot_keyboardtime)
 223         {
 224                 float sk = skill + this.bot_moveskill;
 225                 this.havocbot_keyboardtime =
 226                         max(
 227                                 this.havocbot_keyboardtime
 228                                         + 0.05 / max(1, sk + this.havocbot_keyboardskill)
 229                                         + random() * 0.025 / max(0.00025, skill + this.havocbot_keyboardskill)
 230                         , time);
 231                 keyboard = CS(this).movement / autocvar_sv_maxspeed;
 232
 233                 float trigger = autocvar_bot_ai_keyboard_threshold;
 234                 float trigger1 = -trigger;
 235
 236                 // categorize forward movement
 237                 // at skill < 1.5 only forward
 238                 // at skill < 2.5 only individual directions
 239                 // at skill < 4.5 only individual directions, and forward diagonals
 240                 // at skill >= 4.5, all cases allowed
 241                 if (keyboard.x > trigger)
 242                 {
 243                         keyboard.x = 1;
 244                         if (sk < 2.5)
 245                                 keyboard.y = 0;
 246                 }
 247                 else if (keyboard.x < trigger1 && sk > 1.5)
 248                 {
 249                         keyboard.x = -1;
 250                         if (sk < 4.5)
 251                                 keyboard.y = 0;
 252                 }
 253                 else
 254                 {
 255                         keyboard.x = 0;
 256                         if (sk < 1.5)
 257                                 keyboard.y = 0;
 258                 }
 259                 if (sk < 4.5)
 260                         keyboard.z = 0;
 261
 262                 if (keyboard.y > trigger)
 263                         keyboard.y = 1;
 264                 else if (keyboard.y < trigger1)
 265                         keyboard.y = -1;
 266                 else
 267                         keyboard.y = 0;
 268
 269                 if (keyboard.z > trigger)
 270                         keyboard.z = 1;
 271                 else if (keyboard.z < trigger1)
 272                         keyboard.z = -1;
 273                 else
 274                         keyboard.z = 0;
 275
 276                 this.havocbot_keyboard = keyboard * autocvar_sv_maxspeed;
 277                 if (this.havocbot_ducktime > time)
 278                         PHYS_INPUT_BUTTON_CROUCH(this) = true;
 279         }
 280
 281         keyboard = this.havocbot_keyboard;
 282         float blend = bound(0, vlen(destorg - this.origin) / autocvar_bot_ai_keyboard_distance, 1); // When getting close move with 360 degree
 283         //dprint("movement ", vtos(CS(this).movement), " keyboard ", vtos(keyboard), " blend ", ftos(blend), "\n");
 284         CS(this).movement = CS(this).movement + (keyboard - CS(this).movement) * blend;
 285 }
 286
 287 void havocbot_bunnyhop(entity this, vector dir)
 288 {
 289         float bunnyhopdistance;
 290         vector deviation;
 291         float maxspeed;
 292
 293         // Don't jump when attacking
 294         if(this.aistatus & AI_STATUS_ATTACKING)
 295                 return;
 296
 297         if(IS_PLAYER(this.goalcurrent))
 298                 return;
 299
 300         maxspeed = autocvar_sv_maxspeed;
 301
 302         if(this.aistatus & AI_STATUS_RUNNING && vdist(this.velocity, <, autocvar_sv_maxspeed * 0.75)
 303                 || this.aistatus & AI_STATUS_DANGER_AHEAD)
 304         {
 305                 this.aistatus &= ~AI_STATUS_RUNNING;
 306                 PHYS_INPUT_BUTTON_JUMP(this) = false;
 307                 this.bot_canruntogoal = 0;
 308                 this.bot_timelastseengoal = 0;
 309                 return;
 310         }
 311
 312         if(this.waterlevel > WATERLEVEL_WETFEET)
 313         {
 314                 this.aistatus &= ~AI_STATUS_RUNNING;
 315                 return;
 316         }
 317
 318         if(this.bot_lastseengoal != this.goalcurrent && !(this.aistatus & AI_STATUS_RUNNING))
 319         {
 320                 this.bot_canruntogoal = 0;
 321                 this.bot_timelastseengoal = 0;
 322         }
 323
 324         vector gco = get_closer_dest(this.goalcurrent, this.origin);
 325         bunnyhopdistance = vlen(this.origin - gco);
 326
 327         // Run only to visible goals
 328         if(IS_ONGROUND(this))
 329         if(vdist(vec2(this.velocity), >=, autocvar_sv_maxspeed)) // if -really- running
 330         if(checkpvs(this.origin + this.view_ofs, this.goalcurrent))
 331         {
 332                         this.bot_lastseengoal = this.goalcurrent;
 333
 334                         // seen it before
 335                         if(this.bot_timelastseengoal)
 336                         {
 337                                 // for a period of time
 338                                 if(time - this.bot_timelastseengoal > autocvar_bot_ai_bunnyhop_firstjumpdelay)
 339                                 {
 340                                         float checkdistance;
 341                                         checkdistance = true;
 342
 343                                         // don't run if it is too close
 344                                         if(this.bot_canruntogoal==0)
 345                                         {
 346                                                 if(bunnyhopdistance > autocvar_bot_ai_bunnyhop_startdistance)
 347                                                         this.bot_canruntogoal = 1;
 348                                                 else
 349                                                         this.bot_canruntogoal = -1;
 350                                         }
 351
 352                                         if(this.bot_canruntogoal != 1)
 353                                                 return;
 354
 355                                         if(this.aistatus & AI_STATUS_ROAMING)
 356                                         if(this.goalcurrent.classname=="waypoint")
 357                                         if (!(this.goalcurrent.wpflags & WAYPOINTFLAG_PERSONAL))
 358                                         if(fabs(gco.z - this.origin.z) < this.maxs.z - this.mins.z)
 359                                         if(this.goalstack01 && !wasfreed(this.goalstack01))
 360                                         {
 361                                                 vector gno = (this.goalstack01.absmin + this.goalstack01.absmax) * 0.5;
 362                                                 deviation = vectoangles(gno - this.origin) - vectoangles(gco - this.origin);
 363                                                 while (deviation.y < -180) deviation.y = deviation.y + 360;
 364                                                 while (deviation.y > 180) deviation.y = deviation.y - 360;
 365
 366                                                 if(fabs(deviation.y) < 20)
 367                                                 if(bunnyhopdistance < vlen(this.origin - gno))
 368                                                 if(fabs(gno.z - gco.z) < this.maxs.z - this.mins.z)
 369                                                 {
 370                                                         if(vdist(gco - gno, >, autocvar_bot_ai_bunnyhop_startdistance))
 371                                                         if(checkpvs(this.origin + this.view_ofs, this.goalstack01))
 372                                                         {
 373                                                                 checkdistance = false;
 374                                                         }
 375                                                 }
 376                                         }
 377
 378                                         if(checkdistance)
 379                                         {
 380                                                 this.aistatus &= ~AI_STATUS_RUNNING;
 381                                                 // increase stop distance in case the goal is on a slope or a lower platform
 382                                                 if(bunnyhopdistance > autocvar_bot_ai_bunnyhop_stopdistance + (this.origin.z - gco.z))
 383                                                         PHYS_INPUT_BUTTON_JUMP(this) = true;
 384                                         }
 385                                         else
 386                                         {
 387                                                 this.aistatus |= AI_STATUS_RUNNING;
 388                                                 PHYS_INPUT_BUTTON_JUMP(this) = true;
 389                                         }
 390                                 }
 391                         }
 392                         else
 393                         {
 394                                 this.bot_timelastseengoal = time;
 395                         }
 396         }
 397         else
 398         {
 399                 this.bot_timelastseengoal = 0;
 400         }
 401
 402 #if 0
 403         // Release jump button
 404         if(!cvar("sv_pogostick"))
 405         if((IS_ONGROUND(this)) == 0)
 406         {
 407                 if(this.velocity.z < 0 || vlen(this.velocity)<maxspeed)
 408                         PHYS_INPUT_BUTTON_JUMP(this) = false;
 409
 410                 // Strafe
 411                 if(this.aistatus & AI_STATUS_RUNNING)
 412                 if(vlen(this.velocity)>maxspeed)
 413                 {
 414                         deviation = vectoangles(dir) - vectoangles(this.velocity);
 415                         while (deviation.y < -180) deviation.y = deviation.y + 360;
 416                         while (deviation.y > 180) deviation.y = deviation.y - 360;
 417
 418                         if(fabs(deviation.y)>10)
 419                                 CS(this).movement_x = 0;
 420
 421                         if(deviation.y>10)
 422                                 CS(this).movement_y = maxspeed * -1;
 423                         else if(deviation.y<10)
 424                                 CS(this).movement_y = maxspeed;
 425
 426                 }
 427         }
 428 #endif
 429 }
 430
 431 // return true when bot isn't getting closer to the current goal
 432 bool havocbot_checkgoaldistance(entity this, vector gco)
 433 {
 434         float curr_dist_z = max(20, fabs(this.origin.z - gco.z));
 435         float curr_dist_2d = max(20, vlen(vec2(this.origin - gco)));
 436         float distance_time = this.goalcurrent_distance_time;
 437         if(distance_time < 0)
 438                 distance_time = -distance_time;
 439         if(curr_dist_z >= this.goalcurrent_distance_z && curr_dist_2d >= this.goalcurrent_distance_2d)
 440         {
 441                 if(!distance_time)
 442                         this.goalcurrent_distance_time = time;
 443                 else if (time - distance_time > 0.5)
 444                         return true;
 445         }
 446         else
 447         {
 448                 // reduce it a little bit so it works even with very small approaches to the goal
 449                 this.goalcurrent_distance_z = max(20, curr_dist_z - 10);
 450                 this.goalcurrent_distance_2d = max(20, curr_dist_2d - 10);
 451                 this.goalcurrent_distance_time = 0;
 452         }
 453         return false;
 454 }
 455
 456 void havocbot_movetogoal(entity this)
 457 {
 458         vector diff;
 459         vector dir;
 460         vector flatdir;
 461         vector evadeobstacle;
 462         vector evadelava;
 463         float maxspeed;
 464         vector gco;
 465         //float dist;
 466         vector dodge;
 467         //if (this.goalentity)
 468         //      te_lightning2(this, this.origin, (this.goalentity.absmin + this.goalentity.absmax) * 0.5);
 469         CS(this).movement = '0 0 0';
 470         maxspeed = autocvar_sv_maxspeed;
 471
 472         PHYS_INPUT_BUTTON_JETPACK(this) = false;
 473         // Jetpack navigation
 474         if(this.navigation_jetpack_goal)
 475         if(this.goalcurrent==this.navigation_jetpack_goal)
 476         if(this.ammo_fuel)
 477         {
 478                 if(autocvar_bot_debug_goalstack)
 479                 {
 480                         debuggoalstack(this);
 481                         te_wizspike(this.navigation_jetpack_point);
 482                 }
 483
 484                 // Take off
 485                 if (!(this.aistatus & AI_STATUS_JETPACK_FLYING))
 486                 {
 487                         // Brake almost completely so it can get a good direction
 488                         if(vdist(this.velocity, >, 10))
 489                                 return;
 490                         this.aistatus |= AI_STATUS_JETPACK_FLYING;
 491                 }
 492
 493                 makevectors(this.v_angle.y * '0 1 0');
 494                 dir = normalize(this.navigation_jetpack_point - this.origin);
 495
 496                 // Landing
 497                 if(this.aistatus & AI_STATUS_JETPACK_LANDING)
 498                 {
 499                         // Calculate brake distance in xy
 500                         float d = vlen(vec2(this.origin - (this.goalcurrent.absmin + this.goalcurrent.absmax) * 0.5));
 501                         float v = vlen(vec2(this.velocity));
 502                         float db = ((v ** 2) / (autocvar_g_jetpack_acceleration_side * 2)) + 100;
 503                         //LOG_INFOF("distance %d, velocity %d, brake at %d ", ceil(d), ceil(v), ceil(db));
 504                         if(d < db || d < 500)
 505                         {
 506                                 // Brake
 507                                 if(v > maxspeed * 0.3)
 508                                 {
 509                                         CS(this).movement_x = dir * v_forward * -maxspeed;
 510                                         return;
 511                                 }
 512                                 // Switch to normal mode
 513                                 this.navigation_jetpack_goal = NULL;
 514                                 this.aistatus &= ~AI_STATUS_JETPACK_LANDING;
 515                                 this.aistatus &= ~AI_STATUS_JETPACK_FLYING;
 516                                 return;
 517                         }
 518                 }
 519                 else if(checkpvs(this.origin,this.goalcurrent))
 520                 {
 521                         // If I can see the goal switch to landing code
 522                         this.aistatus &= ~AI_STATUS_JETPACK_FLYING;
 523                         this.aistatus |= AI_STATUS_JETPACK_LANDING;
 524                         return;
 525                 }
 526
 527                 // Flying
 528                 PHYS_INPUT_BUTTON_JETPACK(this) = true;
 529                 if(this.navigation_jetpack_point.z - STAT(PL_MAX, this).z + STAT(PL_MIN, this).z < this.origin.z)
 530                 {
 531                         CS(this).movement_x = dir * v_forward * maxspeed;
 532                         CS(this).movement_y = dir * v_right * maxspeed;
 533                 }
 534                 return;
 535         }
 536
 537         // Handling of jump pads
 538         if(this.jumppadcount)
 539         {
 540                 if(this.goalcurrent.wpflags & WAYPOINTFLAG_TELEPORT)
 541                 {
 542                         this.aistatus |= AI_STATUS_OUT_JUMPPAD;
 543                         navigation_poptouchedgoals(this);
 544                         return;
 545                 }
 546                 else if(this.aistatus & AI_STATUS_OUT_JUMPPAD)
 547                 {
 548                         // If got stuck on the jump pad try to reach the farthest visible waypoint
 549                         // but with some randomness so it can try out different paths
 550                         if(!this.goalcurrent)
 551                         {
 552                                 entity newgoal = NULL;
 553                                 IL_EACH(g_waypoints, vdist(it.origin - this.origin, <=, 1000),
 554                                 {
 555                                         if(it.wpflags & WAYPOINTFLAG_TELEPORT)
 556                                         if(it.origin.z < this.origin.z - 100 && vdist(vec2(it.origin - this.origin), <, 100))
 557                                                 continue;
 558
 559                                         traceline(this.origin + this.view_ofs, ((it.absmin + it.absmax) * 0.5), true, this);
 560
 561                                         if(trace_fraction < 1)
 562                                                 continue;
 563
 564                                         if(!newgoal || ((random() < 0.8) && vlen2(it.origin - this.origin) > vlen2(newgoal.origin - this.origin)))
 565                                                 newgoal = it;
 566                                 });
 567
 568                                 if(newgoal)
 569                                 {
 570                                         this.ignoregoal = this.goalcurrent;
 571                                         this.ignoregoaltime = time + autocvar_bot_ai_ignoregoal_timeout;
 572                                         navigation_clearroute(this);
 573                                         navigation_routetogoal(this, newgoal, this.origin);
 574                                         if(autocvar_bot_debug_goalstack)
 575                                                 debuggoalstack(this);
 576                                         this.aistatus &= ~AI_STATUS_OUT_JUMPPAD;
 577                                 }
 578                         }
 579                         else
 580                         {
 581                                 if (this.goalcurrent.bot_pickup)
 582                                 {
 583                                         entity jumppad_wp = this.goalcurrent_prev;
 584                                         navigation_poptouchedgoals(this);
 585                                         if(!this.goalcurrent && jumppad_wp.wp00)
 586                                         {
 587                                                 // head to the jumppad destination once bot reaches the goal item
 588                                                 navigation_pushroute(this, jumppad_wp.wp00);
 589                                         }
 590                                 }
 591                                 gco = (this.goalcurrent.absmin + this.goalcurrent.absmax) * 0.5;
 592                                 if (this.origin.z > gco.z && vdist(vec2(this.velocity), <, autocvar_sv_maxspeed))
 593                                         this.aistatus &= ~AI_STATUS_OUT_JUMPPAD;
 594                                 else if(havocbot_checkgoaldistance(this, gco))
 595                                 {
 596                                         navigation_clearroute(this);
 597                                         navigation_goalrating_timeout_force(this);
 598                                 }
 599                                 else
 600                                         return;
 601                         }
 602                 }
 603                 else
 604                 {
 605                         if(time - this.lastteleporttime > 0.2 && this.velocity.z > 0)
 606                         {
 607                                 vector velxy = this.velocity; velxy_z = 0;
 608                                 if(vdist(velxy, <, autocvar_sv_maxspeed * 0.2))
 609                                 {
 610                                         LOG_TRACE("Warning: ", this.netname, " got stuck on a jumppad (velocity in xy is ", vtos(velxy), "), trying to get out of it now");
 611                                         this.aistatus |= AI_STATUS_OUT_JUMPPAD;
 612                                 }
 613                                 return;
 614                         }
 615
 616                         // Don't chase players while using a jump pad
 617                         if(IS_PLAYER(this.goalcurrent) || IS_PLAYER(this.goalstack01))
 618                                 return;
 619                 }
 620         }
 621         else if(this.aistatus & AI_STATUS_OUT_JUMPPAD)
 622                 this.aistatus &= ~AI_STATUS_OUT_JUMPPAD;
 623
 624         // If there is a trigger_hurt right below try to use the jetpack or make a rocketjump
 625         if (skill > 6 && !(IS_ONGROUND(this)))
 626         {
 627                 #define ROCKETJUMP_DAMAGE() WEP_CVAR(devastator, damage) * 0.8 \
 628                         * ((this.strength_finished > time) ? autocvar_g_balance_powerup_strength_selfdamage : 1) \
 629                         * ((this.invincible_finished > time) ? autocvar_g_balance_powerup_invincible_takedamage : 1)
 630
 631                 tracebox(this.origin, this.mins, this.maxs, this.origin + '0 0 -65536', MOVE_NOMONSTERS, this);
 632                 if(tracebox_hits_trigger_hurt(this.origin, this.mins, this.maxs, trace_endpos ))
 633                 if(this.items & IT_JETPACK)
 634                 {
 635                         tracebox(this.origin, this.mins, this.maxs, this.origin + '0 0 65536', MOVE_NOMONSTERS, this);
 636                         if(tracebox_hits_trigger_hurt(this.origin, this.mins, this.maxs, trace_endpos + '0 0 1' ))
 637                         {
 638                                 if(this.velocity.z<0)
 639                                         PHYS_INPUT_BUTTON_JETPACK(this) = true;
 640                         }
 641                         else
 642                                 PHYS_INPUT_BUTTON_JETPACK(this) = true;
 643
 644                         // If there is no goal try to move forward
 645
 646                         if(this.goalcurrent==NULL)
 647                                 dir = v_forward;
 648                         else
 649                                 dir = normalize(( ( this.goalcurrent.absmin + this.goalcurrent.absmax ) * 0.5 ) - this.origin);
 650
 651                         vector xyvelocity = this.velocity; xyvelocity_z = 0;
 652                         float xyspeed = xyvelocity * dir;
 653
 654                         if(xyspeed < (maxspeed / 2))
 655                         {
 656                                 makevectors(this.v_angle.y * '0 1 0');
 657                                 tracebox(this.origin, this.mins, this.maxs, this.origin + (dir * maxspeed * 3), MOVE_NOMONSTERS, this);
 658                                 if(trace_fraction==1)
 659                                 {
 660                                         CS(this).movement_x = dir * v_forward * maxspeed;
 661                                         CS(this).movement_y = dir * v_right * maxspeed;
 662                                         if (skill < 10)
 663                                                 havocbot_keyboard_movement(this, this.origin + dir * 100);
 664                                 }
 665                         }
 666
 667                         this.havocbot_blockhead = true;
 668
 669                         return;
 670                 }
 671                 else if(this.health + this.armorvalue > ROCKETJUMP_DAMAGE())
 672                 {
 673                         if(this.velocity.z < 0)
 674                         {
 675                                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 676                                 {
 677                                         .entity weaponentity = weaponentities[slot];
 678
 679                                         if(this.(weaponentity).m_weapon == WEP_Null && slot != 0)
 680                                                 continue;
 681
 682                                         if(client_hasweapon(this, WEP_DEVASTATOR, weaponentity, true, false))
 683                                         {
 684                                                 CS(this).movement_x = maxspeed;
 685
 686                                                 if(this.rocketjumptime)
 687                                                 {
 688                                                         if(time > this.rocketjumptime)
 689                                                         {
 690                                                                 PHYS_INPUT_BUTTON_ATCK2(this) = true;
 691                                                                 this.rocketjumptime = 0;
 692                                                         }
 693                                                         return;
 694                                                 }
 695
 696                                                 this.(weaponentity).m_switchweapon = WEP_DEVASTATOR;
 697                                                 this.v_angle_x = 90;
 698                                                 PHYS_INPUT_BUTTON_ATCK(this) = true;
 699                                                 this.rocketjumptime = time + WEP_CVAR(devastator, detonatedelay);
 700                                                 return;
 701                                         }
 702                                 }
 703                         }
 704                 }
 705                 else
 706                 {
 707                         // If there is no goal try to move forward
 708                         if(this.goalcurrent==NULL)
 709                                 CS(this).movement_x = maxspeed;
 710                 }
 711         }
 712
 713         // If we are under water with no goals, swim up
 714         if(this.waterlevel)
 715         if(this.goalcurrent==NULL)
 716         {
 717                 dir = '0 0 0';
 718                 if(this.waterlevel>WATERLEVEL_SWIMMING)
 719                         dir.z = 1;
 720                 else if(this.velocity.z >= 0 && !(this.waterlevel == WATERLEVEL_WETFEET && this.watertype == CONTENT_WATER))
 721                         PHYS_INPUT_BUTTON_JUMP(this) = true;
 722                 else
 723                         PHYS_INPUT_BUTTON_JUMP(this) = false;
 724                 makevectors(this.v_angle.y * '0 1 0');
 725                 CS(this).movement_x = dir * v_forward * maxspeed;
 726                 CS(this).movement_y = dir * v_right * maxspeed;
 727                 CS(this).movement_z = dir * v_up * maxspeed;
 728         }
 729
 730         // if there is nowhere to go, exit
 731         if (this.goalcurrent == NULL)
 732                 return;
 733
 734
 735         bool locked_goal = false;
 736         if(this.goalentity && wasfreed(this.goalentity))
 737         {
 738                 navigation_clearroute(this);
 739                 navigation_goalrating_timeout_force(this);
 740                 return;
 741         }
 742         else if(this.goalentity.bot_pickup)
 743         {
 744                 if(this.goalentity.bot_pickup_respawning)
 745                 {
 746                         if(this.goalentity.solid) // item respawned
 747                                 this.goalentity.bot_pickup_respawning = false;
 748                         else if(time < this.goalentity.scheduledrespawntime - 10) // item already taken (by someone else)
 749                         {
 750                                 if(checkpvs(this.origin, this.goalentity))
 751                                 {
 752                                         this.goalentity.bot_pickup_respawning = false;
 753                                         navigation_goalrating_timeout_expire(this, random());
 754                                 }
 755                                 locked_goal = true; // wait for item to respawn
 756                         }
 757                         else if(this.goalentity == this.goalcurrent)
 758                                 locked_goal = true; // wait for item to respawn
 759                 }
 760                 else if(!this.goalentity.solid && !boxesoverlap(this.goalentity.absmin, this.goalentity.absmax, this.absmin, this.absmax))
 761                 {
 762                         if(checkpvs(this.origin, this.goalentity))
 763                         {
 764                                 navigation_goalrating_timeout_expire(this, random());
 765                         }
 766                 }
 767         }
 768         if (this.goalcurrent == this.goalentity && this.goalentity_lock_timeout > time)
 769                 locked_goal = true;
 770
 771         if(!locked_goal)
 772         {
 773                 // optimize path finding by anticipating goalrating when bot is near a waypoint;
 774                 // in this case path finding can start directly from a waypoint instead of
 775                 // looking for all the reachable waypoints up to a certain distance
 776                 if(navigation_poptouchedgoals(this) && this.goalcurrent)
 777                 {
 778                         if(navigation_goalrating_timeout_can_be_anticipated(this))
 779                                 navigation_goalrating_timeout_force(this);
 780                 }
 781         }
 782
 783         // if ran out of goals try to use an alternative goal or get a new strategy asap
 784         if(this.goalcurrent == NULL)
 785         {
 786                 navigation_goalrating_timeout_force(this);
 787                 return;
 788         }
 789
 790
 791         if(autocvar_bot_debug_goalstack)
 792                 debuggoalstack(this);
 793
 794         bool bunnyhop_forbidden = false;
 795         vector destorg = get_closer_dest(this.goalcurrent, this.origin);
 796
 797         // in case bot ends up inside the teleport waypoint without touching
 798         // the teleport itself, head to the teleport origin
 799         if(this.goalcurrent.wpisbox && boxesoverlap(this.goalcurrent.absmin, this.goalcurrent.absmax, this.origin + eZ * this.mins.z, this.origin + eZ * this.maxs.z))
 800         {
 801                 bunnyhop_forbidden = true;
 802                 destorg = this.goalcurrent.origin;
 803                 if(destorg.z > this.origin.z)
 804                         PHYS_INPUT_BUTTON_JUMP(this) = true;
 805         }
 806
 807         diff = destorg - this.origin;
 808
 809         if (fabs(diff.x) < 10 && fabs(diff.y) < 10
 810                 && this.goalcurrent == this.goalentity && time < this.goalentity_lock_timeout)
 811         {
 812                 destorg = this.origin;
 813                 diff.x = 0;
 814                 diff.y = 0;
 815         }
 816
 817         dir = normalize(diff);
 818         flatdir = diff;flatdir.z = 0;
 819         flatdir = normalize(flatdir);
 820         gco = (this.goalcurrent.absmin + this.goalcurrent.absmax) * 0.5;
 821
 822         //if (this.bot_dodgevector_time < time)
 823         {
 824                 //this.bot_dodgevector_time = time + cvar("bot_ai_dodgeupdateinterval");
 825                 //this.bot_dodgevector_jumpbutton = 1;
 826                 evadeobstacle = '0 0 0';
 827                 evadelava = '0 0 0';
 828
 829                 this.aistatus &= ~AI_STATUS_DANGER_AHEAD;
 830                 makevectors(this.v_angle.y * '0 1 0');
 831                 if (this.waterlevel)
 832                 {
 833                         if(this.waterlevel>WATERLEVEL_SWIMMING)
 834                         {
 835                                 if(!this.goalcurrent)
 836                                         this.aistatus |= AI_STATUS_OUT_WATER;
 837                                 else if(gco.z > this.origin.z)
 838                                         PHYS_INPUT_BUTTON_JUMP(this) = true;
 839                         }
 840                         else
 841                         {
 842                                 dir = flatdir;
 843                                 if(this.velocity.z >= 0 && !(this.watertype == CONTENT_WATER && gco.z < this.origin.z) &&
 844                                         ( !(this.waterlevel == WATERLEVEL_WETFEET && this.watertype == CONTENT_WATER) || this.aistatus & AI_STATUS_OUT_WATER))
 845                                         PHYS_INPUT_BUTTON_JUMP(this) = true;
 846                                 else
 847                                         PHYS_INPUT_BUTTON_JUMP(this) = false;
 848                         }
 849                 }
 850                 else
 851                 {
 852                         float s;
 853                         vector offset;
 854                         if(this.aistatus & AI_STATUS_OUT_WATER)
 855                                 this.aistatus &= ~AI_STATUS_OUT_WATER;
 856
 857                         // jump if going toward an obstacle that doesn't look like stairs we
 858                         // can walk up directly
 859                         offset = (vdist(this.velocity, >, 32) ? this.velocity * 0.2 : v_forward * 32);
 860                         tracebox(this.origin, this.mins, this.maxs, this.origin + offset, false, this);
 861                         if (trace_fraction < 1)
 862                         if (trace_plane_normal.z < 0.7)
 863                         {
 864                                 s = trace_fraction;
 865                                 tracebox(this.origin + stepheightvec, this.mins, this.maxs, this.origin + offset + stepheightvec, false, this);
 866                                 if (trace_fraction < s + 0.01)
 867                                 if (trace_plane_normal.z < 0.7)
 868                                 {
 869                                         s = trace_fraction;
 870                                         tracebox(this.origin + jumpstepheightvec, this.mins, this.maxs, this.origin + offset + jumpstepheightvec, false, this);
 871                                         if (trace_fraction > s)
 872                                                 PHYS_INPUT_BUTTON_JUMP(this) = true;
 873                                 }
 874                         }
 875
 876                         // if bot for some reason doesn't get close to the current goal find another one
 877                         if(!this.jumppadcount && !IS_PLAYER(this.goalcurrent))
 878                         if(!(locked_goal && this.goalcurrent_distance_z < 50 && this.goalcurrent_distance_2d < 50))
 879                         if(havocbot_checkgoaldistance(this, gco))
 880                         {
 881                                 if(this.goalcurrent_distance_time < 0) // can't get close for the second time
 882                                 {
 883                                         navigation_clearroute(this);
 884                                         navigation_goalrating_timeout_force(this);
 885                                         return;
 886                                 }
 887
 888                                 set_tracewalk_dest(this.goalcurrent, this.origin, false);
 889                                 if (!tracewalk(this, this.origin, this.mins, this.maxs,
 890                                         tracewalk_dest, tracewalk_dest_height, bot_navigation_movemode))
 891                                 {
 892                                         navigation_clearroute(this);
 893                                         navigation_goalrating_timeout_force(this);
 894                                         return;
 895                                 }
 896
 897                                 // give bot only another chance to prevent bot getting stuck
 898                                 // in case it thinks it can walk but actually can't
 899                                 this.goalcurrent_distance_z = FLOAT_MAX;
 900                                 this.goalcurrent_distance_2d = FLOAT_MAX;
 901                                 this.goalcurrent_distance_time = -time; // mark second try
 902                         }
 903
 904                         // Check for water/slime/lava and dangerous edges
 905                         // (only when the bot is on the ground or jumping intentionally)
 906
 907                         vector dst_ahead = this.origin + this.view_ofs + offset;
 908                         vector dst_down = dst_ahead - '0 0 3000';
 909                         traceline(this.origin + this.view_ofs, dst_ahead, true, NULL);
 910
 911                         bool unreachable = false;
 912                         s = CONTENT_SOLID;
 913                         if(trace_fraction == 1 && this.jumppadcount == 0 && !this.goalcurrent.wphardwired )
 914                         if((IS_ONGROUND(this)) || (this.aistatus & AI_STATUS_RUNNING) || (this.aistatus & AI_STATUS_ROAMING) || PHYS_INPUT_BUTTON_JUMP(this))
 915                         {
 916                                 // Look downwards
 917                                 traceline(dst_ahead , dst_down, true, NULL);
 918                                 //te_lightning2(NULL, this.origin + this.view_ofs, dst_ahead); // Draw "ahead" look
 919                                 //te_lightning2(NULL, dst_ahead, dst_down); // Draw "downwards" look
 920                                 if(trace_endpos.z < this.origin.z + this.mins.z)
 921                                 {
 922                                         s = pointcontents(trace_endpos + '0 0 1');
 923                                         if (s != CONTENT_SOLID)
 924                                         if (s == CONTENT_LAVA || s == CONTENT_SLIME)
 925                                                 evadelava = normalize(this.velocity) * -1;
 926                                         else if (s == CONTENT_SKY)
 927                                                 evadeobstacle = normalize(this.velocity) * -1;
 928                                         else if (tracebox_hits_trigger_hurt(dst_ahead, this.mins, this.maxs, trace_endpos))
 929                                         {
 930                                                 // the traceline check isn't enough but is good as optimization,
 931                                                 // when not true (most of the time) this tracebox call is avoided
 932                                                 tracebox(dst_ahead, this.mins, this.maxs, dst_down, true, this);
 933                                                 if (tracebox_hits_trigger_hurt(dst_ahead, this.mins, this.maxs, trace_endpos))
 934                                                 {
 935                                                         if (gco.z > this.origin.z + jumpstepheightvec.z)
 936                                                         {
 937                                                                 // the goal is probably on an upper platform, assume bot can't get there
 938                                                                 unreachable = true;
 939                                                         }
 940                                                         else
 941                                                                 evadelava = normalize(this.velocity) * -1;
 942                                                 }
 943                                         }
 944                                 }
 945                         }
 946
 947                         dir = flatdir;
 948                         evadeobstacle.z = 0;
 949                         evadelava.z = 0;
 950                         makevectors(this.v_angle.y * '0 1 0');
 951
 952                         if(evadeobstacle || evadelava || (s == CONTENT_WATER))
 953                         {
 954                                 this.aistatus |= AI_STATUS_DANGER_AHEAD;
 955                                 if(IS_PLAYER(this.goalcurrent))
 956                                         unreachable = true;
 957                         }
 958                         if(unreachable)
 959                         {
 960                                 navigation_clearroute(this);
 961                                 navigation_goalrating_timeout_force(this);
 962                         }
 963                 }
 964
 965                 dodge = havocbot_dodge(this);
 966                 dodge = dodge * bound(0,0.5+(skill+this.bot_dodgeskill)*0.1,1);
 967                 evadelava = evadelava * bound(1,3-(skill+this.bot_dodgeskill),3); //Noobs fear lava a lot and take more distance from it
 968                 traceline(this.origin, ( ( this.enemy.absmin + this.enemy.absmax ) * 0.5 ), true, NULL);
 969                 if(IS_PLAYER(trace_ent))
 970                         dir = dir * bound(0,(skill+this.bot_dodgeskill)/7,1);
 971
 972                 dir = normalize(dir + dodge + evadeobstacle + evadelava);
 973         //      this.bot_dodgevector = dir;
 974         //      this.bot_dodgevector_jumpbutton = PHYS_INPUT_BUTTON_JUMP(this);
 975         }
 976
 977         if(time < this.ladder_time)
 978         {
 979                 if(this.goalcurrent.origin.z + this.goalcurrent.mins.z > this.origin.z + this.mins.z)
 980                 {
 981                         if(this.origin.z + this.mins.z  < this.ladder_entity.origin.z + this.ladder_entity.maxs.z)
 982                                 dir.z = 1;
 983                 }
 984                 else
 985                 {
 986                         if(this.origin.z + this.mins.z  > this.ladder_entity.origin.z + this.ladder_entity.mins.z)
 987                                 dir.z = -1;
 988                 }
 989         }
 990
 991         //dir = this.bot_dodgevector;
 992         //if (this.bot_dodgevector_jumpbutton)
 993         //      PHYS_INPUT_BUTTON_JUMP(this) = true;
 994         CS(this).movement_x = dir * v_forward * maxspeed;
 995         CS(this).movement_y = dir * v_right * maxspeed;
 996         CS(this).movement_z = dir * v_up * maxspeed;
 997
 998         // Emulate keyboard interface
 999         if (skill < 10)
1000                 havocbot_keyboard_movement(this, destorg);
1001
1002         // Bunnyhop!
1003         //if(this.aistatus & AI_STATUS_ROAMING)
1004         if(!bunnyhop_forbidden && this.goalcurrent)
1005         if(skill+this.bot_moveskill >= autocvar_bot_ai_bunnyhop_skilloffset)
1006                 havocbot_bunnyhop(this, dir);
1007
1008         if ((dir * v_up) >= autocvar_sv_jumpvelocity*0.5 && (IS_ONGROUND(this))) PHYS_INPUT_BUTTON_JUMP(this) = true;
1009         if (((dodge * v_up) > 0) && random()*frametime >= 0.2*bound(0,(10-skill-this.bot_dodgeskill)*0.1,1)) PHYS_INPUT_BUTTON_JUMP(this) = true;
1010         if (((dodge * v_up) < 0) && random()*frametime >= 0.5*bound(0,(10-skill-this.bot_dodgeskill)*0.1,1)) this.havocbot_ducktime=time+0.3/bound(0.1,skill+this.bot_dodgeskill,10);
1011 }
1012
1013 entity havocbot_gettarget(entity this, bool secondary)
1014 {
1015         entity best = NULL;
1016         vector eye = CENTER_OR_VIEWOFS(this);
1017         IL_EACH(g_bot_targets, boolean((secondary) ? it.classname == "misc_breakablemodel" : it.classname != "misc_breakablemodel"),
1018         {
1019                 vector v = CENTER_OR_VIEWOFS(it);
1020                 if(vdist(v - eye, <, autocvar_bot_ai_enemydetectionradius))
1021                 if(!best || vlen2(CENTER_OR_VIEWOFS(best) - eye) > vlen2(v - eye))
1022                 if(bot_shouldattack(this, it))
1023                 {
1024                         traceline(eye, v, true, this);
1025                         if (trace_ent == it || trace_fraction >= 1)
1026                                 best = it;
1027                 }
1028         });
1029
1030         return best;
1031 }
1032
1033 void havocbot_chooseenemy(entity this)
1034 {
1035         if (autocvar_bot_nofire || IS_INDEPENDENT_PLAYER(this))
1036         {
1037                 this.enemy = NULL;
1038                 return;
1039         }
1040         if (this.enemy)
1041         {
1042                 if (!bot_shouldattack(this, this.enemy))
1043                 {
1044                         // enemy died or something, find a new target
1045                         this.enemy = NULL;
1046                         this.havocbot_chooseenemy_finished = time;
1047                 }
1048                 else if (this.havocbot_stickenemy)
1049                 {
1050                         // tracking last chosen enemy
1051                         // if enemy is visible
1052                         // and not really really far away
1053                         // and we're not severely injured
1054                         // then keep tracking for a half second into the future
1055                         traceline(this.origin+this.view_ofs, ( this.enemy.absmin + this.enemy.absmax ) * 0.5,false,NULL);
1056                         if (trace_ent == this.enemy || trace_fraction == 1)
1057                         if (vdist(((this.enemy.absmin + this.enemy.absmax) * 0.5) - this.origin, <, 1000))
1058                         if (this.health > 30)
1059                         {
1060                                 // remain tracking him for a shot while (case he went after a small corner or pilar
1061                                 this.havocbot_chooseenemy_finished = time + 0.5;
1062                                 return;
1063                         }
1064                         // enemy isn't visible, or is far away, or we're injured severely
1065                         // so stop preferring this enemy
1066                         // (it will still take a half second until a new one is chosen)
1067                         this.havocbot_stickenemy = 0;
1068                 }
1069         }
1070         if (time < this.havocbot_chooseenemy_finished)
1071                 return;
1072         this.havocbot_chooseenemy_finished = time + autocvar_bot_ai_enemydetectioninterval;
1073         vector eye = this.origin + this.view_ofs;
1074         entity best = NULL;
1075         float bestrating = 100000000;
1076
1077         // Backup hit flags
1078         int hf = this.dphitcontentsmask;
1079
1080         // Search for enemies, if no enemy can be seen directly try to look through transparent objects
1081
1082         this.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
1083
1084         bool scan_transparent = false;
1085         bool scan_secondary_targets = false;
1086         bool have_secondary_targets = false;
1087         while(true)
1088         {
1089                 scan_secondary_targets = false;
1090 LABEL(scan_targets)
1091                 IL_EACH(g_bot_targets, it.bot_attack,
1092                 {
1093                         if(!scan_secondary_targets)
1094                         {
1095                                 if(it.classname == "misc_breakablemodel")
1096                                 {
1097                                         have_secondary_targets = true;
1098                                         continue;
1099                                 }
1100                         }
1101                         else if(it.classname != "misc_breakablemodel")
1102                                 continue;
1103
1104                         vector v = (it.absmin + it.absmax) * 0.5;
1105                         float rating = vlen2(v - eye);
1106                         if (vdist(v - eye, <, autocvar_bot_ai_enemydetectionradius))
1107                         if (bestrating > rating)
1108                         if (bot_shouldattack(this, it))
1109                         {
1110                                 traceline(eye, v, true, this);
1111                                 if (trace_ent == it || trace_fraction >= 1)
1112                                 {
1113                                         best = it;
1114                                         bestrating = rating;
1115                                 }
1116                         }
1117                 });
1118
1119                 if(!best && have_secondary_targets && !scan_secondary_targets)
1120                 {
1121                         scan_secondary_targets = true;
1122                         // restart the loop
1123                         bestrating = 100000000;
1124                         goto scan_targets;
1125                 }
1126
1127                 // I want to do a second scan if no enemy was found or I don't have weapons
1128                 // TODO: Perform the scan when using the rifle (requires changes on the rifle code)
1129                 if(best || this.weapons) // || this.weapon == WEP_RIFLE.m_id
1130                         break;
1131                 if(scan_transparent)
1132                         break;
1133
1134                 // Set flags to see through transparent objects
1135                 this.dphitcontentsmask |= DPCONTENTS_OPAQUE;
1136
1137                 scan_transparent = true;
1138         }
1139
1140         // Restore hit flags
1141         this.dphitcontentsmask = hf;
1142
1143         this.enemy = best;
1144         this.havocbot_stickenemy = true;
1145         if(best && best.classname == "misc_breakablemodel")
1146                 this.havocbot_stickenemy = false;
1147 }
1148
1149 float havocbot_chooseweapon_checkreload(entity this, .entity weaponentity, int new_weapon)
1150 {
1151         // bots under this skill cannot find unloaded weapons to reload idly when not in combat,
1152         // so skip this for them, or they'll never get to reload their weapons at all.
1153         // this also allows bots under this skill to be more stupid, and reload more often during combat :)
1154         if(skill < 5)
1155                 return false;
1156
1157         // if this weapon is scheduled for reloading, don't switch to it during combat
1158         if (this.(weaponentity).weapon_load[new_weapon] < 0)
1159         {
1160                 FOREACH(Weapons, it != WEP_Null, {
1161                         if(it.wr_checkammo1(it, this, weaponentity) + it.wr_checkammo2(it, this, weaponentity))
1162                                 return true; // other weapon available
1163                 });
1164         }
1165
1166         return false;
1167 }
1168
1169 void havocbot_chooseweapon(entity this, .entity weaponentity)
1170 {
1171         int i;
1172
1173         // ;)
1174         if(g_weaponarena_weapons == WEPSET(TUBA))
1175         {
1176                 this.(weaponentity).m_switchweapon = WEP_TUBA;
1177                 return;
1178         }
1179
1180         // TODO: clean this up by moving it to weapon code
1181         if(this.enemy==NULL)
1182         {
1183                 // If no weapon was chosen get the first available weapon
1184                 if(this.(weaponentity).m_weapon==WEP_Null)
1185                 FOREACH(Weapons, it != WEP_Null, {
1186                         if(client_hasweapon(this, it, weaponentity, true, false))
1187                         {
1188                                 this.(weaponentity).m_switchweapon = it;
1189                                 return;
1190                         }
1191                 });
1192                 return;
1193         }
1194
1195         // Do not change weapon during the next second after a combo
1196         float f = time - this.lastcombotime;
1197         if(f < 1)
1198                 return;
1199
1200         float w;
1201         float distance; distance=bound(10,vlen(this.origin-this.enemy.origin)-200,10000);
1202
1203         // Should it do a weapon combo?
1204         float af, ct, combo_time, combo;
1205
1206         af = ATTACK_FINISHED(this, 0);
1207         ct = autocvar_bot_ai_weapon_combo_threshold;
1208
1209         // Bots with no skill will be 4 times more slower than "godlike" bots when doing weapon combos
1210         // Ideally this 4 should be calculated as longest_weapon_refire / bot_ai_weapon_combo_threshold
1211         combo_time = time + ct + (ct * ((-0.3*(skill+this.bot_weaponskill))+3));
1212
1213         combo = false;
1214
1215         if(autocvar_bot_ai_weapon_combo)
1216         if(this.(weaponentity).m_weapon.m_id == this.(weaponentity).lastfiredweapon)
1217         if(af > combo_time)
1218         {
1219                 combo = true;
1220                 this.lastcombotime = time;
1221         }
1222
1223         distance *= (2 ** this.bot_rangepreference);
1224
1225         // Custom weapon list based on distance to the enemy
1226         if(bot_custom_weapon){
1227
1228                 // Choose weapons for far distance
1229                 if ( distance > bot_distance_far ) {
1230                         for(i=0; i < Weapons_COUNT && bot_weapons_far[i] != -1 ; ++i){
1231                                 w = bot_weapons_far[i];
1232                                 if ( client_hasweapon(this, Weapons_from(w), weaponentity, true, false) )
1233                                 {
1234                                         if ((this.(weaponentity).m_weapon.m_id == w && combo) || havocbot_chooseweapon_checkreload(this, weaponentity, w))
1235                                                 continue;
1236                                         this.(weaponentity).m_switchweapon = Weapons_from(w);
1237                                         return;
1238                                 }
1239                         }
1240                 }
1241
1242                 // Choose weapons for mid distance
1243                 if ( distance > bot_distance_close) {
1244                         for(i=0; i < Weapons_COUNT && bot_weapons_mid[i] != -1 ; ++i){
1245                                 w = bot_weapons_mid[i];
1246                                 if ( client_hasweapon(this, Weapons_from(w), weaponentity, true, false) )
1247                                 {
1248                                         if ((this.(weaponentity).m_weapon.m_id == w && combo) || havocbot_chooseweapon_checkreload(this, weaponentity, w))
1249                                                 continue;
1250                                         this.(weaponentity).m_switchweapon = Weapons_from(w);
1251                                         return;
1252                                 }
1253                         }
1254                 }
1255
1256                 // Choose weapons for close distance
1257                 for(i=0; i < Weapons_COUNT && bot_weapons_close[i] != -1 ; ++i){
1258                         w = bot_weapons_close[i];
1259                         if ( client_hasweapon(this, Weapons_from(w), weaponentity, true, false) )
1260                         {
1261                                 if ((this.(weaponentity).m_weapon.m_id == w && combo) || havocbot_chooseweapon_checkreload(this, weaponentity, w))
1262                                         continue;
1263                                 this.(weaponentity).m_switchweapon = Weapons_from(w);
1264                                 return;
1265                         }
1266                 }
1267         }
1268 }
1269
1270 void havocbot_aim(entity this)
1271 {
1272         if (time < this.nextaim)
1273                 return;
1274         this.nextaim = time + 0.1;
1275         vector myvel = this.velocity;
1276         if (!this.waterlevel)
1277                 myvel.z = 0;
1278         if(MUTATOR_CALLHOOK(HavocBot_Aim, this)) { /* do nothing */ }
1279         else if (this.enemy)
1280         {
1281                 vector enemyvel = this.enemy.velocity;
1282                 if (!this.enemy.waterlevel)
1283                         enemyvel.z = 0;
1284                 lag_additem(this, time + CS(this).ping, 0, 0, this.enemy, this.origin, myvel, (this.enemy.absmin + this.enemy.absmax) * 0.5, enemyvel);
1285         }
1286         else
1287                 lag_additem(this, time + CS(this).ping, 0, 0, NULL, this.origin, myvel, ( this.goalcurrent.absmin + this.goalcurrent.absmax ) * 0.5, '0 0 0');
1288 }
1289
1290 bool havocbot_moveto_refresh_route(entity this)
1291 {
1292         // Refresh path to goal if necessary
1293         entity wp;
1294         wp = this.havocbot_personal_waypoint;
1295         navigation_goalrating_start(this);
1296         navigation_routerating(this, wp, 10000, 10000);
1297         navigation_goalrating_end(this);
1298         return (this.goalentity != NULL);
1299 }
1300
1301 float havocbot_moveto(entity this, vector pos)
1302 {
1303         entity wp;
1304
1305         if(this.aistatus & AI_STATUS_WAYPOINT_PERSONAL_GOING)
1306         {
1307                 // Step 4: Move to waypoint
1308                 if(this.havocbot_personal_waypoint==NULL)
1309                 {
1310                         LOG_TRACE("Error: ", this.netname, " trying to walk to a non existent personal waypoint");
1311                         this.aistatus &= ~AI_STATUS_WAYPOINT_PERSONAL_GOING;
1312                         return CMD_STATUS_ERROR;
1313                 }
1314
1315                 if (!bot_strategytoken_taken)
1316                 if(this.havocbot_personal_waypoint_searchtime<time)
1317                 {
1318                         bot_strategytoken_taken = true;
1319                         if(havocbot_moveto_refresh_route(this))
1320                         {
1321                                 LOG_TRACE(this.netname, " walking to its personal waypoint (after ", ftos(this.havocbot_personal_waypoint_failcounter), " failed attempts)");
1322                                 this.havocbot_personal_waypoint_searchtime = time + 10;
1323                                 this.havocbot_personal_waypoint_failcounter = 0;
1324                         }
1325                         else
1326                         {
1327                                 this.havocbot_personal_waypoint_failcounter += 1;
1328                                 this.havocbot_personal_waypoint_searchtime = time + 2;
1329                                 if(this.havocbot_personal_waypoint_failcounter >= 30)
1330                                 {
1331                                         LOG_TRACE("Warning: can't walk to the personal waypoint located at ", vtos(this.havocbot_personal_waypoint.origin));
1332                                         this.aistatus &= ~AI_STATUS_WAYPOINT_PERSONAL_LINKING;
1333                                         delete(this.havocbot_personal_waypoint);
1334                                         return CMD_STATUS_ERROR;
1335                                 }
1336                                 else
1337                                         LOG_TRACE(this.netname, " can't walk to its personal waypoint (after ", ftos(this.havocbot_personal_waypoint_failcounter), " failed attempts), trying later");
1338                         }
1339                 }
1340
1341                 if(autocvar_bot_debug_goalstack)
1342                         debuggoalstack(this);
1343
1344                 // Heading
1345                 vector dir = get_closer_dest(this.goalcurrent, this.origin);
1346                 dir = dir - (this.origin + this.view_ofs);
1347                 dir.z = 0;
1348                 bot_aimdir(this, dir, -1);
1349
1350                 // Go!
1351                 havocbot_movetogoal(this);
1352
1353                 if(this.aistatus & AI_STATUS_WAYPOINT_PERSONAL_REACHED)
1354                 {
1355                         // Step 5: Waypoint reached
1356                         LOG_TRACE(this.netname, "'s personal waypoint reached");
1357                         delete(this.havocbot_personal_waypoint);
1358                         this.aistatus &= ~AI_STATUS_WAYPOINT_PERSONAL_REACHED;
1359                         return CMD_STATUS_FINISHED;
1360                 }
1361
1362                 return CMD_STATUS_EXECUTING;
1363         }
1364
1365         // Step 2: Linking waypoint
1366         if(this.aistatus & AI_STATUS_WAYPOINT_PERSONAL_LINKING)
1367         {
1368                 // Wait until it is linked
1369                 if(!this.havocbot_personal_waypoint.wplinked)
1370                 {
1371                         LOG_TRACE(this.netname, " waiting for personal waypoint to be linked");
1372                         return CMD_STATUS_EXECUTING;
1373                 }
1374
1375                 this.havocbot_personal_waypoint_searchtime = time; // so we set the route next frame
1376                 this.aistatus &= ~AI_STATUS_WAYPOINT_PERSONAL_LINKING;
1377                 this.aistatus |= AI_STATUS_WAYPOINT_PERSONAL_GOING;
1378
1379                 // Step 3: Route to waypoint
1380                 LOG_TRACE(this.netname, " walking to its personal waypoint");
1381
1382                 return CMD_STATUS_EXECUTING;
1383         }
1384
1385         // Step 1: Spawning waypoint
1386         wp = waypoint_spawnpersonal(this, pos);
1387         if(wp==NULL)
1388         {
1389                 LOG_TRACE("Error: Can't spawn personal waypoint at ",vtos(pos));
1390                 return CMD_STATUS_ERROR;
1391         }
1392
1393         this.havocbot_personal_waypoint = wp;
1394         this.havocbot_personal_waypoint_failcounter = 0;
1395         this.aistatus |= AI_STATUS_WAYPOINT_PERSONAL_LINKING;
1396
1397         // if pos is inside a teleport, then let's mark it as teleport waypoint
1398         IL_EACH(g_teleporters, WarpZoneLib_BoxTouchesBrush(pos, pos, it, NULL),
1399         {
1400                 wp.wpflags |= WAYPOINTFLAG_TELEPORT;
1401                 this.lastteleporttime = 0;
1402         });
1403
1404 /*
1405         if(wp.wpflags & WAYPOINTFLAG_TELEPORT)
1406                 print("routing to a teleporter\n");
1407         else
1408                 print("routing to a non-teleporter\n");
1409 */
1410
1411         return CMD_STATUS_EXECUTING;
1412 }
1413
1414 float havocbot_resetgoal(entity this)
1415 {
1416         navigation_clearroute(this);
1417         return CMD_STATUS_FINISHED;
1418 }
1419
1420 void havocbot_setupbot(entity this)
1421 {
1422         this.bot_ai = havocbot_ai;
1423         this.cmd_moveto = havocbot_moveto;
1424         this.cmd_resetgoal = havocbot_resetgoal;
1425
1426         havocbot_chooserole(this);
1427 }
1428
1429 vector havocbot_dodge(entity this)
1430 {
1431         // LordHavoc: disabled because this is too expensive
1432         return '0 0 0';
1433 #if 0
1434         entity head;
1435         vector dodge, v, n;
1436         float danger, bestdanger, vl, d;
1437         dodge = '0 0 0';
1438         bestdanger = -20;
1439         // check for dangerous objects near bot or approaching bot
1440         head = findchainfloat(bot_dodge, true);
1441         while(head)
1442         {
1443                 if (head.owner != this)
1444                 {
1445                         vl = vlen(head.velocity);
1446                         if (vl > autocvar_sv_maxspeed * 0.3)
1447                         {
1448                                 n = normalize(head.velocity);
1449                                 v = this.origin - head.origin;
1450                                 d = v * n;
1451                                 if (d > (0 - head.bot_dodgerating))
1452                                 if (d < (vl * 0.2 + head.bot_dodgerating))
1453                                 {
1454                                         // calculate direction and distance from the flight path, by removing the forward axis
1455                                         v = v - (n * (v * n));
1456                                         danger = head.bot_dodgerating - vlen(v);
1457                                         if (bestdanger < danger)
1458                                         {
1459                                                 bestdanger = danger;
1460                                                 // dodge to the side of the object
1461                                                 dodge = normalize(v);
1462                                         }
1463                                 }
1464                         }
1465                         else
1466                         {
1467                                 danger = head.bot_dodgerating - vlen(head.origin - this.origin);
1468                                 if (bestdanger < danger)
1469                                 {
1470                                         bestdanger = danger;
1471                                         dodge = normalize(this.origin - head.origin);
1472                                 }
1473                         }
1474                 }
1475                 head = head.chain;
1476         }
1477         return dodge;
1478 #endif
1479 }