Merge branch 'master' into terencehill/music_player
[xonotic/xonotic-data.pk3dir.git] / qcsrc / client / csqcmodel_hooks.qc
1 void CSQCModel_Hook_PreDraw(float isplayer);
2
3 .float isplayermodel;
4
5 // FEATURE: LOD
6 .float lodmodelindex0;
7 .float lodmodelindex1;
8 .float lodmodelindex2;
9 void CSQCPlayer_LOD_Apply(void)
10 {
11         // LOD model loading
12         if(self.lodmodelindex0 != self.modelindex)
13         {
14                 string modelname = self.model;
15                 string s;
16
17                 vector mi = self.mins;
18                 vector ma = self.maxs;
19
20                 // set modelindex
21                 self.lodmodelindex0 = self.modelindex;
22                 self.lodmodelindex1 = self.modelindex;
23                 self.lodmodelindex2 = self.modelindex;
24
25                 // FIXME: this only supports 3-letter extensions
26                 s = strcat(substring(modelname, 0, strlen(modelname)-4), "_lod1", substring(modelname, -4, 4));
27                 if(fexists(s))
28                 {
29                         precache_model(s);
30                         setmodel(self, s);
31                         if(self.modelindex)
32                                 self.lodmodelindex1 = self.modelindex;
33                 }
34
35                 s = strcat(substring(modelname, 0, strlen(modelname)-4), "_lod2", substring(modelname, -4, 4));
36                 if(fexists(s))
37                 {
38                         precache_model(s);
39                         setmodel(self, s);
40                         if(self.modelindex)
41                                 self.lodmodelindex2 = self.modelindex;
42                 }
43
44                 setmodel(self, modelname); // make everything normal again
45                 setsize(self, mi, ma);
46         }
47
48         // apply LOD
49         if(autocvar_cl_playerdetailreduction <= 0)
50         {
51                 if(autocvar_cl_playerdetailreduction <= -2)
52                         self.modelindex = self.lodmodelindex2;
53                 else if(autocvar_cl_playerdetailreduction <= -1)
54                         self.modelindex = self.lodmodelindex1;
55                 else
56                         self.modelindex = self.lodmodelindex0;
57         }
58         else
59         {
60                 float distance = vlen(self.origin - view_origin);
61                 float f = (distance * current_viewzoom + 100.0) * autocvar_cl_playerdetailreduction;
62                 f *= 1.0 / bound(0.01, view_quality, 1);
63                 if(f > autocvar_cl_loddistance2)
64                         self.modelindex = self.lodmodelindex2;
65                 else if(f > autocvar_cl_loddistance1)
66                         self.modelindex = self.lodmodelindex1;
67                 else
68                         self.modelindex = self.lodmodelindex0;
69         }
70 }
71
72 // FEATURE: forcemodel and model color selection (MUST be called BEFORE LOD!)
73 string forceplayermodels_model;
74 float forceplayermodels_modelisgoodmodel;
75 float forceplayermodels_modelindex;
76 float forceplayermodels_skin;
77
78 string forceplayermodels_mymodel;
79 float forceplayermodels_myisgoodmodel;
80 float forceplayermodels_mymodelindex;
81
82 float forceplayermodels_attempted;
83
84 .string forceplayermodels_savemodel;
85 .float forceplayermodels_savemodelindex;
86 .float forceplayermodels_saveskin;
87 .float forceplayermodels_savecolormap;
88
89 .string forceplayermodels_isgoodmodel_mdl;
90 .float forceplayermodels_isgoodmodel;
91
92 string forceplayermodels_goodmodel;
93 float forceplayermodels_goodmodelindex;
94
95 .vector glowmod;
96 .vector old_glowmod;
97
98 void CSQCPlayer_ModelAppearance_PreUpdate(void)
99 {
100         self.model = self.forceplayermodels_savemodel;
101         self.modelindex = self.forceplayermodels_savemodelindex;
102         self.skin = self.forceplayermodels_saveskin;
103         self.colormap = self.forceplayermodels_savecolormap;
104 }
105 void CSQCPlayer_ModelAppearance_PostUpdate(void)
106 {
107         self.forceplayermodels_savemodel = self.model;
108         self.forceplayermodels_savemodelindex = self.modelindex;
109         self.forceplayermodels_saveskin = self.skin;
110         self.forceplayermodels_savecolormap = self.colormap;
111
112         if(self.forceplayermodels_savemodel != self.forceplayermodels_isgoodmodel_mdl)
113         {
114                 self.forceplayermodels_isgoodmodel = fexists(self.forceplayermodels_savemodel);
115                 self.forceplayermodels_isgoodmodel_mdl = self.forceplayermodels_savemodel;
116                 if(!self.forceplayermodels_isgoodmodel)
117                         printf("Warning: missing model %s has been used\n", self.forceplayermodels_savemodel);
118         }
119 }
120 void CSQCPlayer_ModelAppearance_Apply(float islocalplayer)
121 {
122         // FORCEMODEL
123         // which one is ALWAYS good?
124         if (!forceplayermodels_goodmodel)
125         {
126                 entity e;
127                 e = spawn();
128                 precache_model(cvar_defstring("_cl_playermodel"));
129                 setmodel(e, cvar_defstring("_cl_playermodel"));
130                 forceplayermodels_goodmodel = e.model;
131                 forceplayermodels_goodmodelindex = e.modelindex;
132                 remove(e);
133         }
134
135         // first, try finding it from the server
136         if(self.forceplayermodels_savemodelindex && self.forceplayermodels_savemodel != "null")
137         {
138                 if(islocalplayer)
139                 {
140                         if(!isdemo()) // this is mainly cheat protection; not needed for demos
141                         {
142                                 // trust server's idea of "own player model"
143                                 forceplayermodels_modelisgoodmodel = self.forceplayermodels_isgoodmodel;
144                                 forceplayermodels_model = self.forceplayermodels_savemodel;
145                                 forceplayermodels_modelindex = self.forceplayermodels_savemodelindex;
146                                 forceplayermodels_skin = self.forceplayermodels_saveskin;
147                                 forceplayermodels_attempted = 1;
148                         }
149                 }
150         }
151
152         // forcemodel finding
153         if(!forceplayermodels_attempted)
154         {
155                 forceplayermodels_attempted = 1;
156
157                 // only if this failed, find it out on our own
158                 entity e;
159                 e = spawn();
160                 setmodel(e, autocvar__cl_playermodel); // this is harmless, see below
161                 forceplayermodels_modelisgoodmodel = fexists(e.model);
162                 forceplayermodels_model = e.model;
163                 forceplayermodels_modelindex = e.modelindex;
164                 forceplayermodels_skin = autocvar__cl_playerskin;
165                 remove(e);
166         }
167
168         if(autocvar_cl_forcemyplayermodel != "" && autocvar_cl_forcemyplayermodel != forceplayermodels_mymodel)
169         {
170                 entity e;
171                 e = spawn();
172                 setmodel(e, autocvar_cl_forcemyplayermodel); // this is harmless, see below
173                 forceplayermodels_myisgoodmodel = fexists(e.model);
174                 forceplayermodels_mymodel = e.model;
175                 forceplayermodels_mymodelindex = e.modelindex;
176                 remove(e);
177         }
178
179         // apply it
180         float isfriend;
181         float cm;
182         cm = self.forceplayermodels_savecolormap;
183         cm = (cm >= 1024) ? cm : (stof(getplayerkeyvalue(cm - 1, "colors")) + 1024);
184
185         if(teamplay)
186                 isfriend = (cm == 1024 + 17 * myteam);
187         else
188                 isfriend = islocalplayer;
189
190         if(autocvar_cl_forcemyplayermodel != "" && forceplayermodels_myisgoodmodel && isfriend)
191         {
192                 self.model = forceplayermodels_mymodel;
193                 self.modelindex = forceplayermodels_mymodelindex;
194                 self.skin = autocvar_cl_forcemyplayerskin;
195         }
196         else if(autocvar_cl_forceplayermodels && forceplayermodels_modelisgoodmodel)
197         {
198                 self.model = forceplayermodels_model;
199                 self.modelindex = forceplayermodels_modelindex;
200                 self.skin = forceplayermodels_skin;
201         }
202         else if(self.forceplayermodels_isgoodmodel)
203         {
204                 self.model = self.forceplayermodels_savemodel;
205                 self.modelindex = self.forceplayermodels_savemodelindex;
206                 self.skin = self.forceplayermodels_saveskin;
207         }
208         else
209         {
210                 self.model = forceplayermodels_goodmodel;
211                 self.modelindex = forceplayermodels_goodmodelindex;
212                 self.skin = self.forceplayermodels_saveskin;
213         }
214
215         // forceplayercolors too
216         if(teamplay)
217         {
218                 // own team's color is never forced
219                 float forcecolor_friend = 0;
220                 float forcecolor_enemy = 0;
221                 entity tm;
222
223                 if(autocvar_cl_forcemyplayercolors)
224                         forcecolor_friend = 1024 + autocvar_cl_forcemyplayercolors;
225                 if(autocvar_cl_forceplayercolors && team_count == 2)
226                         forcecolor_enemy = 1024 + autocvar__cl_color;
227
228                 if(forcecolor_enemy && !forcecolor_friend)
229                 {
230                         // only enemy color is forced?
231                         // verify it is not equal to the friend color
232                         if(forcecolor_enemy == 1024 + 17 * myteam)
233                                 forcecolor_enemy = 0;
234                 }
235
236                 if(forcecolor_friend && !forcecolor_enemy)
237                 {
238                         // only friend color is forced?
239                         // verify it is not equal to the enemy color
240                         for(tm = teams.sort_next; tm; tm = tm.sort_next)
241                                 // note: we even compare against our own team.
242                                 // if we rejected because we matched our OWN team color,
243                                 // this is not bad; we then simply keep our color as is
244                                 // anyway.
245                                 if(forcecolor_friend == 1024 + 17 * tm.team)
246                                         forcecolor_friend = 0;
247                 }
248
249                 if(cm == 1024 + 17 * myteam)
250                 {
251                         if(forcecolor_friend)
252                                 self.colormap = forcecolor_friend;
253                 }
254                 else
255                 {
256                         if(forcecolor_enemy)
257                                 self.colormap = forcecolor_enemy;
258                 }
259         }
260         else
261         {
262                 if(autocvar_cl_forcemyplayercolors && islocalplayer)
263                         self.colormap = 1024 + autocvar_cl_forcemyplayercolors;
264                 else if(autocvar_cl_forceplayercolors)
265                         self.colormap = player_localnum + 1;
266         }
267
268         // GLOWMOD AND DEATH FADING
269         if(self.colormap > 0)
270                 self.glowmod = colormapPaletteColor(((self.colormap >= 1024) ? self.colormap : stof(getplayerkeyvalue(self.colormap - 1, "colors"))) & 0x0F, TRUE) * 2;
271         else
272                 self.glowmod = '1 1 1';
273
274         if(autocvar_cl_deathglow > 0)
275         {
276                 if(self.csqcmodel_isdead)
277                 {
278                         // Fade out to black now...
279                         if(self.old_glowmod == '0 0 0') { self.old_glowmod = self.glowmod; }
280                         self.colormap = 0;
281
282                         self.glowmod = self.old_glowmod * bound(0, 1 - (time - self.death_time) / autocvar_cl_deathglow, 1);
283                         self.glowmod_x = max(self.glowmod_x, 0.0001);
284                         self.glowmod_y = max(self.glowmod_y, 0.0001);
285                         self.glowmod_z = max(self.glowmod_z, 0.0001);
286                 }
287                 else if(self.old_glowmod != '0 0 0') { self.old_glowmod = '0 0 0'; }
288         }
289
290         //printf("CSQCPlayer_ModelAppearance_Apply(): state = %s, colormap = %f, glowmod = %s\n", (self.csqcmodel_isdead ? "DEAD" : "ALIVE"), self.colormap, vtos(self.glowmod));
291 }
292
293 // FEATURE: fallback frames
294 .float csqcmodel_saveframe;
295 .float csqcmodel_saveframe2;
296 #ifdef CSQCMODEL_HAVE_TWO_FRAMES
297 .float csqcmodel_saveframe3;
298 .float csqcmodel_saveframe4;
299 #endif
300 .float csqcmodel_framecount;
301
302 #define IS_DEAD_FRAME(f) ((f) == 0 || (f) == 1)
303 void CSQCPlayer_FallbackFrame_PreUpdate(void)
304 {
305         self.frame = self.csqcmodel_saveframe;
306         self.frame2 = self.csqcmodel_saveframe2;
307 #ifdef CSQCMODEL_HAVE_TWO_FRAMES
308         self.frame3 = self.csqcmodel_saveframe3;
309         self.frame4 = self.csqcmodel_saveframe4;
310 #endif
311 }
312 void CSQCPlayer_FallbackFrame_PostUpdate(float isnew)
313 {
314         self.csqcmodel_saveframe = self.frame;
315         self.csqcmodel_saveframe2 = self.frame2;
316 #ifdef CSQCMODEL_HAVE_TWO_FRAMES
317         self.csqcmodel_saveframe3 = self.frame3;
318         self.csqcmodel_saveframe4 = self.frame4;
319 #endif
320
321         // hack for death animations: set their frametime to zero in case a
322         // player "pops in"
323         if(isnew)
324         {
325 #define FIX_FRAMETIME(f,ft) \
326                 if(IS_DEAD_FRAME(self.f) && self.ft != 0 && self.death_time != 0) \
327                 { \
328                         self.ft = self.death_time; \
329                 }
330                 FIX_FRAMETIME(frame, frame1time)
331                 FIX_FRAMETIME(frame2, frame2time)
332 #ifdef CSQCMODEL_HAVE_TWO_FRAMES
333                 FIX_FRAMETIME(frame3, frame3time)
334                 FIX_FRAMETIME(frame4, frame4time)
335 #endif
336         }
337         self.csqcmodel_isdead = IS_DEAD_FRAME(self.frame);
338 }
339 void CSQCPlayer_AnimDecide_PostUpdate(float isnew)
340 {
341         self.csqcmodel_isdead = !!(self.anim_state & (ANIMSTATE_DEAD1 | ANIMSTATE_DEAD2));
342 }
343 float CSQCPlayer_FallbackFrame(float f)
344 {
345         if(frameduration(self.modelindex, f) > 0)
346                 return f; // goooooood
347         if(frameduration(self.modelindex, 1) <= 0)
348                 return f; // this is a static model. We can't fix it if we wanted to
349         switch(f)
350         {
351                 case 23: return 11; // anim_melee -> anim_shoot
352                 case 24: return 4; // anim_duckwalkbackwards -> anim_duckwalk
353                 case 25: return 4; // anim_duckwalkstrafeleft -> anim_duckwalk
354                 case 26: return 4; // anim_duckwalkstraferight -> anim_duckwalk
355                 case 27: return 4; // anim_duckwalkforwardright -> anim_duckwalk
356                 case 28: return 4; // anim_duckwalkforwardleft -> anim_duckwalk
357                 case 29: return 4; // anim_duckwalkbackright -> anim_duckwalk
358                 case 30: return 4; // anim_duckwalkbackleft -> anim_duckwalk
359         }
360         printf("Frame %d missing in model %s, and we have no fallback - FAIL!\n", f, self.model);
361         return f;
362 }
363 void CSQCPlayer_FallbackFrame_Apply(void)
364 {
365         self.frame = CSQCPlayer_FallbackFrame(self.frame);
366         self.frame2 = CSQCPlayer_FallbackFrame(self.frame2);
367 #ifdef CSQCMODEL_HAVE_TWO_FRAMES
368         self.frame3 = CSQCPlayer_FallbackFrame(self.frame3);
369         self.frame4 = CSQCPlayer_FallbackFrame(self.frame4);
370 #endif
371 }
372
373 // FEATURE: auto tag_index
374 .entity tag_entity;
375 .float tag_entity_lastmodelindex;
376 .float tag_index;
377 void CSQCModel_AutoTagIndex_Apply(void)
378 {
379         if(self.tag_entity && wasfreed(self.tag_entity))
380                 self.tag_entity = world;
381
382         if(self.tag_networkentity)
383         {
384                 // we are ATTACHED!
385                 float changed = 0;
386                 if(self.tag_entity.entnum != self.tag_networkentity)
387                 {
388                         self.tag_entity = findfloat(world, entnum, self.tag_networkentity);
389                         changed = 1;
390                 }
391
392                 // recursive predraw call to fix issues with forcemodels and LOD if bone indexes mismatch
393                 if(self.tag_entity.classname == "csqcmodel")
394                 {
395                         entity oldself = self;
396                         self = self.tag_entity;
397                         CSQCModel_Hook_PreDraw((self.entnum >= 1 && self.entnum <= maxclients));
398                         self = oldself;
399                 }
400
401                 if(self.tag_entity.modelindex != self.tag_entity_lastmodelindex)
402                 {
403                         self.tag_entity_lastmodelindex = self.tag_entity.modelindex;
404                         changed = 1;
405                 }
406                 if(changed)
407                 {
408                         if(self.tag_entity)
409                         {
410                                 // the best part is: IT EXISTS
411                                 if(substring(self.model, 0, 17) == "models/weapons/v_")
412                                 {
413                                         if(substring(self.tag_entity.model, 0, 17) == "models/weapons/h_")
414                                         {
415                                                 self.tag_index = gettagindex(self.tag_entity, "weapon");
416                                                 if(!self.tag_index)
417                                                         self.tag_index = gettagindex(self.tag_entity, "tag_weapon");
418                                                 if(!self.tag_index)
419                                                 {
420                                                         // we need to prevent this from 'appening
421                                                         self.tag_entity = world;
422                                                         self.drawmask = 0;
423                                                         dprint("h_ model lacks weapon attachment, but v_ model is attached to it\n");
424                                                 }
425                                         }
426                                         else if(self.tag_entity.isplayermodel)
427                                         {
428                                                 skeleton_loadinfo(self.tag_entity);
429                                                 self.tag_index = self.tag_entity.bone_weapon;
430                                         }
431                                 }
432
433                                 if(substring(self.tag_entity.model, 0, 17) == "models/weapons/v_")
434                                 {
435                                         self.tag_index = gettagindex(self.tag_entity, "shot");
436                                         if(!self.tag_index)
437                                                 self.tag_index = gettagindex(self.tag_entity, "tag_shot");
438                                 }
439                         }
440                         else
441                         {
442                                 // damn, see you next frame
443                                 self.drawmask = 0;
444                         }
445                 }
446         }
447 }
448
449 // FEATURE: EF_NODRAW workalike
450 const float EF_BRIGHTFIELD      = 1;
451 const float EF_BRIGHTLIGHT      = 4;
452 const float EF_DIMLIGHT         = 8;
453 const float EF_DOUBLESIDED = 32768;
454 const float EF_NOSELFSHADOW = 65536;
455 const float EF_DYNAMICMODELLIGHT = 131072;
456 const float EF_RESTARTANIM_BIT = 1048576;
457 const float EF_TELEPORT_BIT = 2097152;
458 const float MF_ROCKET  =   1; // leave a trail
459 const float MF_GRENADE =   2; // leave a trail
460 const float MF_GIB     =   4; // leave a trail
461 const float MF_ROTATE  =   8; // rotate (bonus items)
462 const float MF_TRACER  =  16; // green split trail
463 const float MF_ZOMGIB  =  32; // small blood trail
464 const float MF_TRACER2 =  64; // orange split trail
465 const float MF_TRACER3 = 128; // purple trail
466 .float csqcmodel_effects;
467 .float csqcmodel_modelflags;
468 void CSQCModel_Effects_PreUpdate(void)
469 {
470         self.effects = self.csqcmodel_effects;
471         self.modelflags = self.csqcmodel_modelflags;
472 }
473 void Reset_ArcBeam(void);
474 void CSQCModel_Effects_PostUpdate(void)
475 {
476         if (self == csqcplayer) {
477                 if (self.csqcmodel_teleported) {
478                         Reset_ArcBeam();
479                 }
480         }
481         self.csqcmodel_effects = self.effects;
482         self.csqcmodel_modelflags = self.modelflags;
483         self.effects = 0;
484         self.modelflags = 0;
485         if(self.csqcmodel_teleported)
486                 Projectile_ResetTrail(self.origin);
487 }
488 .float snd_looping;
489 void CSQCModel_Effects_Apply(void)
490 {
491         float eff = self.csqcmodel_effects;
492         eff &= ~CSQCMODEL_EF_RESPAWNGHOST;
493
494         self.renderflags &= ~(RF_DEPTHHACK | RF_ADDITIVE | RF_FULLBRIGHT | EF_NOSHADOW | RF_USEAXIS);
495         self.effects = 0;
496         self.traileffect = 0;
497
498         if(eff & EF_BRIGHTFIELD)
499                 self.traileffect = particleeffectnum("TR_NEXUIZPLASMA");
500         // ignoring EF_MUZZLEFLASH
501         if(eff & EF_BRIGHTLIGHT)
502                 adddynamiclight(self.origin, 400, '3 3 3');
503         if(eff & EF_DIMLIGHT)
504                 adddynamiclight(self.origin, 200, '1.5 1.5 1.5');
505         if((eff & EF_NODRAW) || (self.alpha < 0))
506                 self.drawmask = 0;
507         if(eff & EF_ADDITIVE)
508                 self.renderflags |= RF_ADDITIVE;
509         if(eff & EF_BLUE)
510                 adddynamiclight(self.origin, 200, '0.15 0.15 1.5');
511         if(eff & EF_RED)
512                 adddynamiclight(self.origin, 200, '1.5 0.15 0.15');
513         // ignoring EF_NOGUNBOB
514         if(eff & EF_FULLBRIGHT)
515                 self.renderflags |= RF_FULLBRIGHT;
516         if(eff & EF_FLAME)
517                 pointparticles(particleeffectnum("EF_FLAME"), self.origin, '0 0 0', bound(0, frametime, 0.1));
518         if(eff & EF_STARDUST)
519                 pointparticles(particleeffectnum("EF_STARDUST"), self.origin, '0 0 0', bound(0, frametime, 0.1));
520         if(eff & EF_NOSHADOW)
521                 self.renderflags |= RF_NOSHADOW;
522         if(eff & EF_NODEPTHTEST)
523                 self.renderflags |= RF_DEPTHHACK;
524         // ignoring EF_SELECTABLE
525         if(eff & EF_DOUBLESIDED)
526                 self.effects |= EF_DOUBLESIDED;
527         if(eff & EF_NOSELFSHADOW)
528                 self.effects |= EF_NOSELFSHADOW;
529         if(eff & EF_DYNAMICMODELLIGHT)
530                 self.renderflags |= RF_DYNAMICMODELLIGHT;
531         // ignoring EF_UNUSED18, EF_UNUSED19, EF_RESTARTANIM_BIT, EF_TELEPORT_BIT, EF_LOWPRECISION
532         if(self.csqcmodel_modelflags & MF_ROCKET)
533                 self.traileffect = particleeffectnum("TR_ROCKET");
534         if(self.csqcmodel_modelflags & MF_GRENADE)
535                 self.traileffect = particleeffectnum("TR_GRENADE");
536         if(self.csqcmodel_modelflags & MF_GIB)
537                 self.traileffect = particleeffectnum("TR_BLOOD");
538         if(self.csqcmodel_modelflags & MF_ROTATE)
539         {
540                 self.renderflags |= RF_USEAXIS;
541                 makevectors(self.angles + '0 100 0' * fmod(time, 3.6));
542         }
543         if(self.csqcmodel_modelflags & MF_TRACER)
544                 self.traileffect = particleeffectnum("TR_WIZSPIKE");
545         if(self.csqcmodel_modelflags & MF_ZOMGIB)
546                 self.traileffect = particleeffectnum("TR_SLIGHTBLOOD");
547         if(self.csqcmodel_modelflags & MF_TRACER2)
548                 self.traileffect = particleeffectnum("TR_KNIGHTSPIKE");
549         if(self.csqcmodel_modelflags & MF_TRACER3)
550                 self.traileffect = particleeffectnum("TR_VORESPIKE");
551
552         if(self.drawmask)
553                 Projectile_DrawTrail(self.origin);
554         else
555                 Projectile_ResetTrail(self.origin);
556
557         if(self.csqcmodel_effects & CSQCMODEL_EF_RESPAWNGHOST)
558                 self.renderflags |= RF_ADDITIVE;
559                 // also special in CSQCPlayer_GlowMod_Apply
560
561         if(self.csqcmodel_modelflags & MF_ROCKET)
562         {
563                 if(!self.snd_looping)
564                 {
565                         sound(self, CH_TRIGGER_SINGLE, "misc/jetpack_fly.wav", VOL_BASE, autocvar_g_jetpack_attenuation);
566                         self.snd_looping = CH_TRIGGER_SINGLE;
567                 }
568         }
569         else
570         {
571                 if(self.snd_looping)
572                 {
573                         sound(self, self.snd_looping, "misc/null.wav", VOL_BASE, autocvar_g_jetpack_attenuation);
574                         self.snd_looping = 0;
575                 }
576         }
577 }
578
579 void CSQCPlayer_Precache()
580 {
581         precache_sound("misc/jetpack_fly.wav");
582 }
583
584 // general functions
585 .float csqcmodel_predraw_run;
586 .float anim_frame;
587 .float anim_frame1time;
588 .float anim_frame2;
589 .float anim_frame2time;
590 .float anim_saveframe;
591 .float anim_saveframe1time;
592 .float anim_saveframe2;
593 .float anim_saveframe2time;
594 .float anim_prev_pmove_flags;
595 void CSQCModel_Hook_PreDraw(float isplayer)
596 {
597         if(self.csqcmodel_predraw_run == framecount)
598                 return;
599         self.csqcmodel_predraw_run = framecount;
600
601         if(!self.modelindex || self.model == "null")
602         {
603                 self.drawmask = 0;
604                 return;
605         }
606         else
607                 self.drawmask = MASK_NORMAL;
608
609         if(self.isplayermodel) // this checks if it's a player MODEL!
610         {
611                 CSQCPlayer_ModelAppearance_Apply(self.entnum == player_localnum + 1);
612                 CSQCPlayer_LOD_Apply();
613                 if(!isplayer)
614                 {
615                         skeleton_loadinfo(self);
616                         float doblend = (self.bone_upperbody >= 0);
617                         CSQCPlayer_FallbackFrame_Apply();
618                         if(doblend)
619                         {
620                                 skeleton_from_frames(self, self.csqcmodel_isdead);
621                         }
622                         else
623                         {
624                                 free_skeleton_from_frames(self);
625                                 // just in case, clear these (we're animating in frame and frame3)
626                                 self.lerpfrac = 0;
627                                 self.lerpfrac4 = 0;
628                         }
629                 }
630                 else
631                 {
632                         // we know that frame3 and frame4 fields, used by InterpolateAnimation, are left alone - but that is all we know!
633                         skeleton_loadinfo(self);
634                         float doblend = (self.bone_upperbody >= 0);
635                         float onground = 0;
636                         if(self == csqcplayer)
637                         {
638                                 if(self.pmove_flags & PMF_ONGROUND)
639                                         onground = 1;
640                                 self.anim_prev_pmove_flags = self.pmove_flags;
641                                 if(self.pmove_flags & PMF_DUCKED)
642                                         animdecide_setstate(self, self.anim_state | ANIMSTATE_DUCK, FALSE);
643                                 else if(self.anim_state & ANIMSTATE_DUCK)
644                                         animdecide_setstate(self, self.anim_state - ANIMSTATE_DUCK, FALSE);
645                         }
646                         else
647                         {
648                                 tracebox(self.origin + '0 0 1', self.mins, self.maxs, self.origin - '0 0 4', MOVE_NORMAL, self);
649                                 if(trace_startsolid || trace_fraction < 1)
650                                         onground = 1;
651                         }
652                         animdecide_init(self);
653                         animdecide_setimplicitstate(self, onground);
654                         animdecide_setframes(self, doblend, anim_frame, anim_frame1time, anim_frame2, anim_frame2time);
655                         float sf = 0;
656                         if(self.anim_saveframe != self.anim_frame || self.anim_saveframe1time != self.anim_frame1time)
657                                 sf |= CSQCMODEL_PROPERTY_FRAME;
658                         if(self.anim_saveframe2 != self.anim_frame2 || self.anim_saveframe2time != self.anim_frame2time)
659                                 sf |= CSQCMODEL_PROPERTY_FRAME2;
660                         self.anim_saveframe = self.anim_frame;
661                         self.anim_saveframe1time = self.anim_frame1time;
662                         self.anim_saveframe2 = self.anim_frame2;
663                         self.anim_saveframe2time = self.anim_frame2time;
664                         // Note: we always consider lerpfrac "changed", as it uses fixed values every time anyway.
665                         // This ensures that .frame etc. are always written.
666                         CSQCModel_InterpolateAnimation_2To4_PreNote(sf | CSQCMODEL_PROPERTY_LERPFRAC);
667                         self.lerpfrac = (doblend ? 0.5 : 0);
668                         self.frame = self.anim_frame;
669                         self.frame1time = self.anim_frame1time;
670                         self.frame2 = self.anim_frame2;
671                         self.frame2time = self.anim_frame2time;
672                         CSQCModel_InterpolateAnimation_2To4_Note(sf | CSQCMODEL_PROPERTY_LERPFRAC, FALSE);
673                         CSQCModel_InterpolateAnimation_2To4_Do();
674                         if(doblend)
675                         {
676                                 skeleton_from_frames(self, self.csqcmodel_isdead);
677                         }
678                         else
679                         {
680                                 free_skeleton_from_frames(self);
681                                 // just in case, clear these (we're animating in frame and frame3)
682                                 self.lerpfrac = 0;
683                                 self.lerpfrac4 = 0;
684                         }
685                 }
686         }
687
688         CSQCModel_AutoTagIndex_Apply();
689
690         CSQCModel_Effects_Apply();
691 }
692
693 void CSQCModel_Hook_PreUpdate(float isnew, float isplayer, float islocalplayer)
694 {
695         // interpolate v_angle
696         self.iflags |= IFLAG_V_ANGLE_X;
697         // revert to values from server
698         CSQCModel_Effects_PreUpdate();
699         if(self.isplayermodel)
700         {
701                 if(!isplayer)
702                         CSQCPlayer_FallbackFrame_PreUpdate();
703                 CSQCPlayer_ModelAppearance_PreUpdate();
704         }
705 }
706
707 void CSQCModel_Hook_PostUpdate(float isnew, float isplayer, float islocalplayer)
708 {
709         // is it a player model? (shared state)
710         self.isplayermodel = (substring(self.model, 0, 14) == "models/player/" || substring(self.model, 0, 17) == "models/ok_player/");
711
712         // save values set by server
713         if(self.isplayermodel)
714         {
715                 CSQCPlayer_ModelAppearance_PostUpdate();
716                 if(isplayer)
717                         CSQCPlayer_AnimDecide_PostUpdate(isnew);
718                 else
719                         CSQCPlayer_FallbackFrame_PostUpdate(isnew);
720         }
721         CSQCModel_Effects_PostUpdate();
722 }