qcsrc/client/hud_config.qc

   1 #define HUD_Write(s) fputs(fh, s)
   2 // q: quoted, n: not quoted
   3 #define HUD_Write_Cvar_n(cvar) HUD_Write(strcat("seta ", cvar, " ", cvar_string(cvar), "\n"))
   4 #define HUD_Write_Cvar_q(cvar) HUD_Write(strcat("seta ", cvar, " \"", cvar_string(cvar), "\"\n"))
   5 #define HUD_Write_PanelCvar_n(cvar_suf) HUD_Write_Cvar_n(strcat("hud_panel_", panel.panel_name, cvar_suf))
   6 #define HUD_Write_PanelCvar_q(cvar_suf) HUD_Write_Cvar_q(strcat("hud_panel_", panel.panel_name, cvar_suf))
   7 // Save the config
   8 void HUD_Panel_ExportCfg(string cfgname)
   9 {
  10         float fh;
  11         string filename = strcat("hud_", autocvar_hud_skin, "_", cfgname, ".cfg");
  12         fh = fopen(filename, FILE_WRITE);
  13         if(fh >= 0)
  14         {
  15                 HUD_Write_Cvar_q("hud_skin");
  16                 HUD_Write_Cvar_q("hud_panel_bg");
  17                 HUD_Write_Cvar_q("hud_panel_bg_color");
  18                 HUD_Write_Cvar_q("hud_panel_bg_color_team");
  19                 HUD_Write_Cvar_q("hud_panel_bg_alpha");
  20                 HUD_Write_Cvar_q("hud_panel_bg_border");
  21                 HUD_Write_Cvar_q("hud_panel_bg_padding");
  22                 HUD_Write_Cvar_q("hud_panel_fg_alpha");
  23                 HUD_Write("\n");
  24
  25                 HUD_Write_Cvar_q("hud_dock");
  26                 HUD_Write_Cvar_q("hud_dock_color");
  27                 HUD_Write_Cvar_q("hud_dock_color_team");
  28                 HUD_Write_Cvar_q("hud_dock_alpha");
  29                 HUD_Write("\n");
  30
  31                 HUD_Write_Cvar_q("hud_progressbar_alpha");
  32                 HUD_Write_Cvar_q("hud_progressbar_strength_color");
  33                 HUD_Write_Cvar_q("hud_progressbar_shield_color");
  34                 HUD_Write_Cvar_q("hud_progressbar_health_color");
  35                 HUD_Write_Cvar_q("hud_progressbar_armor_color");
  36                 HUD_Write_Cvar_q("hud_progressbar_fuel_color");
  37                 HUD_Write_Cvar_q("hud_progressbar_nexball_color");
  38                 HUD_Write_Cvar_q("hud_progressbar_speed_color");
  39                 HUD_Write_Cvar_q("hud_progressbar_acceleration_color");
  40                 HUD_Write_Cvar_q("hud_progressbar_acceleration_neg_color");
  41                 HUD_Write("\n");
  42
  43                 HUD_Write_Cvar_q("_hud_panelorder");
  44                 HUD_Write("\n");
  45
  46                 HUD_Write_Cvar_q("hud_configure_grid");
  47                 HUD_Write_Cvar_q("hud_configure_grid_xsize");
  48                 HUD_Write_Cvar_q("hud_configure_grid_ysize");
  49                 HUD_Write("\n");
  50
  51                 // common cvars for all panels
  52                 float i;
  53                 for (i = 0; i < HUD_PANEL_NUM; ++i)
  54                 {
  55                         panel = hud_panel[i];
  56
  57                         HUD_Write_PanelCvar_n("");
  58                         HUD_Write_PanelCvar_q("_pos");
  59                         HUD_Write_PanelCvar_q("_size");
  60                         HUD_Write_PanelCvar_q("_bg");
  61                         HUD_Write_PanelCvar_q("_bg_color");
  62                         HUD_Write_PanelCvar_q("_bg_color_team");
  63                         HUD_Write_PanelCvar_q("_bg_alpha");
  64                         HUD_Write_PanelCvar_q("_bg_border");
  65                         HUD_Write_PanelCvar_q("_bg_padding");
  66                         switch(i) {
  67                                 case HUD_PANEL_WEAPONS:
  68                                         HUD_Write_PanelCvar_q("_accuracy");
  69                                         HUD_Write_PanelCvar_q("_label");
  70                                         HUD_Write_PanelCvar_q("_complainbubble");
  71                                         HUD_Write_PanelCvar_q("_complainbubble_padding");
  72                                         HUD_Write_PanelCvar_q("_complainbubble_time");
  73                                         HUD_Write_PanelCvar_q("_complainbubble_fadetime");
  74                                         HUD_Write_PanelCvar_q("_complainbubble_color_outofammo");
  75                                         HUD_Write_PanelCvar_q("_complainbubble_color_donthave");
  76                                         HUD_Write_PanelCvar_q("_complainbubble_color_unavailable");
  77                                         HUD_Write_PanelCvar_q("_ammo");
  78                                         HUD_Write_PanelCvar_q("_ammo_color");
  79                                         HUD_Write_PanelCvar_q("_ammo_alpha");
  80                                         HUD_Write_PanelCvar_q("_aspect");
  81                                         HUD_Write_PanelCvar_q("_timeout");
  82                                         HUD_Write_PanelCvar_q("_timeout_effect");
  83                                         HUD_Write_PanelCvar_q("_timeout_fadebgmin");
  84                                         HUD_Write_PanelCvar_q("_timeout_fadefgmin");
  85                                         HUD_Write_PanelCvar_q("_timeout_speed_in");
  86                                         HUD_Write_PanelCvar_q("_timeout_speed_out");
  87                                         HUD_Write_PanelCvar_q("_onlyowned");
  88                                         break;
  89                                 case HUD_PANEL_AMMO:
  90                                         HUD_Write_PanelCvar_q("_onlycurrent");
  91                                         HUD_Write_PanelCvar_q("_noncurrent_alpha");
  92                                         HUD_Write_PanelCvar_q("_noncurrent_scale");
  93                                         HUD_Write_PanelCvar_q("_iconalign");
  94                                         HUD_Write_PanelCvar_q("_progressbar");
  95                                         HUD_Write_PanelCvar_q("_progressbar_name");
  96                                         HUD_Write_PanelCvar_q("_progressbar_xoffset");
  97                                         HUD_Write_PanelCvar_q("_text");
  98                                         break;
  99                                 case HUD_PANEL_POWERUPS:
 100                                         HUD_Write_PanelCvar_q("_flip");
 101                                         HUD_Write_PanelCvar_q("_iconalign");
 102                                         HUD_Write_PanelCvar_q("_baralign");
 103                                         HUD_Write_PanelCvar_q("_progressbar");
 104                                         HUD_Write_PanelCvar_q("_progressbar_strength");
 105                                         HUD_Write_PanelCvar_q("_progressbar_shield");
 106                                         HUD_Write_PanelCvar_q("_text");
 107                                         break;
 108                                 case HUD_PANEL_HEALTHARMOR:
 109                                         HUD_Write_PanelCvar_q("_flip");
 110                                         HUD_Write_PanelCvar_q("_iconalign");
 111                                         HUD_Write_PanelCvar_q("_baralign");
 112                                         HUD_Write_PanelCvar_q("_progressbar");
 113                                         HUD_Write_PanelCvar_q("_progressbar_health");
 114                                         HUD_Write_PanelCvar_q("_progressbar_armor");
 115                                         HUD_Write_PanelCvar_q("_progressbar_gfx");
 116                                         HUD_Write_PanelCvar_q("_progressbar_gfx_smooth");
 117                                         HUD_Write_PanelCvar_q("_text");
 118                                         break;
 119                                 case HUD_PANEL_NOTIFY:
 120                                         HUD_Write_PanelCvar_q("_flip");
 121                                         HUD_Write_PanelCvar_q("_fontsize");
 122                                         HUD_Write_PanelCvar_q("_time");
 123                                         HUD_Write_PanelCvar_q("_fadetime");
 124                                         HUD_Write_PanelCvar_q("_icon_aspect");
 125                                         break;
 126                                 case HUD_PANEL_TIMER:
 127                                         HUD_Write_PanelCvar_q("_increment");
 128                                         break;
 129                                 case HUD_PANEL_RADAR:
 130                                         HUD_Write_PanelCvar_q("_foreground_alpha");
 131                                         HUD_Write_PanelCvar_q("_rotation");
 132                                         HUD_Write_PanelCvar_q("_zoommode");
 133                                         HUD_Write_PanelCvar_q("_scale");
 134                                         HUD_Write_PanelCvar_q("_maximized_scale");
 135                                         HUD_Write_PanelCvar_q("_maximized_size");
 136                                         HUD_Write_PanelCvar_q("_maximized_rotation");
 137                                         HUD_Write_PanelCvar_q("_maximized_zoommode");
 138                                         break;
 139                                 case HUD_PANEL_SCORE:
 140                                         HUD_Write_PanelCvar_q("_rankings");
 141                                         break;
 142                                 case HUD_PANEL_VOTE:
 143                                         HUD_Write_PanelCvar_q("_alreadyvoted_alpha");
 144                                         break;
 145                                 case HUD_PANEL_MODICONS:
 146                                         HUD_Write_PanelCvar_q("_ca_layout");
 147                                         HUD_Write_PanelCvar_q("_dom_layout");
 148                                         HUD_Write_PanelCvar_q("_freezetag_layout");
 149                                         break;
 150                                 case HUD_PANEL_PRESSEDKEYS:
 151                                         HUD_Write_PanelCvar_q("_aspect");
 152                                         HUD_Write_PanelCvar_q("_attack");
 153                                         break;
 154                                 case HUD_PANEL_ENGINEINFO:
 155                                         HUD_Write_PanelCvar_q("_framecounter_time");
 156                                         HUD_Write_PanelCvar_q("_framecounter_decimals");
 157                                         break;
 158                                 case HUD_PANEL_INFOMESSAGES:
 159                                         HUD_Write_PanelCvar_q("_flip");
 160                                         break;
 161                                 case HUD_PANEL_PHYSICS:
 162                                         HUD_Write_PanelCvar_q("_speed_unit");
 163                                         HUD_Write_PanelCvar_q("_speed_unit_show");
 164                                         HUD_Write_PanelCvar_q("_speed_max");
 165                                         HUD_Write_PanelCvar_q("_speed_vertical");
 166                                         HUD_Write_PanelCvar_q("_topspeed");
 167                                         HUD_Write_PanelCvar_q("_topspeed_time");
 168                                         HUD_Write_PanelCvar_q("_acceleration_max");
 169                                         HUD_Write_PanelCvar_q("_acceleration_vertical");
 170                                         HUD_Write_PanelCvar_q("_flip");
 171                                         HUD_Write_PanelCvar_q("_baralign");
 172                                         HUD_Write_PanelCvar_q("_progressbar");
 173                                         HUD_Write_PanelCvar_q("_progressbar_acceleration_mode");
 174                                         HUD_Write_PanelCvar_q("_progressbar_acceleration_scale");
 175                                         HUD_Write_PanelCvar_q("_progressbar_acceleration_nonlinear");
 176                                         HUD_Write_PanelCvar_q("_text");
 177                                         HUD_Write_PanelCvar_q("_text_scale");
 178                                         break;
 179                                 case HUD_PANEL_CENTERPRINT:
 180                                         HUD_Write_PanelCvar_q("_align");
 181                                         HUD_Write_PanelCvar_q("_flip");
 182                                         HUD_Write_PanelCvar_q("_fontscale");
 183                                         HUD_Write_PanelCvar_q("_time");
 184                                         HUD_Write_PanelCvar_q("_fade_in");
 185                                         HUD_Write_PanelCvar_q("_fade_out");
 186                                         HUD_Write_PanelCvar_q("_fade_subsequent");
 187                                         HUD_Write_PanelCvar_q("_fade_subsequent_passone");
 188                                         HUD_Write_PanelCvar_q("_fade_subsequent_passone_minalpha");
 189                                         HUD_Write_PanelCvar_q("_fade_subsequent_passtwo");
 190                                         HUD_Write_PanelCvar_q("_fade_subsequent_passtwo_minalpha");
 191                                         HUD_Write_PanelCvar_q("_fade_subsequent_minfontsize");
 192                                         HUD_Write_PanelCvar_q("_fade_minfontsize");
 193                                         break;
 194                         }
 195                         HUD_Write("\n");
 196                 }
 197                 HUD_Write("menu_sync\n"); // force the menu to reread the cvars, so that the dialogs are updated
 198
 199                 printf(_("^2Successfully exported to %s! (Note: It's saved in data/data/)\n"), filename);
 200                 fclose(fh);
 201         }
 202         else
 203                 printf(_("^1Couldn't write to %s\n"), filename);
 204 }
 205
 206 void HUD_Configure_Exit_Force()
 207 {
 208         if (menu_enabled)
 209         {
 210                 menu_enabled = 0;
 211                 localcmd("togglemenu\n");
 212         }
 213         cvar_set("_hud_configure", "0");
 214 }
 215
 216 // check if move will result in panel being moved into another panel. If so, return snapped vector, otherwise return the given vector
 217 vector HUD_Panel_CheckMove(vector myPos, vector mySize)
 218 {
 219         float i;
 220         float myCenter_x, myCenter_y, targCenter_x, targCenter_y;
 221         vector myTarget;
 222         myTarget = myPos;
 223
 224         for (i = 0; i < HUD_PANEL_NUM; ++i) {
 225                 panel = hud_panel[i];
 226                 if(panel == highlightedPanel) continue;
 227                 HUD_Panel_UpdatePosSize()
 228                 if(!panel_enabled) continue;
 229
 230                 panel_pos -= '1 1 0' * panel_bg_border;
 231                 panel_size += '2 2 0' * panel_bg_border;
 232
 233                 if(myPos_y + mySize_y < panel_pos_y)
 234                         continue;
 235                 if(myPos_y > panel_pos_y + panel_size_y)
 236                         continue;
 237
 238                 if(myPos_x + mySize_x < panel_pos_x)
 239                         continue;
 240                 if(myPos_x > panel_pos_x + panel_size_x)
 241                         continue;
 242
 243                 // OK, there IS a collision.
 244
 245                 myCenter_x = myPos_x + 0.5 * mySize_x;
 246                 myCenter_y = myPos_y + 0.5 * mySize_y;
 247
 248                 targCenter_x = panel_pos_x + 0.5 * panel_size_x;
 249                 targCenter_y = panel_pos_y + 0.5 * panel_size_y;
 250
 251                 if(myCenter_x < targCenter_x && myCenter_y < targCenter_y) // top left (of the target panel)
 252                 {
 253                         if(myPos_x + mySize_x - panel_pos_x < myPos_y + mySize_y - panel_pos_y) // push it to the side
 254                                 myTarget_x = panel_pos_x - mySize_x;
 255                         else // push it upwards
 256                                 myTarget_y = panel_pos_y - mySize_y;
 257                 }
 258                 else if(myCenter_x > targCenter_x && myCenter_y < targCenter_y) // top right
 259                 {
 260                         if(panel_pos_x + panel_size_x - myPos_x < myPos_y + mySize_y - panel_pos_y) // push it to the side
 261                                 myTarget_x = panel_pos_x + panel_size_x;
 262                         else // push it upwards
 263                                 myTarget_y = panel_pos_y - mySize_y;
 264                 }
 265                 else if(myCenter_x < targCenter_x && myCenter_y > targCenter_y) // bottom left
 266                 {
 267                         if(myPos_x + mySize_x - panel_pos_x < panel_pos_y + panel_size_y - myPos_y) // push it to the side
 268                                 myTarget_x = panel_pos_x - mySize_x;
 269                         else // push it downwards
 270                                 myTarget_y = panel_pos_y + panel_size_y;
 271                 }
 272                 else if(myCenter_x > targCenter_x && myCenter_y > targCenter_y) // bottom right
 273                 {
 274                         if(panel_pos_x + panel_size_x - myPos_x < panel_pos_y + panel_size_y - myPos_y) // push it to the side
 275                                 myTarget_x = panel_pos_x + panel_size_x;
 276                         else // push it downwards
 277                                 myTarget_y = panel_pos_y + panel_size_y;
 278                 }
 279                 //if(cvar("hud_configure_checkcollisions_debug"))
 280                         //drawfill(panel_pos, panel_size, '1 1 0', .3, DRAWFLAG_NORMAL);
 281         }
 282
 283         return myTarget;
 284 }
 285
 286 void HUD_Panel_SetPos(vector pos)
 287 {
 288         panel = highlightedPanel;
 289         HUD_Panel_UpdatePosSize()
 290         vector mySize;
 291         mySize = panel_size;
 292
 293         //if(cvar("hud_configure_checkcollisions_debug"))
 294                 //drawfill(pos, mySize, '1 1 1', .2, DRAWFLAG_NORMAL);
 295
 296         if(autocvar_hud_configure_grid)
 297         {
 298                 pos_x = floor((pos_x/vid_conwidth)/hud_configure_gridSize_x + 0.5) * hud_configure_realGridSize_x;
 299                 pos_y = floor((pos_y/vid_conheight)/hud_configure_gridSize_y + 0.5) * hud_configure_realGridSize_y;
 300         }
 301
 302         if(hud_configure_checkcollisions)
 303                 pos = HUD_Panel_CheckMove(pos, mySize);
 304
 305         pos_x = bound(0, pos_x, vid_conwidth - mySize_x);
 306         pos_y = bound(0, pos_y, vid_conheight - mySize_y);
 307
 308         string s;
 309         s = strcat(ftos(pos_x/vid_conwidth), " ", ftos(pos_y/vid_conheight));
 310
 311         cvar_set(strcat("hud_panel_", highlightedPanel.panel_name, "_pos"), s);
 312 }
 313
 314 // check if resize will result in panel being moved into another panel. If so, return snapped vector, otherwise return the given vector
 315 vector HUD_Panel_CheckResize(vector mySize, vector resizeorigin) {
 316         float i;
 317
 318         vector targEndPos;
 319
 320         float dist_x, dist_y;
 321         float ratio;
 322         ratio = mySize_x/mySize_y;
 323
 324         for (i = 0; i < HUD_PANEL_NUM; ++i) {
 325                 panel = hud_panel[i];
 326                 if(panel == highlightedPanel) continue;
 327                 HUD_Panel_UpdatePosSize()
 328                 if(!panel_enabled) continue;
 329
 330                 panel_pos -= '1 1 0' * panel_bg_border;
 331                 panel_size += '2 2 0' * panel_bg_border;
 332
 333                 targEndPos = panel_pos + panel_size;
 334
 335                 // resizeorigin is WITHIN target panel, just abort any collision testing against that particular panel to produce expected behaviour!
 336                 if(resizeorigin_x > panel_pos_x && resizeorigin_x < targEndPos_x && resizeorigin_y > panel_pos_y && resizeorigin_y < targEndPos_y)
 337                         continue;
 338
 339                 if (resizeCorner == 1)
 340                 {
 341                         // check if this panel is on our way
 342                         if (resizeorigin_x <= panel_pos_x)
 343                                 continue;
 344                         if (resizeorigin_y <= panel_pos_y)
 345                                 continue;
 346                         if (targEndPos_x <= resizeorigin_x - mySize_x)
 347                                 continue;
 348                         if (targEndPos_y <= resizeorigin_y - mySize_y)
 349                                 continue;
 350
 351                         // there is a collision:
 352                         // detect which side of the panel we are facing is actually limiting the resizing
 353                         // (which side the resize direction finds for first) and reduce the size up to there
 354                         //
 355                         // dist is the distance between resizeorigin and the "analogous" point of the panel
 356                         // in this case between resizeorigin (bottom-right point) and the bottom-right point of the panel
 357                         dist_x = resizeorigin_x - targEndPos_x;
 358                         dist_y = resizeorigin_y - targEndPos_y;
 359                         if (dist_y <= 0 || dist_x / dist_y > ratio)
 360                                 mySize_x = min(mySize_x, dist_x);
 361                         else
 362                                 mySize_y = min(mySize_y, dist_y);
 363                 }
 364                 else if (resizeCorner == 2)
 365                 {
 366                         if (resizeorigin_x >= targEndPos_x)
 367                                 continue;
 368                         if (resizeorigin_y <= panel_pos_y)
 369                                 continue;
 370                         if (panel_pos_x >= resizeorigin_x + mySize_x)
 371                                 continue;
 372                         if (targEndPos_y <= resizeorigin_y - mySize_y)
 373                                 continue;
 374
 375                         dist_x = panel_pos_x - resizeorigin_x;
 376                         dist_y = resizeorigin_y - targEndPos_y;
 377                         if (dist_y <= 0 || dist_x / dist_y > ratio)
 378                                 mySize_x = min(mySize_x, dist_x);
 379                         else
 380                                 mySize_y = min(mySize_y, dist_y);
 381                 }
 382                 else if (resizeCorner == 3)
 383                 {
 384                         if (resizeorigin_x <= panel_pos_x)
 385                                 continue;
 386                         if (resizeorigin_y >= targEndPos_y)
 387                                 continue;
 388                         if (targEndPos_x <= resizeorigin_x - mySize_x)
 389                                 continue;
 390                         if (panel_pos_y >= resizeorigin_y + mySize_y)
 391                                 continue;
 392
 393                         dist_x = resizeorigin_x - targEndPos_x;
 394                         dist_y = panel_pos_y - resizeorigin_y;
 395                         if (dist_y <= 0 || dist_x / dist_y > ratio)
 396                                 mySize_x = min(mySize_x, dist_x);
 397                         else
 398                                 mySize_y = min(mySize_y, dist_y);
 399                 }
 400                 else if (resizeCorner == 4)
 401                 {
 402                         if (resizeorigin_x >= targEndPos_x)
 403                                 continue;
 404                         if (resizeorigin_y >= targEndPos_y)
 405                                 continue;
 406                         if (panel_pos_x >= resizeorigin_x + mySize_x)
 407                                 continue;
 408                         if (panel_pos_y >= resizeorigin_y + mySize_y)
 409                                 continue;
 410
 411                         dist_x = panel_pos_x - resizeorigin_x;
 412                         dist_y = panel_pos_y - resizeorigin_y;
 413                         if (dist_y <= 0 || dist_x / dist_y > ratio)
 414                                 mySize_x = min(mySize_x, dist_x);
 415                         else
 416                                 mySize_y = min(mySize_y, dist_y);
 417                 }
 418                 //if(cvar("hud_configure_checkcollisions_debug"))
 419                         //drawfill(panel_pos, panel_size, '1 1 0', .3, DRAWFLAG_NORMAL);
 420         }
 421
 422         return mySize;
 423 }
 424
 425 void HUD_Panel_SetPosSize(vector mySize)
 426 {
 427         panel = highlightedPanel;
 428         HUD_Panel_UpdatePosSize()
 429         vector resizeorigin;
 430         resizeorigin = panel_click_resizeorigin;
 431         local noref vector myPos; // fteqcc sucks
 432
 433         // minimum panel size cap
 434         mySize_x = max(0.025 * vid_conwidth, mySize_x);
 435         mySize_y = max(0.025 * vid_conheight, mySize_y);
 436
 437         if(highlightedPanel == HUD_PANEL(CHAT)) // some panels have their own restrictions, like the chat panel (which actually only moves the engine chat print around). Looks bad if it's too small.
 438         {
 439                 mySize_x = max(17 * autocvar_con_chatsize, mySize_x);
 440                 mySize_y = max(2 * autocvar_con_chatsize + 2 * panel_bg_padding, mySize_y);
 441         }
 442
 443         // collision testing|
 444         // -----------------+
 445
 446         // we need to know pos at this stage, but it might still change later if we hit a screen edge/other panel (?)
 447         if(resizeCorner == 1) {
 448                 myPos_x = resizeorigin_x - mySize_x;
 449                 myPos_y = resizeorigin_y - mySize_y;
 450         } else if(resizeCorner == 2) {
 451                 myPos_x = resizeorigin_x;
 452                 myPos_y = resizeorigin_y - mySize_y;
 453         } else if(resizeCorner == 3) {
 454                 myPos_x = resizeorigin_x - mySize_x;
 455                 myPos_y = resizeorigin_y;
 456         } else { // resizeCorner == 4
 457                 myPos_x = resizeorigin_x;
 458                 myPos_y = resizeorigin_y;
 459         }
 460
 461         // left/top screen edges
 462         if(myPos_x < 0)
 463                 mySize_x = mySize_x + myPos_x;
 464         if(myPos_y < 0)
 465                 mySize_y = mySize_y + myPos_y;
 466
 467         // bottom/right screen edges
 468         if(myPos_x + mySize_x > vid_conwidth)
 469                 mySize_x = vid_conwidth - myPos_x;
 470         if(myPos_y + mySize_y > vid_conheight)
 471                 mySize_y = vid_conheight - myPos_y;
 472
 473         //if(cvar("hud_configure_checkcollisions_debug"))
 474                 //drawfill(myPos, mySize, '1 1 1', .2, DRAWFLAG_NORMAL);
 475
 476         // before checkresize, otherwise panel can be snapped partially inside another panel or panel aspect ratio can be broken
 477         if(autocvar_hud_configure_grid)
 478         {
 479                 mySize_x = floor((mySize_x/vid_conwidth)/hud_configure_gridSize_x + 0.5) * hud_configure_realGridSize_x;
 480                 mySize_y = floor((mySize_y/vid_conheight)/hud_configure_gridSize_y + 0.5) * hud_configure_realGridSize_y;
 481         }
 482
 483         if(hud_configure_checkcollisions)
 484                 mySize = HUD_Panel_CheckResize(mySize, resizeorigin);
 485
 486         // minimum panel size cap, do this once more so we NEVER EVER EVER have a panel smaller than this, JUST IN CASE above code still makes the panel eg negative (impossible to resize back without changing cvars manually then)
 487         mySize_x = max(0.025 * vid_conwidth, mySize_x);
 488         mySize_y = max(0.025 * vid_conheight, mySize_y);
 489
 490         // do another pos check, as size might have changed by now
 491         if(resizeCorner == 1) {
 492                 myPos_x = resizeorigin_x - mySize_x;
 493                 myPos_y = resizeorigin_y - mySize_y;
 494         } else if(resizeCorner == 2) {
 495                 myPos_x = resizeorigin_x;
 496                 myPos_y = resizeorigin_y - mySize_y;
 497         } else if(resizeCorner == 3) {
 498                 myPos_x = resizeorigin_x - mySize_x;
 499                 myPos_y = resizeorigin_y;
 500         } else { // resizeCorner == 4
 501                 myPos_x = resizeorigin_x;
 502                 myPos_y = resizeorigin_y;
 503         }
 504
 505         //if(cvar("hud_configure_checkcollisions_debug"))
 506                 //drawfill(myPos, mySize, '0 1 0', .3, DRAWFLAG_NORMAL);
 507
 508         string s;
 509         s = strcat(ftos(mySize_x/vid_conwidth), " ", ftos(mySize_y/vid_conheight));
 510         cvar_set(strcat("hud_panel_", highlightedPanel.panel_name, "_size"), s);
 511
 512         s = strcat(ftos(myPos_x/vid_conwidth), " ", ftos(myPos_y/vid_conheight));
 513         cvar_set(strcat("hud_panel_", highlightedPanel.panel_name, "_pos"), s);
 514 }
 515
 516 float pressed_key_time;
 517 vector highlightedPanel_initial_pos, highlightedPanel_initial_size;
 518 void HUD_Panel_Arrow_Action(float nPrimary)
 519 {
 520         if(!highlightedPanel)
 521                 return;
 522
 523         hud_configure_checkcollisions = (!(hudShiftState & S_CTRL) && autocvar_hud_configure_checkcollisions);
 524
 525         float step;
 526         if(autocvar_hud_configure_grid)
 527         {
 528                 if (nPrimary == K_UPARROW || nPrimary == K_DOWNARROW)
 529                 {
 530                         if (hudShiftState & S_SHIFT)
 531                                 step = hud_configure_realGridSize_y;
 532                         else
 533                                 step = 2 * hud_configure_realGridSize_y;
 534                 }
 535                 else
 536                 {
 537                         if (hudShiftState & S_SHIFT)
 538                                 step = hud_configure_realGridSize_x;
 539                         else
 540                                 step = 2 * hud_configure_realGridSize_x;
 541                 }
 542         }
 543         else
 544         {
 545                 if (nPrimary == K_UPARROW || nPrimary == K_DOWNARROW)
 546                         step = vid_conheight;
 547                 else
 548                         step = vid_conwidth;
 549                 if (hudShiftState & S_SHIFT)
 550                         step = (step / 256); // more precision
 551                 else
 552                         step = (step / 64) * (1 + 2 * (time - pressed_key_time));
 553         }
 554
 555         panel = highlightedPanel;
 556         HUD_Panel_UpdatePosSize()
 557
 558         highlightedPanel_initial_pos = panel_pos;
 559         highlightedPanel_initial_size = panel_size;
 560
 561         if (hudShiftState & S_ALT) // resize
 562         {
 563                 highlightedAction = 1;
 564                 if(nPrimary == K_UPARROW)
 565                         resizeCorner = 1;
 566                 else if(nPrimary == K_RIGHTARROW)
 567                         resizeCorner = 2;
 568                 else if(nPrimary == K_LEFTARROW)
 569                         resizeCorner = 3;
 570                 else // if(nPrimary == K_DOWNARROW)
 571                         resizeCorner = 4;
 572
 573                 // ctrl+arrow reduces the size, instead of increasing it
 574                 // Note that ctrl disables collisions check too, but it's fine
 575                 // since we don't collide with anything reducing the size
 576                 if (hudShiftState & S_CTRL) {
 577                         step = -step;
 578                         resizeCorner = 5 - resizeCorner;
 579                 }
 580
 581                 vector mySize;
 582                 mySize = panel_size;
 583                 panel_click_resizeorigin = panel_pos;
 584                 if(resizeCorner == 1) {
 585                         panel_click_resizeorigin += mySize;
 586                         mySize_y += step;
 587                 } else if(resizeCorner == 2) {
 588                         panel_click_resizeorigin_y += mySize_y;
 589                         mySize_x += step;
 590                 } else if(resizeCorner == 3) {
 591                         panel_click_resizeorigin_x += mySize_x;
 592                         mySize_x += step;
 593                 } else { // resizeCorner == 4
 594                         mySize_y += step;
 595                 }
 596                 HUD_Panel_SetPosSize(mySize);
 597         }
 598         else // move
 599         {
 600                 highlightedAction = 2;
 601                 vector pos;
 602                 pos = panel_pos;
 603                 if(nPrimary == K_UPARROW)
 604                         pos_y -= step;
 605                 else if(nPrimary == K_DOWNARROW)
 606                         pos_y += step;
 607                 else if(nPrimary == K_LEFTARROW)
 608                         pos_x -= step;
 609                 else // if(nPrimary == K_RIGHTARROW)
 610                         pos_x += step;
 611
 612                 HUD_Panel_SetPos(pos);
 613         }
 614
 615         panel = highlightedPanel;
 616         HUD_Panel_UpdatePosSize()
 617
 618         if (highlightedPanel_initial_pos != panel_pos || highlightedPanel_initial_size != panel_size)
 619         {
 620                 // backup!
 621                 panel_pos_backup = highlightedPanel_initial_pos;
 622                 panel_size_backup = highlightedPanel_initial_size;
 623                 highlightedPanel_backup = highlightedPanel;
 624         }
 625 }
 626
 627 const float S_MOUSE1 = 1;
 628 const float S_MOUSE2 = 2;
 629 const float S_MOUSE3 = 4;
 630 float mouseClicked;
 631 float prevMouseClicked; // previous state
 632 float prevMouseClickedTime; // time during previous left mouse click, to check for doubleclicks
 633 vector prevMouseClickedPos; // pos during previous left mouse click, to check for doubleclicks
 634
 635 void HUD_Panel_EnableMenu();
 636 entity tab_panels[HUD_PANEL_MAX];
 637 entity tab_panel;
 638 vector tab_panel_pos;
 639 float tab_backward;
 640 void HUD_Panel_FirstInDrawQ(float id);
 641 void reset_tab_panels()
 642 {
 643         int i;
 644         for(i = 0; i < HUD_PANEL_NUM; ++i)
 645                 tab_panels[i] = world;
 646 }
 647 float HUD_Panel_InputEvent(float bInputType, float nPrimary, float nSecondary)
 648 {
 649         string s;
 650
 651         if(bInputType == 2)
 652                 return false;
 653
 654         if(!autocvar__hud_configure)
 655                 return false;
 656
 657         if(bInputType == 3)
 658         {
 659                 mousepos_x = nPrimary;
 660                 mousepos_y = nSecondary;
 661                 return true;
 662         }
 663
 664         // block any input while a menu dialog is fading
 665         // don't block mousepos read as it leads to cursor jumps in the interaction with the menu
 666         if(autocvar__menu_alpha)
 667         {
 668                 hudShiftState = 0;
 669                 mouseClicked = 0;
 670                 return true;
 671         }
 672
 673         // allow console bind to work
 674         string con_keys;
 675         float keys;
 676         con_keys = findkeysforcommand("toggleconsole", 0);
 677         keys = tokenize(con_keys); // findkeysforcommand returns data for this
 678
 679         float hit_con_bind = 0, i;
 680         for (i = 0; i < keys; ++i)
 681         {
 682                 if(nPrimary == stof(argv(i)))
 683                         hit_con_bind = 1;
 684         }
 685
 686         if(bInputType == 0) {
 687                 if(nPrimary == K_ALT) hudShiftState |= S_ALT;
 688                 if(nPrimary == K_CTRL) hudShiftState |= S_CTRL;
 689                 if(nPrimary == K_SHIFT) hudShiftState |= S_SHIFT;
 690         }
 691         else if(bInputType == 1) {
 692                 if(nPrimary == K_ALT) hudShiftState -= (hudShiftState & S_ALT);
 693                 if(nPrimary == K_CTRL) hudShiftState -= (hudShiftState & S_CTRL);
 694                 if(nPrimary == K_SHIFT) hudShiftState -= (hudShiftState & S_SHIFT);
 695         }
 696
 697         if(nPrimary == K_CTRL)
 698         {
 699                 if (bInputType == 1) //ctrl has been released
 700                 {
 701                         if (tab_panel)
 702                         {
 703                                 //switch to selected panel
 704                                 highlightedPanel = tab_panel;
 705                                 highlightedAction = 0;
 706                                 HUD_Panel_FirstInDrawQ(highlightedPanel.panel_id);
 707                         }
 708                         tab_panel = world;
 709                         reset_tab_panels();
 710                 }
 711         }
 712
 713         if(nPrimary == K_MOUSE1)
 714         {
 715                 if(bInputType == 0) // key pressed
 716                         mouseClicked |= S_MOUSE1;
 717                 else if(bInputType == 1) // key released
 718                         mouseClicked -= (mouseClicked & S_MOUSE1);
 719         }
 720         else if(nPrimary == K_MOUSE2)
 721         {
 722                 if(bInputType == 0) // key pressed
 723                         mouseClicked |= S_MOUSE2;
 724                 else if(bInputType == 1) // key released
 725                         mouseClicked -= (mouseClicked & S_MOUSE2);
 726         }
 727         else if(nPrimary == K_ESCAPE)
 728         {
 729                 if (bInputType == 1)
 730                         return true;
 731                 menu_enabled = 1;
 732                 localcmd("menu_showhudexit\n");
 733         }
 734         else if(nPrimary == K_BACKSPACE && hudShiftState & S_CTRL)
 735         {
 736                 if (bInputType == 1)
 737                         return true;
 738                 if (!menu_enabled)
 739                         cvar_set("_hud_configure", "0");
 740         }
 741         else if(nPrimary == K_TAB && hudShiftState & S_CTRL) // select and highlight another panel
 742         {
 743                 if (bInputType == 1 || mouseClicked)
 744                         return true;
 745
 746                 //FIXME: if a panel is highlighted, has the same pos_x and lays in the same level
 747                 //of other panels then next consecutive ctrl-tab will select the highlighted panel too
 748                 //(it should only after every other panel of the hud)
 749                 //It's a minor bug anyway, we can live with it
 750
 751                 entity starting_panel;
 752                 entity old_tab_panel = tab_panel;
 753                 if (!tab_panel) //first press of TAB
 754                 {
 755                         if (highlightedPanel)
 756                         {
 757                                 panel = highlightedPanel;
 758                                 HUD_Panel_UpdatePosSize()
 759                         }
 760                         else
 761                                 panel_pos = '0 0 0';
 762                         starting_panel = highlightedPanel;
 763                         tab_panel_pos = panel_pos; //to compute level
 764                 }
 765                 else
 766                 {
 767                         if ( ((!tab_backward) && (hudShiftState & S_SHIFT)) || (tab_backward && !(hudShiftState & S_SHIFT)) ) //tab direction changed?
 768                                 reset_tab_panels();
 769                         starting_panel = tab_panel;
 770                 }
 771                 tab_backward = (hudShiftState & S_SHIFT);
 772
 773                 float k, level = 0, start_pos_x;
 774                 vector candidate_pos = '0 0 0';
 775                 const float LEVELS_NUM = 4;
 776                 float level_height = vid_conheight / LEVELS_NUM;
 777 :find_tab_panel
 778                 level = floor(tab_panel_pos_y / level_height) * level_height; //starting level
 779                 candidate_pos_x = (!tab_backward) ? vid_conwidth : 0;
 780                 start_pos_x = tab_panel_pos_x;
 781                 tab_panel = world;
 782                 k=0;
 783                 while(++k)
 784                 {
 785                         for(i = 0; i < HUD_PANEL_NUM; ++i)
 786                         {
 787                                 panel = hud_panel[i];
 788                                 if (panel == tab_panels[i] || panel == starting_panel)
 789                                         continue;
 790                                 HUD_Panel_UpdatePosSize()
 791                                 if (panel_pos_y >= level && (panel_pos_y - level) < level_height)
 792                                 if (  ( !tab_backward && panel_pos_x >= start_pos_x && (panel_pos_x < candidate_pos_x || (panel_pos_x == candidate_pos_x && panel_pos_y <= candidate_pos_y)) )
 793                                         || ( tab_backward && panel_pos_x <= start_pos_x && (panel_pos_x > candidate_pos_x || (panel_pos_x == candidate_pos_x && panel_pos_y >= candidate_pos_y)) )  )
 794                                 {
 795                                         tab_panel = panel;
 796                                         tab_panel_pos = candidate_pos = panel_pos;
 797                                 }
 798                         }
 799                         if (tab_panel)
 800                                 break;
 801                         if (k == LEVELS_NUM) //tab_panel not found
 802                         {
 803                                 reset_tab_panels();
 804                                 if (!old_tab_panel)
 805                                 {
 806                                         tab_panel = world;
 807                                         return true;
 808                                 }
 809                                 starting_panel = old_tab_panel;
 810                                 old_tab_panel = world;
 811                                 goto find_tab_panel; //u must find tab_panel!
 812                         }
 813                         if (!tab_backward)
 814                         {
 815                                 level = (level + level_height) % vid_conheight;
 816                                 start_pos_x = 0;
 817                                 candidate_pos_x = vid_conwidth;
 818                         }
 819                         else
 820                         {
 821                                 level = (level - level_height) % vid_conheight;
 822                                 start_pos_x = vid_conwidth;
 823                                 candidate_pos_x = 0;
 824                         }
 825                 }
 826
 827                 tab_panels[tab_panel.panel_id] = tab_panel;
 828         }
 829         else if(nPrimary == K_SPACE && hudShiftState & S_CTRL) // enable/disable highlighted panel or dock
 830         {
 831                 if (bInputType == 1 || mouseClicked)
 832                         return true;
 833
 834                 if (highlightedPanel)
 835                         cvar_set(strcat("hud_panel_", highlightedPanel.panel_name), ftos(!cvar(strcat("hud_panel_", highlightedPanel.panel_name))));
 836                 else
 837                         cvar_set(strcat("hud_dock"), (autocvar_hud_dock == "") ? "dock" : "");
 838         }
 839         else if(nPrimary == 'c' && hudShiftState & S_CTRL) // copy highlighted panel size
 840         {
 841                 if (bInputType == 1 || mouseClicked)
 842                         return true;
 843
 844                 if (highlightedPanel)
 845                 {
 846                         panel = highlightedPanel;
 847                         HUD_Panel_UpdatePosSize()
 848                         panel_size_copied = panel_size;
 849                 }
 850         }
 851         else if(nPrimary == 'v' && hudShiftState & S_CTRL) // past copied size on the highlighted panel
 852         {
 853                 if (bInputType == 1 || mouseClicked)
 854                         return true;
 855
 856                 if (panel_size_copied == '0 0 0' || !highlightedPanel)
 857                         return true;
 858
 859                 panel = highlightedPanel;
 860                 HUD_Panel_UpdatePosSize()
 861
 862                 // reduce size if it'd go beyond screen boundaries
 863                 vector tmp_size = panel_size_copied;
 864                 if (panel_pos_x + panel_size_copied_x > vid_conwidth)
 865                         tmp_size_x = vid_conwidth - panel_pos_x;
 866                 if (panel_pos_y + panel_size_copied_y > vid_conheight)
 867                         tmp_size_y = vid_conheight - panel_pos_y;
 868
 869                 if (panel_size == tmp_size)
 870                         return true;
 871
 872                 // backup first!
 873                 panel_pos_backup = panel_pos;
 874                 panel_size_backup = panel_size;
 875                 highlightedPanel_backup = highlightedPanel;
 876
 877                 s = strcat(ftos(tmp_size_x/vid_conwidth), " ", ftos(tmp_size_y/vid_conheight));
 878                 cvar_set(strcat("hud_panel_", highlightedPanel.panel_name, "_size"), s);
 879         }
 880         else if(nPrimary == 'z' && hudShiftState & S_CTRL) // undo last action
 881         {
 882                 if (bInputType == 1 || mouseClicked)
 883                         return true;
 884                 //restore previous values
 885                 if (highlightedPanel_backup)
 886                 {
 887                         s = strcat(ftos(panel_pos_backup_x/vid_conwidth), " ", ftos(panel_pos_backup_y/vid_conheight));
 888                         cvar_set(strcat("hud_panel_", highlightedPanel_backup.panel_name, "_pos"), s);
 889                         s = strcat(ftos(panel_size_backup_x/vid_conwidth), " ", ftos(panel_size_backup_y/vid_conheight));
 890                         cvar_set(strcat("hud_panel_", highlightedPanel_backup.panel_name, "_size"), s);
 891                         highlightedPanel_backup = world;
 892                 }
 893         }
 894         else if(nPrimary == K_UPARROW || nPrimary == K_DOWNARROW || nPrimary == K_LEFTARROW || nPrimary == K_RIGHTARROW)
 895         {
 896                 if (bInputType == 1)
 897                 {
 898                         pressed_key_time = 0;
 899                         return true;
 900                 }
 901                 else if (pressed_key_time == 0)
 902                         pressed_key_time = time;
 903
 904                 if (!mouseClicked)
 905                         HUD_Panel_Arrow_Action(nPrimary); //move or resize panel
 906         }
 907         else if(nPrimary == K_ENTER || nPrimary == K_SPACE || nPrimary == K_KP_ENTER)
 908         {
 909                 if (bInputType == 1)
 910                         return true;
 911                 if (highlightedPanel)
 912                         HUD_Panel_EnableMenu();
 913         }
 914         else if(hit_con_bind)
 915                 return false;
 916
 917         return true;
 918 }
 919
 920 float HUD_Panel_Check_Mouse_Pos(float allow_move)
 921 {
 922         float i, j = 0, border;
 923
 924         while(j < HUD_PANEL_NUM)
 925         {
 926                 i = panel_order[j];
 927                 j += 1;
 928
 929                 panel = hud_panel[i];
 930                 HUD_Panel_UpdatePosSize()
 931
 932                 border = max(8, panel_bg_border); // FORCED border so a small border size doesn't mean you can't resize
 933
 934                 // move
 935                 if(allow_move && mousepos_x > panel_pos_x && mousepos_y > panel_pos_y && mousepos_x < panel_pos_x + panel_size_x && mousepos_y < panel_pos_y + panel_size_y)
 936                 {
 937                         return 1;
 938                 }
 939                 // resize from topleft border
 940                 else if(mousepos_x >= panel_pos_x - border && mousepos_y >= panel_pos_y - border && mousepos_x <= panel_pos_x + 0.5 * panel_size_x && mousepos_y <= panel_pos_y + 0.5 * panel_size_y)
 941                 {
 942                         return 2;
 943                 }
 944                 // resize from topright border
 945                 else if(mousepos_x >= panel_pos_x + 0.5 * panel_size_x && mousepos_y >= panel_pos_y - border && mousepos_x <= panel_pos_x + panel_size_x + border && mousepos_y <= panel_pos_y + 0.5 * panel_size_y)
 946                 {
 947                         return 3;
 948                 }
 949                 // resize from bottomleft border
 950                 else if(mousepos_x >= panel_pos_x - border && mousepos_y >= panel_pos_y + 0.5 * panel_size_y && mousepos_x <= panel_pos_x + 0.5 * panel_size_x && mousepos_y <= panel_pos_y + panel_size_y + border)
 951                 {
 952                         return 3;
 953                 }
 954                 // resize from bottomright border
 955                 else if(mousepos_x >= panel_pos_x + 0.5 * panel_size_x && mousepos_y >= panel_pos_y + 0.5 * panel_size_y && mousepos_x <= panel_pos_x + panel_size_x + border && mousepos_y <= panel_pos_y + panel_size_y + border)
 956                 {
 957                         return 2;
 958                 }
 959         }
 960         return 0;
 961 }
 962
 963 // move a panel to the beginning of the panel order array (which means it gets drawn last, on top of everything else)
 964 void HUD_Panel_FirstInDrawQ(float id)
 965 {
 966         float i;
 967         var float place = -1;
 968         // find out where in the array our current id is, save into place
 969         for(i = 0; i < HUD_PANEL_NUM; ++i)
 970         {
 971                 if(panel_order[i] == id)
 972                 {
 973                         place = i;
 974                         break;
 975                 }
 976         }
 977         // place last if we didn't find a place for it yet (probably new panel, or screwed up cvar)
 978         if(place == -1)
 979                 place = HUD_PANEL_NUM - 1;
 980
 981         // move all ids up by one step in the array until "place"
 982         for(i = place; i > 0; --i)
 983         {
 984                 panel_order[i] = panel_order[i-1];
 985         }
 986         // now save the new top id
 987         panel_order[0] = id;
 988
 989         // let's save them into the cvar by some strcat trickery
 990         string s = "";
 991         for(i = 0; i < HUD_PANEL_NUM; ++i)
 992         {
 993                 s = strcat(s, ftos(panel_order[i]), " ");
 994         }
 995         cvar_set("_hud_panelorder", s);
 996         if(hud_panelorder_prev)
 997                 strunzone(hud_panelorder_prev);
 998         hud_panelorder_prev = strzone(autocvar__hud_panelorder); // prevent HUD_Main from doing useless update, we already updated here
 999 }
1000
1001 void HUD_Panel_Highlight(float allow_move)
1002 {
1003         float i, j = 0, border;
1004
1005         while(j < HUD_PANEL_NUM)
1006         {
1007                 i = panel_order[j];
1008                 j += 1;
1009
1010                 panel = hud_panel[i];
1011                 HUD_Panel_UpdatePosSize()
1012
1013                 border = max(8, panel_bg_border); // FORCED border so a small border size doesn't mean you can't resize
1014
1015                 // move
1016                 if(allow_move && mousepos_x > panel_pos_x && mousepos_y > panel_pos_y && mousepos_x < panel_pos_x + panel_size_x && mousepos_y < panel_pos_y + panel_size_y)
1017                 {
1018                         highlightedPanel = hud_panel[i];
1019                         HUD_Panel_FirstInDrawQ(i);
1020                         highlightedAction = 1;
1021                         panel_click_distance = mousepos - panel_pos;
1022                         return;
1023                 }
1024                 // resize from topleft border
1025                 else if(mousepos_x >= panel_pos_x - border && mousepos_y >= panel_pos_y - border && mousepos_x <= panel_pos_x + 0.5 * panel_size_x && mousepos_y <= panel_pos_y + 0.5 * panel_size_y)
1026                 {
1027                         highlightedPanel = hud_panel[i];
1028                         HUD_Panel_FirstInDrawQ(i);
1029                         highlightedAction = 2;
1030                         resizeCorner = 1;
1031                         panel_click_distance = mousepos - panel_pos;
1032                         panel_click_resizeorigin = panel_pos + panel_size;
1033                         return;
1034                 }
1035                 // resize from topright border
1036                 else if(mousepos_x >= panel_pos_x + 0.5 * panel_size_x && mousepos_y >= panel_pos_y - border && mousepos_x <= panel_pos_x + panel_size_x + border && mousepos_y <= panel_pos_y + 0.5 * panel_size_y)
1037                 {
1038                         highlightedPanel = hud_panel[i];
1039                         HUD_Panel_FirstInDrawQ(i);
1040                         highlightedAction = 2;
1041                         resizeCorner = 2;
1042                         panel_click_distance_x = panel_size_x - mousepos_x + panel_pos_x;
1043                         panel_click_distance_y = mousepos_y - panel_pos_y;
1044                         panel_click_resizeorigin = panel_pos + eY * panel_size_y;
1045                         return;
1046                 }
1047                 // resize from bottomleft border
1048                 else if(mousepos_x >= panel_pos_x - border && mousepos_y >= panel_pos_y + 0.5 * panel_size_y && mousepos_x <= panel_pos_x + 0.5 * panel_size_x && mousepos_y <= panel_pos_y + panel_size_y + border)
1049                 {
1050                         highlightedPanel = hud_panel[i];
1051                         HUD_Panel_FirstInDrawQ(i);
1052                         highlightedAction = 2;
1053                         resizeCorner = 3;
1054                         panel_click_distance_x = mousepos_x - panel_pos_x;
1055                         panel_click_distance_y = panel_size_y - mousepos_y + panel_pos_y;
1056                         panel_click_resizeorigin = panel_pos + eX * panel_size_x;
1057                         return;
1058                 }
1059                 // resize from bottomright border
1060                 else if(mousepos_x >= panel_pos_x + 0.5 * panel_size_x && mousepos_y >= panel_pos_y + 0.5 * panel_size_y && mousepos_x <= panel_pos_x + panel_size_x + border && mousepos_y <= panel_pos_y + panel_size_y + border)
1061                 {
1062                         highlightedPanel = hud_panel[i];
1063                         HUD_Panel_FirstInDrawQ(i);
1064                         highlightedAction = 2;
1065                         resizeCorner = 4;
1066                         panel_click_distance = panel_size - mousepos + panel_pos;
1067                         panel_click_resizeorigin = panel_pos;
1068                         return;
1069                 }
1070         }
1071         highlightedPanel = world;
1072         highlightedAction = 0;
1073 }
1074
1075 void HUD_Panel_EnableMenu()
1076 {
1077         menu_enabled = 2;
1078         localcmd("menu_showhudoptions ", highlightedPanel.panel_name, "\n");
1079 }
1080 float mouse_over_panel;
1081 void HUD_Panel_Mouse()
1082 {
1083         if(autocvar__menu_alpha == 1)
1084                 return;
1085
1086         if (!autocvar_hud_cursormode)
1087         {
1088                 mousepos = mousepos + getmousepos() * autocvar_menu_mouse_speed;
1089
1090                 mousepos_x = bound(0, mousepos_x, vid_conwidth);
1091                 mousepos_y = bound(0, mousepos_y, vid_conheight);
1092         }
1093
1094         if(mouseClicked)
1095         {
1096                 if(prevMouseClicked == 0)
1097                 {
1098                         if (tab_panel)
1099                         {
1100                                 //stop ctrl-tab selection
1101                                 tab_panel = world;
1102                                 reset_tab_panels();
1103                         }
1104                         HUD_Panel_Highlight(mouseClicked & S_MOUSE1); // sets highlightedPanel, highlightedAction, panel_click_distance, panel_click_resizeorigin
1105                                                                         // and calls HUD_Panel_UpdatePosSize() for the highlighted panel
1106                         if (highlightedPanel)
1107                         {
1108                                 highlightedPanel_initial_pos = panel_pos;
1109                                 highlightedPanel_initial_size = panel_size;
1110                         }
1111                         // doubleclick check
1112                         if ((mouseClicked & S_MOUSE1) && time - prevMouseClickedTime < 0.4 && highlightedPanel && prevMouseClickedPos == mousepos)
1113                         {
1114                                 mouseClicked = 0; // to prevent spam, I guess.
1115                                 HUD_Panel_EnableMenu();
1116                         }
1117                         else
1118                         {
1119                                 if (mouseClicked & S_MOUSE1)
1120                                 {
1121                                         prevMouseClickedTime = time;
1122                                         prevMouseClickedPos = mousepos;
1123                                 }
1124                                 mouse_over_panel = HUD_Panel_Check_Mouse_Pos(mouseClicked & S_MOUSE1);
1125                         }
1126                 }
1127                 else
1128                 {
1129                         panel = highlightedPanel;
1130                         HUD_Panel_UpdatePosSize()
1131                 }
1132
1133                 if (highlightedPanel)
1134                 {
1135                         drawfill(panel_pos - '1 1 0' * panel_bg_border, panel_size + '2 2 0' * panel_bg_border, '1 1 1', .1, DRAWFLAG_NORMAL);
1136                         if (highlightedPanel_initial_pos != panel_pos || highlightedPanel_initial_size != panel_size)
1137                         {
1138                                 hud_configure_checkcollisions = (!(hudShiftState & S_CTRL) && autocvar_hud_configure_checkcollisions);
1139                                 // backup!
1140                                 panel_pos_backup = highlightedPanel_initial_pos;
1141                                 panel_size_backup = highlightedPanel_initial_size;
1142                                 highlightedPanel_backup = highlightedPanel;
1143                         }
1144                         else
1145                                 // in case the clicked panel is inside another panel and we aren't
1146                                 // moving it, avoid the immediate "fix" of its position/size
1147                                 // (often unwanted and hateful) by disabling collisions check
1148                                 hud_configure_checkcollisions = false;
1149                 }
1150
1151                 if(highlightedAction == 1)
1152                         HUD_Panel_SetPos(mousepos - panel_click_distance);
1153                 else if(highlightedAction == 2)
1154                 {
1155                         vector mySize = '0 0 0';
1156                         if(resizeCorner == 1) {
1157                                 mySize_x = panel_click_resizeorigin_x - (mousepos_x - panel_click_distance_x);
1158                                 mySize_y = panel_click_resizeorigin_y - (mousepos_y - panel_click_distance_y);
1159                         } else if(resizeCorner == 2) {
1160                                 mySize_x = mousepos_x + panel_click_distance_x - panel_click_resizeorigin_x;
1161                                 mySize_y = panel_click_distance_y + panel_click_resizeorigin_y - mousepos_y;
1162                         } else if(resizeCorner == 3) {
1163                                 mySize_x = panel_click_resizeorigin_x + panel_click_distance_x - mousepos_x;
1164                                 mySize_y = mousepos_y + panel_click_distance_y - panel_click_resizeorigin_y;
1165                         } else { // resizeCorner == 4
1166                                 mySize_x = mousepos_x - (panel_click_resizeorigin_x - panel_click_distance_x);
1167                                 mySize_y = mousepos_y - (panel_click_resizeorigin_y - panel_click_distance_y);
1168                         }
1169                         HUD_Panel_SetPosSize(mySize);
1170                 }
1171         }
1172         else
1173         {
1174                 if(menu_enabled == 2)
1175                         mouse_over_panel = 0;
1176                 else
1177                         mouse_over_panel = HUD_Panel_Check_Mouse_Pos(TRUE);
1178                 if (mouse_over_panel && !tab_panel)
1179                         drawfill(panel_pos - '1 1 0' * panel_bg_border, panel_size + '2 2 0' * panel_bg_border, '1 1 1', .1, DRAWFLAG_NORMAL);
1180         }
1181         // draw cursor after performing move/resize to have the panel pos/size updated before mouse_over_panel
1182         const vector cursorsize = '32 32 0';
1183         float cursor_alpha = 1 - autocvar__menu_alpha;
1184
1185         if(!mouse_over_panel)
1186                 drawpic(mousepos, strcat("gfx/menu/", autocvar_menu_skin, "/cursor.tga"), cursorsize, '1 1 1', cursor_alpha, DRAWFLAG_NORMAL);
1187         else if(mouse_over_panel == 1)
1188                 drawpic(mousepos - cursorsize * 0.5, strcat("gfx/menu/", autocvar_menu_skin, "/cursor_move.tga"), cursorsize, '1 1 1', cursor_alpha, DRAWFLAG_NORMAL);
1189         else if(mouse_over_panel == 2)
1190                 drawpic(mousepos - cursorsize * 0.5, strcat("gfx/menu/", autocvar_menu_skin, "/cursor_resize.tga"), cursorsize, '1 1 1', cursor_alpha, DRAWFLAG_NORMAL);
1191         else
1192                 drawpic(mousepos - cursorsize * 0.5, strcat("gfx/menu/", autocvar_menu_skin, "/cursor_resize2.tga"), cursorsize, '1 1 1', cursor_alpha, DRAWFLAG_NORMAL);
1193
1194         prevMouseClicked = mouseClicked;
1195 }
1196 void HUD_Configure_DrawGrid()
1197 {
1198         float i;
1199         if(autocvar_hud_configure_grid && autocvar_hud_configure_grid_alpha)
1200         {
1201                 hud_configure_gridSize_x = bound(0.005, cvar("hud_configure_grid_xsize"), 0.2);
1202                 hud_configure_gridSize_y = bound(0.005, cvar("hud_configure_grid_ysize"), 0.2);
1203                 hud_configure_realGridSize_x = hud_configure_gridSize_x * vid_conwidth;
1204                 hud_configure_realGridSize_y = hud_configure_gridSize_y * vid_conheight;
1205                 vector s;
1206                 // x-axis
1207                 s = eX + eY * vid_conheight;
1208                 for(i = 1; i < 1/hud_configure_gridSize_x; ++i)
1209                         drawfill(eX * i * hud_configure_realGridSize_x, s, '0.5 0.5 0.5', autocvar_hud_configure_grid_alpha, DRAWFLAG_NORMAL);
1210                 // y-axis
1211                 s = eY + eX * vid_conwidth;
1212                 for(i = 1; i < 1/hud_configure_gridSize_y; ++i)
1213                         drawfill(eY * i * hud_configure_realGridSize_y, s, '0.5 0.5 0.5', autocvar_hud_configure_grid_alpha, DRAWFLAG_NORMAL);
1214         }
1215 }
1216
1217 float _menu_alpha_prev;
1218 void HUD_Configure_Frame()
1219 {
1220         float i;
1221         if(autocvar__hud_configure)
1222         {
1223                 if(isdemo() || intermission == 2)
1224                 {
1225                         HUD_Configure_Exit_Force();
1226                         return;
1227                 }
1228
1229                 if(!hud_configure_prev || hud_configure_prev == -1)
1230                 {
1231                         if(autocvar_hud_cursormode)
1232                                 setcursormode(1);
1233                         hudShiftState = 0;
1234                         for(i = HUD_PANEL_NUM - 1; i >= 0; --i)
1235                                 hud_panel[panel_order[i]].update_time = time;
1236                 }
1237
1238                 // NOTE this check is necessary because _menu_alpha isn't updated the frame the menu gets enabled
1239                 if(autocvar__menu_alpha != _menu_alpha_prev)
1240                 {
1241                         if(autocvar__menu_alpha == 0)
1242                                 menu_enabled = 0;
1243                         _menu_alpha_prev = autocvar__menu_alpha;
1244                 }
1245
1246                 HUD_Configure_DrawGrid();
1247         }
1248         else if(hud_configure_prev)
1249         {
1250                 if(menu_enabled)
1251                         menu_enabled = 0;
1252                 if(autocvar_hud_cursormode)
1253                         setcursormode(0);
1254         }
1255 }
1256
1257 const float hlBorderSize = 4;
1258 const string hlBorder = "gfx/hud/default/border_highlighted";
1259 const string hlBorder2 = "gfx/hud/default/border_highlighted2";
1260 void HUD_Panel_HlBorder(float myBorder, vector color, float theAlpha)
1261 {
1262         drawfill(panel_pos - '1 1 0' * myBorder, panel_size + '2 2 0' * myBorder, '0 0.5 1', .5 * theAlpha, DRAWFLAG_NORMAL);
1263         drawpic_tiled(panel_pos - '1 1 0' * myBorder, hlBorder, '8 1 0' * hlBorderSize, eX * (panel_size_x + 2 * myBorder) + eY * hlBorderSize, color, theAlpha, DRAWFLAG_NORMAL);
1264         drawpic_tiled(panel_pos - '1 1 0' * myBorder + eY * (panel_size_y + 2 * myBorder - hlBorderSize), hlBorder, '8 1 0' * hlBorderSize, eX * (panel_size_x + 2 * myBorder) + eY * hlBorderSize, color, theAlpha, DRAWFLAG_NORMAL);
1265         drawpic_tiled(panel_pos - '1 1 0' * myBorder + eY * hlBorderSize, hlBorder2, '1 8 0' * hlBorderSize, eY * (panel_size_y + 2 * myBorder - 2 * hlBorderSize) + eX * hlBorderSize, color, theAlpha, DRAWFLAG_NORMAL);
1266         drawpic_tiled(panel_pos - '1 1 0' * myBorder + eY * hlBorderSize + eX * (panel_size_x + 2 * myBorder - hlBorderSize), hlBorder2, '1 8 0' * hlBorderSize, eY * (panel_size_y + 2 * myBorder - 2 * hlBorderSize) + eX * hlBorderSize, color, theAlpha, DRAWFLAG_NORMAL);
1267 }
1268
1269 void HUD_Configure_PostDraw()
1270 {
1271         if(autocvar__hud_configure)
1272         {
1273                 if(tab_panel)
1274                 {
1275                         panel = tab_panel;
1276                         HUD_Panel_UpdatePosSize()
1277                         drawfill(panel_pos - '1 1 0' * panel_bg_border, panel_size + '2 2 0' * panel_bg_border, '1 1 1', .2, DRAWFLAG_NORMAL);
1278                 }
1279                 if(highlightedPanel)
1280                 {
1281                         panel = highlightedPanel;
1282                         HUD_Panel_UpdatePosSize()
1283                         HUD_Panel_HlBorder(panel_bg_border + 1.5 * hlBorderSize, '0 0.5 1', 0.25 * (1 - autocvar__menu_alpha));
1284                 }
1285         }
1286 }