qcsrc/server/vehicles/spiderbot.qc

   1 const vector SPIDERBOT_MIN = '-75 -75 10';
   2 const vector SPIDERBOT_MAX  = '75 75 125';
   3
   4 #ifdef SVQC
   5 float autocvar_g_vehicle_spiderbot_respawntime;
   6
   7 float autocvar_g_vehicle_spiderbot_speed_stop;
   8 float autocvar_g_vehicle_spiderbot_speed_strafe;
   9 float autocvar_g_vehicle_spiderbot_speed_walk;
  10 float autocvar_g_vehicle_spiderbot_turnspeed;
  11 float autocvar_g_vehicle_spiderbot_movement_inertia;
  12
  13 float autocvar_g_vehicle_spiderbot_springlength;
  14 float autocvar_g_vehicle_spiderbot_springup;
  15 float autocvar_g_vehicle_spiderbot_springblend;
  16
  17 float autocvar_g_vehicle_spiderbot_head_pitchlimit_down;
  18 float autocvar_g_vehicle_spiderbot_head_pitchlimit_up;
  19 float autocvar_g_vehicle_spiderbot_head_pitchspeed;
  20 float autocvar_g_vehicle_spiderbot_head_turnlimit;
  21 float autocvar_g_vehicle_spiderbot_head_turnspeed;
  22
  23 //float autocvar_g_vehicle_spiderbot_energy;
  24 //float autocvar_g_vehicle_spiderbot_energy_regen;
  25 //float autocvar_g_vehicle_spiderbot_energy_regen_pause;
  26
  27 float autocvar_g_vehicle_spiderbot_health;
  28 float autocvar_g_vehicle_spiderbot_health_regen;
  29 float autocvar_g_vehicle_spiderbot_health_regen_pause;
  30
  31 float autocvar_g_vehicle_spiderbot_shield;
  32 float autocvar_g_vehicle_spiderbot_shield_regen;
  33 float autocvar_g_vehicle_spiderbot_shield_regen_pause;
  34
  35 float autocvar_g_vehicle_spiderbot_minigun_damage;
  36 float autocvar_g_vehicle_spiderbot_minigun_refire;
  37 float autocvar_g_vehicle_spiderbot_minigun_spread;
  38 float autocvar_g_vehicle_spiderbot_minigun_ammo_cost;
  39 float autocvar_g_vehicle_spiderbot_minigun_ammo_max;
  40 float autocvar_g_vehicle_spiderbot_minigun_ammo_regen;
  41 float autocvar_g_vehicle_spiderbot_minigun_ammo_regen_pause;
  42
  43 float autocvar_g_vehicle_spiderbot_rocket_damage;
  44 float autocvar_g_vehicle_spiderbot_rocket_force;
  45 float autocvar_g_vehicle_spiderbot_rocket_radius;
  46 float autocvar_g_vehicle_spiderbot_rocket_speed;
  47 float autocvar_g_vehicle_spiderbot_rocket_refire;
  48 float autocvar_g_vehicle_spiderbot_rocket_reload;
  49 float autocvar_g_vehicle_spiderbot_rocket_health;
  50 float autocvar_g_vehicle_spiderbot_rocket_noise;
  51 float autocvar_g_vehicle_spiderbot_rocket_turnrate;
  52 float autocvar_g_vehicle_spiderbot_rocket_lifetime;
  53
  54 float autocvar_g_vehicle_spiderbot_bouncefactor;
  55 float autocvar_g_vehicle_spiderbot_bouncestop;
  56 vector autocvar_g_vehicle_spiderbot_bouncepain;
  57
  58
  59 void spiderbot_exit(float eject);
  60 void spiderbot_enter();
  61 void spiderbot_spawn();
  62
  63 void spiderbot_rocket_unguided()
  64 {
  65     vector newdir, olddir;
  66
  67     self.nextthink  = time;
  68
  69     olddir = normalize(self.velocity);
  70     newdir = normalize(self.pos1 - self.origin) + randomvec() * autocvar_g_vehicle_spiderbot_rocket_noise;
  71     self.velocity = normalize(olddir + newdir * autocvar_g_vehicle_spiderbot_rocket_turnrate) * autocvar_g_vehicle_spiderbot_rocket_speed;
  72
  73     UpdateCSQCProjectile(self);
  74
  75     if (self.owner.deadflag != DEAD_NO || self.cnt < time || vlen(self.pos1 - self.origin) < 16)
  76         self.use();
  77 }
  78
  79 void spiderbot_rocket_guided()
  80 {
  81     vector newdir, olddir;
  82
  83     self.nextthink  = time;
  84
  85     if not (self.realowner.vehicle)
  86         self.think = spiderbot_rocket_unguided;
  87
  88     crosshair_trace(self.realowner);
  89     olddir = normalize(self.velocity);
  90     newdir = normalize(trace_endpos - self.origin) + randomvec() * autocvar_g_vehicle_spiderbot_rocket_noise;
  91     self.velocity = normalize(olddir + newdir * autocvar_g_vehicle_spiderbot_rocket_turnrate) * autocvar_g_vehicle_spiderbot_rocket_speed;
  92
  93     UpdateCSQCProjectile(self);
  94
  95     if (self.owner.deadflag != DEAD_NO || self.cnt < time)
  96         self.use();
  97 }
  98
  99 void spiderbot_guide_release()
 100 {
 101     entity rkt;
 102     rkt = findchainentity(realowner, self.owner);
 103     if not (rkt)
 104         return;
 105
 106     crosshair_trace(self.owner);
 107     while(rkt)
 108     {
 109         if(rkt.think == spiderbot_rocket_guided)
 110         {
 111             rkt.pos1 = trace_endpos;
 112             rkt.think = spiderbot_rocket_unguided;
 113         }
 114         rkt = rkt.chain;
 115     }
 116 }
 117
 118 void spiderbot_rocket_do()
 119 {
 120
 121     vector v;
 122     entity rocket;
 123
 124     if (self.owner.BUTTON_ATCK2)
 125     {
 126         if (self.wait == 1)
 127         if (self.tur_head.frame == 9 || self.tur_head.frame == 1)
 128         {
 129             if(self.gun2.cnt < time && self.tur_head.frame == 9)
 130                 self.tur_head.frame = 1;
 131
 132             return;
 133         }
 134         self.wait = 1;
 135     }
 136     else
 137     {
 138         if(self.wait)
 139             spiderbot_guide_release();
 140
 141         self.wait = 0;
 142     }
 143
 144     if(self.gun2.cnt > time)
 145         return;
 146
 147     if (self.tur_head.frame >= 9)
 148         self.tur_head.frame = 1;
 149
 150     if not (self.owner.BUTTON_ATCK2)
 151         return;
 152
 153     crosshair_trace(self.owner);
 154
 155     v = gettaginfo(self.tur_head,gettagindex(self.tur_head,"tag_fire"));
 156     rocket = vehicles_projectile("spiderbot_rocket_launch", "weapons/rocket_fire.wav",
 157                            v, normalize(v_forward) * autocvar_g_vehicle_spiderbot_rocket_speed,
 158                            autocvar_g_vehicle_spiderbot_rocket_damage, autocvar_g_vehicle_spiderbot_rocket_radius, autocvar_g_vehicle_spiderbot_rocket_force, 1,
 159                            DEATH_SBROCKET, PROJECTILE_SPIDERROCKET, autocvar_g_vehicle_spiderbot_rocket_health, FALSE, FALSE);
 160
 161     rocket.cnt        = time + 15;
 162     rocket.classname  = "spiderbot_rocket";
 163     rocket.pos1       = trace_endpos;
 164     rocket.think      = spiderbot_rocket_guided;
 165     rocket.nextthink  = time;
 166     rocket.cnt        = time + autocvar_g_vehicle_spiderbot_rocket_lifetime;
 167
 168     self.tur_head.frame += 1;
 169     if (self.tur_head.frame == 9)
 170         self.attack_finished_single = autocvar_g_vehicle_spiderbot_rocket_reload;
 171     else
 172         self.attack_finished_single = autocvar_g_vehicle_spiderbot_rocket_refire;
 173
 174     self.gun2.cnt = time + self.attack_finished_single;
 175 }
 176
 177 float spiderbot_frame()
 178 {
 179     vector ad, vf;
 180     entity player, spider;
 181     float ftmp;
 182
 183         if(intermission_running)
 184                 return 1;
 185
 186     player = self;
 187     spider = self.vehicle;
 188     self   = spider;
 189
 190     vehicles_painframe();
 191
 192     player.BUTTON_ZOOM      = 0;
 193     player.BUTTON_CROUCH    = 0;
 194     player.switchweapon     = 0;
 195
 196 #if 1 // 0 to enable per-gun impact aux crosshairs
 197     // Avarage gun impact point's -> aux cross
 198     ad = gettaginfo(spider.tur_head, gettagindex(spider.tur_head, "tag_hardpoint01"));
 199     vf = v_forward;
 200     ad += gettaginfo(spider.tur_head, gettagindex(spider.tur_head, "tag_hardpoint02"));
 201     vf += v_forward;
 202     ad = ad * 0.5;
 203     v_forward = vf * 0.5;
 204     traceline(ad, ad + v_forward * MAX_SHOT_DISTANCE, MOVE_NORMAL, spider);
 205     UpdateAuxiliaryXhair(player, trace_endpos, ('1 0 0' * player.vehicle_reload1) + ('0 1 0' * (1 - player.vehicle_reload1)), 0);
 206 #else
 207     ad = gettaginfo(spider.gun1, gettagindex(spider.gun1, "barrels"));
 208     traceline(ad, ad + v_forward * MAX_SHOT_DISTANCE, MOVE_NORMAL, spider);
 209     UpdateAuxiliaryXhair(player, trace_endpos, ('1 0 0' * player.vehicle_reload1) + ('0 1 0' * (1 - player.vehicle_reload1)), 0);
 210     vf = ad;
 211     ad = gettaginfo(spider.gun2, gettagindex(spider.gun2, "barrels"));
 212     traceline(ad, ad + v_forward * MAX_SHOT_DISTANCE, MOVE_NORMAL, spider);
 213     UpdateAuxiliaryXhair(player, trace_endpos, ('1 0 0' * player.vehicle_reload1) + ('0 1 0' * (1 - player.vehicle_reload1)), 1);
 214     ad = 0.5 * (ad + vf);
 215 #endif
 216
 217     crosshair_trace(player);
 218     ad = vectoangles(normalize(trace_endpos - ad));
 219     ad = AnglesTransform_ToAngles(AnglesTransform_LeftDivide(AnglesTransform_FromAngles(spider.angles), AnglesTransform_FromAngles(ad))) - spider.tur_head.angles;
 220     ad = AnglesTransform_Normalize(ad, TRUE);
 221     //UpdateAuxiliaryXhair(player, trace_endpos, ('1 0 0' * player.vehicle_reload2) + ('0 1 0' * (1 - player.vehicle_reload2)), 2);
 222
 223     // Rotate head
 224     ftmp = autocvar_g_vehicle_spiderbot_head_turnspeed * sys_frametime;
 225     ad_y = bound(-ftmp, ad_y, ftmp);
 226     spider.tur_head.angles_y = bound(autocvar_g_vehicle_spiderbot_head_turnlimit * -1, spider.tur_head.angles_y + ad_y, autocvar_g_vehicle_spiderbot_head_turnlimit);
 227
 228     // Pitch head
 229     ftmp = autocvar_g_vehicle_spiderbot_head_pitchspeed * sys_frametime;
 230     ad_x = bound(ftmp * -1, ad_x, ftmp);
 231     spider.tur_head.angles_x = bound(autocvar_g_vehicle_spiderbot_head_pitchlimit_down, spider.tur_head.angles_x + ad_x, autocvar_g_vehicle_spiderbot_head_pitchlimit_up);
 232
 233     // Turn Body
 234     ftmp = autocvar_g_vehicle_spiderbot_turnspeed * sys_frametime;
 235     ftmp = bound(-ftmp, spider.tur_head.angles_y, ftmp);
 236
 237     //fixedmakevectors(spider.angles);
 238     makevectors(spider.angles + '-2 0 0' * spider.angles_x);
 239
 240     movelib_groundalign4point(autocvar_g_vehicle_spiderbot_springlength, autocvar_g_vehicle_spiderbot_springup, autocvar_g_vehicle_spiderbot_springblend);
 241
 242     if(spider.flags & FL_ONGROUND)
 243     {
 244         if(spider.frame == 4 && self.tur_head.wait != 0)
 245         {
 246             sound (self, CH_TRIGGER_SINGLE, "vehicles/spiderbot_land.wav", VOL_VEHICLEENGINE, ATTN_NORM);
 247             spider.frame = 5;
 248         }
 249
 250         if(player.BUTTON_JUMP && self.tur_head.wait < time)
 251         {
 252             sound (self, CH_TRIGGER_SINGLE, "vehicles/spiderbot_jump.wav", VOL_VEHICLEENGINE, ATTN_NORM);
 253             //dprint("spiderbot_jump:", ftos(soundlength("vehicles/spiderbot_jump.wav")), "\n");
 254             self.delay = 0;
 255
 256             self.tur_head.wait = time + 2;
 257             player.BUTTON_JUMP = 0;
 258             spider.velocity   = v_forward * 700 + v_up * 600;
 259             spider.frame = 4;
 260         }
 261         else
 262         {
 263             if(vlen(player.movement) == 0)
 264             {
 265                 if(self.sound_nexttime < time || self.delay != 3)
 266                 {
 267                     self.delay = 3;
 268                     self.sound_nexttime = time + 6.486500; //soundlength("vehicles/spiderbot_idle.wav");
 269                     //dprint("spiderbot_idle:", ftos(soundlength("vehicles/spiderbot_idle.wav")), "\n");
 270                     sound (self, CH_TRIGGER_SINGLE, "vehicles/spiderbot_idle.wav", VOL_VEHICLEENGINE, ATTN_NORM);
 271                 }
 272                 movelib_beak_simple(autocvar_g_vehicle_spiderbot_speed_stop);
 273                 spider.frame = 5;
 274             }
 275             else
 276             {
 277                 spider.angles_y = anglemods(spider.angles_y + ftmp);
 278                 spider.tur_head.angles_y -= ftmp;
 279
 280                 if(player.movement_x != 0)
 281                 {
 282                     if(player.movement_x > 0)
 283                     {
 284                         player.movement_x = 1;
 285                         spider.frame = 0;
 286                     }
 287                     else if(player.movement_x < 0)
 288                     {
 289                         player.movement_x = -1;
 290                         spider.frame = 1;
 291                     }
 292                     player.movement_y = 0;
 293                     movelib_move_simple(normalize(v_forward * player.movement_x),autocvar_g_vehicle_spiderbot_speed_walk,autocvar_g_vehicle_spiderbot_movement_inertia);
 294
 295                     if(self.sound_nexttime < time || self.delay != 1)
 296                     {
 297                         self.delay = 1;
 298                         self.sound_nexttime = time + 6.486500; //soundlength("vehicles/spiderbot_walk.wav");
 299                         sound (self, CH_TRIGGER_SINGLE, "vehicles/spiderbot_walk.wav", VOL_VEHICLEENGINE, ATTN_NORM);
 300                         //dprint("spiderbot_walk:", ftos(soundlength("vehicles/spiderbot_walk.wav")), "\n");
 301                     }
 302                 }
 303                 else if(player.movement_y != 0)
 304                 {
 305                     if(player.movement_y < 0)
 306                     {
 307                         player.movement_y = -1;
 308                         spider.frame = 2;
 309                     }
 310                     else if(player.movement_y > 0)
 311                     {
 312                         player.movement_y = 1;
 313                         spider.frame = 3;
 314                     }
 315                     movelib_move_simple(normalize(v_right * player.movement_y),autocvar_g_vehicle_spiderbot_speed_strafe,autocvar_g_vehicle_spiderbot_movement_inertia);
 316                     if(self.sound_nexttime < time || self.delay != 2)
 317                     {
 318                         self.delay = 2;
 319                         self.sound_nexttime = time + 6.486500; //soundlength("vehicles/spiderbot_strafe.wav");
 320                         sound (self, CH_TRIGGER_SINGLE, "vehicles/spiderbot_strafe.wav", VOL_VEHICLEENGINE, ATTN_NORM);
 321                         //dprint("spiderbot_strafe:", ftos(soundlength("vehicles/spiderbot_strafe.wav")), "\n");
 322                     }
 323                 }
 324             }
 325         }
 326     }
 327
 328     self.angles_x = bound(-45, self.angles_x, 45);
 329     self.angles_z = bound(-45, self.angles_z, 45);
 330
 331     if(player.BUTTON_ATCK)
 332     {
 333         spider.cnt = time;
 334         if(spider.vehicle_ammo1 >= autocvar_g_vehicle_spiderbot_minigun_ammo_cost && spider.tur_head.attack_finished_single <= time)
 335         {
 336             entity gun;
 337             vector v;
 338             spider.misc_bulletcounter += 1;
 339
 340             self = player;
 341
 342             mod(spider.misc_bulletcounter, 2) ? gun = spider.gun1 : gun = spider.gun2;
 343             v = gettaginfo(gun, gettagindex(gun, "barrels"));
 344             v_forward = normalize(v_forward);
 345             v += v_forward * 50;
 346
 347             fireBullet (v, v_forward, autocvar_g_vehicle_spiderbot_minigun_spread, autocvar_g_vehicle_spiderbot_minigun_damage,
 348                 autocvar_g_vehicle_spiderbot_minigun_spread, DEATH_SBMINIGUN, 0);
 349
 350             sound (gun, CH_WEAPON_A, "weapons/uzi_fire.wav", VOL_BASE, ATTN_NORM);
 351             trailparticles(self, particleeffectnum("spiderbot_minigun_trail"), v, trace_endpos);
 352             pointparticles(particleeffectnum("spiderbot_minigun_muzzleflash"), v, v_forward * 2500, 1);
 353
 354             self = spider;
 355
 356             spider.vehicle_ammo1 -= autocvar_g_vehicle_spiderbot_minigun_ammo_cost;
 357             spider.tur_head.attack_finished_single = time + autocvar_g_vehicle_spiderbot_minigun_refire;
 358             player.vehicle_ammo1 = (spider.vehicle_ammo1 / autocvar_g_vehicle_spiderbot_minigun_ammo_max) * 100;
 359             spider.gun1.angles_z += 45;
 360             spider.gun2.angles_z -= 45;
 361             if(spider.gun1.angles_z >= 360)
 362             {
 363                 spider.gun1.angles_z = 0;
 364                 spider.gun2.angles_z = 0;
 365             }
 366         }
 367     }
 368     else
 369         vehicles_regen(cnt, vehicle_ammo1, autocvar_g_vehicle_spiderbot_minigun_ammo_max,
 370                                            autocvar_g_vehicle_spiderbot_minigun_ammo_regen_pause,
 371                                            autocvar_g_vehicle_spiderbot_minigun_ammo_regen, frametime);
 372
 373
 374     spiderbot_rocket_do();
 375
 376     if(self.vehicle_flags  & VHF_SHIELDREGEN)
 377         vehicles_regen(dmg_time, vehicle_shield, autocvar_g_vehicle_spiderbot_shield, autocvar_g_vehicle_spiderbot_shield_regen_pause, autocvar_g_vehicle_spiderbot_shield_regen, frametime);
 378
 379     if(self.vehicle_flags  & VHF_HEALTHREGEN)
 380         vehicles_regen(dmg_time, vehicle_health, autocvar_g_vehicle_spiderbot_health, autocvar_g_vehicle_spiderbot_health_regen_pause, autocvar_g_vehicle_spiderbot_health_regen, frametime);
 381
 382     player.BUTTON_ATCK = player.BUTTON_ATCK2 = 0;
 383     player.vehicle_ammo2 = spider.tur_head.frame;
 384
 385     if(spider.gun2.cnt <= time)
 386         player.vehicle_reload2 = 100;
 387     else
 388         player.vehicle_reload2 = 100 - ((spider.gun2.cnt - time) / spider.attack_finished_single) * 100;
 389
 390     setorigin(player, spider.origin + '0 0 1' * SPIDERBOT_MAX_z);
 391     player.velocity = spider.velocity;
 392
 393     VEHICLE_UPDATE_PLAYER(health, spiderbot);
 394
 395     if(self.vehicle_flags & VHF_HASSHIELD)
 396         VEHICLE_UPDATE_PLAYER(shield, spiderbot);
 397
 398     self = player;
 399     return 1;
 400 }
 401 void spiderbot_think()
 402 {
 403     if(self.flags & FL_ONGROUND)
 404         movelib_beak_simple(autocvar_g_vehicle_spiderbot_speed_stop);
 405
 406     self.nextthink = time;
 407 }
 408
 409 void spiderbot_enter()
 410 {
 411     self.movetype   = MOVETYPE_WALK;
 412
 413     self.owner.vehicle_health = (self.vehicle_health / autocvar_g_vehicle_spiderbot_health) * 100;
 414     self.owner.vehicle_shield = (self.vehicle_shield / autocvar_g_vehicle_spiderbot_shield) * 100;
 415
 416     if(self.owner.flagcarried)
 417     {
 418         setattachment(self.owner.flagcarried, self.tur_head, "");
 419         setorigin(self.owner.flagcarried, '-20 0 120');
 420     }
 421 }
 422
 423 void spiderbot_exit(float eject)
 424 {
 425     entity e;
 426     vector spot;
 427
 428     e = findchain(classname,"spiderbot_rocket");
 429     while(e)
 430     {
 431         if(e.owner == self.owner)
 432         {
 433             e.realowner = self.owner;
 434             e.owner = world;
 435         }
 436         e = e.chain;
 437     }
 438
 439     self.velocity   = '0 0 0';
 440     self.think      = spiderbot_think;
 441     self.nextthink  = time;
 442     self.frame      = 5;
 443     self.movetype   = MOVETYPE_WALK;
 444
 445     if not (self.owner)
 446         return;
 447
 448         makevectors(self.angles);
 449         if(eject)
 450         {
 451             spot = self.origin + v_forward * 100 + '0 0 64';
 452             spot = vehicles_findgoodexit(spot);
 453             setorigin(self.owner , spot);
 454             self.owner.velocity = (v_up + v_forward * 0.25) * 750;
 455         }
 456         else
 457         {
 458             spot = self.origin - v_forward * 200 + '0 0 64';
 459             spot = vehicles_findgoodexit(spot);
 460             setorigin(self.owner , spot);
 461         }
 462
 463     self.owner = world;
 464 }
 465 void spider_impact()
 466 {
 467     if(autocvar_g_vehicle_spiderbot_bouncepain_x)
 468         vehilces_impact(autocvar_g_vehicle_spiderbot_bouncepain_x, autocvar_g_vehicle_spiderbot_bouncepain_y, autocvar_g_vehicle_spiderbot_bouncepain_z);
 469 }
 470 void spiderbot_spawn()
 471 {
 472     self.frame              = 5;
 473     self.tur_head.frame     = 1;
 474     self.think              = spiderbot_think;
 475     self.nextthink          = time;
 476     self.vehicle_health     = autocvar_g_vehicle_spiderbot_health;
 477     self.vehicle_shield     = autocvar_g_vehicle_spiderbot_shield;
 478     self.movetype           = MOVETYPE_WALK;
 479     self.solid              = SOLID_SLIDEBOX;
 480     self.alpha              = self.tur_head.alpha = self.gun1.alpha = self.gun2.alpha = 1;
 481     self.tur_head.angles    = '0 0 0';
 482
 483     setorigin(self, self.pos1 + '0 0 128');
 484     self.angles = self.pos2;
 485     self.vehicle_impact = spider_impact;
 486 }
 487
 488 void spiderbot_headfade()
 489 {
 490         self.think = spiderbot_headfade;
 491         self.nextthink = self.fade_time;
 492         self.alpha = 1 - (time - self.fade_time) * self.fade_rate;
 493
 494     if(self.cnt < time || self.alpha < 0.1)
 495     {
 496         if(self.alpha > 0.1)
 497         {
 498             sound (self, CH_SHOTS, "weapons/rocket_impact.wav", VOL_BASE, ATTN_NORM);
 499             pointparticles(particleeffectnum("explosion_big"), self.origin + '0 0 100', '0 0 0', 1);
 500         }
 501         remove(self);
 502     }
 503 }
 504
 505 void spiderbot_blowup()
 506 {
 507     if(self.cnt > time)
 508     {
 509         if(random() < 0.1)
 510         {
 511             sound (self, CH_SHOTS, "weapons/rocket_impact.wav", VOL_BASE, ATTN_NORM);
 512             pointparticles(particleeffectnum("explosion_small"), randomvec() * 80 + (self.origin + '0 0 100'), '0 0 0', 1);
 513         }
 514         self.nextthink = time + 0.1;
 515         return;
 516     }
 517
 518     entity h, g1, g2, b;
 519     b = spawn();
 520     h = spawn();
 521     g1 = spawn();
 522     g2 = spawn();
 523
 524     setmodel(b,  "models/vehicles/spiderbot.dpm");
 525     setmodel(h,  "models/vehicles/spiderbot_top.dpm");
 526     setmodel(g1, "models/vehicles/spiderbot_barrels.dpm");
 527     setmodel(g2, "models/vehicles/spiderbot_barrels.dpm");
 528
 529     setorigin(b, self.origin);
 530     b.frame         = 11;
 531     b.angles        = self.angles;
 532     setsize(b, self.mins, self.maxs);
 533
 534     setorigin(h, gettaginfo(self, gettagindex(self, "tag_head")));
 535     h.movetype      = MOVETYPE_BOUNCE;
 536     h.solid         = SOLID_BBOX;
 537     h.velocity      = v_up * (500 + random() * 500) + randomvec() * 128;
 538     h.modelflags    = MF_ROCKET;
 539     h.effects       = EF_FLAME | EF_LOWPRECISION;
 540     h.avelocity     = randomvec() * 360;
 541
 542     h.alpha         = 1;
 543     h.cnt           = time + (3.5 * random());
 544     h.fade_rate     = 1 / min(autocvar_g_vehicle_spiderbot_respawntime, 10);
 545     h.fade_time     = time;
 546     h.think         = spiderbot_headfade;
 547     h.nextthink     = time;
 548
 549     setorigin(g1, gettaginfo(self.tur_head, gettagindex(self.tur_head, "tag_hardpoint01")));
 550     g1.movetype     = MOVETYPE_TOSS;
 551     g1.solid        = SOLID_CORPSE;
 552     g1.velocity     = v_forward * 700 + (randomvec() * 32);
 553     g1.avelocity    = randomvec() * 180;
 554
 555     setorigin(g2, gettaginfo(self.tur_head, gettagindex(self.tur_head, "tag_hardpoint02")));
 556     g2.movetype     = MOVETYPE_TOSS;
 557     g2.solid        = SOLID_CORPSE;
 558     g2.velocity     = v_forward * 700 + (randomvec() * 32);
 559     g2.avelocity    = randomvec() * 180;
 560
 561     h.colormod = b.colormod = g1.colormod = g2.colormod = '-2 -2 -2';
 562
 563     SUB_SetFade(b,  time + 5, min(autocvar_g_vehicle_spiderbot_respawntime, 1));
 564     //SUB_SetFade(h,  time, min(autocvar_g_vehicle_spiderbot_respawntime, 10));
 565     SUB_SetFade(g1, time, min(autocvar_g_vehicle_spiderbot_respawntime, 10));
 566     SUB_SetFade(g2, time, min(autocvar_g_vehicle_spiderbot_respawntime, 10));
 567
 568     RadiusDamage (self, self, 250, 15, 250, world, 250, DEATH_SBBLOWUP, world);
 569
 570     self.alpha = self.tur_head.alpha = self.gun1.alpha = self.gun2.alpha = -1;
 571     self.movetype   = MOVETYPE_NONE;
 572     self.deadflag   = DEAD_DEAD;
 573     self.solid      = SOLID_NOT;
 574     self.tur_head.effects  &~=  EF_FLAME;
 575         self.vehicle_hudmodel.viewmodelforclient = self;
 576 }
 577
 578 void spiderbot_die()
 579 {
 580     self.health             = 0;
 581     self.event_damage       = SUB_Null;
 582     self.takedamage         = DAMAGE_NO;
 583     self.touch              = SUB_Null;
 584     self.cnt                = 3.4 + time + random() * 2;
 585     self.think              = spiderbot_blowup;
 586     self.nextthink          = time;
 587     self.deadflag           = DEAD_DYING;
 588         self.frame              = 5;
 589         self.tur_head.effects  |= EF_FLAME;
 590         self.colormod           = self.tur_head.colormod = '-1 -1 -1';
 591         self.frame              = 10;
 592         self.movetype           = MOVETYPE_TOSS;
 593 }
 594
 595 void vewhicle_spiderbot_dinit()
 596 {
 597     if not (vehicle_initialize(
 598              "Spiderbot",
 599              "models/vehicles/spiderbot.dpm",
 600              "models/vehicles/spiderbot_top.dpm",
 601              "models/vehicles/spiderbot_cockpit.dpm",
 602              "tag_head", "tag_hud", "",
 603              HUD_SPIDERBOT,
 604              SPIDERBOT_MIN, SPIDERBOT_MAX,
 605              FALSE,
 606              spiderbot_spawn, autocvar_g_vehicle_spiderbot_respawntime,
 607              spiderbot_frame,
 608              spiderbot_enter, spiderbot_exit,
 609              spiderbot_die,   spiderbot_think,
 610              FALSE))
 611     {
 612         remove(self);
 613         return;
 614     }
 615
 616
 617     self.gun1               = spawn();
 618     self.gun2               = spawn();
 619
 620     setmodel(self.gun1, "models/vehicles/spiderbot_barrels.dpm");
 621     setmodel(self.gun2, "models/vehicles/spiderbot_barrels.dpm");
 622
 623     setattachment(self.gun1, self.tur_head, "tag_hardpoint01");
 624     setattachment(self.gun2, self.tur_head, "tag_hardpoint02");
 625
 626     self.gravity            = 2;
 627     self.mass               = 5000;
 628 }
 629
 630 void spawnfunc_vehicle_spiderbot()
 631 {
 632     self.vehicle_flags |= VHF_DMGSHAKE;
 633     //self.vehicle_flags |= VHF_DMGROLL;
 634     //self.vehicle_flags |= VHF_DMGHEADROLL;
 635
 636     precache_model ( "models/vhshield.md3");
 637     precache_model ( "models/vehicles/spiderbot.dpm");
 638     precache_model ( "models/vehicles/spiderbot_top.dpm");
 639     precache_model ( "models/vehicles/spiderbot_barrels.dpm");
 640     precache_model ( "models/vehicles/spiderbot_cockpit.dpm");
 641     precache_model ( "models/uziflash.md3");
 642
 643     precache_sound ( "weapons/uzi_fire.wav" );
 644     precache_sound ( "weapons/rocket_impact.wav");
 645
 646     precache_sound ( "vehicles/spiderbot_die.wav");
 647     precache_sound ( "vehicles/spiderbot_idle.wav");
 648     precache_sound ( "vehicles/spiderbot_jump.wav");
 649     precache_sound ( "vehicles/spiderbot_strafe.wav");
 650     precache_sound ( "vehicles/spiderbot_walk.wav");
 651     precache_sound ( "vehicles/spiderbot_land.wav");
 652
 653     vehicles_configcheck("vehicle_spiderbot.cfg", autocvar_g_vehicle_spiderbot_health);
 654     if(autocvar_g_vehicle_spiderbot_shield)
 655         self.vehicle_flags |= VHF_HASSHIELD;
 656
 657     if(autocvar_g_vehicle_spiderbot_shield_regen)
 658         self.vehicle_flags |= VHF_SHIELDREGEN;
 659
 660     if(autocvar_g_vehicle_spiderbot_health_regen)
 661         self.vehicle_flags |= VHF_HEALTHREGEN;
 662
 663     self.think = vewhicle_spiderbot_dinit;
 664
 665     if(g_assault)
 666         self.nextthink = time + 0.5;
 667     else
 668         self.nextthink = time + (autocvar_g_vehicles_delayspawn ? autocvar_g_vehicle_spiderbot_respawntime + (random() * autocvar_g_vehicles_delayspawn_jitter) : 0.5);
 669 }
 670 #endif // SVQC