qcsrc/server/w_laser.qc

   1 #ifdef REGISTER_WEAPON
   2 REGISTER_WEAPON(LASER, w_laser, 0, 1, WEP_FLAG_NORMAL | WEP_FLAG_CANCLIMB | WEP_TYPE_SPLASH, 0, "laser", "laser", "Laser");
   3 #else
   4 #ifdef SVQC
   5 void(float imp) W_SwitchWeapon;
   6
   7 void W_Laser_Touch (void)
   8 {
   9         PROJECTILE_TOUCH;
  10
  11         self.event_damage = SUB_Null;
  12         if (self.dmg)
  13                 RadiusDamage (self, self.owner, cvar("g_balance_laser_secondary_damage"), cvar("g_balance_laser_secondary_edgedamage"), cvar("g_balance_laser_secondary_radius"), world, cvar("g_balance_laser_secondary_force"), self.projectiledeathtype, other);
  14         else
  15                 RadiusDamage (self, self.owner, cvar("g_balance_laser_primary_damage"), cvar("g_balance_laser_primary_edgedamage"), cvar("g_balance_laser_primary_radius"), world, cvar("g_balance_laser_primary_force"), self.projectiledeathtype, other);
  16
  17         remove (self);
  18 }
  19
  20 void W_Laser_Think()
  21 {
  22         self.movetype = MOVETYPE_FLY;
  23         self.think = SUB_Remove;
  24         if (self.dmg)
  25                 self.nextthink = time + cvar("g_balance_laser_secondary_lifetime");
  26         else
  27                 self.nextthink = time + cvar("g_balance_laser_primary_lifetime");
  28         CSQCProjectile(self, TRUE, PROJECTILE_LASER, TRUE);
  29 }
  30
  31 void W_Laser_Attack (float issecondary)
  32 {
  33         local entity missile;
  34         vector s_forward;
  35         float a;
  36         float nodamage;
  37
  38         if(issecondary == 2) // minstanex shot
  39                 nodamage = g_minstagib;
  40         else
  41                 nodamage = FALSE;
  42
  43         a = cvar("g_balance_laser_primary_shotangle");
  44         s_forward = v_forward * cos(a * DEG2RAD) + v_up * sin(a * DEG2RAD);
  45
  46         if(nodamage)
  47                 W_SetupShot_Dir (self, s_forward, FALSE, 3, "weapons/lasergun_fire.wav", 0);
  48         else if(issecondary == 1)
  49                 W_SetupShot_Dir (self, s_forward, FALSE, 3, "weapons/lasergun_fire.wav", cvar("g_balance_laser_secondary_damage"));
  50         else
  51                 W_SetupShot_Dir (self, s_forward, FALSE, 3, "weapons/lasergun_fire.wav", cvar("g_balance_laser_primary_damage"));
  52         pointparticles(particleeffectnum("laser_muzzleflash"), w_shotorg, w_shotdir * 1000, 1);
  53
  54         missile = spawn ();
  55         missile.owner = self;
  56         missile.classname = "laserbolt";
  57         missile.dmg = 0;
  58         if(!nodamage)
  59         {
  60                 missile.bot_dodge = TRUE;
  61                 missile.bot_dodgerating = cvar("g_balance_laser_primary_damage");
  62         }
  63
  64         PROJECTILE_MAKETRIGGER(missile);
  65         missile.projectiledeathtype = WEP_LASER;
  66
  67         setorigin (missile, w_shotorg);
  68         setsize(missile, '0 0 0', '0 0 0');
  69
  70         W_SETUPPROJECTILEVELOCITY(missile, g_balance_laser_primary);
  71         missile.angles = vectoangles (missile.velocity);
  72         //missile.glow_color = 250; // 244, 250
  73         //missile.glow_size = 120;
  74         missile.touch = W_Laser_Touch;
  75
  76         missile.flags = FL_PROJECTILE;
  77
  78         missile.think = W_Laser_Think;
  79         missile.nextthink = time + cvar("g_balance_laser_primary_delay");
  80
  81         other = missile; MUTATOR_CALLHOOK(EditProjectile);
  82
  83         if(time >= missile.nextthink)
  84         {
  85                 entity oldself;
  86                 oldself = self;
  87                 self = missile;
  88                 self.think();
  89                 self = oldself;
  90         }
  91 }
  92
  93 .vector hook_start, hook_end;
  94 float gauntletbeam_send(entity to, float sf)
  95 {
  96         WriteByte(MSG_ENTITY, ENT_CLIENT_GAUNTLET);
  97         sf = sf & 0x7F;
  98         if(sound_allowed(MSG_BROADCAST, self.owner))
  99                 sf |= 0x80;
 100         WriteByte(MSG_ENTITY, sf);
 101         if(sf & 1)
 102         {
 103                 WriteByte(MSG_ENTITY, num_for_edict(self.owner));
 104         }
 105         if(sf & 2)
 106         {
 107                 WriteCoord(MSG_ENTITY, self.hook_start_x);
 108                 WriteCoord(MSG_ENTITY, self.hook_start_y);
 109                 WriteCoord(MSG_ENTITY, self.hook_start_z);
 110         }
 111         if(sf & 4)
 112         {
 113                 WriteCoord(MSG_ENTITY, self.hook_end_x);
 114                 WriteCoord(MSG_ENTITY, self.hook_end_y);
 115                 WriteCoord(MSG_ENTITY, self.hook_end_z);
 116         }
 117         return TRUE;
 118 }
 119 .entity gauntletbeam;
 120 .float prevgauntletfire;
 121 void gauntletbeam_think()
 122 {
 123         float damage, myforce, myradius;
 124         damage = cvar("g_balance_laser_secondary_damage");
 125         myforce = cvar("g_balance_laser_secondary_force");
 126         myradius = cvar("g_balance_laser_secondary_radius");
 127
 128         self.owner.prevgauntletfire = time;
 129         if (self.owner.weaponentity.state != WS_INUSE || self != self.owner.gauntletbeam || self.owner.deadflag != DEAD_NO || !self.owner.BUTTON_ATCK2)
 130         {
 131                 remove(self);
 132                 return;
 133         }
 134
 135         self.nextthink = time;
 136
 137         makevectors(self.owner.v_angle);
 138
 139         float dt;
 140         dt = frametime;
 141
 142         W_SetupShot_Range(self.owner, TRUE, 0, "", damage * dt, myradius);
 143         WarpZone_traceline_antilag(self.owner, w_shotorg, w_shotend, MOVE_NORMAL, self.owner, ANTILAG_LATENCY(self.owner));
 144
 145         // apply the damage
 146         if(trace_ent)
 147         {
 148                 vector force;
 149                 force = w_shotdir * myforce;
 150                 Damage (trace_ent, self.owner, self.owner, damage * dt, WEP_LASER | HITTYPE_SECONDARY, trace_endpos, force * dt);
 151                 Damage_RecordDamage(self.owner, WEP_LASER | HITTYPE_SECONDARY, damage * dt);
 152         }
 153
 154         // draw effect
 155         if(w_shotorg != self.hook_start)
 156         {
 157                 self.SendFlags |= 2;
 158                 self.hook_start = w_shotorg;
 159         }
 160         if(w_shotend != self.hook_end)
 161         {
 162                 self.SendFlags |= 4;
 163                 self.hook_end = w_shotend;
 164         }
 165 }
 166
 167 // experimental gauntlet
 168 void W_Laser_Attack2 ()
 169 {
 170         // only play fire sound if 0.5 sec has passed since player let go the fire button
 171         if(time - self.prevgauntletfire > 0.5)
 172         {
 173                 sound (self, CHAN_WEAPON, "weapons/gauntlet_fire.wav", VOL_BASE, ATTN_NORM);
 174         }
 175
 176         entity beam, oldself;
 177
 178         self.gauntletbeam = beam = spawn();
 179         beam.solid = SOLID_NOT;
 180         beam.think = gauntletbeam_think;
 181         beam.owner = self;
 182         beam.movetype = MOVETYPE_NONE;
 183         beam.shot_spread = 0;
 184         beam.bot_dodge = TRUE;
 185         beam.bot_dodgerating = cvar("g_balance_laser_primary_damage");
 186         Net_LinkEntity(beam, FALSE, 0, gauntletbeam_send);
 187
 188         oldself = self;
 189         self = beam;
 190         self.think();
 191         self = oldself;
 192 }
 193
 194 void LaserInit()
 195 {
 196         weapon_action(WEP_LASER, WR_PRECACHE);
 197         gauntlet_shotorigin[0] = shotorg_adjust_values(CL_Weapon_GetShotOrg(WEP_LASER), FALSE, FALSE, 1);
 198         gauntlet_shotorigin[1] = shotorg_adjust_values(CL_Weapon_GetShotOrg(WEP_LASER), FALSE, FALSE, 2);
 199         gauntlet_shotorigin[2] = shotorg_adjust_values(CL_Weapon_GetShotOrg(WEP_LASER), FALSE, FALSE, 3);
 200         gauntlet_shotorigin[3] = shotorg_adjust_values(CL_Weapon_GetShotOrg(WEP_LASER), FALSE, FALSE, 4);
 201 }
 202
 203 void spawnfunc_weapon_laser (void)
 204 {
 205         weapon_defaultspawnfunc(WEP_LASER);
 206 }
 207
 208 float w_laser(float req)
 209 {
 210         local float r1;
 211         local float r2;
 212         if (req == WR_AIM)
 213         {
 214                 if(cvar("g_balance_laser_secondary"))
 215                 {
 216                         r1 = cvar("g_balance_laser_primary_damage");
 217                         r2 = cvar("g_balance_laser_secondary_damage");
 218                         if (random() * (r2 + r1) > r1)
 219                                 self.BUTTON_ATCK2 = bot_aim(cvar("g_balance_laser_secondary_speed"), 0, cvar("g_balance_laser_secondary_lifetime"), FALSE);
 220                         else
 221                                 self.BUTTON_ATCK = bot_aim(cvar("g_balance_laser_primary_speed"), 0, cvar("g_balance_laser_primary_lifetime"), FALSE);
 222                 }
 223                 else
 224                         self.BUTTON_ATCK = bot_aim(cvar("g_balance_laser_primary_speed"), 0, cvar("g_balance_laser_primary_lifetime"), FALSE);
 225         }
 226         else if (req == WR_THINK)
 227         {
 228                 if (self.BUTTON_ATCK)
 229                 if (weapon_prepareattack(0, cvar("g_balance_laser_primary_refire")))
 230                 {
 231                         W_Laser_Attack(1);
 232                         weapon_thinkf(WFRAME_FIRE1, cvar("g_balance_laser_primary_animtime"), w_ready);
 233                 }
 234                 if (self.BUTTON_ATCK2)
 235                 {
 236                         if(cvar("g_balance_laser_secondary"))
 237                         {
 238                                 if (weapon_prepareattack(0, 0))
 239                                 {
 240                                         W_Laser_Attack2();
 241                                         weapon_thinkf(WFRAME_FIRE2, cvar("g_balance_laser_secondary_animtime"), w_ready);
 242                                 }
 243                         }
 244                         else
 245                         {
 246                                 if(self.switchweapon == WEP_LASER) // don't do this if already switching
 247                                         W_SwitchWeapon (self.cnt);
 248                         }
 249                 }
 250         }
 251         else if (req == WR_PRECACHE)
 252         {
 253                 precache_model ("models/weapons/g_laser.md3");
 254                 precache_model ("models/weapons/v_laser.md3");
 255                 precache_model ("models/weapons/h_laser.iqm");
 256                 precache_sound ("weapons/lasergun_fire.wav");
 257                 precache_sound ("weapons/gauntlet_fire.wav");
 258         }
 259         else if (req == WR_SETUP)
 260                 weapon_setup(WEP_LASER);
 261         else if (req == WR_CHECKAMMO1)
 262                 return TRUE;
 263         else if (req == WR_CHECKAMMO2)
 264                 return TRUE;
 265         return TRUE;
 266 };
 267 #endif
 268 #ifdef CSQC
 269 float w_laser(float req)
 270 {
 271         if(req == WR_IMPACTEFFECT)
 272         {
 273                 vector org2;
 274                 org2 = w_org + w_backoff * 6;
 275                 pointparticles(particleeffectnum("laser_impact"), org2, w_backoff * 1000, 1);
 276                 if(!w_issilent)
 277                         sound(self, CHAN_PROJECTILE, "weapons/laserimpact.wav", VOL_BASE, ATTN_NORM);
 278         }
 279         else if(req == WR_PRECACHE)
 280         {
 281                 precache_sound("weapons/laserimpact.wav");
 282         }
 283         else if (req == WR_SUICIDEMESSAGE)
 284                 w_deathtypestring = "%s lasered themself to hell";
 285         else if (req == WR_KILLMESSAGE)
 286         {
 287                 if(w_deathtype & HITTYPE_SECONDARY)
 288                         w_deathtypestring = "%s was cut in half by %s's gauntlet"; // unchecked: SPLASH
 289                 else
 290                         w_deathtypestring = "%s was lasered to death by %s"; // unchecked: SPLASH
 291         }
 292         return TRUE;
 293 }
 294 #endif
 295 #endif