qcsrc/client/teamradar.qc

   1 #include "teamradar.qh"
   2
   3 #include "autocvars.qh"
   4 #include "defs.qh"
   5 #include "hud.qh"
   6 #include "main.qh"
   7 #include "miscfunctions.qh"
   8 #include "../common/util.qh"
   9 #include "../csqcmodellib/interpolate.qh"
  10
  11 float vlen2d(vector v)
  12 {
  13         return sqrt(v.x * v.x + v.y * v.y);
  14 }
  15
  16 float vlen_maxnorm2d(vector v)
  17 {
  18         return max(v.x, v.y, -v.x, -v.y);
  19 }
  20
  21 float vlen_minnorm2d(vector v)
  22 {
  23         return min(max(v.x, -v.x), max(v.y, -v.y));
  24 }
  25
  26 vector teamradar_3dcoord_to_texcoord(vector in)
  27 {
  28         vector out;
  29         out.x = (in.x - mi_picmin.x) / (mi_picmax.x - mi_picmin.x);
  30         out.y = (in.y - mi_picmin.y) / (mi_picmax.y - mi_picmin.y);
  31         out.z = 0;
  32         return out;
  33 }
  34
  35 vector teamradar_texcoord_to_2dcoord(vector in)
  36 {
  37         vector out;
  38         in -= teamradar_origin3d_in_texcoord;
  39
  40         out = rotate(in, teamradar_angle * DEG2RAD);
  41         out.y = - out.y; // screen space is reversed
  42
  43         out = out * teamradar_size;
  44         if(v_flipped)
  45                 out.x = -out.x;
  46         out += teamradar_origin2d;
  47         return out;
  48 }
  49
  50 vector yinvert(vector v)
  51 {
  52         v.y = 1 - v.y;
  53         return v;
  54 }
  55
  56 void draw_teamradar_background(float fg)
  57 {
  58         float fga;
  59         vector fgc;
  60
  61         if(fg > 0 && minimapname != "")
  62         {
  63                 fga = 1;
  64                 fgc = '1 1 1' * fg;
  65                 R_BeginPolygon(minimapname, DRAWFLAG_SCREEN | DRAWFLAG_MIPMAP);
  66                 if(v_flipped)
  67                 {
  68                         R_PolygonVertex(teamradar_texcoord_to_2dcoord(mi_pictexcoord3), yinvert(mi_pictexcoord3), fgc, fga);
  69                         R_PolygonVertex(teamradar_texcoord_to_2dcoord(mi_pictexcoord2), yinvert(mi_pictexcoord2), fgc, fga);
  70                         R_PolygonVertex(teamradar_texcoord_to_2dcoord(mi_pictexcoord1), yinvert(mi_pictexcoord1), fgc, fga);
  71                         R_PolygonVertex(teamradar_texcoord_to_2dcoord(mi_pictexcoord0), yinvert(mi_pictexcoord0), fgc, fga);
  72                 }
  73                 else
  74                 {
  75                         R_PolygonVertex(teamradar_texcoord_to_2dcoord(mi_pictexcoord0), yinvert(mi_pictexcoord0), fgc, fga);
  76                         R_PolygonVertex(teamradar_texcoord_to_2dcoord(mi_pictexcoord1), yinvert(mi_pictexcoord1), fgc, fga);
  77                         R_PolygonVertex(teamradar_texcoord_to_2dcoord(mi_pictexcoord2), yinvert(mi_pictexcoord2), fgc, fga);
  78                         R_PolygonVertex(teamradar_texcoord_to_2dcoord(mi_pictexcoord3), yinvert(mi_pictexcoord3), fgc, fga);
  79                 }
  80                 R_EndPolygon();
  81         }
  82 }
  83
  84 void draw_teamradar_player(vector coord3d, vector pangles, vector rgb)
  85 {
  86         vector coord, rgb2;
  87
  88         coord = teamradar_texcoord_to_2dcoord(teamradar_3dcoord_to_texcoord(coord3d));
  89
  90         makevectors(pangles - '0 1 0' * teamradar_angle);
  91         if(v_flipped)
  92         {
  93                 v_forward.x = -v_forward.x;
  94                 v_right.x = -v_right.x;
  95                 v_up.x = -v_up.x;
  96         }
  97         v_forward.z = 0;
  98         v_forward = normalize(v_forward);
  99         v_forward.y *= -1.0;
 100         v_right.x = -v_forward.y;
 101         v_right.y = v_forward.x;
 102
 103         if(rgb == '1 1 1')
 104                 rgb2 = '0 0 0';
 105         else
 106                 rgb2 = '1 1 1';
 107
 108         R_BeginPolygon("", 0);
 109         R_PolygonVertex(coord+v_forward*3, '0 0 0', rgb2, panel_fg_alpha);
 110         R_PolygonVertex(coord+v_right*4-v_forward*2.5, '0 1 0', rgb2, panel_fg_alpha);
 111         R_PolygonVertex(coord-v_forward*2, '1 0 0', rgb2, panel_fg_alpha);
 112         R_PolygonVertex(coord-v_right*4-v_forward*2.5, '1 1 0', rgb2, panel_fg_alpha);
 113         R_EndPolygon();
 114
 115         R_BeginPolygon("", 0);
 116         R_PolygonVertex(coord+v_forward*2, '0 0 0', rgb, panel_fg_alpha);
 117         R_PolygonVertex(coord+v_right*3-v_forward*2, '0 1 0', rgb, panel_fg_alpha);
 118         R_PolygonVertex(coord-v_forward, '1 0 0', rgb, panel_fg_alpha);
 119         R_PolygonVertex(coord-v_right*3-v_forward*2, '1 1 0', rgb, panel_fg_alpha);
 120         R_EndPolygon();
 121 }
 122
 123 void draw_teamradar_icon(vector coord, float icon, entity pingdata, vector rgb, float a)
 124 {
 125         coord = teamradar_texcoord_to_2dcoord(teamradar_3dcoord_to_texcoord(coord));
 126         drawpic(coord - '4 4 0', strcat("gfx/teamradar_icon_", ftos(icon)), '8 8 0', rgb, a, 0);
 127
 128         if(pingdata)
 129         {
 130                 for(int i = 0; i < MAX_TEAMRADAR_TIMES; ++i)
 131                 {
 132                         float dt = pingdata.(teamradar_times[i]);
 133                         if(dt == 0)
 134                                 continue;
 135                         dt = time - dt;
 136                         if(dt >= 1 || dt <= 0)
 137                                 continue;
 138                         vector v = '2 2 0' * teamradar_size * dt;
 139                         drawpic(coord - 0.5 * v, "gfx/teamradar_ping", v, '1 1 1', (1 - dt) * a, DRAWFLAG_ADDITIVE);
 140                 }
 141         }
 142 }
 143
 144 void draw_teamradar_link(vector start, vector end, int colors)
 145 {
 146         vector c0, c1, norm;
 147
 148         start = teamradar_texcoord_to_2dcoord(teamradar_3dcoord_to_texcoord(start));
 149         end = teamradar_texcoord_to_2dcoord(teamradar_3dcoord_to_texcoord(end));
 150         norm = normalize(start - end);
 151         norm.z = norm.x;
 152         norm.x = -norm.y;
 153         norm.y = norm.z;
 154         norm.z = 0;
 155
 156         c0 = colormapPaletteColor(colors & 0x0F, false);
 157         c1 = colormapPaletteColor((colors & 0xF0) / 0x10, false);
 158
 159         R_BeginPolygon("", 0);
 160         R_PolygonVertex(start - norm, '0 0 0', c0, panel_fg_alpha);
 161         R_PolygonVertex(start + norm, '0 1 0', c0, panel_fg_alpha);
 162         R_PolygonVertex(end + norm, '1 1 0', c1, panel_fg_alpha);
 163         R_PolygonVertex(end - norm, '1 0 0', c1, panel_fg_alpha);
 164         R_EndPolygon();
 165 }
 166
 167 void teamradar_loadcvars()
 168 {
 169         v_flipped = autocvar_v_flipped;
 170         hud_panel_radar_scale = autocvar_hud_panel_radar_scale;
 171         if (hud_panel_radar_maximized && !autocvar__hud_configure)
 172         {
 173                 if (autocvar_hud_panel_radar_maximized_scale > 0)
 174                         hud_panel_radar_scale = autocvar_hud_panel_radar_maximized_scale;
 175         }
 176         hud_panel_radar_foreground_alpha = autocvar_hud_panel_radar_foreground_alpha * panel_fg_alpha;
 177         hud_panel_radar_rotation = autocvar_hud_panel_radar_rotation;
 178         hud_panel_radar_zoommode = autocvar_hud_panel_radar_zoommode;
 179         hud_panel_radar_maximized_rotation = autocvar_hud_panel_radar_maximized_rotation;
 180         hud_panel_radar_maximized_zoommode = autocvar_hud_panel_radar_maximized_zoommode;
 181
 182         // others default to 0
 183         // match this to defaultXonotic.cfg!
 184         if(!hud_panel_radar_scale) hud_panel_radar_scale = 4096;
 185         if(!hud_panel_radar_foreground_alpha) hud_panel_radar_foreground_alpha = 0.8 * panel_fg_alpha;
 186         if(!hud_panel_radar_size.x) hud_panel_radar_size.x = 128;
 187         if(!hud_panel_radar_size.y) hud_panel_radar_size.y = hud_panel_radar_size.x;
 188 }
 189
 190 // radar links
 191
 192 void Ent_RadarLink()
 193 {
 194         int sendflags = ReadByte();
 195
 196         InterpolateOrigin_Undo();
 197
 198         self.iflags = IFLAG_VELOCITY | IFLAG_ORIGIN;
 199         self.classname = "radarlink";
 200
 201         if(sendflags & 1)
 202         {
 203                 self.origin_x = ReadCoord();
 204                 self.origin_y = ReadCoord();
 205                 self.origin_z = ReadCoord();
 206                 setorigin(self, self.origin);
 207         }
 208
 209         if(sendflags & 2)
 210         {
 211                 self.velocity_x = ReadCoord();
 212                 self.velocity_y = ReadCoord();
 213                 self.velocity_z = ReadCoord();
 214         }
 215
 216         if(sendflags & 4)
 217         {
 218                 self.team = ReadByte();
 219         }
 220
 221         InterpolateOrigin_Note();
 222 }