qcsrc/client/hud_config.qc

   1 #define HUD_Write(s) fputs(fh, s)
   2 // q: quoted, n: not quoted
   3 #define HUD_Write_Cvar_n(cvar) HUD_Write(strcat("seta ", cvar, " ", cvar_string(cvar), "\n"))
   4 #define HUD_Write_Cvar_q(cvar) HUD_Write(strcat("seta ", cvar, " \"", cvar_string(cvar), "\"\n"))
   5 #define HUD_Write_PanelCvar_n(cvar_suf) HUD_Write_Cvar_n(strcat("hud_panel_", panel_name, cvar_suf))
   6 #define HUD_Write_PanelCvar_q(cvar_suf) HUD_Write_Cvar_q(strcat("hud_panel_", panel_name, cvar_suf))
   7 // Save the config
   8 void HUD_Panel_ExportCfg(string cfgname)
   9 {
  10         float fh;
  11         string filename = strcat("hud_", autocvar_hud_skin, "_", cfgname, ".cfg");
  12         fh = fopen(filename, FILE_WRITE);
  13         if(fh >= 0)
  14         {
  15                 HUD_Write_Cvar_q("hud_skin");
  16                 HUD_Write_Cvar_q("hud_panel_bg");
  17                 HUD_Write_Cvar_q("hud_panel_bg_color");
  18                 HUD_Write_Cvar_q("hud_panel_bg_color_team");
  19                 HUD_Write_Cvar_q("hud_panel_bg_alpha");
  20                 HUD_Write_Cvar_q("hud_panel_bg_border");
  21                 HUD_Write_Cvar_q("hud_panel_bg_padding");
  22                 HUD_Write_Cvar_q("hud_panel_fg_alpha");
  23                 HUD_Write("\n");
  24
  25                 HUD_Write_Cvar_q("hud_dock");
  26                 HUD_Write_Cvar_q("hud_dock_color");
  27                 HUD_Write_Cvar_q("hud_dock_color_team");
  28                 HUD_Write_Cvar_q("hud_dock_alpha");
  29                 HUD_Write("\n");
  30
  31                 HUD_Write_Cvar_q("hud_progressbar_alpha");
  32                 HUD_Write_Cvar_q("hud_progressbar_strength_color");
  33                 HUD_Write_Cvar_q("hud_progressbar_shield_color");
  34                 HUD_Write_Cvar_q("hud_progressbar_health_color");
  35                 HUD_Write_Cvar_q("hud_progressbar_armor_color");
  36                 HUD_Write_Cvar_q("hud_progressbar_fuel_color");
  37                 HUD_Write_Cvar_q("hud_progressbar_nexball_color");
  38                 HUD_Write_Cvar_q("hud_progressbar_speed_color");
  39                 HUD_Write_Cvar_q("hud_progressbar_acceleration_color");
  40                 HUD_Write_Cvar_q("hud_progressbar_acceleration_neg_color");
  41                 HUD_Write("\n");
  42
  43                 HUD_Write_Cvar_q("_hud_panelorder");
  44                 HUD_Write("\n");
  45
  46                 HUD_Write_Cvar_q("hud_configure_grid");
  47                 HUD_Write_Cvar_q("hud_configure_grid_xsize");
  48                 HUD_Write_Cvar_q("hud_configure_grid_ysize");
  49                 HUD_Write("\n");
  50
  51                 // common cvars for all panels
  52                 float i;
  53                 for (i = 0; i < HUD_PANEL_NUM; ++i)
  54                 {
  55                         HUD_Panel_GetName(i);
  56
  57                         HUD_Write_PanelCvar_n("");
  58                         HUD_Write_PanelCvar_q("_pos");
  59                         HUD_Write_PanelCvar_q("_size");
  60                         HUD_Write_PanelCvar_q("_bg");
  61                         HUD_Write_PanelCvar_q("_bg_color");
  62                         HUD_Write_PanelCvar_q("_bg_color_team");
  63                         HUD_Write_PanelCvar_q("_bg_alpha");
  64                         HUD_Write_PanelCvar_q("_bg_border");
  65                         HUD_Write_PanelCvar_q("_bg_padding");
  66                         switch(i) {
  67                                 case HUD_PANEL_WEAPONS:
  68                                         HUD_Write_PanelCvar_q("_accuracy");
  69                                         HUD_Write_PanelCvar_q("_label");
  70                                         HUD_Write_PanelCvar_q("_complainbubble");
  71                                         HUD_Write_PanelCvar_q("_complainbubble_padding");
  72                                         HUD_Write_PanelCvar_q("_complainbubble_time");
  73                                         HUD_Write_PanelCvar_q("_complainbubble_fadetime");
  74                                         HUD_Write_PanelCvar_q("_complainbubble_color_outofammo");
  75                                         HUD_Write_PanelCvar_q("_complainbubble_color_donthave");
  76                                         HUD_Write_PanelCvar_q("_complainbubble_color_unavailable");
  77                                         HUD_Write_PanelCvar_q("_ammo");
  78                                         HUD_Write_PanelCvar_q("_ammo_color");
  79                                         HUD_Write_PanelCvar_q("_ammo_alpha");
  80                                         HUD_Write_PanelCvar_q("_aspect");
  81                                         HUD_Write_PanelCvar_q("_timeout");
  82                                         HUD_Write_PanelCvar_q("_timeout_effect");
  83                                         HUD_Write_PanelCvar_q("_onlyowned");
  84                                         break;
  85                                 case HUD_PANEL_AMMO:
  86                                         HUD_Write_PanelCvar_q("_onlycurrent");
  87                                         HUD_Write_PanelCvar_q("_iconalign");
  88                                         HUD_Write_PanelCvar_q("_progressbar");
  89                                         HUD_Write_PanelCvar_q("_progressbar_name");
  90                                         HUD_Write_PanelCvar_q("_progressbar_xoffset");
  91                                         HUD_Write_PanelCvar_q("_text");
  92                                         break;
  93                                 case HUD_PANEL_POWERUPS:
  94                                         HUD_Write_PanelCvar_q("_flip");
  95                                         HUD_Write_PanelCvar_q("_iconalign");
  96                                         HUD_Write_PanelCvar_q("_baralign");
  97                                         HUD_Write_PanelCvar_q("_progressbar");
  98                                         HUD_Write_PanelCvar_q("_progressbar_strength");
  99                                         HUD_Write_PanelCvar_q("_progressbar_shield");
 100                                         HUD_Write_PanelCvar_q("_text");
 101                                         break;
 102                                 case HUD_PANEL_HEALTHARMOR:
 103                                         HUD_Write_PanelCvar_q("_flip");
 104                                         HUD_Write_PanelCvar_q("_iconalign");
 105                                         HUD_Write_PanelCvar_q("_baralign");
 106                                         HUD_Write_PanelCvar_q("_progressbar");
 107                                         HUD_Write_PanelCvar_q("_progressbar_health");
 108                                         HUD_Write_PanelCvar_q("_progressbar_armor");
 109                                         HUD_Write_PanelCvar_q("_progressbar_gfx");
 110                                         HUD_Write_PanelCvar_q("_progressbar_gfx_smooth");
 111                                         HUD_Write_PanelCvar_q("_text");
 112                                         break;
 113                                 case HUD_PANEL_NOTIFY:
 114                                         HUD_Write_PanelCvar_q("_flip");
 115                                         HUD_Write_PanelCvar_q("_fontsize");
 116                                         HUD_Write_PanelCvar_q("_print");
 117                                         HUD_Write_PanelCvar_q("_time");
 118                                         HUD_Write_PanelCvar_q("_fadetime");
 119                                         break;
 120                                 case HUD_PANEL_TIMER:
 121                                         HUD_Write_PanelCvar_q("_increment");
 122                                         break;
 123                                 case HUD_PANEL_RADAR:
 124                                         HUD_Write_PanelCvar_q("_foreground_alpha");
 125                                         HUD_Write_PanelCvar_q("_rotation");
 126                                         HUD_Write_PanelCvar_q("_zoommode");
 127                                         HUD_Write_PanelCvar_q("_scale");
 128                                         HUD_Write_PanelCvar_q("_maximized_scale");
 129                                         HUD_Write_PanelCvar_q("_maximized_size");
 130                                         break;
 131                                 case HUD_PANEL_SCORE:
 132                                         HUD_Write_PanelCvar_q("_rankings");
 133                                         break;
 134                                 case HUD_PANEL_VOTE:
 135                                         HUD_Write_PanelCvar_q("_alreadyvoted_alpha");
 136                                         break;
 137                                 case HUD_PANEL_MODICONS:
 138                                         HUD_Write_PanelCvar_q("_ca_layout");
 139                                         HUD_Write_PanelCvar_q("_dom_layout");
 140                                         HUD_Write_PanelCvar_q("_freezetag_layout");
 141                                         break;
 142                                 case HUD_PANEL_PRESSEDKEYS:
 143                                         HUD_Write_PanelCvar_q("_attack");
 144                                         HUD_Write_PanelCvar_q("_aspect");
 145                                         break;
 146                                 case HUD_PANEL_ENGINEINFO:
 147                                         HUD_Write_PanelCvar_q("_framecounter_time");
 148                                         HUD_Write_PanelCvar_q("_framecounter_decimals");
 149                                         break;
 150                                 case HUD_PANEL_INFOMESSAGES:
 151                                         HUD_Write_PanelCvar_q("_flip");
 152                                         break;
 153                                 case HUD_PANEL_PHYSICS:
 154                                         HUD_Write_PanelCvar_q("_speed_unit");
 155                                         HUD_Write_PanelCvar_q("_speed_unit_show");
 156                                         HUD_Write_PanelCvar_q("_speed_max");
 157                                         HUD_Write_PanelCvar_q("_speed_vertical");
 158                                         HUD_Write_PanelCvar_q("_topspeed");
 159                                         HUD_Write_PanelCvar_q("_topspeed_time");
 160                                         HUD_Write_PanelCvar_q("_acceleration_max");
 161                                         HUD_Write_PanelCvar_q("_acceleration_vertical");
 162                                         HUD_Write_PanelCvar_q("_flip");
 163                                         HUD_Write_PanelCvar_q("_baralign");
 164                                         HUD_Write_PanelCvar_q("_progressbar");
 165                                         HUD_Write_PanelCvar_q("_progressbar_acceleration_mode");
 166                                         HUD_Write_PanelCvar_q("_progressbar_acceleration_scale");
 167                                         HUD_Write_PanelCvar_q("_progressbar_acceleration_nonlinear");
 168                                         HUD_Write_PanelCvar_q("_text");
 169                                         HUD_Write_PanelCvar_q("_text_scale");
 170                                         break;
 171                                 case HUD_PANEL_CENTERPRINT:
 172                                         HUD_Write_PanelCvar_q("_align");
 173                                         HUD_Write_PanelCvar_q("_flip");
 174                                         HUD_Write_PanelCvar_q("_fontscale");
 175                                         HUD_Write_PanelCvar_q("_time");
 176                                         HUD_Write_PanelCvar_q("_fade_in");
 177                                         HUD_Write_PanelCvar_q("_fade_out");
 178                                         HUD_Write_PanelCvar_q("_fade_subsequent");
 179                                         HUD_Write_PanelCvar_q("_fade_subsequent_passone");
 180                                         HUD_Write_PanelCvar_q("_fade_subsequent_passone_minalpha");
 181                                         HUD_Write_PanelCvar_q("_fade_subsequent_passtwo");
 182                                         HUD_Write_PanelCvar_q("_fade_subsequent_passtwo_minalpha");
 183                                         HUD_Write_PanelCvar_q("_fade_subsequent_minfontsize");
 184                                         HUD_Write_PanelCvar_q("_fade_minfontsize");
 185                                         break;
 186                         }
 187                         HUD_Write("\n");
 188                 }
 189                 HUD_Write("menu_sync\n"); // force the menu to reread the cvars, so that the dialogs are updated
 190
 191                 print(sprintf(_("^2Successfully exported to %s! (Note: It's saved in data/data/)\n"), filename));
 192                 fclose(fh);
 193         }
 194         else
 195                 print(sprintf(_("^1Couldn't write to %s\n"), filename));
 196 }
 197
 198 void HUD_Configure_Exit_Force()
 199 {
 200         if (menu_enabled)
 201         {
 202                 menu_enabled = 0;
 203                 localcmd("togglemenu\n");
 204         }
 205         cvar_set("_hud_configure", "0");
 206 }
 207
 208 // check if move will result in panel being moved into another panel. If so, return snapped vector, otherwise return the given vector
 209 vector HUD_Panel_CheckMove(vector myPos, vector mySize)
 210 {
 211         float i;
 212         float myCenter_x, myCenter_y, targCenter_x, targCenter_y;
 213         vector myTarget;
 214         myTarget = myPos;
 215
 216         for (i = 0; i < HUD_PANEL_NUM; ++i) {
 217                 if(i == highlightedPanel || !panel_enabled)
 218                         continue;
 219
 220                 HUD_Panel_UpdatePosSizeForId(i);
 221
 222                 panel_pos -= '1 1 0' * panel_bg_border;
 223                 panel_size += '2 2 0' * panel_bg_border;
 224
 225                 if(myPos_y + mySize_y < panel_pos_y)
 226                         continue;
 227                 if(myPos_y > panel_pos_y + panel_size_y)
 228                         continue;
 229
 230                 if(myPos_x + mySize_x < panel_pos_x)
 231                         continue;
 232                 if(myPos_x > panel_pos_x + panel_size_x)
 233                         continue;
 234
 235                 // OK, there IS a collision.
 236
 237                 myCenter_x = myPos_x + 0.5 * mySize_x;
 238                 myCenter_y = myPos_y + 0.5 * mySize_y;
 239
 240                 targCenter_x = panel_pos_x + 0.5 * panel_size_x;
 241                 targCenter_y = panel_pos_y + 0.5 * panel_size_y;
 242
 243                 if(myCenter_x < targCenter_x && myCenter_y < targCenter_y) // top left (of the target panel)
 244                 {
 245                         if(myPos_x + mySize_x - panel_pos_x < myPos_y + mySize_y - panel_pos_y) // push it to the side
 246                                 myTarget_x = panel_pos_x - mySize_x;
 247                         else // push it upwards
 248                                 myTarget_y = panel_pos_y - mySize_y;
 249                 }
 250                 else if(myCenter_x > targCenter_x && myCenter_y < targCenter_y) // top right
 251                 {
 252                         if(panel_pos_x + panel_size_x - myPos_x < myPos_y + mySize_y - panel_pos_y) // push it to the side
 253                                 myTarget_x = panel_pos_x + panel_size_x;
 254                         else // push it upwards
 255                                 myTarget_y = panel_pos_y - mySize_y;
 256                 }
 257                 else if(myCenter_x < targCenter_x && myCenter_y > targCenter_y) // bottom left
 258                 {
 259                         if(myPos_x + mySize_x - panel_pos_x < panel_pos_y + panel_size_y - myPos_y) // push it to the side
 260                                 myTarget_x = panel_pos_x - mySize_x;
 261                         else // push it downwards
 262                                 myTarget_y = panel_pos_y + panel_size_y;
 263                 }
 264                 else if(myCenter_x > targCenter_x && myCenter_y > targCenter_y) // bottom right
 265                 {
 266                         if(panel_pos_x + panel_size_x - myPos_x < panel_pos_y + panel_size_y - myPos_y) // push it to the side
 267                                 myTarget_x = panel_pos_x + panel_size_x;
 268                         else // push it downwards
 269                                 myTarget_y = panel_pos_y + panel_size_y;
 270                 }
 271                 //if(cvar("hud_configure_checkcollisions_debug"))
 272                         //drawfill(panel_pos, panel_size, '1 1 0', .3, DRAWFLAG_NORMAL);
 273         }
 274
 275         return myTarget;
 276 }
 277
 278 void HUD_Panel_SetPos(vector pos)
 279 {
 280         HUD_Panel_UpdatePosSizeForId(highlightedPanel);
 281         vector mySize;
 282         mySize = panel_size;
 283
 284         //if(cvar("hud_configure_checkcollisions_debug"))
 285                 //drawfill(pos, mySize, '1 1 1', .2, DRAWFLAG_NORMAL);
 286
 287         if(autocvar_hud_configure_grid)
 288         {
 289                 pos_x = floor((pos_x/vid_conwidth)/hud_configure_gridSize_x + 0.5) * hud_configure_realGridSize_x;
 290                 pos_y = floor((pos_y/vid_conheight)/hud_configure_gridSize_y + 0.5) * hud_configure_realGridSize_y;
 291         }
 292
 293         if(hud_configure_checkcollisions)
 294                 pos = HUD_Panel_CheckMove(pos, mySize);
 295
 296         pos_x = bound(0, pos_x, vid_conwidth - mySize_x);
 297         pos_y = bound(0, pos_y, vid_conheight - mySize_y);
 298
 299         string s;
 300         s = strcat(ftos(pos_x/vid_conwidth), " ", ftos(pos_y/vid_conheight));
 301
 302         HUD_Panel_GetName(highlightedPanel);
 303         cvar_set(strcat("hud_panel_", panel_name, "_pos"), s);
 304 }
 305
 306 // check if resize will result in panel being moved into another panel. If so, return snapped vector, otherwise return the given vector
 307 vector HUD_Panel_CheckResize(vector mySize, vector resizeorigin) {
 308         float i;
 309
 310         vector targEndPos;
 311
 312         float dist_x, dist_y;
 313         float ratio;
 314         ratio = mySize_x/mySize_y;
 315
 316         for (i = 0; i < HUD_PANEL_NUM; ++i) {
 317                 if(i == highlightedPanel || !panel_enabled)
 318                         continue;
 319
 320                 HUD_Panel_UpdatePosSizeForId(i);
 321
 322                 panel_pos -= '1 1 0' * panel_bg_border;
 323                 panel_size += '2 2 0' * panel_bg_border;
 324
 325                 targEndPos = panel_pos + panel_size;
 326
 327                 // resizeorigin is WITHIN target panel, just abort any collision testing against that particular panel to produce expected behaviour!
 328                 if(resizeorigin_x > panel_pos_x && resizeorigin_x < targEndPos_x && resizeorigin_y > panel_pos_y && resizeorigin_y < targEndPos_y)
 329                         continue;
 330
 331                 if (resizeCorner == 1)
 332                 {
 333                         // check if this panel is on our way
 334                         if (resizeorigin_x <= panel_pos_x)
 335                                 continue;
 336                         if (resizeorigin_y <= panel_pos_y)
 337                                 continue;
 338                         if (targEndPos_x <= resizeorigin_x - mySize_x)
 339                                 continue;
 340                         if (targEndPos_y <= resizeorigin_y - mySize_y)
 341                                 continue;
 342
 343                         // there is a collision:
 344                         // detect which side of the panel we are facing is actually limiting the resizing
 345                         // (which side the resize direction finds for first) and reduce the size up to there
 346                         //
 347                         // dist is the distance between resizeorigin and the "analogous" point of the panel
 348                         // in this case between resizeorigin (bottom-right point) and the bottom-right point of the panel
 349                         dist_x = resizeorigin_x - targEndPos_x;
 350                         dist_y = resizeorigin_y - targEndPos_y;
 351                         if (dist_y <= 0 || dist_x / dist_y > ratio)
 352                                 mySize_x = min(mySize_x, dist_x);
 353                         else
 354                                 mySize_y = min(mySize_y, dist_y);
 355                 }
 356                 else if (resizeCorner == 2)
 357                 {
 358                         if (resizeorigin_x >= targEndPos_x)
 359                                 continue;
 360                         if (resizeorigin_y <= panel_pos_y)
 361                                 continue;
 362                         if (panel_pos_x >= resizeorigin_x + mySize_x)
 363                                 continue;
 364                         if (targEndPos_y <= resizeorigin_y - mySize_y)
 365                                 continue;
 366
 367                         dist_x = panel_pos_x - resizeorigin_x;
 368                         dist_y = resizeorigin_y - targEndPos_y;
 369                         if (dist_y <= 0 || dist_x / dist_y > ratio)
 370                                 mySize_x = min(mySize_x, dist_x);
 371                         else
 372                                 mySize_y = min(mySize_y, dist_y);
 373                 }
 374                 else if (resizeCorner == 3)
 375                 {
 376                         if (resizeorigin_x <= panel_pos_x)
 377                                 continue;
 378                         if (resizeorigin_y >= targEndPos_y)
 379                                 continue;
 380                         if (targEndPos_x <= resizeorigin_x - mySize_x)
 381                                 continue;
 382                         if (panel_pos_y >= resizeorigin_y + mySize_y)
 383                                 continue;
 384
 385                         dist_x = resizeorigin_x - targEndPos_x;
 386                         dist_y = panel_pos_y - resizeorigin_y;
 387                         if (dist_y <= 0 || dist_x / dist_y > ratio)
 388                                 mySize_x = min(mySize_x, dist_x);
 389                         else
 390                                 mySize_y = min(mySize_y, dist_y);
 391                 }
 392                 else if (resizeCorner == 4)
 393                 {
 394                         if (resizeorigin_x >= targEndPos_x)
 395                                 continue;
 396                         if (resizeorigin_y >= targEndPos_y)
 397                                 continue;
 398                         if (panel_pos_x >= resizeorigin_x + mySize_x)
 399                                 continue;
 400                         if (panel_pos_y >= resizeorigin_y + mySize_y)
 401                                 continue;
 402
 403                         dist_x = panel_pos_x - resizeorigin_x;
 404                         dist_y = panel_pos_y - resizeorigin_y;
 405                         if (dist_y <= 0 || dist_x / dist_y > ratio)
 406                                 mySize_x = min(mySize_x, dist_x);
 407                         else
 408                                 mySize_y = min(mySize_y, dist_y);
 409                 }
 410                 //if(cvar("hud_configure_checkcollisions_debug"))
 411                         //drawfill(panel_pos, panel_size, '1 1 0', .3, DRAWFLAG_NORMAL);
 412         }
 413
 414         return mySize;
 415 }
 416
 417 void HUD_Panel_SetPosSize(vector mySize)
 418 {
 419         HUD_Panel_UpdatePosSizeForId(highlightedPanel);
 420         vector resizeorigin;
 421         resizeorigin = panel_click_resizeorigin;
 422         local noref vector myPos; // fteqcc sucks
 423
 424         // minimum panel size cap
 425         mySize_x = max(0.025 * vid_conwidth, mySize_x);
 426         mySize_y = max(0.025 * vid_conheight, mySize_y);
 427
 428         if(highlightedPanel == HUD_PANEL_CHAT) // some panels have their own restrictions, like the chat panel (which actually only moves the engine chat print around). Looks bad if it's too small.
 429         {
 430                 mySize_x = max(17 * autocvar_con_chatsize, mySize_x);
 431                 mySize_y = max(2 * autocvar_con_chatsize + 2 * panel_bg_padding, mySize_y);
 432         }
 433
 434         // collision testing|
 435         // -----------------+
 436
 437         // we need to know pos at this stage, but it might still change later if we hit a screen edge/other panel (?)
 438         if(resizeCorner == 1) {
 439                 myPos_x = resizeorigin_x - mySize_x;
 440                 myPos_y = resizeorigin_y - mySize_y;
 441         } else if(resizeCorner == 2) {
 442                 myPos_x = resizeorigin_x;
 443                 myPos_y = resizeorigin_y - mySize_y;
 444         } else if(resizeCorner == 3) {
 445                 myPos_x = resizeorigin_x - mySize_x;
 446                 myPos_y = resizeorigin_y;
 447         } else { // resizeCorner == 4
 448                 myPos_x = resizeorigin_x;
 449                 myPos_y = resizeorigin_y;
 450         }
 451
 452         // left/top screen edges
 453         if(myPos_x < 0)
 454                 mySize_x = mySize_x + myPos_x;
 455         if(myPos_y < 0)
 456                 mySize_y = mySize_y + myPos_y;
 457
 458         // bottom/right screen edges
 459         if(myPos_x + mySize_x > vid_conwidth)
 460                 mySize_x = vid_conwidth - myPos_x;
 461         if(myPos_y + mySize_y > vid_conheight)
 462                 mySize_y = vid_conheight - myPos_y;
 463
 464         //if(cvar("hud_configure_checkcollisions_debug"))
 465                 //drawfill(myPos, mySize, '1 1 1', .2, DRAWFLAG_NORMAL);
 466
 467         // before checkresize, otherwise panel can be snapped partially inside another panel or panel aspect ratio can be broken
 468         if(autocvar_hud_configure_grid)
 469         {
 470                 mySize_x = floor((mySize_x/vid_conwidth)/hud_configure_gridSize_x + 0.5) * hud_configure_realGridSize_x;
 471                 mySize_y = floor((mySize_y/vid_conheight)/hud_configure_gridSize_y + 0.5) * hud_configure_realGridSize_y;
 472         }
 473
 474         if(hud_configure_checkcollisions)
 475                 mySize = HUD_Panel_CheckResize(mySize, resizeorigin);
 476
 477         // minimum panel size cap, do this once more so we NEVER EVER EVER have a panel smaller than this, JUST IN CASE above code still makes the panel eg negative (impossible to resize back without changing cvars manually then)
 478         mySize_x = max(0.025 * vid_conwidth, mySize_x);
 479         mySize_y = max(0.025 * vid_conheight, mySize_y);
 480
 481         // do another pos check, as size might have changed by now
 482         if(resizeCorner == 1) {
 483                 myPos_x = resizeorigin_x - mySize_x;
 484                 myPos_y = resizeorigin_y - mySize_y;
 485         } else if(resizeCorner == 2) {
 486                 myPos_x = resizeorigin_x;
 487                 myPos_y = resizeorigin_y - mySize_y;
 488         } else if(resizeCorner == 3) {
 489                 myPos_x = resizeorigin_x - mySize_x;
 490                 myPos_y = resizeorigin_y;
 491         } else { // resizeCorner == 4
 492                 myPos_x = resizeorigin_x;
 493                 myPos_y = resizeorigin_y;
 494         }
 495
 496         //if(cvar("hud_configure_checkcollisions_debug"))
 497                 //drawfill(myPos, mySize, '0 1 0', .3, DRAWFLAG_NORMAL);
 498
 499         HUD_Panel_GetName(highlightedPanel);
 500         string s;
 501         s = strcat(ftos(mySize_x/vid_conwidth), " ", ftos(mySize_y/vid_conheight));
 502         cvar_set(strcat("hud_panel_", panel_name, "_size"), s);
 503
 504         s = strcat(ftos(myPos_x/vid_conwidth), " ", ftos(myPos_y/vid_conheight));
 505         cvar_set(strcat("hud_panel_", panel_name, "_pos"), s);
 506 }
 507
 508 float pressed_key_time;
 509 vector highlightedPanel_initial_pos, highlightedPanel_initial_size;
 510 void HUD_Panel_Arrow_Action(float nPrimary)
 511 {
 512         if (highlightedPanel == -1)
 513                 return;
 514
 515         hud_configure_checkcollisions = (!(hudShiftState & S_CTRL) && autocvar_hud_configure_checkcollisions);
 516
 517         float step;
 518         if(autocvar_hud_configure_grid)
 519         {
 520                 if (nPrimary == K_UPARROW || nPrimary == K_DOWNARROW)
 521                 {
 522                         if (hudShiftState & S_SHIFT)
 523                                 step = hud_configure_realGridSize_y;
 524                         else
 525                                 step = 2 * hud_configure_realGridSize_y;
 526                 }
 527                 else
 528                 {
 529                         if (hudShiftState & S_SHIFT)
 530                                 step = hud_configure_realGridSize_x;
 531                         else
 532                                 step = 2 * hud_configure_realGridSize_x;
 533                 }
 534         }
 535         else
 536         {
 537                 if (nPrimary == K_UPARROW || nPrimary == K_DOWNARROW)
 538                         step = vid_conheight;
 539                 else
 540                         step = vid_conwidth;
 541                 if (hudShiftState & S_SHIFT)
 542                         step = (step / 256); // more precision
 543                 else
 544                         step = (step / 64) * (1 + 2 * (time - pressed_key_time));
 545         }
 546
 547         HUD_Panel_UpdatePosSizeForId(highlightedPanel);
 548
 549         highlightedPanel_initial_pos = panel_pos;
 550         highlightedPanel_initial_size = panel_size;
 551
 552         if (hudShiftState & S_ALT) // resize
 553         {
 554                 highlightedAction = 1;
 555                 if(nPrimary == K_UPARROW)
 556                         resizeCorner = 1;
 557                 else if(nPrimary == K_RIGHTARROW)
 558                         resizeCorner = 2;
 559                 else if(nPrimary == K_LEFTARROW)
 560                         resizeCorner = 3;
 561                 else // if(nPrimary == K_DOWNARROW)
 562                         resizeCorner = 4;
 563
 564                 // ctrl+arrow reduces the size, instead of increasing it
 565                 // Note that ctrl disables collisions check too, but it's fine
 566                 // since we don't collide with anything reducing the size
 567                 if (hudShiftState & S_CTRL) {
 568                         step = -step;
 569                         resizeCorner = 5 - resizeCorner;
 570                 }
 571
 572                 vector mySize;
 573                 mySize = panel_size;
 574                 panel_click_resizeorigin = panel_pos;
 575                 if(resizeCorner == 1) {
 576                         panel_click_resizeorigin += mySize;
 577                         mySize_y += step;
 578                 } else if(resizeCorner == 2) {
 579                         panel_click_resizeorigin_y += mySize_y;
 580                         mySize_x += step;
 581                 } else if(resizeCorner == 3) {
 582                         panel_click_resizeorigin_x += mySize_x;
 583                         mySize_x += step;
 584                 } else { // resizeCorner == 4
 585                         mySize_y += step;
 586                 }
 587                 HUD_Panel_SetPosSize(mySize);
 588         }
 589         else // move
 590         {
 591                 highlightedAction = 2;
 592                 vector pos;
 593                 pos = panel_pos;
 594                 if(nPrimary == K_UPARROW)
 595                         pos_y -= step;
 596                 else if(nPrimary == K_DOWNARROW)
 597                         pos_y += step;
 598                 else if(nPrimary == K_LEFTARROW)
 599                         pos_x -= step;
 600                 else // if(nPrimary == K_RIGHTARROW)
 601                         pos_x += step;
 602
 603                 HUD_Panel_SetPos(pos);
 604         }
 605
 606         HUD_Panel_UpdatePosSizeForId(highlightedPanel);
 607
 608         if (highlightedPanel_initial_pos != panel_pos || highlightedPanel_initial_size != panel_size)
 609         {
 610                 // backup!
 611                 panel_pos_backup = highlightedPanel_initial_pos;
 612                 panel_size_backup = highlightedPanel_initial_size;
 613                 highlightedPanel_backup = highlightedPanel;
 614         }
 615 }
 616
 617 const float S_MOUSE1 = 1;
 618 const float S_MOUSE2 = 2;
 619 const float S_MOUSE3 = 4;
 620 float mouseClicked;
 621 float prevMouseClicked; // previous state
 622 float prevMouseClickedTime; // time during previous left mouse click, to check for doubleclicks
 623 vector prevMouseClickedPos; // pos during previous left mouse click, to check for doubleclicks
 624
 625 void HUD_Panel_EnableMenu();
 626 float tab_panels[HUD_PANEL_NUM];
 627 float tab_panel, tab_backward;
 628 vector tab_panel_pos;
 629 void HUD_Panel_FirstInDrawQ(float id);
 630 void reset_tab_panels()
 631 {
 632         int i;
 633         for(i = 0; i < HUD_PANEL_NUM; ++i)
 634                 tab_panels[i] = -1;
 635 }
 636 float HUD_Panel_InputEvent(float bInputType, float nPrimary, float nSecondary)
 637 {
 638         string s;
 639
 640         if(bInputType == 2)
 641                 return false;
 642
 643         if(!autocvar__hud_configure)
 644                 return false;
 645
 646         // block any input while a menu dialog is fading
 647         if(autocvar__menu_alpha)
 648                 return true;
 649
 650         if(bInputType == 3)
 651         {
 652                 mousepos_x = nPrimary;
 653                 mousepos_y = nSecondary;
 654                 return true;
 655         }
 656
 657         // allow console bind to work
 658         string con_keys;
 659         float keys;
 660         con_keys = findkeysforcommand("toggleconsole", 0);
 661         keys = tokenize(con_keys); // findkeysforcommand returns data for this
 662
 663         float hit_con_bind, i;
 664         for (i = 0; i < keys; ++i)
 665         {
 666                 if(nPrimary == stof(argv(i)))
 667                         hit_con_bind = 1;
 668         }
 669
 670         if(bInputType == 0) {
 671                 if(nPrimary == K_ALT) hudShiftState |= S_ALT;
 672                 if(nPrimary == K_CTRL) hudShiftState |= S_CTRL;
 673                 if(nPrimary == K_SHIFT) hudShiftState |= S_SHIFT;
 674         }
 675         else if(bInputType == 1) {
 676                 if(nPrimary == K_ALT) hudShiftState -= (hudShiftState & S_ALT);
 677                 if(nPrimary == K_CTRL) hudShiftState -= (hudShiftState & S_CTRL);
 678                 if(nPrimary == K_SHIFT) hudShiftState -= (hudShiftState & S_SHIFT);
 679         }
 680
 681         if(nPrimary == K_CTRL)
 682         {
 683                 if (bInputType == 1) //ctrl has been released
 684                 {
 685                         if (tab_panel != -1)
 686                         {
 687                                 //switch to selected panel
 688                                 highlightedPanel = tab_panel;
 689                                 highlightedAction = 0;
 690                                 HUD_Panel_FirstInDrawQ(highlightedPanel);
 691                         }
 692                         tab_panel = -1;
 693                         reset_tab_panels();
 694                 }
 695         }
 696
 697         if(nPrimary == K_MOUSE1)
 698         {
 699                 if(bInputType == 0) // key pressed
 700                         mouseClicked |= S_MOUSE1;
 701                 else if(bInputType == 1) // key released
 702                         mouseClicked -= (mouseClicked & S_MOUSE1);
 703         }
 704         else if(nPrimary == K_MOUSE2)
 705         {
 706                 if(bInputType == 0) // key pressed
 707                         mouseClicked |= S_MOUSE2;
 708                 else if(bInputType == 1) // key released
 709                         mouseClicked -= (mouseClicked & S_MOUSE2);
 710         }
 711         else if(nPrimary == K_ESCAPE)
 712         {
 713                 if (bInputType == 1)
 714                         return true;
 715                 menu_enabled = 1;
 716                 menu_enabled_time = time;
 717                 localcmd("menu_showhudexit\n");
 718         }
 719         else if(nPrimary == K_BACKSPACE && hudShiftState & S_CTRL)
 720         {
 721                 if (bInputType == 1)
 722                         return true;
 723                 if (!menu_enabled)
 724                         cvar_set("_hud_configure", "0");
 725         }
 726         else if(nPrimary == K_TAB && hudShiftState & S_CTRL) // select and highlight another panel
 727         {
 728                 if (bInputType == 1 || mouseClicked)
 729                         return true;
 730
 731                 //FIXME: if a panel is highlighted, has the same pos_x and lays in the same level
 732                 //of other panels then next consecutive ctrl-tab will select the highlighted panel too
 733                 //(it should only after every other panel of the hud)
 734                 //It's a minor bug anyway, we can live with it
 735
 736                 float starting_panel;
 737                 float old_tab_panel = tab_panel;
 738                 if (tab_panel == -1) //first press of TAB
 739                 {
 740                         if (highlightedPanel != -1)
 741                                 HUD_Panel_UpdatePosSizeForId(highlightedPanel)
 742                         else
 743                                 panel_pos = '0 0 0';
 744                         starting_panel = highlightedPanel; //can be -1, it means no starting panel
 745                         tab_panel_pos = panel_pos; //to compute level
 746                 }
 747                 else
 748                 {
 749                         if ( ((!tab_backward) && (hudShiftState & S_SHIFT)) || (tab_backward && !(hudShiftState & S_SHIFT)) ) //tab direction changed?
 750                                 reset_tab_panels();
 751                         starting_panel = tab_panel;
 752                 }
 753                 tab_backward = (hudShiftState & S_SHIFT);
 754
 755                 float k, level, start_pos_x;
 756                 vector candidate_pos;
 757                 const float LEVELS_NUM = 4;
 758                 float level_height = vid_conheight / LEVELS_NUM;
 759 :find_tab_panel
 760                 level = floor(tab_panel_pos_y / level_height) * level_height; //starting level
 761                 candidate_pos_x = (!tab_backward) ? vid_conwidth : 0;
 762                 start_pos_x = tab_panel_pos_x;
 763                 tab_panel = -1;
 764                 k=0;
 765                 while(++k)
 766                 {
 767                         for(i = 0; i < HUD_PANEL_NUM; ++i)
 768                         {
 769                                 if (i == tab_panels[i] || i == starting_panel)
 770                                         continue;
 771                                 HUD_Panel_UpdatePosSizeForId(i)
 772                                 if (panel_pos_y >= level && (panel_pos_y - level) < level_height)
 773                                 if (  ( !tab_backward && panel_pos_x >= start_pos_x && (panel_pos_x < candidate_pos_x || (panel_pos_x == candidate_pos_x && panel_pos_y <= candidate_pos_y)) )
 774                                         || ( tab_backward && panel_pos_x <= start_pos_x && (panel_pos_x > candidate_pos_x || (panel_pos_x == candidate_pos_x && panel_pos_y >= candidate_pos_y)) )  )
 775                                 {
 776                                         tab_panel = i;
 777                                         tab_panel_pos = candidate_pos = panel_pos;
 778                                 }
 779                         }
 780                         if (tab_panel != -1)
 781                                 break;
 782                         if (k == LEVELS_NUM) //tab_panel not found
 783                         {
 784                                 reset_tab_panels();
 785                                 if (old_tab_panel == -2) //this prevents an infinite loop (should not happen normally)
 786                                 {
 787                                         tab_panel = -1;
 788                                         return true;
 789                                 }
 790                                 starting_panel = old_tab_panel;
 791                                 old_tab_panel = -2;
 792                                 goto find_tab_panel; //u must find tab_panel!
 793                         }
 794                         if (!tab_backward)
 795                         {
 796                                 level = mod(level + level_height, vid_conheight);
 797                                 start_pos_x = 0;
 798                                 candidate_pos_x = vid_conwidth;
 799                         }
 800                         else
 801                         {
 802                                 level = mod(level - level_height, vid_conheight);
 803                                 start_pos_x = vid_conwidth;
 804                                 candidate_pos_x = 0;
 805                         }
 806                 }
 807
 808                 tab_panels[tab_panel] = tab_panel;
 809         }
 810         else if(nPrimary == K_SPACE && hudShiftState & S_CTRL) // enable/disable highlighted panel or dock
 811         {
 812                 if (bInputType == 1 || mouseClicked)
 813                         return true;
 814
 815                 if (highlightedPanel != -1)
 816                 {
 817                         HUD_Panel_GetName(highlightedPanel);
 818                         cvar_set(strcat("hud_panel_", panel_name), ftos(!(panel_enabled)));
 819                 }
 820                 else
 821                         cvar_set(strcat("hud_dock"), (autocvar_hud_dock == "") ? "dock" : "");
 822         }
 823         else if(nPrimary == 'c' && hudShiftState & S_CTRL) // copy highlighted panel size
 824         {
 825                 if (bInputType == 1 || mouseClicked)
 826                         return true;
 827
 828                 if (highlightedPanel != -1)
 829                 {
 830                         HUD_Panel_UpdatePosSizeForId(highlightedPanel);
 831                         panel_size_copied = panel_size;
 832                         highlightedPanel_copied = highlightedPanel;
 833                 }
 834         }
 835         else if(nPrimary == 'v' && hudShiftState & S_CTRL) // past copied size on the highlighted panel
 836         {
 837                 if (bInputType == 1 || mouseClicked)
 838                         return true;
 839
 840                 if (highlightedPanel_copied == -1 || highlightedPanel == -1)
 841                         return true;
 842
 843                 HUD_Panel_UpdatePosSizeForId(highlightedPanel);
 844
 845                 // reduce size if it'd go beyond screen boundaries
 846                 vector tmp_size = panel_size_copied;
 847                 if (panel_pos_x + panel_size_copied_x > vid_conwidth)
 848                         tmp_size_x = vid_conwidth - panel_pos_x;
 849                 if (panel_pos_y + panel_size_copied_y > vid_conheight)
 850                         tmp_size_y = vid_conheight - panel_pos_y;
 851
 852                 if (panel_size == tmp_size)
 853                         return true;
 854
 855                 // backup first!
 856                 panel_pos_backup = panel_pos;
 857                 panel_size_backup = panel_size;
 858                 highlightedPanel_backup = highlightedPanel;
 859
 860                 s = strcat(ftos(tmp_size_x/vid_conwidth), " ", ftos(tmp_size_y/vid_conheight));
 861                 HUD_Panel_GetName(highlightedPanel);
 862                 cvar_set(strcat("hud_panel_", panel_name, "_size"), s);
 863         }
 864         else if(nPrimary == 'z' && hudShiftState & S_CTRL) // undo last action
 865         {
 866                 if (bInputType == 1 || mouseClicked)
 867                         return true;
 868                 //restore previous values
 869                 if (highlightedPanel_backup != -1)
 870                 {
 871                         HUD_Panel_GetName(highlightedPanel_backup);
 872                         s = strcat(ftos(panel_pos_backup_x/vid_conwidth), " ", ftos(panel_pos_backup_y/vid_conheight));
 873                         cvar_set(strcat("hud_panel_", panel_name, "_pos"), s);
 874                         s = strcat(ftos(panel_size_backup_x/vid_conwidth), " ", ftos(panel_size_backup_y/vid_conheight));
 875                         cvar_set(strcat("hud_panel_", panel_name, "_size"), s);
 876                         highlightedPanel_backup = -1;
 877                 }
 878         }
 879         else if(nPrimary == K_UPARROW || nPrimary == K_DOWNARROW || nPrimary == K_LEFTARROW || nPrimary == K_RIGHTARROW)
 880         {
 881                 if (bInputType == 1)
 882                 {
 883                         pressed_key_time = 0;
 884                         return true;
 885                 }
 886                 else if (pressed_key_time == 0)
 887                         pressed_key_time = time;
 888
 889                 if (!mouseClicked)
 890                         HUD_Panel_Arrow_Action(nPrimary); //move or resize panel
 891         }
 892         else if(nPrimary == K_ENTER || nPrimary == K_SPACE || nPrimary == K_KP_ENTER)
 893         {
 894                 if (bInputType == 1)
 895                         return true;
 896                 if (highlightedPanel != -1)
 897                         HUD_Panel_EnableMenu();
 898         }
 899         else if(hit_con_bind)
 900                 return false;
 901
 902         return true;
 903 }
 904
 905 float HUD_Panel_Check_Mouse_Pos(float allow_move)
 906 {
 907         float i, j, border;
 908
 909         while(j < HUD_PANEL_NUM)
 910         {
 911                 i = panel_order[j];
 912                 j += 1;
 913
 914                 HUD_Panel_UpdatePosSizeForId(i);
 915
 916                 border = max(8, panel_bg_border); // FORCED border so a small border size doesn't mean you can't resize
 917
 918                 // move
 919                 if(allow_move && mousepos_x > panel_pos_x && mousepos_y > panel_pos_y && mousepos_x < panel_pos_x + panel_size_x && mousepos_y < panel_pos_y + panel_size_y)
 920                 {
 921                         return 1;
 922                 }
 923                 // resize from topleft border
 924                 else if(mousepos_x >= panel_pos_x - border && mousepos_y >= panel_pos_y - border && mousepos_x <= panel_pos_x + 0.5 * panel_size_x && mousepos_y <= panel_pos_y + 0.5 * panel_size_y)
 925                 {
 926                         return 2;
 927                 }
 928                 // resize from topright border
 929                 else if(mousepos_x >= panel_pos_x + 0.5 * panel_size_x && mousepos_y >= panel_pos_y - border && mousepos_x <= panel_pos_x + panel_size_x + border && mousepos_y <= panel_pos_y + 0.5 * panel_size_y)
 930                 {
 931                         return 3;
 932                 }
 933                 // resize from bottomleft border
 934                 else if(mousepos_x >= panel_pos_x - border && mousepos_y >= panel_pos_y + 0.5 * panel_size_y && mousepos_x <= panel_pos_x + 0.5 * panel_size_x && mousepos_y <= panel_pos_y + panel_size_y + border)
 935                 {
 936                         return 3;
 937                 }
 938                 // resize from bottomright border
 939                 else if(mousepos_x >= panel_pos_x + 0.5 * panel_size_x && mousepos_y >= panel_pos_y + 0.5 * panel_size_y && mousepos_x <= panel_pos_x + panel_size_x + border && mousepos_y <= panel_pos_y + panel_size_y + border)
 940                 {
 941                         return 2;
 942                 }
 943         }
 944         return 0;
 945 }
 946
 947 // move a panel to the beginning of the panel order array (which means it gets drawn last, on top of everything else)
 948 void HUD_Panel_FirstInDrawQ(float id)
 949 {
 950         float i;
 951         var float place = -1;
 952         // find out where in the array our current id is, save into place
 953         for(i = 0; i < HUD_PANEL_NUM; ++i)
 954         {
 955                 if(panel_order[i] == id)
 956                 {
 957                         place = i;
 958                         break;
 959                 }
 960         }
 961         // place last if we didn't find a place for it yet (probably new panel, or screwed up cvar)
 962         if(place == -1)
 963                 place = HUD_PANEL_NUM - 1;
 964
 965         // move all ids up by one step in the array until "place"
 966         for(i = place; i > 0; --i)
 967         {
 968                 panel_order[i] = panel_order[i-1];
 969         }
 970         // now save the new top id
 971         panel_order[0] = id;
 972
 973         // let's save them into the cvar by some strcat trickery
 974         string s;
 975         for(i = 0; i < HUD_PANEL_NUM; ++i)
 976         {
 977                 s = strcat(s, ftos(panel_order[i]), " ");
 978         }
 979         cvar_set("_hud_panelorder", s);
 980         if(hud_panelorder_prev)
 981                 strunzone(hud_panelorder_prev);
 982         hud_panelorder_prev = strzone(autocvar__hud_panelorder); // prevent HUD_Main from doing useless update, we already updated here
 983 }
 984
 985 void HUD_Panel_Highlight(float allow_move)
 986 {
 987         float i, j, border;
 988
 989         while(j < HUD_PANEL_NUM)
 990         {
 991                 i = panel_order[j];
 992                 j += 1;
 993
 994                 HUD_Panel_UpdatePosSizeForId(i);
 995
 996                 border = max(8, panel_bg_border); // FORCED border so a small border size doesn't mean you can't resize
 997
 998                 // move
 999                 if(allow_move && mousepos_x > panel_pos_x && mousepos_y > panel_pos_y && mousepos_x < panel_pos_x + panel_size_x && mousepos_y < panel_pos_y + panel_size_y)
1000                 {
1001                         highlightedPanel = i;
1002                         HUD_Panel_FirstInDrawQ(i);
1003                         highlightedAction = 1;
1004                         panel_click_distance = mousepos - panel_pos;
1005                         return;
1006                 }
1007                 // resize from topleft border
1008                 else if(mousepos_x >= panel_pos_x - border && mousepos_y >= panel_pos_y - border && mousepos_x <= panel_pos_x + 0.5 * panel_size_x && mousepos_y <= panel_pos_y + 0.5 * panel_size_y)
1009                 {
1010                         highlightedPanel = i;
1011                         HUD_Panel_FirstInDrawQ(i);
1012                         highlightedAction = 2;
1013                         resizeCorner = 1;
1014                         panel_click_distance = mousepos - panel_pos;
1015                         panel_click_resizeorigin = panel_pos + panel_size;
1016                         return;
1017                 }
1018                 // resize from topright border
1019                 else if(mousepos_x >= panel_pos_x + 0.5 * panel_size_x && mousepos_y >= panel_pos_y - border && mousepos_x <= panel_pos_x + panel_size_x + border && mousepos_y <= panel_pos_y + 0.5 * panel_size_y)
1020                 {
1021                         highlightedPanel = i;
1022                         HUD_Panel_FirstInDrawQ(i);
1023                         highlightedAction = 2;
1024                         resizeCorner = 2;
1025                         panel_click_distance_x = panel_size_x - mousepos_x + panel_pos_x;
1026                         panel_click_distance_y = mousepos_y - panel_pos_y;
1027                         panel_click_resizeorigin = panel_pos + eY * panel_size_y;
1028                         return;
1029                 }
1030                 // resize from bottomleft border
1031                 else if(mousepos_x >= panel_pos_x - border && mousepos_y >= panel_pos_y + 0.5 * panel_size_y && mousepos_x <= panel_pos_x + 0.5 * panel_size_x && mousepos_y <= panel_pos_y + panel_size_y + border)
1032                 {
1033                         highlightedPanel = i;
1034                         HUD_Panel_FirstInDrawQ(i);
1035                         highlightedAction = 2;
1036                         resizeCorner = 3;
1037                         panel_click_distance_x = mousepos_x - panel_pos_x;
1038                         panel_click_distance_y = panel_size_y - mousepos_y + panel_pos_y;
1039                         panel_click_resizeorigin = panel_pos + eX * panel_size_x;
1040                         return;
1041                 }
1042                 // resize from bottomright border
1043                 else if(mousepos_x >= panel_pos_x + 0.5 * panel_size_x && mousepos_y >= panel_pos_y + 0.5 * panel_size_y && mousepos_x <= panel_pos_x + panel_size_x + border && mousepos_y <= panel_pos_y + panel_size_y + border)
1044                 {
1045                         highlightedPanel = i;
1046                         HUD_Panel_FirstInDrawQ(i);
1047                         highlightedAction = 2;
1048                         resizeCorner = 4;
1049                         panel_click_distance = panel_size - mousepos + panel_pos;
1050                         panel_click_resizeorigin = panel_pos;
1051                         return;
1052                 }
1053         }
1054         highlightedPanel = -1;
1055         highlightedAction = 0;
1056 }
1057
1058 void HUD_Panel_EnableMenu()
1059 {
1060         menu_enabled = 2;
1061         menu_enabled_time = time;
1062         HUD_Panel_GetName(highlightedPanel);
1063         localcmd("menu_showhudoptions ", panel_name, "\n");
1064 }
1065 float mouse_over_panel;
1066 void HUD_Panel_Mouse()
1067 {
1068         // TODO: needs better check... is there any float that contains the current state of the menu? _menu_alpha isn't apparently updated the frame the menu gets enabled
1069         if (autocvar__menu_alpha == 0 && time - menu_enabled_time > 0.5)
1070                 menu_enabled = 0;
1071
1072         /*
1073         print("menu_enabled: ", ftos(menu_enabled), "\n");
1074         print("Highlighted: ", ftos(highlightedPanel), "\n");
1075         print("Menu theAlpha: ", ftos(autocvar__menu_alpha), "\n");
1076         */
1077
1078         if(autocvar__menu_alpha == 1)
1079                 return;
1080
1081         if not(autocvar_hud_cursormode)
1082         {
1083                 mousepos = mousepos + getmousepos() * autocvar_menu_mouse_speed;
1084
1085                 mousepos_x = bound(0, mousepos_x, vid_conwidth);
1086                 mousepos_y = bound(0, mousepos_y, vid_conheight);
1087         }
1088
1089         if(mouseClicked)
1090         {
1091                 if(prevMouseClicked == 0)
1092                 {
1093                         if (tab_panel != -1)
1094                         {
1095                                 //stop ctrl-tab selection
1096                                 tab_panel = -1;
1097                                 reset_tab_panels();
1098                         }
1099                         HUD_Panel_Highlight(mouseClicked & S_MOUSE1); // sets highlightedPanel, highlightedAction, panel_click_distance, panel_click_resizeorigin
1100                                                                         // and calls HUD_Panel_UpdatePosSizeForId() for the highlighted panel
1101                         if (highlightedPanel != -1)
1102                         {
1103                                 highlightedPanel_initial_pos = panel_pos;
1104                                 highlightedPanel_initial_size = panel_size;
1105                         }
1106                         // doubleclick check
1107                         if ((mouseClicked & S_MOUSE1) && time - prevMouseClickedTime < 0.4 && highlightedPanel != -1 && prevMouseClickedPos == mousepos)
1108                         {
1109                                 mouseClicked = 0; // to prevent spam, I guess.
1110                                 HUD_Panel_EnableMenu();
1111                         }
1112                         else
1113                         {
1114                                 if (mouseClicked & S_MOUSE1)
1115                                 {
1116                                         prevMouseClickedTime = time;
1117                                         prevMouseClickedPos = mousepos;
1118                                 }
1119                                 mouse_over_panel = HUD_Panel_Check_Mouse_Pos(mouseClicked & S_MOUSE1);
1120                         }
1121                 }
1122                 else
1123                         HUD_Panel_UpdatePosSizeForId(highlightedPanel);
1124
1125                 if (highlightedPanel != -1)
1126                 {
1127                         drawfill(panel_pos - '1 1 0' * panel_bg_border, panel_size + '2 2 0' * panel_bg_border, '1 1 1', .1, DRAWFLAG_NORMAL);
1128                         if (highlightedPanel_initial_pos != panel_pos || highlightedPanel_initial_size != panel_size)
1129                         {
1130                                 hud_configure_checkcollisions = (!(hudShiftState & S_CTRL) && autocvar_hud_configure_checkcollisions);
1131                                 // backup!
1132                                 panel_pos_backup = highlightedPanel_initial_pos;
1133                                 panel_size_backup = highlightedPanel_initial_size;
1134                                 highlightedPanel_backup = highlightedPanel;
1135                         }
1136                         else
1137                                 // in case the clicked panel is inside another panel and we aren't
1138                                 // moving it, avoid the immediate "fix" of its position/size
1139                                 // (often unwanted and hateful) by disabling collisions check
1140                                 hud_configure_checkcollisions = false;
1141                 }
1142
1143                 if(highlightedAction == 1)
1144                         HUD_Panel_SetPos(mousepos - panel_click_distance);
1145                 else if(highlightedAction == 2)
1146                 {
1147                         vector mySize;
1148                         if(resizeCorner == 1) {
1149                                 mySize_x = panel_click_resizeorigin_x - (mousepos_x - panel_click_distance_x);
1150                                 mySize_y = panel_click_resizeorigin_y - (mousepos_y - panel_click_distance_y);
1151                         } else if(resizeCorner == 2) {
1152                                 mySize_x = mousepos_x + panel_click_distance_x - panel_click_resizeorigin_x;
1153                                 mySize_y = panel_click_distance_y + panel_click_resizeorigin_y - mousepos_y;
1154                         } else if(resizeCorner == 3) {
1155                                 mySize_x = panel_click_resizeorigin_x + panel_click_distance_x - mousepos_x;
1156                                 mySize_y = mousepos_y + panel_click_distance_y - panel_click_resizeorigin_y;
1157                         } else { // resizeCorner == 4
1158                                 mySize_x = mousepos_x - (panel_click_resizeorigin_x - panel_click_distance_x);
1159                                 mySize_y = mousepos_y - (panel_click_resizeorigin_y - panel_click_distance_y);
1160                         }
1161                         HUD_Panel_SetPosSize(mySize);
1162                 }
1163         }
1164         else
1165         {
1166                 if(menu_enabled == 2)
1167                         mouse_over_panel = 0;
1168                 else
1169                         mouse_over_panel = HUD_Panel_Check_Mouse_Pos(TRUE);
1170                 if (mouse_over_panel && tab_panel == -1)
1171                         drawfill(panel_pos - '1 1 0' * panel_bg_border, panel_size + '2 2 0' * panel_bg_border, '1 1 1', .1, DRAWFLAG_NORMAL);
1172         }
1173         // draw cursor after performing move/resize to have the panel pos/size updated before mouse_over_panel
1174         const vector cursorsize = '32 32 0';
1175         float cursor_alpha = 1 - autocvar__menu_alpha;
1176
1177         if(!mouse_over_panel)
1178                 drawpic(mousepos, strcat("gfx/menu/", autocvar_menu_skin, "/cursor.tga"), cursorsize, '1 1 1', cursor_alpha, DRAWFLAG_NORMAL);
1179         else if(mouse_over_panel == 1)
1180                 drawpic(mousepos - cursorsize * 0.5, strcat("gfx/menu/", autocvar_menu_skin, "/cursor_move.tga"), cursorsize, '1 1 1', cursor_alpha, DRAWFLAG_NORMAL);
1181         else if(mouse_over_panel == 2)
1182                 drawpic(mousepos - cursorsize * 0.5, strcat("gfx/menu/", autocvar_menu_skin, "/cursor_resize.tga"), cursorsize, '1 1 1', cursor_alpha, DRAWFLAG_NORMAL);
1183         else
1184                 drawpic(mousepos - cursorsize * 0.5, strcat("gfx/menu/", autocvar_menu_skin, "/cursor_resize2.tga"), cursorsize, '1 1 1', cursor_alpha, DRAWFLAG_NORMAL);
1185
1186         prevMouseClicked = mouseClicked;
1187 }
1188
1189 const float hlBorderSize = 4;
1190 const string hlBorder = "gfx/hud/default/border_highlighted";
1191 const string hlBorder2 = "gfx/hud/default/border_highlighted2";
1192 void HUD_Panel_HlBorder(float myBorder, vector color, float theAlpha)
1193 {
1194         drawfill(panel_pos - '1 1 0' * myBorder, panel_size + '2 2 0' * myBorder, '0 0.5 1', .5 * theAlpha, DRAWFLAG_NORMAL);
1195         drawpic_tiled(panel_pos - '1 1 0' * myBorder, hlBorder, '8 1 0' * hlBorderSize, eX * (panel_size_x + 2 * myBorder) + eY * hlBorderSize, color, theAlpha, DRAWFLAG_NORMAL);
1196         drawpic_tiled(panel_pos - '1 1 0' * myBorder + eY * (panel_size_y + 2 * myBorder - hlBorderSize), hlBorder, '8 1 0' * hlBorderSize, eX * (panel_size_x + 2 * myBorder) + eY * hlBorderSize, color, theAlpha, DRAWFLAG_NORMAL);
1197         drawpic_tiled(panel_pos - '1 1 0' * myBorder + eY * hlBorderSize, hlBorder2, '1 8 0' * hlBorderSize, eY * (panel_size_y + 2 * myBorder - 2 * hlBorderSize) + eX * hlBorderSize, color, theAlpha, DRAWFLAG_NORMAL);
1198         drawpic_tiled(panel_pos - '1 1 0' * myBorder + eY * hlBorderSize + eX * (panel_size_x + 2 * myBorder - hlBorderSize), hlBorder2, '1 8 0' * hlBorderSize, eY * (panel_size_y + 2 * myBorder - 2 * hlBorderSize) + eX * hlBorderSize, color, theAlpha, DRAWFLAG_NORMAL);
1199 }