qcsrc/server/cheats.qc

   1 #include "cheats.qh"
   2
   3 #include "g_damage.qh"
   4 #include "race.qh"
   5 #include "../common/triggers/teleporters.qh"
   6
   7 #include "mutators/all.qh"
   8
   9 #include "weapons/tracing.qh"
  10
  11 #include "../common/constants.qh"
  12 #include "../common/deathtypes/all.qh"
  13 #include "../common/util.qh"
  14
  15 #include "../common/monsters/all.qh"
  16
  17 #include "../common/weapons/all.qh"
  18
  19 #include "../common/triggers/subs.qh"
  20
  21 #include "../common/triggers/func/breakable.qh"
  22
  23 #include "../lib/csqcmodel/sv_model.qh"
  24
  25 #include "../lib/warpzone/anglestransform.qh"
  26 #include "../lib/warpzone/util_server.qh"
  27
  28 void CopyBody(float keepvelocity);
  29
  30 #ifdef NOCHEATS
  31
  32 float CheatImpulse(int imp) { return 0; }
  33 float CheatCommand(float argc) { return 0; }
  34 float CheatFrame() { return 0; }
  35 void CheatInit() { cheatcount_total = world.cheatcount; }
  36 void CheatShutdown() { }
  37 void CheatShutdownClient() { }
  38 void Drag_MoveDrag(entity from, entity to) { }
  39
  40 #else
  41
  42 .float maycheat;
  43 float gamestart_sv_cheats;
  44
  45
  46
  47 void CheatInit()
  48 {
  49         gamestart_sv_cheats = autocvar_sv_cheats;
  50 }
  51
  52 void CheatShutdown()
  53 {
  54 }
  55
  56 void CheatShutdownClient()
  57 {
  58 }
  59
  60 float CheatsAllowed(float i, float argc, float fr) // the cheat gets passed as argument for possible future ACL checking
  61 {SELFPARAM();
  62         // dead people cannot cheat
  63         if(IS_DEAD(self))
  64                 return 0;
  65         if(gamestart_sv_cheats < 2 && !IS_PLAYER(self))
  66                 return 0;
  67
  68         // sv_clones
  69         if(i == CHIMPULSE_CLONE_MOVING.impulse || i == CHIMPULSE_CLONE_STANDING.impulse)
  70                 if(self.lip < sv_clones)
  71                         return 1;
  72
  73         // haha
  74         if(self.maycheat)
  75                 return 1;
  76
  77         // sv_cheats
  78         if(gamestart_sv_cheats && autocvar_sv_cheats)
  79                 return 1;
  80
  81         // if we get here, player is not allowed to cheat. Log it.
  82         if(i)
  83                 bprintf("Player %s^7 tried to use cheat 'impulse %d'\n", self.netname, i);
  84         else if(argc)
  85                 bprintf("Player %s^7 tried to use cheat '%s'\n", self.netname, argv(0));
  86         else if(fr)
  87                 bprintf("Player %s^7 tried to use cheat frame %d\n", self.netname, fr);
  88         else
  89                 bprintf("Player %s^7 tried to use an unknown cheat\n", self.netname);
  90
  91         return 0;
  92 }
  93
  94 #define BEGIN_CHEAT_FUNCTION() \
  95         float cheating, attempting; \
  96         cheating = 0; attempting = 0
  97 #define DID_CHEAT() \
  98         ++cheating
  99 #define ADD_CHEATS(e,n) \
 100         cheatcount_total += n; \
 101         e.cheatcount += n
 102 #define END_CHEAT_FUNCTION() \
 103         ADD_CHEATS(self,cheating); \
 104         return attempting
 105 #define IS_CHEAT(i,argc,fr) \
 106         if((++attempting, !CheatsAllowed(i,argc,fr))) \
 107                 break
 108
 109 float num_autoscreenshot;
 110 void info_autoscreenshot_findtarget()
 111 {SELFPARAM();
 112         entity e;
 113         e = find(world, targetname, self.target);
 114         if(!e)
 115         {
 116                 objerror("Missing target. FAIL!");
 117                 return;
 118         }
 119         vector a = vectoangles(e.origin - self.origin);
 120         a.x = -a.x; // don't ask
 121         self.angles_x = a.x;
 122         self.angles_y = a.y;
 123         // we leave Rick Roll alone
 124 }
 125 spawnfunc(info_autoscreenshot)
 126 {
 127         if(++num_autoscreenshot > autocvar_g_max_info_autoscreenshot)
 128         {
 129                 objerror("Too many info_autoscreenshot entitites. FAIL!");
 130                 return;
 131         }
 132         if(self.target != "")
 133                 InitializeEntity(self, info_autoscreenshot_findtarget, INITPRIO_FINDTARGET);
 134         // this one just has to exist
 135 }
 136
 137 float CheatImpulse(int imp)
 138 {SELFPARAM();
 139         BEGIN_CHEAT_FUNCTION();
 140         switch(imp)
 141         {
 142                 entity e, e2;
 143
 144                 case CHIMPULSE_SPEEDRUN_INIT.impulse: // deploy personal waypoint
 145                         // shared with regular waypoint init, so this is not a cheat by itself
 146                         if(!self.personal)
 147                         {
 148                                 self.personal = new(personal_wp);
 149                         }
 150                         self.personal.origin = self.origin;
 151                         self.personal.v_angle = self.v_angle;
 152                         self.personal.velocity = self.velocity;
 153                         self.personal.ammo_rockets = self.ammo_rockets;
 154                         self.personal.ammo_nails = self.ammo_nails;
 155                         self.personal.ammo_cells = self.ammo_cells;
 156                         self.personal.ammo_plasma = self.ammo_plasma;
 157                         self.personal.ammo_shells = self.ammo_shells;
 158                         self.personal.ammo_fuel = self.ammo_fuel;
 159                         self.personal.health = self.health;
 160                         self.personal.armorvalue = self.armorvalue;
 161                         self.personal.weapons = self.weapons;
 162                         self.personal.items = self.items;
 163                         self.personal.pauserotarmor_finished = self.pauserotarmor_finished;
 164                         self.personal.pauserothealth_finished = self.pauserothealth_finished;
 165                         self.personal.pauserotfuel_finished = self.pauserotfuel_finished;
 166                         self.personal.pauseregen_finished = self.pauseregen_finished;
 167                         self.personal.strength_finished = self.strength_finished;
 168                         self.personal.invincible_finished = self.invincible_finished;
 169                         self.personal.teleport_time = time;
 170                         break; // this part itself doesn't cheat, so let's not count this
 171                 case CHIMPULSE_CLONE_MOVING.impulse:
 172                         IS_CHEAT(imp, 0, 0);
 173                         makevectors (self.v_angle);
 174                         self.velocity = self.velocity + v_forward * 300;
 175                         CopyBody(1);
 176                         self.lip += 1;
 177                         self.velocity = self.velocity - v_forward * 300;
 178                         DID_CHEAT();
 179                         break;
 180                 case CHIMPULSE_CLONE_STANDING.impulse:
 181                         IS_CHEAT(imp, 0, 0);
 182                         CopyBody(0);
 183                         self.lip += 1;
 184                         DID_CHEAT();
 185                         break;
 186                 case CHIMPULSE_GIVE_ALL.impulse:
 187                         IS_CHEAT(imp, 0, 0);
 188                         CheatCommand(tokenize_console("give all"));
 189                         break; // already counted as cheat
 190                 case CHIMPULSE_SPEEDRUN.impulse:
 191                         IS_CHEAT(imp, 0, 0);
 192                         if(self.personal)
 193                         {
 194                                 self.speedrunning = true;
 195                                 tracebox(self.personal.origin, self.mins, self.maxs, self.personal.origin, MOVE_WORLDONLY, self);
 196                                 if(trace_startsolid)
 197                                 {
 198                                         sprint(self, "Cannot move there, cheater - only waypoints set using g_waypointsprite_personal work\n");
 199                                 }
 200                                 else
 201                                 {
 202                                         // Abort speedrun, teleport back
 203                                         setorigin(self, self.personal.origin);
 204                                         self.oldvelocity = self.velocity = self.personal.velocity;
 205                                         self.angles = self.personal.v_angle;
 206                                         self.fixangle = true;
 207
 208                                         MUTATOR_CALLHOOK(AbortSpeedrun, self);
 209                                 }
 210
 211                                 self.ammo_rockets = self.personal.ammo_rockets;
 212                                 self.ammo_nails = self.personal.ammo_nails;
 213                                 self.ammo_cells = self.personal.ammo_cells;
 214                                 self.ammo_plasma = self.personal.ammo_plasma;
 215                                 self.ammo_shells = self.personal.ammo_shells;
 216                                 self.ammo_fuel = self.personal.ammo_fuel;
 217                                 self.health = self.personal.health;
 218                                 self.armorvalue = self.personal.armorvalue;
 219                                 self.weapons = self.personal.weapons;
 220                                 self.items = self.personal.items;
 221                                 self.pauserotarmor_finished = time + self.personal.pauserotarmor_finished - self.personal.teleport_time;
 222                                 self.pauserothealth_finished = time + self.personal.pauserothealth_finished - self.personal.teleport_time;
 223                                 self.pauserotfuel_finished = time + self.personal.pauserotfuel_finished - self.personal.teleport_time;
 224                                 self.pauseregen_finished = time + self.personal.pauseregen_finished - self.personal.teleport_time;
 225                                 self.strength_finished = time + self.personal.strength_finished - self.personal.teleport_time;
 226                                 self.invincible_finished = time + self.personal.invincible_finished - self.personal.teleport_time;
 227
 228                                 DID_CHEAT();
 229                                 break;
 230                         }
 231                         if(IS_DEAD(self))
 232                                 sprint(self, "UR DEAD AHAHAH))\n");
 233                         else
 234                                 sprint(self, "No waypoint set, cheater (use g_waypointsprite_personal to set one)\n");
 235                         break;
 236                 case CHIMPULSE_TELEPORT.impulse:
 237                         IS_CHEAT(imp, 0, 0);
 238                         if(self.movetype == MOVETYPE_NOCLIP)
 239                         {
 240                                 e = find(world, classname, "info_autoscreenshot");
 241                                 if(e)
 242                                 {
 243                                         sprint(self, "Emergency teleport used info_autoscreenshot location\n");
 244                                         setorigin(self, e.origin);
 245                                         self.angles = e.angles;
 246                                         remove(e);
 247                                         // should we? self.angles_x = -self.angles_x;
 248                                         self.fixangle = true;
 249                                         self.velocity = '0 0 0';
 250                                         DID_CHEAT();
 251                                         break;
 252                                 }
 253                         }
 254                         if(MoveToRandomMapLocation(self, DPCONTENTS_SOLID | DPCONTENTS_CORPSE | DPCONTENTS_PLAYERCLIP, DPCONTENTS_SLIME | DPCONTENTS_LAVA | DPCONTENTS_SKY | DPCONTENTS_BODY | DPCONTENTS_DONOTENTER, Q3SURFACEFLAG_SKY, ((gamestart_sv_cheats < 2) ? 100 : 100000), 384, 384))
 255                         {
 256                                 sprint(self, "Emergency teleport used random location\n");
 257                                 self.angles_x = -self.angles.x;
 258                                 self.fixangle = true;
 259                                 self.velocity = '0 0 0';
 260                                 DID_CHEAT();
 261                                 break;
 262                         }
 263                         sprint(self, "Emergency teleport could not find a good location, forget it!\n");
 264                         break;
 265                 case CHIMPULSE_R00T.impulse:
 266                         IS_CHEAT(imp, 0, 0);
 267                         RandomSelection_Init();
 268                         FOREACH_CLIENT(IS_PLAYER(it) && !IS_DEAD(it) && DIFF_TEAM(it, self), LAMBDA(RandomSelection_Add(it, 0, string_null, 1, 1)));
 269                         if(RandomSelection_chosen_ent)
 270                                 e = RandomSelection_chosen_ent;
 271                         else
 272                                 e = self;
 273
 274                         Send_Effect(EFFECT_ROCKET_EXPLODE, e.origin, '0 0 0', 1);
 275                         sound(e, CH_SHOTS, SND_ROCKET_IMPACT, VOL_BASE, ATTEN_NORM);
 276
 277                         e2 = spawn();
 278                         setorigin(e2, e.origin);
 279                         RadiusDamage(e2, self, 1000, 0, 128, world, world, 500, DEATH_CHEAT.m_id, e);
 280                         remove(e2);
 281
 282                         LOG_INFO("404 Sportsmanship not found.\n");
 283                         DID_CHEAT();
 284                         break;
 285         }
 286
 287         END_CHEAT_FUNCTION();
 288 }
 289
 290 void DragBox_Think();
 291 float drag_lastcnt;
 292 float CheatCommand(float argc)
 293 {SELFPARAM();
 294         BEGIN_CHEAT_FUNCTION();
 295         string cmd;
 296         cmd = argv(0);
 297         switch(cmd)
 298         {
 299                 float effectnum, f;
 300                 vector start, end;
 301                 entity oldself;
 302
 303                 case "pointparticles":
 304                         IS_CHEAT(0, argc, 0);
 305                         if(argc == 5)
 306                         {
 307                                 // arguments:
 308                                 //   effectname
 309                                 //   origin (0..1, on crosshair line)
 310                                 //   velocity
 311                                 //   howmany
 312                                 f = stof(argv(2));
 313                                 crosshair_trace(self);
 314                                 start = (1-f) * self.origin + f * trace_endpos;
 315                                 end = stov(argv(3));
 316                                 f = stof(argv(4));
 317                                 Send_Effect_(argv(1), start, end, f);
 318                                 DID_CHEAT();
 319                                 break;
 320                         }
 321                         sprint(self, "Usage: sv_cheats 1; restart; cmd pointparticles effectname position(0..1) velocityvector multiplier\n");
 322                         break;
 323                 case "trailparticles":
 324                         IS_CHEAT(0, argc, 0);
 325                         if(argc == 2)
 326                         {
 327                                 // arguments:
 328                                 //   effectname
 329                                 effectnum = _particleeffectnum(argv(1));
 330                                 W_SetupShot(self, false, false, "", CH_WEAPON_A, 0);
 331                                 traceline(w_shotorg, w_shotorg + w_shotdir * MAX_SHOT_DISTANCE, MOVE_NORMAL, self);
 332                                 __trailparticles(self, effectnum, w_shotorg, trace_endpos);
 333                                 DID_CHEAT();
 334                                 break;
 335                         }
 336                         sprint(self, "Usage: sv_cheats 1; restart; cmd trailparticles effectname\n");
 337                         break;
 338                 case "make":
 339                         IS_CHEAT(0, argc, 0);
 340                         if(argc == 3)
 341                         {
 342                                 // arguments:
 343                                 //   modelname mode
 344                                 f = stof(argv(2));
 345                                 W_SetupShot(self, false, false, "", CH_WEAPON_A, 0);
 346                                 traceline(w_shotorg, w_shotorg + w_shotdir * 2048, MOVE_NORMAL, self);
 347                                 if((trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT) || trace_fraction == 1)
 348                                 {
 349                                         sprint(self, "cannot make stuff there (bad surface)\n");
 350                                 }
 351                                 else
 352                                 {
 353                                         entity e = spawn();
 354                                         e.model = strzone(argv(1));
 355                                         e.mdl = "rocket_explode";
 356                                         e.health = 1000;
 357                                         setorigin(e, trace_endpos);
 358                                         e.effects = EF_NOMODELFLAGS;
 359                                         if(f == 1)
 360                                         {
 361                                                 e.angles = fixedvectoangles2(trace_plane_normal, v_forward);
 362                                                 e.angles = AnglesTransform_ApplyToAngles(e.angles, '-90 0 0'); // so unrotated models work
 363                                         }
 364                                         WITH(entity, self, e, spawnfunc_func_breakable(e));
 365                                         // now, is it valid?
 366                                         if(f == 0)
 367                                         {
 368                                                 tracebox(e.origin, e.mins, e.maxs, e.origin, MOVE_NORMAL, e);
 369                                                 if(trace_startsolid)
 370                                                 {
 371                                                         remove(e);
 372                                                         sprint(self, "cannot make stuff there (no space)\n");
 373                                                 }
 374                                                 else
 375                                                         DID_CHEAT();
 376                                         }
 377                                         else
 378                                                 DID_CHEAT();
 379                                 }
 380                         }
 381                         else
 382                                 sprint(self, "Usage: sv_cheats 1; restart; cmd make models/... 0/1/2\n");
 383                         break;
 384                 case "penalty":
 385                         IS_CHEAT(0, argc, 0);
 386                         if(argc == 3)
 387                         {
 388                                 race_ImposePenaltyTime(self, stof(argv(1)), argv(2));
 389                                 DID_CHEAT();
 390                                 break;
 391                         }
 392                         sprint(self, "Usage: sv_cheats 1; restart; cmd penalty 5.0 AHAHAHAHAHAHAH))\n");
 393                         break;
 394                 case "dragbox_spawn": {
 395                         IS_CHEAT(0, argc, 0);
 396                         entity e = new(dragbox_box);
 397                         e.think = DragBox_Think;
 398                         e.nextthink = time;
 399                         e.solid = -1; // black
 400                         setmodel(e, MDL_Null); // network it
 401                         if(argc == 4)
 402                                 e.cnt = stof(argv(1));
 403                         else
 404                                 e.cnt = max(0, drag_lastcnt);
 405
 406                         e.aiment = new(dragbox_corner_1);
 407                         e.aiment.owner = e;
 408                         setmodel(e.aiment, MDL_MARKER);
 409                         e.aiment.skin = 0;
 410                         setsize(e.aiment, '0 0 0', '0 0 0');
 411                         if(argc == 4)
 412                                 setorigin(e.aiment, stov(argv(2)));
 413                         else
 414                         {
 415                                 crosshair_trace(self);
 416                                 setorigin(e.aiment, trace_endpos);
 417                         }
 418
 419                         e.enemy = new(dragbox_corner_2);
 420                         e.enemy.owner = e;
 421                         setmodel(e.enemy, MDL_MARKER);
 422                         e.enemy.skin = 1;
 423                         setsize(e.enemy, '0 0 0', '0 0 0');
 424                         end = normalize(self.origin + self.view_ofs - e.aiment.origin);
 425                         end.x = (end.x > 0) * 2 - 1;
 426                         end.y = (end.y > 0) * 2 - 1;
 427                         end.z = (end.z > 0) * 2 - 1;
 428                         if(argc == 4)
 429                                 setorigin(e.enemy, stov(argv(3)));
 430                         else
 431                                 setorigin(e.enemy, e.aiment.origin + 32 * end);
 432
 433                         e.killindicator = new(drag_digit);
 434                         e.killindicator.owner = e;
 435                         setattachment(e.killindicator, e, "");
 436                         setorigin(e.killindicator, '0 0 -8');
 437                         e.killindicator.killindicator = new(drag_digit);
 438                         e.killindicator.killindicator.owner = e;
 439                         setattachment(e.killindicator.killindicator, e, "");
 440                         setorigin(e.killindicator.killindicator, '0 0 8');
 441                         DID_CHEAT();
 442                         break;
 443                 }
 444                 case "dragpoint_spawn": {
 445                         IS_CHEAT(0, argc, 0);
 446                         entity e = new(dragpoint);
 447                         e.think = DragBox_Think;
 448                         e.nextthink = time;
 449                         e.solid = 0; // nothing special
 450                         setmodel(e, MDL_MARKER);
 451                         setsize(e, STAT(PL_MIN, NULL), STAT(PL_MAX, NULL));
 452                         e.skin = 2;
 453                         if(argc == 3)
 454                                 e.cnt = stof(argv(1));
 455                         else
 456                                 e.cnt = drag_lastcnt;
 457                         if(argc == 3)
 458                                 setorigin(e, stov(argv(2)));
 459                         else
 460                         {
 461                                 crosshair_trace(self);
 462                                 setorigin(e, trace_endpos + normalize(self.origin + self.view_ofs - trace_endpos));
 463                                 move_out_of_solid(e);
 464                         }
 465
 466                         e.killindicator = new(drag_digit);
 467                         e.killindicator.owner = e;
 468                         setattachment(e.killindicator, e, "");
 469                         setorigin(e.killindicator, '0 0 40');
 470                         e.killindicator.killindicator = new(drag_digit);
 471                         e.killindicator.killindicator.owner = e;
 472                         setattachment(e.killindicator.killindicator, e, "");
 473                         setorigin(e.killindicator.killindicator, '0 0 56');
 474                         DID_CHEAT();
 475                         break;
 476                 }
 477                 case "drag_remove":
 478                         IS_CHEAT(0, argc, 0);
 479                         RandomSelection_Init();
 480                         crosshair_trace(self);
 481                         for(entity e = world; (e = find(e, classname, "dragbox_box")); )
 482                                 RandomSelection_Add(e, 0, string_null, 1, 1 / vlen(e.origin + (e.mins + e.maxs) * 0.5 - trace_endpos));
 483                         for(entity e = world; (e = find(e, classname, "dragpoint")); )
 484                                 RandomSelection_Add(e, 0, string_null, 1, 1 / vlen(e.origin + (e.mins + e.maxs) * 0.5 - trace_endpos));
 485                         if(RandomSelection_chosen_ent)
 486                         {
 487                                 remove(RandomSelection_chosen_ent.killindicator.killindicator);
 488                                 remove(RandomSelection_chosen_ent.killindicator);
 489                                 if(RandomSelection_chosen_ent.aiment)
 490                                         remove(RandomSelection_chosen_ent.aiment);
 491                                 if(RandomSelection_chosen_ent.enemy)
 492                                         remove(RandomSelection_chosen_ent.enemy);
 493                                 remove(RandomSelection_chosen_ent);
 494                         }
 495                         DID_CHEAT();
 496                         break;
 497                 case "drag_setcnt":
 498                         IS_CHEAT(0, argc, 0);
 499                         if(argc == 2)
 500                         {
 501                                 RandomSelection_Init();
 502                                 crosshair_trace(self);
 503                                 for(entity e = world; (e = find(e, classname, "dragbox_box")); )
 504                                         RandomSelection_Add(e, 0, string_null, 1, 1 / vlen(e.origin + (e.mins + e.maxs) * 0.5 - trace_endpos));
 505                                 for(entity e = world; (e = find(e, classname, "dragpoint")); )
 506                                         RandomSelection_Add(e, 0, string_null, 1, 1 / vlen(e.origin + (e.mins + e.maxs) * 0.5 - trace_endpos));
 507                                 if(RandomSelection_chosen_ent)
 508                                 {
 509                                         if(substring(argv(1), 0, 1) == "*")
 510                                                 RandomSelection_chosen_ent.cnt = drag_lastcnt = RandomSelection_chosen_ent.cnt + stof(substring(argv(1), 1, -1));
 511                                         else
 512                                                 RandomSelection_chosen_ent.cnt = drag_lastcnt = stof(argv(1));
 513                                 }
 514                                 DID_CHEAT();
 515                                 break;
 516                         }
 517                         sprint(self, "Usage: sv_cheats 1; restart; cmd dragbox_setcnt cnt\n");
 518                         break;
 519                 case "drag_save":
 520                         IS_CHEAT(0, argc, 0);
 521                         if(argc == 2)
 522                         {
 523                                 f = fopen(argv(1), FILE_WRITE);
 524                                 fputs(f, "cmd drag_clear\n");
 525                                 for(entity e = world; (e = find(e, classname, "dragbox_box")); )
 526                                 {
 527                                         fputs(f, strcat("cmd dragbox_spawn ", ftos(e.cnt), " \"", vtos(e.aiment.origin), "\" \"", vtos(e.enemy.origin), "\"\n"));
 528                                 }
 529                                 for(entity e = world; (e = find(e, classname, "dragpoint")); )
 530                                 {
 531                                         fputs(f, strcat("cmd dragpoint_spawn ", ftos(e.cnt), " \"", vtos(e.origin), "\"\n"));
 532                                 }
 533                                 fclose(f);
 534                                 DID_CHEAT();
 535                                 break;
 536                         }
 537                         sprint(self, "Usage: sv_cheats 1; restart; cmd dragbox_save filename\n");
 538                         break;
 539                 case "drag_saveraceent":
 540                         IS_CHEAT(0, argc, 0);
 541                         if(argc == 2)
 542                         {
 543                                 f = fopen(argv(1), FILE_WRITE);
 544                                 for(entity e = world; (e = find(e, classname, "dragbox_box")); )
 545                                 {
 546                                         fputs(f, "{\n");
 547                                         fputs(f, "\"classname\" \"trigger_race_checkpoint\"\n");
 548                                         fputs(f, strcat("\"origin\" \"", ftos(e.absmin.x), " ", ftos(e.absmin.y), " ", ftos(e.absmin.z), "\"\n"));
 549                                         fputs(f, strcat("\"maxs\" \"", ftos(e.absmax.x - e.absmin.x), " ", ftos(e.absmax.y - e.absmin.y), " ", ftos(e.absmax.z - e.absmin.z), "\"\n"));
 550                                         fputs(f, strcat("\"cnt\" \"", ftos(e.cnt), "\"\n"));
 551                                         fputs(f, strcat("\"targetname\" \"checkpoint", ftos(e.cnt), "\"\n"));
 552                                         fputs(f, "}\n");
 553                                 }
 554                                 for(entity e = world; (e = find(e, classname, "dragpoint")); )
 555                                 {
 556                                         start = '0 0 0';
 557                                         effectnum = 0;
 558                                         for(oldself = world; (oldself = find(oldself, classname, "dragbox_box")); )
 559                                         {
 560                                                 if(e.cnt <= 0 && oldself.cnt == 0 || e.cnt == oldself.cnt)
 561                                                 {
 562                                                         start = start + oldself.origin;
 563                                                         ++effectnum;
 564                                                 }
 565                                         }
 566                                         start *= 1 / effectnum;
 567                                         fputs(f, "{\n");
 568                                         fputs(f, "\"classname\" \"info_player_race\"\n");
 569                                         fputs(f, strcat("\"angle\" \"", ftos(vectoyaw(start - e.origin)), "\"\n"));
 570                                         fputs(f, strcat("\"origin\" \"", ftos(e.origin.x), " ", ftos(e.origin.y), " ", ftos(e.origin.z), "\"\n"));
 571                                         if(e.cnt == -2)
 572                                         {
 573                                                 fputs(f, "\"target\" \"checkpoint0\"\n");
 574                                                 fputs(f, "\"race_place\" \"0\"\n");
 575                                         }
 576                                         else if(e.cnt == -1)
 577                                         {
 578                                                 fputs(f, "\"target\" \"checkpoint0\"\n");
 579                                                 fputs(f, "\"race_place\" \"-1\"\n");
 580                                         }
 581                                         else
 582                                         {
 583                                                 fputs(f, strcat("\"target\" \"checkpoint", ftos(e.cnt), "\"\n"));
 584                                                 if(e.cnt == 0)
 585                                                 {
 586                                                         // these need race_place
 587                                                         // counting...
 588                                                         effectnum = 1;
 589                                                         for(oldself = world; (oldself = find(oldself, classname, "dragpoint")); )
 590                                                         if(oldself.cnt == 0)
 591                                                         {
 592                                                                 if(vlen(oldself.origin - start) < vlen(e.origin - start))
 593                                                                         ++effectnum;
 594                                                                 else if(vlen(oldself.origin - start) == vlen(e.origin - start) && etof(oldself) < etof(e))
 595                                                                         ++effectnum;
 596                                                         }
 597                                                         fputs(f, strcat("\"race_place\" \"", ftos(effectnum), "\"\n"));
 598                                                 }
 599                                         }
 600                                         fputs(f, "}\n");
 601                                 }
 602                                 fclose(f);
 603                                 DID_CHEAT();
 604                                 break;
 605                         }
 606                         sprint(self, "Usage: sv_cheats 1; restart; cmd dragbox_save filename\n");
 607                         break;
 608                 case "drag_clear":
 609                         IS_CHEAT(0, argc, 0);
 610                         for(entity e = world; (e = find(e, classname, "dragbox_box")); )
 611                                 remove(e);
 612                         for(entity e = world; (e = find(e, classname, "dragbox_corner_1")); )
 613                                 remove(e);
 614                         for(entity e = world; (e = find(e, classname, "dragbox_corner_2")); )
 615                                 remove(e);
 616                         for(entity e = world; (e = find(e, classname, "dragpoint")); )
 617                                 remove(e);
 618                         for(entity e = world; (e = find(e, classname, "drag_digit")); )
 619                                 remove(e);
 620                         DID_CHEAT();
 621                         break;
 622                 case "god":
 623                         IS_CHEAT(0, argc, 0);
 624                         BITXOR_ASSIGN(self.flags, FL_GODMODE);
 625                         if(self.flags & FL_GODMODE)
 626                         {
 627                                 sprint(self, "godmode ON\n");
 628                                 DID_CHEAT();
 629                         }
 630                         else
 631                                 sprint(self, "godmode OFF\n");
 632                         break;
 633                 case "notarget":
 634                         IS_CHEAT(0, argc, 0);
 635                         BITXOR_ASSIGN(self.flags, FL_NOTARGET);
 636                         if(self.flags & FL_NOTARGET)
 637                         {
 638                                 sprint(self, "notarget ON\n");
 639                                 DID_CHEAT();
 640                         }
 641                         else
 642                                 sprint(self, "notarget OFF\n");
 643                         break;
 644                 case "noclip":
 645                         IS_CHEAT(0, argc, 0);
 646                         if(self.movetype != MOVETYPE_NOCLIP)
 647                         {
 648                                 self.movetype = MOVETYPE_NOCLIP;
 649                                 sprint(self, "noclip ON\n");
 650                                 DID_CHEAT();
 651                         }
 652                         else
 653                         {
 654                                 self.movetype = MOVETYPE_WALK;
 655                                 sprint(self, "noclip OFF\n");
 656                         }
 657                         break;
 658                 case "fly":
 659                         IS_CHEAT(0, argc, 0);
 660                         if(self.movetype != MOVETYPE_FLY)
 661                         {
 662                                 self.movetype = MOVETYPE_FLY;
 663                                 sprint(self, "flymode ON\n");
 664                                 DID_CHEAT();
 665                         }
 666                         else
 667                         {
 668                                 self.movetype = MOVETYPE_WALK;
 669                                 sprint(self, "flymode OFF\n");
 670                         }
 671                         break;
 672                 case "give":
 673                         IS_CHEAT(0, argc, 0);
 674                         if(GiveItems(self, 1, argc))
 675                                 DID_CHEAT();
 676                         break;
 677                 case "usetarget":
 678                         IS_CHEAT(0, argc, 0);
 679                         setself(spawn());
 680                         self.target = argv(1);
 681                         activator = this;
 682                         SUB_UseTargets();
 683                         remove(self);
 684                         setself(this);
 685                         DID_CHEAT();
 686                         break;
 687                 case "killtarget":
 688                         IS_CHEAT(0, argc, 0);
 689                         setself(spawn());
 690                         self.killtarget = argv(1);
 691                         activator = this;
 692                         SUB_UseTargets();
 693                         remove(self);
 694                         setself(this);
 695                         DID_CHEAT();
 696                         break;
 697                 case "teleporttotarget":
 698                         IS_CHEAT(0, argc, 0);
 699                         setself(new(cheattriggerteleport));
 700                         setorigin(self, self.origin);
 701                         self.target = argv(1);
 702                         teleport_findtarget();
 703                         if(!wasfreed(self))
 704                         {
 705                                 Simple_TeleportPlayer(self, this);
 706                                 remove(self);
 707                                 DID_CHEAT();
 708                         }
 709                         setself(this);
 710                         break;
 711         }
 712
 713         END_CHEAT_FUNCTION();
 714 }
 715
 716 float Drag(float force_allow_pick, float ischeat);
 717 void Drag_Begin(entity dragger, entity draggee, vector touchpoint);
 718 void Drag_Finish(entity dragger);
 719 float Drag_IsDraggable(entity draggee);
 720 float Drag_MayChangeAngles(entity draggee);
 721 void Drag_MoveForward(entity dragger);
 722 void Drag_SetSpeed(entity dragger, float s);
 723 void Drag_MoveBackward(entity dragger);
 724 void Drag_Update(entity dragger);
 725 float Drag_CanDrag(entity dragger);
 726 float Drag_IsDragging(entity dragger);
 727 void Drag_MoveDrag(entity from, entity to);
 728 .entity dragentity;
 729
 730 float CheatFrame()
 731 {SELFPARAM();
 732         BEGIN_CHEAT_FUNCTION();
 733
 734         // Dragging can be used as either a cheat, or a function for some objects. If sv_cheats is active,
 735         // the cheat dragging is used (unlimited pickup range and any entity can be carried). If sv_cheats
 736         // is disabled, normal dragging is used (limited pickup range and only dragable objects can be carried),
 737         // grabbing itself no longer being accounted as cheating.
 738
 739         switch(0)
 740         {
 741                 default:
 742                         if(self.maycheat || (gamestart_sv_cheats && autocvar_sv_cheats))
 743                         {
 744                                 // use cheat dragging if cheats are enabled
 745                                 crosshair_trace_plusvisibletriggers(self);
 746                                 Drag(true, true);
 747                         }
 748                         else
 749                         {
 750                                 Drag(false, false); // execute dragging
 751                         }
 752                         break;
 753         }
 754
 755         END_CHEAT_FUNCTION();
 756 }
 757
 758
 759
 760
 761
 762 // ENTITY DRAGGING
 763
 764 // on dragger:
 765 .float draggravity;
 766 .float dragspeed; // speed of mouse wheel action
 767 .float dragdistance; // distance of dragentity's draglocalvector from view_ofs
 768 .vector draglocalvector; // local attachment vector of the dragentity
 769 .float draglocalangle;
 770 // on draggee:
 771 .entity draggedby;
 772 .float dragmovetype;
 773
 774 float Drag(float force_allow_pick, float ischeat)
 775 {SELFPARAM();
 776         BEGIN_CHEAT_FUNCTION();
 777
 778         // returns true when an entity has been picked up
 779         // If pick is true, the object can also be picked up if it's not being held already
 780         // If pick is false, only keep dragging the object if it's already being held
 781
 782         switch(0)
 783         {
 784                 default:
 785                         if(Drag_IsDragging(self))
 786                         {
 787                                 if(self.BUTTON_DRAG)
 788                                 {
 789                                         if(self.impulse == 10 || self.impulse == 15 || self.impulse == 18)
 790                                         {
 791                                                 Drag_MoveForward(self);
 792                                                 self.impulse = 0;
 793                                         }
 794                                         else if(self.impulse == 12 || self.impulse == 16 || self.impulse == 19)
 795                                         {
 796                                                 Drag_MoveBackward(self);
 797                                                 self.impulse = 0;
 798                                         }
 799                                         else if(self.impulse >= 1 && self.impulse <= 9)
 800                                         {
 801                                                 Drag_SetSpeed(self, self.impulse - 1);
 802                                         }
 803                                         else if(self.impulse == 14)
 804                                         {
 805                                                 Drag_SetSpeed(self, 9);
 806                                         }
 807
 808                                         if(frametime)
 809                                                 Drag_Update(self);
 810                                 }
 811                                 else
 812                                 {
 813                                         Drag_Finish(self);
 814                                 }
 815                         }
 816                         else
 817                         {
 818                                 if(Drag_CanDrag(self))
 819                                         if(self.BUTTON_DRAG)
 820                                         {
 821                                                 crosshair_trace_plusvisibletriggers(self);
 822                                                 entity e = trace_ent;
 823                                                 float pick = force_allow_pick;
 824                                                 if (e && !pick)
 825                                                 {
 826                                                         // pick is true if the object can be picked up. While an object is being carried, the Drag() function
 827                                                         // must execute for it either way, otherwise it would cause bugs if it went out of the player's trace.
 828                                                         // This also makes sure that an object can only pe picked up if in range, but does not get dropped if
 829                                                         // it goes out of range while slinging it around.
 830
 831                                                         if(vlen(self.origin - e.origin) <= autocvar_g_grab_range)
 832                                                         {
 833                                                                 switch(e.grab)
 834                                                                 {
 835                                                                         case 0: // can't grab
 836                                                                                 break;
 837                                                                         case 1: // owner can grab
 838                                                                                 if(e.owner == self || e.realowner == self)
 839                                                                                         pick = true;
 840                                                                                 break;
 841                                                                         case 2: // owner and team mates can grab
 842                                                                                 if(SAME_TEAM(e.owner, self) || SAME_TEAM(e.realowner, self) || e.team == self.team)
 843                                                                                         pick = true;
 844                                                                                 break;
 845                                                                         case 3: // anyone can grab
 846                                                                                 pick = true;
 847                                                                                 break;
 848                                                                         default:
 849                                                                                 break;
 850                                                                 }
 851                                                         }
 852                                                 }
 853                                                 // Find e and pick
 854                                                 if(e && pick)
 855                                                         if(Drag_IsDraggable(e))
 856                                                         {
 857                                                                 if(ischeat)
 858                                                                         IS_CHEAT(0, 0, CHRAME_DRAG);
 859                                                                 if(e.draggedby)
 860                                                                         Drag_Finish(e.draggedby);
 861                                                                 if(e.tag_entity)
 862                                                                         detach_sameorigin(e);
 863                                                                 Drag_Begin(self, e, trace_endpos);
 864                                                                 if(ischeat)
 865                                                                         DID_CHEAT();
 866                                                                 return true;
 867                                                         }
 868                                         }
 869                         }
 870                         break;
 871         }
 872         return false;
 873 }
 874
 875 void Drag_Begin(entity dragger, entity draggee, vector touchpoint)
 876 {
 877         float tagscale;
 878
 879         draggee.dragmovetype = draggee.movetype;
 880         draggee.draggravity = draggee.gravity;
 881         draggee.movetype = MOVETYPE_WALK;
 882         draggee.gravity = 0.00001;
 883         UNSET_ONGROUND(draggee);
 884         draggee.draggedby = dragger;
 885
 886         dragger.dragentity = draggee;
 887
 888         dragger.dragdistance = vlen(touchpoint - dragger.origin - dragger.view_ofs);
 889         dragger.draglocalangle = draggee.angles.y - dragger.v_angle.y;
 890         touchpoint = touchpoint - gettaginfo(draggee, 0);
 891         tagscale = pow(vlen(v_forward), -2);
 892         dragger.draglocalvector_x = touchpoint * v_forward * tagscale;
 893         dragger.draglocalvector_y = touchpoint * v_right * tagscale;
 894         dragger.draglocalvector_z = touchpoint * v_up * tagscale;
 895
 896         dragger.dragspeed = 64;
 897 }
 898
 899 void Drag_Finish(entity dragger)
 900 {
 901         entity draggee;
 902         draggee = dragger.dragentity;
 903         if(dragger)
 904                 dragger.dragentity = world;
 905         draggee.draggedby = world;
 906         draggee.movetype = draggee.dragmovetype;
 907         draggee.gravity = draggee.draggravity;
 908
 909         switch(draggee.movetype)
 910         {
 911                 case MOVETYPE_TOSS:
 912                 case MOVETYPE_WALK:
 913                 case MOVETYPE_STEP:
 914                 case MOVETYPE_FLYMISSILE:
 915                 case MOVETYPE_BOUNCE:
 916                 case MOVETYPE_BOUNCEMISSILE:
 917                 case MOVETYPE_PHYSICS:
 918                         break;
 919                 default:
 920                         draggee.velocity = '0 0 0';
 921                         break;
 922         }
 923
 924         if((draggee.flags & FL_ITEM) && (vlen(draggee.velocity) < 32))
 925         {
 926                 draggee.velocity = '0 0 0';
 927                 SET_ONGROUND(draggee); // floating items are FUN
 928         }
 929 }
 930
 931 float Drag_IsDraggable(entity draggee)
 932 {
 933         // TODO add more checks for bad stuff here
 934         if(draggee == world)
 935                 return false;
 936         if(draggee.classname == "func_bobbing")
 937                 return false;
 938         if(draggee.classname == "door") // FIXME find out why these must be excluded, or work around the problem (trying to drag these causes like 4 fps)
 939                 return false;
 940         if(draggee.classname == "plat")
 941                 return false;
 942         if(draggee.classname == "func_button")
 943                 return false;
 944 //      if(draggee.model == "")
 945 //              return false;
 946         if(IS_SPEC(draggee))
 947                 return false;
 948         if(IS_OBSERVER(draggee))
 949                 return false;
 950         if(draggee.classname == "exteriorweaponentity")
 951                 return false;
 952         if(draggee.classname == "weaponentity")
 953                 return false;
 954
 955         return true;
 956 }
 957
 958 float Drag_MayChangeAngles(entity draggee)
 959 {
 960         // TODO add more checks for bad stuff here
 961         if(substring(draggee.model, 0, 1) == "*")
 962                 return false;
 963         return true;
 964 }
 965
 966 void Drag_MoveForward(entity dragger)
 967 {
 968         dragger.dragdistance += dragger.dragspeed;
 969 }
 970
 971 void Drag_SetSpeed(entity dragger, float s)
 972 {
 973         dragger.dragspeed = pow(2, s);
 974 }
 975
 976 void Drag_MoveBackward(entity dragger)
 977 {
 978         dragger.dragdistance = max(0, dragger.dragdistance - dragger.dragspeed);
 979 }
 980
 981 void Drag_Update(entity dragger)
 982 {
 983         vector curorigin, neworigin, goodvelocity;
 984         float f;
 985         entity draggee;
 986
 987         draggee = dragger.dragentity;
 988         UNSET_ONGROUND(draggee);
 989
 990         curorigin = gettaginfo(draggee, 0);
 991         curorigin = curorigin + v_forward * dragger.draglocalvector.x + v_right * dragger.draglocalvector.y + v_up * dragger.draglocalvector.z;
 992         makevectors(dragger.v_angle);
 993         neworigin = dragger.origin + dragger.view_ofs + v_forward * dragger.dragdistance;
 994         goodvelocity = (neworigin - curorigin) * (1 / frametime);
 995
 996         while(draggee.angles.y - dragger.v_angle.y - dragger.draglocalangle > 180)
 997                 dragger.draglocalangle += 360;
 998         while(draggee.angles.y - dragger.v_angle.y - dragger.draglocalangle <= -180)
 999                 dragger.draglocalangle -= 360;
1000
1001         f = min(frametime * 10, 1);
1002         draggee.velocity = draggee.velocity * (1 - f) + goodvelocity * f;
1003
1004         if(Drag_MayChangeAngles(draggee))
1005                 draggee.angles_y = draggee.angles.y * (1 - f) + (dragger.v_angle.y + dragger.draglocalangle) * f;
1006
1007         draggee.ltime = max(servertime + serverframetime, draggee.ltime); // fixes func_train breakage
1008
1009         vector vecs = '0 0 0';
1010         .entity weaponentity = weaponentities[0]; // TODO: unhardcode
1011         if(dragger.(weaponentity).movedir.x > 0)
1012                 vecs = dragger.(weaponentity).movedir;
1013
1014         vector dv = v_right * -vecs_y + v_up * vecs_z;
1015
1016         te_lightning1(draggee, dragger.origin + dragger.view_ofs + dv, curorigin);
1017 }
1018
1019 float Drag_CanDrag(entity dragger)
1020 {
1021         return (!IS_DEAD(dragger)) || (IS_PLAYER(dragger));
1022 }
1023
1024 float Drag_IsDragging(entity dragger)
1025 {
1026         if(!dragger.dragentity)
1027                 return false;
1028         if(wasfreed(dragger.dragentity) || dragger.dragentity.draggedby != dragger)
1029         {
1030                 dragger.dragentity = world;
1031                 return false;
1032         }
1033         if(!Drag_CanDrag(dragger) || !Drag_IsDraggable(dragger.dragentity))
1034         {
1035                 Drag_Finish(dragger);
1036                 return false;
1037         }
1038         return true;
1039 }
1040
1041 void Drag_MoveDrag(entity from, entity to)
1042 {
1043         if(from.draggedby)
1044         {
1045                 to.draggedby = from.draggedby;
1046                 to.draggedby.dragentity = to;
1047                 from.draggedby = world;
1048         }
1049 }
1050
1051 void DragBox_Think()
1052 {SELFPARAM();
1053         if(self.aiment && self.enemy)
1054         {
1055                 self.origin_x = (self.aiment.origin.x + self.enemy.origin.x) * 0.5;
1056                 self.origin_y = (self.aiment.origin.y + self.enemy.origin.y) * 0.5;
1057                 self.origin_z = (self.aiment.origin.z + self.enemy.origin.z) * 0.5;
1058                 self.maxs_x = fabs(self.aiment.origin.x - self.enemy.origin.x) * 0.5;
1059                 self.maxs_y = fabs(self.aiment.origin.y - self.enemy.origin.y) * 0.5;
1060                 self.maxs_z = fabs(self.aiment.origin.z - self.enemy.origin.z) * 0.5;
1061                 self.mins = -1 * self.maxs;
1062                 setorigin(self, self.origin);
1063                 setsize(self, self.mins, self.maxs); // link edict
1064         }
1065
1066         if(self.cnt == -1) // actually race_place -1
1067         {
1068                 // show "10 10" for qualifying spawns
1069                 setmodel(self.killindicator, MDL_NUM(10));
1070                 setmodel(self.killindicator.killindicator, MDL_NUM(10));
1071         }
1072         else if(self.cnt == -2) // actually race_place 0
1073         {
1074                 // show "10 0" for loser spawns
1075                 setmodel(self.killindicator, MDL_NUM(10));
1076                 setmodel(self.killindicator.killindicator, MDL_NUM(0));
1077         }
1078         else
1079         {
1080                 setmodel(self.killindicator, MDL_NUM(self.cnt % 10));
1081                 setmodel(self.killindicator.killindicator, MDL_NUM(floor(self.cnt / 10)));
1082         }
1083
1084         self.nextthink = time;
1085 }
1086
1087 #endif