qcsrc/server/mutators/sandbox.qc

   1 const float MAX_STORAGE_ATTACHMENTS = 16;
   2 float object_count;
   3 .entity object_attach;
   4 .string material;
   5
   6 .float touch_timer;
   7 void sandbox_ObjectFunction_Touch()
   8 {
   9         // apply material impact effects
  10
  11         if(!self.material)
  12                 return;
  13         if(self.touch_timer > time)
  14                 return; // don't execute each frame
  15         self.touch_timer = time + 0.1;
  16
  17         // make particle count and sound volume depend on impact speed
  18         float intensity;
  19         intensity = vlen(self.velocity) + vlen(other.velocity);
  20         if(intensity) // avoid divisions by 0
  21                 intensity /= 2; // average the two velocities
  22         if not(intensity >= autocvar_g_sandbox_object_material_velocity_min)
  23                 return; // impact not strong enough to do anything
  24         // now offset intensity and apply it to the effects
  25         intensity -= autocvar_g_sandbox_object_material_velocity_min; // start from minimum velocity, not actual velocity
  26         intensity = bound(0, intensity * autocvar_g_sandbox_object_material_velocity_factor, 1);
  27
  28         sound(self, CH_TRIGGER, strcat("object/impact_", self.material, "_", ftos(ceil(random() * 5)) , ".ogg"), VOL_BASE * intensity, ATTN_NORM);
  29         pointparticles(particleeffectnum(strcat("impact_", self.material)), self.origin, '0 0 0', ceil(intensity * 10)); // allow a count from 1 to 10
  30 }
  31
  32 void sandbox_ObjectFunction_Think()
  33 {
  34         entity e;
  35
  36         // decide if and how this object can be grabbed
  37         if(autocvar_g_sandbox_editor_free < 2 && self.crypto_idfp)
  38                 self.grab = 1;
  39         else
  40                 self.grab = 3;
  41
  42         // Object owner is stored via player UID, but we also need the owner as an entity (if the player is available on the server).
  43         // Therefore, scan for all players, and update the owner as long as the player is present. We must always do this,
  44         // since if the owning player disconnects, the object's owner should also be reset.
  45         FOR_EACH_REALPLAYER(e) // bots can't have objects
  46         {
  47                 if(self.crypto_idfp == e.crypto_idfp)
  48                 {
  49                         self.realowner = e;
  50                         break;
  51                 }
  52                 self.realowner = world;
  53         }
  54
  55         self.nextthink = time;
  56 }
  57
  58 entity sandbox_ObjectEdit_Get(float permissions)
  59 {
  60         // returns the traced entity if the player can edit it, and world if not
  61         // if permissions if FALSE, the object is returned regardless of editing rights
  62         // attached objects are SOLID_NOT and don't risk getting traced
  63
  64         makevectors(self.v_angle);
  65         WarpZone_TraceLine(self.origin + self.view_ofs, self.origin + self.view_ofs + v_forward * autocvar_g_sandbox_editor_distance_edit, MOVE_NORMAL, self);
  66
  67         if(trace_ent.classname != "object")
  68                 return world; // entity is not an object
  69         if(!permissions)
  70                 return trace_ent; // don't check permissions, anyone can edit this object
  71         if(!trace_ent.crypto_idfp)
  72                 return trace_ent; // the player who spawned this object did not have an UID, so anyone can edit it
  73         if not(trace_ent.realowner != self && autocvar_g_sandbox_editor_free < 2)
  74                 return trace_ent; // object does not belong to the player, and players can only edit their own objects on this server
  75         return world;
  76 }
  77
  78 void sandbox_ObjectEdit_Scale(entity e, float f)
  79 {
  80         e.scale = f;
  81         if(e.scale)
  82         {
  83                 e.scale = bound(autocvar_g_sandbox_object_scale_min, e.scale, autocvar_g_sandbox_object_scale_max);
  84                 setsize(e, e.mins * e.scale, e.maxs * e.scale); // adapt bounding box size to model size
  85         }
  86 }
  87
  88 .float old_movetype;
  89 void sandbox_ObjectAttach_Remove(entity e);
  90 void sandbox_ObjectAttach_Set(entity e, entity parent, string s)
  91 {
  92         // attaches e to parent on string s
  93
  94         // we can't attach to an attachment, for obvious reasons
  95         sandbox_ObjectAttach_Remove(e);
  96
  97         e.old_movetype = e.movetype; // persist physics
  98         e.movetype = MOVETYPE_FOLLOW;
  99         e.solid = SOLID_NOT;
 100         e.takedamage = DAMAGE_NO;
 101
 102         setattachment(e, parent, s);
 103         e.owner = parent;
 104 }
 105
 106 void sandbox_ObjectAttach_Remove(entity e)
 107 {
 108         // detaches any object attached to e
 109
 110         entity head;
 111         for(head = world; (head = find(head, classname, "object")); )
 112         {
 113                 if(head.owner == e)
 114                 {
 115                         vector org;
 116                         head.movetype = head.old_movetype; // restore persisted physics
 117                         head.solid = SOLID_BBOX;
 118                         head.takedamage = DAMAGE_AIM;
 119
 120                         org = gettaginfo(head, 0);
 121                         setattachment(head, world, "");
 122                         head.owner = world;
 123
 124                         // objects change origin and angles when detached, so apply previous position
 125                         setorigin(head, org);
 126                         head.angles = e.angles; // don't allow detached objects to spin or roll
 127                 }
 128         }
 129 }
 130
 131 entity sandbox_ObjectSpawn(float database)
 132 {
 133         // spawn a new object with default properties
 134
 135         entity e;
 136         e = spawn();
 137         e.classname = "object";
 138         e.takedamage = DAMAGE_AIM;
 139         e.damageforcescale = 1;
 140         e.solid = SOLID_BBOX; // SOLID_BSP would be best, but can lag the server badly
 141         e.movetype = MOVETYPE_TOSS;
 142         e.frame = 0;
 143         e.skin = 0;
 144         e.material = string_null;
 145         e.touch = sandbox_ObjectFunction_Touch;
 146         e.think = sandbox_ObjectFunction_Think;
 147         e.nextthink = time;
 148         //e.effects |= EF_SELECTABLE; // don't do this all the time, maybe just when editing objects?
 149
 150         if(!database)
 151         {
 152                 // set the object's owner via player UID
 153                 // if the player does not have an UID, the owner cannot be stored and his objects may be edited by anyone
 154                 if(self.crypto_idfp != "")
 155                         e.crypto_idfp = strzone(self.crypto_idfp);
 156                 else
 157                         print_to(self, "^1SANDBOX - WARNING: ^7You spawned an object, but lack a player UID. ^1Your objects are not secured and can be edited by any player!");
 158
 159                 // set public object information
 160                 e.netname = strzone(self.netname); // name of the owner
 161                 e.message = strzone(strftime(TRUE, "%d-%m-%Y %H:%M:%S")); // creation time
 162                 e.message2 = strzone(strftime(TRUE, "%d-%m-%Y %H:%M:%S")); // last editing time
 163
 164                 // set origin and direction based on player position and view angle
 165                 makevectors(self.v_angle);
 166                 WarpZone_TraceLine(self.origin + self.view_ofs, self.origin + self.view_ofs + v_forward * autocvar_g_sandbox_editor_distance_spawn, MOVE_NORMAL, self);
 167                 setorigin(e, trace_endpos);
 168                 e.angles_y = self.v_angle_y;
 169         }
 170
 171         object_count += 1;
 172         return e;
 173 }
 174
 175 void sandbox_ObjectRemove(entity e)
 176 {
 177         sandbox_ObjectAttach_Remove(e); // detach child objects
 178
 179         if(e.material)  {       strunzone(e.material);  e.material = string_null;       }
 180         if(e.crypto_idfp)       {       strunzone(e.crypto_idfp);       e.crypto_idfp = string_null;    }
 181         if(e.netname)   {       strunzone(e.netname);   e.netname = string_null;        }
 182         if(e.message)   {       strunzone(e.message);   e.message = string_null;        }
 183         if(e.message2)  {       strunzone(e.message2);  e.message2 = string_null;       }
 184         remove(e);
 185         e = world;
 186
 187         object_count -= 1;
 188 }
 189
 190 string port_string[MAX_STORAGE_ATTACHMENTS]; // fteqcc crashes if this isn't defined as a global
 191
 192 string sandbox_ObjectPort_Save(entity e, float database)
 193 {
 194         // save object properties, and return them as a string
 195         float i;
 196         string s;
 197         entity head;
 198
 199         for(head = world; (head = find(head, classname, "object")); )
 200         {
 201                 // the main object needs to be first in the array [0] with attached objects following
 202                 float slot, physics;
 203                 if(head == e) // this is the main object, place it first
 204                 {
 205                         slot = 0;
 206                         physics = head.movetype; // applied physics are normal physics for parents
 207                 }
 208                 else if(head.owner == e) // child object, list them in order
 209                 {
 210                         i += 1; // children start from 1
 211                         slot = i;
 212                         physics = head.old_movetype; // persisted physics are normal physics for children
 213                         gettaginfo(head.owner, head.tag_index); // get the name of the tag our object is attached to, used further below
 214                 }
 215                 else
 216                         continue;
 217
 218                 // ---------------- OBJECT PROPERTY STORAGE: SAVE ----------------
 219                 if(slot)
 220                 {
 221                         // properties stored only for child objects
 222                         if(gettaginfo_name)     port_string[slot] = strcat(port_string[slot], "\"", gettaginfo_name, "\" ");    else    port_string[slot] = strcat(port_string[slot], "- "); // none
 223                 }
 224                 else
 225                 {
 226                         // properties stored only for parent objects
 227                         if(database)
 228                         {
 229                                 port_string[slot] = strcat(port_string[slot], sprintf("\"%.9v\"", head.origin), " ");
 230                                 port_string[slot] = strcat(port_string[slot], sprintf("\"%.9v\"", head.angles), " ");
 231                         }
 232                 }
 233                 // properties stored for all objects
 234                 port_string[slot] = strcat(port_string[slot], "\"", head.model, "\" ");
 235                 port_string[slot] = strcat(port_string[slot], ftos(head.skin), " ");
 236                 port_string[slot] = strcat(port_string[slot], ftos(head.alpha), " ");
 237                 port_string[slot] = strcat(port_string[slot], sprintf("\"%.9v\"", head.colormod), " ");
 238                 port_string[slot] = strcat(port_string[slot], sprintf("\"%.9v\"", head.glowmod), " ");
 239                 port_string[slot] = strcat(port_string[slot], ftos(head.frame), " ");
 240                 port_string[slot] = strcat(port_string[slot], ftos(head.scale), " ");
 241                 port_string[slot] = strcat(port_string[slot], ftos(physics), " ");
 242                 port_string[slot] = strcat(port_string[slot], ftos(head.damageforcescale), " ");
 243                 if(head.material)       port_string[slot] = strcat(port_string[slot], "\"", head.material, "\" ");      else    port_string[slot] = strcat(port_string[slot], "- "); // none
 244                 if(database)
 245                 {
 246                         // properties stored only for the database
 247                         if(head.crypto_idfp)    port_string[slot] = strcat(port_string[slot], "\"", head.crypto_idfp, "\" ");   else    port_string[slot] = strcat(port_string[slot], "- "); // none
 248                         port_string[slot] = strcat(port_string[slot], "\"", e.netname, "\" ");
 249                         port_string[slot] = strcat(port_string[slot], "\"", e.message, "\" ");
 250                         port_string[slot] = strcat(port_string[slot], "\"", e.message2, "\" ");
 251                 }
 252         }
 253
 254         // now apply the array to a simple string, with the ; symbol separating objects
 255         for(i = 0; i <= MAX_STORAGE_ATTACHMENTS; ++i)
 256         {
 257                 if(port_string[i])
 258                         s = strcat(s, port_string[i], "; ");
 259                 port_string[i] = string_null; // fully clear the string
 260         }
 261
 262         return s;
 263 }
 264
 265 entity sandbox_ObjectPort_Load(string s, float database)
 266 {
 267         // load object properties, and spawn a new object with them
 268         float n, i;
 269         entity e, parent;
 270
 271         // separate objects between the ; symbols
 272         n = tokenizebyseparator(s, "; ");
 273         for(i = 0; i < n; ++i)
 274                 port_string[i] = argv(i);
 275
 276         // now separate and apply the properties of each object
 277         for(i = 0; i < n; ++i)
 278         {
 279                 float argv_num;
 280                 string tagname;
 281                 argv_num = 0;
 282                 tokenize_console(port_string[i]);
 283                 e = sandbox_ObjectSpawn(database);
 284
 285                 // ---------------- OBJECT PROPERTY STORAGE: LOAD ----------------
 286                 if(i)
 287                 {
 288                         // properties stored only for child objects
 289                         if(argv(argv_num) != "-")       tagname = argv(argv_num);       else tagname = string_null;     ++argv_num;
 290                 }
 291                 else
 292                 {
 293                         // properties stored only for parent objects
 294                         if(database)
 295                         {
 296                                 setorigin(e, stov(argv(argv_num)));     ++argv_num;
 297                                 e.angles = stov(argv(argv_num));        ++argv_num;
 298                         }
 299                         parent = e; // mark parent objects as such
 300                 }
 301                 // properties stored for all objects
 302                 setmodel(e, argv(argv_num));    ++argv_num;
 303                 e.skin = stof(argv(argv_num));  ++argv_num;
 304                 e.alpha = stof(argv(argv_num)); ++argv_num;
 305                 e.colormod = stov(argv(argv_num));      ++argv_num;
 306                 e.glowmod = stov(argv(argv_num));       ++argv_num;
 307                 e.frame = stof(argv(argv_num)); ++argv_num;
 308                 sandbox_ObjectEdit_Scale(e, stof(argv(argv_num)));      ++argv_num;
 309                 e.movetype = e.old_movetype = stof(argv(argv_num));     ++argv_num;
 310                 e.damageforcescale = stof(argv(argv_num));      ++argv_num;
 311                 if(e.material)  strunzone(e.material);  if(argv(argv_num) != "-")       e.material = strzone(argv(argv_num));   else    e.material = string_null;       ++argv_num;
 312                 if(database)
 313                 {
 314                         // properties stored only for the database
 315                         if(e.crypto_idfp)       strunzone(e.crypto_idfp);       if(argv(argv_num) != "-")       e.crypto_idfp = strzone(argv(argv_num));        else    e.crypto_idfp = string_null;    ++argv_num;
 316                         if(e.netname)   strunzone(e.netname);   e.netname = strzone(argv(argv_num));    ++argv_num;
 317                         if(e.message)   strunzone(e.message);   e.message = strzone(argv(argv_num));    ++argv_num;
 318                         if(e.message2)  strunzone(e.message2);  e.message2 = strzone(argv(argv_num));   ++argv_num;
 319                 }
 320
 321                 // attach last
 322                 if(i)
 323                         sandbox_ObjectAttach_Set(e, parent, tagname);
 324         }
 325
 326         for(i = 0; i <= MAX_STORAGE_ATTACHMENTS; ++i)
 327                 port_string[i] = string_null; // fully clear the string
 328
 329         return e;
 330 }
 331
 332 void sandbox_Database_Save()
 333 {
 334         // saves all objects to the database file
 335         entity head;
 336         string file_name;
 337         float file_get;
 338
 339         file_name = strcat("sandbox/storage_", autocvar_g_sandbox_storage_name, "_", GetMapname(), ".txt");
 340         file_get = fopen(file_name, FILE_WRITE);
 341         fputs(file_get, strcat("// sandbox storage \"", autocvar_g_sandbox_storage_name, "\" for map \"", GetMapname(), "\" last updated ", strftime(TRUE, "%d-%m-%Y %H:%M:%S")));
 342         fputs(file_get, strcat(" containing ", ftos(object_count), " objects\n"));
 343
 344         for(head = world; (head = find(head, classname, "object")); )
 345         {
 346                 // attached objects are persisted separately, ignore them here
 347                 if(head.owner != world)
 348                         continue;
 349
 350                 // use a line of text for each object, listing all properties
 351                 fputs(file_get, strcat(sandbox_ObjectPort_Save(head, TRUE), "\n"));
 352         }
 353         fclose(file_get);
 354 }
 355
 356 void sandbox_Database_Load()
 357 {
 358         // loads all objects from the database file
 359         string file_read, file_name;
 360         float file_get, i;
 361
 362         file_name = strcat("sandbox/storage_", autocvar_g_sandbox_storage_name, "_", GetMapname(), ".txt");
 363         file_get = fopen(file_name, FILE_READ);
 364         if(file_get < 0)
 365         {
 366                 if(autocvar_g_sandbox_info > 0)
 367                         print(strcat("^3SANDBOX - SERVER: ^7could not find storage file ^3", file_name, "^7, no objects were loaded\n"));
 368         }
 369         else
 370         {
 371                 for(;;)
 372                 {
 373                         file_read = fgets(file_get);
 374                         if(!file_read)
 375                                 break;
 376                         if(substring(file_read, 0, 2) == "//")
 377                                 continue;
 378                         if(substring(file_read, 0, 1) == "#")
 379                                 continue;
 380
 381                         entity e;
 382                         e = sandbox_ObjectPort_Load(file_read, TRUE);
 383
 384                         if(e.material)
 385                         {
 386                                 // since objects are being loaded for the first time, precache material sounds for each
 387                                 for (i = 1; i <= 5; i++) // 5 sounds in total
 388                                         precache_sound(strcat("object/impact_", e.material, "_", ftos(i), ".ogg"));
 389                         }
 390                 }
 391                 if(autocvar_g_sandbox_info > 0)
 392                         print(strcat("^3SANDBOX - SERVER: ^7successfully loaded storage file ^3", file_name, "\n"));
 393         }
 394 }
 395
 396 MUTATOR_HOOKFUNCTION(sandbox_PlayerCommand)
 397 {
 398         if(MUTATOR_RETURNVALUE) // command was already handled?
 399                 return FALSE;
 400         if(cmd_name == "g_sandbox")
 401         {
 402                 if(cmd_argc < 2)
 403                 {
 404                         print_to(self, "Sandbox mode is active. For usage information, type 'sandbox help'");
 405                         return TRUE;
 406                 }
 407
 408                 switch(argv(1))
 409                 {
 410                         entity e;
 411                         float i;
 412                         string s;
 413
 414                         // ---------------- COMMAND: HELP ----------------
 415                         case "help":
 416                                 print_to(self, "You can use the following sandbox commands:");
 417                                 print_to(self, "^7\"^2object_spawn ^3models/foo/bar.md3^7\" spawns a new object in front of the player, and gives it the specified model");
 418                                 print_to(self, "^7\"^2object_remove^7\" removes the object the player is looking at. Players can only remove their own objects");
 419                                 print_to(self, "^7\"^2object_duplicate ^3value^7\" duplicates the object, if the player has copying rights over the original");
 420                                 print_to(self, "^3copy value ^7- copies the properties of the object to the specified client cvar");
 421                                 print_to(self, "^3paste value ^7- spawns an object with the given properties. Properties or cvars must be specified as follows; eg1: \"0 1 2 ...\", eg2: \"$cl_cvar\"");
 422                                 print_to(self, "^7\"^2object_attach ^3property value^7\" attaches one object to another. Players can only attach their own objects");
 423                                 print_to(self, "^3get ^7- selects the object you are facing as the object to be attached");
 424                                 print_to(self, "^3set value ^7- attaches the previously selected object to the object you are facing, on the specified bone");
 425                                 print_to(self, "^3remove ^7- detaches all objects from the object you are facing");
 426                                 print_to(self, "^7\"^2object_edit ^3property value^7\" edits the given property of the object. Players can only edit their own objects");
 427                                 print_to(self, "^3skin value ^7- changes the skin of the object");
 428                                 print_to(self, "^3alpha value ^7- sets object transparency");
 429                                 print_to(self, "^3colormod \"value_x value_y value_z\" ^7- main object color");
 430                                 print_to(self, "^3glowmod \"value_x value_y value_z\" ^7- glow object color");
 431                                 print_to(self, "^3frame value ^7- object animation frame, for self-animated models");
 432                                 print_to(self, "^3scale value ^7- changes object scale. 0.5 is half size and 2 is double size");
 433                                 print_to(self, "^3physics value ^7- object physics, 0 = static, 1 = movable, 2 = physical");
 434                                 print_to(self, "^3force value ^7- amount of force applied to objects that are shot");
 435                                 print_to(self, "^3material value ^7- sets the material of the object. Default materials are: metal, stone, wood, flesh");
 436                                 print_to(self, "^7\"^2object_claim^7\" sets the player as the owner of the object, if he has the right to edit it");
 437                                 print_to(self, "^7\"^2object_info ^3value^7\" shows public information about the object");
 438                                 print_to(self, "^3object ^7- prints general information about the object, such as owner and creation / editing date");
 439                                 print_to(self, "^3mesh ^7- prints information about the object's mesh, including skeletal bones");
 440                                 print_to(self, "^3attachments ^7- prints information about the object's attachments");
 441                                 print_to(self, "^7The ^1drag object ^7key can be used to grab and carry objects. Players can only grab their own objects");
 442                                 return TRUE;
 443
 444                         // ---------------- COMMAND: OBJECT, SPAWN ----------------
 445                         case "object_spawn":
 446                                 if(object_count >= autocvar_g_sandbox_editor_maxobjects)
 447                                 {
 448                                         print_to(self, strcat("^1SANDBOX - WARNING: ^7Cannot spawn any more objects. Up to ^3", ftos(autocvar_g_sandbox_editor_maxobjects), " ^7objects may exist at a time"));
 449                                         return TRUE;
 450                                 }
 451                                 if(cmd_argc < 3)
 452                                 {
 453                                         print_to(self, "^1SANDBOX - WARNING: ^7Attempted to spawn an object without specifying a model. Please specify the path to your model file after the 'object_spawn' command");
 454                                         return TRUE;
 455                                 }
 456                                 else if not(fexists(argv(2)))
 457                                 {
 458                                         print_to(self, "^1SANDBOX - WARNING: ^7Attempted to spawn an object with a non-existent model. Make sure the path to your model file is correct");
 459                                         return TRUE;
 460                                 }
 461
 462                                 e = sandbox_ObjectSpawn(FALSE);
 463                                 setmodel(e, argv(2));
 464
 465                                 if(autocvar_g_sandbox_info > 0)
 466                                         print(strcat("^3SANDBOX - SERVER: ^7", self.netname, " spawned an object at origin ^3", vtos(e.origin), "\n"));
 467                                 return TRUE;
 468
 469                         // ---------------- COMMAND: OBJECT, REMOVE ----------------
 470                         case "object_remove":
 471                                 e = sandbox_ObjectEdit_Get(TRUE);
 472                                 if(e != world)
 473                                 {
 474                                         if(autocvar_g_sandbox_info > 0)
 475                                                 print(strcat("^3SANDBOX - SERVER: ^7", self.netname, " removed an object at origin ^3", vtos(e.origin), "\n"));
 476                                         sandbox_ObjectRemove(e);
 477                                         return TRUE;
 478                                 }
 479
 480                                 print_to(self, "^1SANDBOX - WARNING: ^7Object could not be removed. Make sure you are facing an object that you have edit rights over");
 481                                 return TRUE;
 482
 483                         // ---------------- COMMAND: OBJECT, DUPLICATE ----------------
 484                         case "object_duplicate":
 485                                 switch(argv(2))
 486                                 {
 487                                         case "copy":
 488                                                 // copies customizable properties of the selected object to the clipboard cvar
 489                                                 e = sandbox_ObjectEdit_Get(autocvar_g_sandbox_editor_free); // can we copy objects we can't edit?
 490                                                 if(e != world)
 491                                                 {
 492                                                         s = sandbox_ObjectPort_Save(e, FALSE);
 493                                                         s = strreplace("\"", "\\\"", s);
 494                                                         stuffcmd(self, strcat("set ", argv(3), " \"", s, "\""));
 495
 496                                                         print_to(self, "^2SANDBOX - INFO: ^7Object copied to clipboard");
 497                                                         return TRUE;
 498                                                 }
 499                                                 print_to(self, "^1SANDBOX - WARNING: ^7Object could not be copied. Make sure you are facing an object that you have copy rights over");
 500                                                 return TRUE;
 501
 502                                         case "paste":
 503                                                 // spawns a new object using the properties in the player's clipboard cvar
 504                                                 if(!argv(3)) // no object in clipboard
 505                                                 {
 506                                                         print_to(self, "^1SANDBOX - WARNING: ^7No object in clipboard. You must copy an object before you can paste it");
 507                                                         return TRUE;
 508                                                 }
 509                                                 if(object_count >= autocvar_g_sandbox_editor_maxobjects)
 510                                                 {
 511                                                         print_to(self, strcat("^1SANDBOX - WARNING: ^7Cannot spawn any more objects. Up to ^3", ftos(autocvar_g_sandbox_editor_maxobjects), " ^7objects may exist at a time"));
 512                                                         return TRUE;
 513                                                 }
 514                                                 e = sandbox_ObjectPort_Load(argv(3), FALSE);
 515
 516                                                 print_to(self, "^2SANDBOX - INFO: ^7Object pasted successfully");
 517                                                 if(autocvar_g_sandbox_info > 0)
 518                                                         print(strcat("^3SANDBOX - SERVER: ^7", self.netname, " pasted an object at origin ^3", vtos(e.origin), "\n"));
 519                                                 return TRUE;
 520                                 }
 521                                 return TRUE;
 522
 523                         // ---------------- COMMAND: OBJECT, ATTACH ----------------
 524                         case "object_attach":
 525                                 switch(argv(2))
 526                                 {
 527                                         case "get":
 528                                                 // select e as the object as meant to be attached
 529                                                 e = sandbox_ObjectEdit_Get(TRUE);
 530                                                 if(e != world)
 531                                                 {
 532                                                         self.object_attach = e;
 533                                                         print_to(self, "^2SANDBOX - INFO: ^7Object selected for attachment");
 534                                                         return TRUE;
 535                                                 }
 536                                                 print_to(self, "^1SANDBOX - WARNING: ^7Object could not be selected for attachment. Make sure you are facing an object that you have edit rights over");
 537                                                 return TRUE;
 538                                         case "set":
 539                                                 if(self.object_attach == world)
 540                                                 {
 541                                                         print_to(self, "^1SANDBOX - WARNING: ^7No object selected for attachment. Please select an object to be attached first.");
 542                                                         return TRUE;
 543                                                 }
 544
 545                                                 // attaches the previously selected object to e
 546                                                 e = sandbox_ObjectEdit_Get(TRUE);
 547                                                 if(e != world)
 548                                                 {
 549                                                         sandbox_ObjectAttach_Set(self.object_attach, e, argv(3));
 550                                                         self.object_attach = world; // object was attached, no longer keep it scheduled for attachment
 551                                                         print_to(self, "^2SANDBOX - INFO: ^7Object attached successfully");
 552                                                         if(autocvar_g_sandbox_info > 1)
 553                                                                 print(strcat("^3SANDBOX - SERVER: ^7", self.netname, " attached objects at origin ^3", vtos(e.origin), "\n"));
 554                                                         return TRUE;
 555                                                 }
 556                                                 print_to(self, "^1SANDBOX - WARNING: ^7Object could not be attached to the parent. Make sure you are facing an object that you have edit rights over");
 557                                                 return TRUE;
 558                                         case "remove":
 559                                                 // removes e if it was attached
 560                                                 e = sandbox_ObjectEdit_Get(TRUE);
 561                                                 if(e != world)
 562                                                 {
 563                                                         sandbox_ObjectAttach_Remove(e);
 564                                                         print_to(self, "^2SANDBOX - INFO: ^7Child objects detached successfully");
 565                                                         if(autocvar_g_sandbox_info > 1)
 566                                                                 print(strcat("^3SANDBOX - SERVER: ^7", self.netname, " detached objects at origin ^3", vtos(e.origin), "\n"));
 567                                                         return TRUE;
 568                                                 }
 569                                                 print_to(self, "^1SANDBOX - WARNING: ^7Child objects could not be detached. Make sure you are facing an object that you have edit rights over");
 570                                                 return TRUE;
 571                                 }
 572                                 return TRUE;
 573
 574                         // ---------------- COMMAND: OBJECT, EDIT ----------------
 575                         case "object_edit":
 576                                 if(!argv(2))
 577                                 {
 578                                         print_to(self, "^1SANDBOX - WARNING: ^7Too few parameters. You must specify a property to edit");
 579                                         return TRUE;
 580                                 }
 581
 582                                 e = sandbox_ObjectEdit_Get(TRUE);
 583                                 if(e != world)
 584                                 {
 585                                         switch(argv(2))
 586                                         {
 587                                                 case "skin":
 588                                                         e.skin = stof(argv(3));
 589                                                         break;
 590                                                 case "alpha":
 591                                                         e.alpha = stof(argv(3));
 592                                                         break;
 593                                                 case "color_main":
 594                                                         e.colormod = stov(argv(3));
 595                                                         break;
 596                                                 case "color_glow":
 597                                                         e.glowmod = stov(argv(3));
 598                                                         break;
 599                                                 case "frame":
 600                                                         e.frame = stof(argv(3));
 601                                                         break;
 602                                                 case "scale":
 603                                                         sandbox_ObjectEdit_Scale(e, stof(argv(3)));
 604                                                         break;
 605                                                 case "physics":
 606                                                         switch(argv(3))
 607                                                         {
 608                                                                 case "0": // static
 609                                                                         e.movetype = MOVETYPE_NONE;
 610                                                                         break;
 611                                                                 case "1": // movable
 612                                                                         e.movetype = MOVETYPE_TOSS;
 613                                                                         break;
 614                                                                 case "2": // physical
 615                                                                         e.movetype = MOVETYPE_PHYSICS;
 616                                                                         break;
 617                                                                 default:
 618                                                                         break;
 619                                                         }
 620                                                         break;
 621                                                 case "force":
 622                                                         e.damageforcescale = stof(argv(3));
 623                                                         break;
 624                                                 case "material":
 625                                                         if(e.material)  strunzone(e.material);
 626                                                         if(argv(3))
 627                                                         {
 628                                                                 for (i = 1; i <= 5; i++) // precache material sounds, 5 in total
 629                                                                         precache_sound(strcat("object/impact_", argv(3), "_", ftos(i), ".ogg"));
 630                                                                 e.material = strzone(argv(3));
 631                                                         }
 632                                                         else
 633                                                                 e.material = string_null; // no material
 634                                                         break;
 635                                                 default:
 636                                                         print_to(self, "^1SANDBOX - WARNING: ^7Invalid object property. For usage information, type 'sandbox help'");
 637                                                         return TRUE;
 638                                         }
 639
 640                                         // update last editing time
 641                                         if(e.message2)  strunzone(e.message2);
 642                                         e.message2 = strzone(strftime(TRUE, "%d-%m-%Y %H:%M:%S"));
 643
 644                                         if(autocvar_g_sandbox_info > 1)
 645                                                 print(strcat("^3SANDBOX - SERVER: ^7", self.netname, " edited property ^3", argv(2), " ^7of an object at origin ^3", vtos(e.origin), "\n"));
 646                                         return TRUE;
 647                                 }
 648
 649                                 print_to(self, "^1SANDBOX - WARNING: ^7Object could not be edited. Make sure you are facing an object that you have edit rights over");
 650                                 return TRUE;
 651
 652                         // ---------------- COMMAND: OBJECT, CLAIM ----------------
 653                         case "object_claim":
 654                                 // if the player can edit an object but is not its owner, this can be used to claim that object
 655                                 if(self.crypto_idfp == "")
 656                                 {
 657                                         print_to(self, "^1SANDBOX - WARNING: ^7You do not have a player UID, and cannot claim objects");
 658                                         return TRUE;
 659                                 }
 660                                 e = sandbox_ObjectEdit_Get(TRUE);
 661                                 if(e != world)
 662                                 {
 663                                         // update the owner's name
 664                                         // Do this before checking if you're already the owner and skipping if such, so we
 665                                         // also update the player's nickname if he changed it (but has the same player UID)
 666                                         if(e.netname != self.netname)
 667                                         {
 668                                                 if(e.netname)   strunzone(e.netname);
 669                                                 e.netname = strzone(self.netname);
 670                                                 print_to(self, "^2SANDBOX - INFO: ^7Object owner name updated");
 671                                         }
 672
 673                                         if(e.crypto_idfp == self.crypto_idfp)
 674                                         {
 675                                                 print_to(self, "^2SANDBOX - INFO: ^7Object is already yours, nothing to claim");
 676                                                 return TRUE;
 677                                         }
 678
 679                                         if(e.crypto_idfp)       strunzone(e.crypto_idfp);
 680                                         e.crypto_idfp = strzone(self.crypto_idfp);
 681
 682                                         print_to(self, "^2SANDBOX - INFO: ^7Object claimed successfully");
 683                                 }
 684                                 print_to(self, "^1SANDBOX - WARNING: ^7Object could not be claimed. Make sure you are facing an object that you have edit rights over");
 685                                 return TRUE;
 686
 687                         // ---------------- COMMAND: OBJECT, INFO ----------------
 688                         case "object_info":
 689                                 // prints public information about the object to the player
 690                                 e = sandbox_ObjectEdit_Get(FALSE);
 691                                 if(e != world)
 692                                 {
 693                                         switch(argv(2))
 694                                         {
 695                                                 case "object":
 696                                                         print_to(self, strcat("^2SANDBOX - INFO: ^7Object is owned by \"^7", e.netname, "^7\", created \"^3", e.message, "^7\", last edited \"^3", e.message2, "^7\""));
 697                                                         return TRUE;
 698                                                 case "mesh":
 699                                                         for(i = 1; gettaginfo(e, i); i++)
 700                                                                 s = strcat(s, "^7\"^5", gettaginfo_name, "^7\", ");
 701                                                         print_to(self, strcat("^2SANDBOX - INFO: ^7Object mesh is \"^3", e.model, "^7\" at animation frame ^3", ftos(e.frame), " ^7containing the following tags: ", s));
 702                                                         return TRUE;
 703                                                 case "attachments":
 704                                                         // this should show the same info as 'mesh' but for attachments
 705                                                         entity head;
 706                                                         for(head = world; (head = find(head, classname, "object")); )
 707                                                         {
 708                                                                 if(head.owner == e)
 709                                                                 {
 710                                                                         ++i; // start from 1
 711                                                                         gettaginfo(e, head.tag_index);
 712                                                                         s = strcat(s, "^1attachment ", ftos(i), "^7 has mesh \"^3", head.model, "^7\" at animation frame ^3", ftos(head.frame));
 713                                                                         s = strcat(s, "^7 and is attached to bone \"^5", gettaginfo_name, "^7\", ");
 714                                                                 }
 715                                                         }
 716                                                         if(i) // object contains attachments
 717                                                                 print_to(self, strcat("^2SANDBOX - INFO: ^7Object contains the following ^1", ftos(i), "^7 attachment(s): ", s));
 718                                                         else
 719                                                                 print_to(self, "^2SANDBOX - INFO: ^7Object contains no attachments");
 720                                                         return TRUE;
 721                                         }
 722                                 }
 723                                 print_to(self, "^1SANDBOX - WARNING: ^7No information could be found. Make sure you are facing an object");
 724                                 return TRUE;
 725
 726                         // ---------------- COMMAND: DEFAULT ----------------
 727                         default:
 728                                 print_to(self, "Invalid command. For usage information, type 'sandbox help'");
 729                                 return TRUE;
 730                 }
 731         }
 732         return FALSE;
 733 }
 734
 735 float autosave_time;
 736 MUTATOR_HOOKFUNCTION(sandbox_StartFrame)
 737 {
 738         if(!autocvar_g_sandbox_storage_autosave)
 739                 return FALSE;
 740         if(time < autosave_time)
 741                 return FALSE;
 742         autosave_time = time + autocvar_g_sandbox_storage_autosave;
 743
 744         sandbox_Database_Save();
 745
 746         return TRUE;
 747 }
 748
 749 MUTATOR_DEFINITION(sandbox)
 750 {
 751         MUTATOR_HOOK(SV_ParseClientCommand, sandbox_PlayerCommand, CBC_ORDER_ANY);
 752         MUTATOR_HOOK(SV_StartFrame, sandbox_StartFrame, CBC_ORDER_ANY);
 753
 754         MUTATOR_ONADD
 755         {
 756                 autosave_time = time + autocvar_g_sandbox_storage_autosave; // don't save the first server frame
 757                 if(autocvar_g_sandbox_storage_autoload)
 758                         sandbox_Database_Load();
 759         }
 760
 761         return FALSE;
 762 }
 763