qcsrc/client/view.qc

   1
   2 #include "announcer.qh"
   3 #include "hook.qh"
   4 #include "hud.qh"
   5 #include "hud_config.qh"
   6 #include "mapvoting.qh"
   7 #include "scoreboard.qh"
   8 #include "shownames.qh"
   9 #include "quickmenu.qh"
  10
  11 #include "mutators/events.qh"
  12
  13 #include "../common/anim.qh"
  14 #include "../common/constants.qh"
  15 #include "../common/mapinfo.qh"
  16 #include "../common/gamemodes/all.qh"
  17 #include "../common/nades/all.qh"
  18 #include "../common/stats.qh"
  19 #include "../common/triggers/target/music.qh"
  20 #include "../common/teams.qh"
  21
  22 #include "../common/vehicles/all.qh"
  23 #include "../common/weapons/all.qh"
  24 #include "../common/viewloc.qh"
  25 #include "../common/minigames/cl_minigames.qh"
  26 #include "../common/minigames/cl_minigames_hud.qh"
  27
  28 #include "../lib/csqcmodel/cl_player.qh"
  29
  30 #include "../lib/warpzone/client.qh"
  31 #include "../lib/warpzone/common.qh"
  32
  33 void viewmodel_draw(entity this)
  34 {
  35         int c = stof(getplayerkeyvalue(current_player, "colors"));
  36         vector g = colormapPaletteColor(c & 0x0F, true) * 2;
  37         for (entity e = this; e; e = e.weaponchild)
  38         {
  39                 e.colormap = c;
  40                 e.glowmod = g;
  41         }
  42 }
  43
  44 entity viewmodel;
  45 STATIC_INIT(viewmodel) {
  46         viewmodel = new(viewmodel);
  47         viewmodel.drawmask = MASK_NORMAL;
  48         viewmodel.draw = viewmodel_draw;
  49 }
  50
  51 entity porto;
  52 vector polyline[16];
  53 void Porto_Draw(entity this)
  54 {
  55         vector p, dir, ang, q, nextdir;
  56         float portal_number, portal1_idx;
  57
  58         if(activeweapon != WEP_PORTO.m_id || spectatee_status || gametype == MAPINFO_TYPE_NEXBALL)
  59                 return;
  60         if(g_balance_porto_secondary)
  61                 return;
  62         if(intermission == 1)
  63                 return;
  64         if(intermission == 2)
  65                 return;
  66         if (getstati(STAT_HEALTH) <= 0)
  67                 return;
  68
  69         dir = view_forward;
  70
  71         if(angles_held_status)
  72         {
  73                 makevectors(angles_held);
  74                 dir = v_forward;
  75         }
  76
  77         p = view_origin;
  78
  79         polyline[0] = p;
  80         int idx = 1;
  81         portal_number = 0;
  82         nextdir = dir;
  83
  84         for (;;)
  85         {
  86                 dir = nextdir;
  87                 traceline(p, p + 65536 * dir, true, porto);
  88                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
  89                         return;
  90                 nextdir = dir - 2 * (dir * trace_plane_normal) * trace_plane_normal; // mirror dir at trace_plane_normal
  91                 p = trace_endpos;
  92                 polyline[idx] = p;
  93                 ++idx;
  94                 if(idx >= 16)
  95                         return;
  96                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_SLICK || trace_dphitcontents & DPCONTENTS_PLAYERCLIP)
  97                         continue;
  98                 ++portal_number;
  99                 ang = vectoangles2(trace_plane_normal, dir);
 100                 ang.x = -ang.x;
 101                 makevectors(ang);
 102                 if(!CheckWireframeBox(porto, p - 48 * v_right - 48 * v_up + 16 * v_forward, 96 * v_right, 96 * v_up, 96 * v_forward))
 103                         return;
 104                 if(portal_number == 1)
 105                 {
 106                         portal1_idx = idx;
 107                         if(portal_number >= 2)
 108                                 break;
 109                 }
 110         }
 111
 112         while(idx >= 2)
 113         {
 114                 p = polyline[idx-2];
 115                 q = polyline[idx-1];
 116                 if(idx == 2)
 117                         p = p - view_up * 16;
 118                 if(idx-1 >= portal1_idx)
 119                 {
 120                         Draw_CylindricLine(p, q, 4, "", 1, 0, '0 0 1', 0.5, DRAWFLAG_NORMAL, view_origin);
 121                 }
 122                 else
 123                 {
 124                         Draw_CylindricLine(p, q, 4, "", 1, 0, '1 0 0', 0.5, DRAWFLAG_NORMAL, view_origin);
 125                 }
 126                 --idx;
 127         }
 128 }
 129
 130 void Porto_Init()
 131 {
 132         porto = spawn();
 133         porto.classname = "porto";
 134         porto.draw = Porto_Draw;
 135         porto.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP;
 136 }
 137
 138 float drawtime;
 139 float avgspeed;
 140 vector GetCurrentFov(float fov)
 141 {
 142         float zoomsensitivity, zoomspeed, zoomfactor, zoomdir;
 143         float velocityzoom, curspeed;
 144         vector v;
 145
 146         zoomsensitivity = autocvar_cl_zoomsensitivity;
 147         zoomfactor = autocvar_cl_zoomfactor;
 148         if(zoomfactor < 1 || zoomfactor > 30)
 149                 zoomfactor = 2.5;
 150         zoomspeed = autocvar_cl_zoomspeed;
 151         if(zoomspeed >= 0)
 152         if(zoomspeed < 0.5 || zoomspeed > 16)
 153                         zoomspeed = 3.5;
 154
 155         zoomdir = button_zoom;
 156         if(hud == HUD_NORMAL)
 157         if(switchweapon == activeweapon)
 158         if((activeweapon == WEP_VORTEX.m_id && vortex_scope) || (activeweapon == WEP_RIFLE.m_id && rifle_scope)) // do NOT use switchweapon here
 159                 zoomdir += button_attack2;
 160         if(spectatee_status > 0 || isdemo())
 161         {
 162                 if(spectatorbutton_zoom)
 163                 {
 164                         if(zoomdir)
 165                                 zoomdir = 0;
 166                         else
 167                                 zoomdir = 1;
 168                 }
 169                 // fteqcc failed twice here already, don't optimize this
 170         }
 171
 172         if(zoomdir) { zoomin_effect = 0; }
 173
 174         if(camera_active)
 175         {
 176                 current_viewzoom = min(1, current_viewzoom + drawframetime);
 177         }
 178         else if(autocvar_cl_spawnzoom && zoomin_effect)
 179         {
 180                 float spawnzoomfactor = bound(1, autocvar_cl_spawnzoom_factor, 30);
 181
 182                 current_viewzoom += (autocvar_cl_spawnzoom_speed * (spawnzoomfactor - current_viewzoom) * drawframetime);
 183                 current_viewzoom = bound(1 / spawnzoomfactor, current_viewzoom, 1);
 184                 if(current_viewzoom == 1) { zoomin_effect = 0; }
 185         }
 186         else
 187         {
 188                 if(zoomspeed < 0) // instant zoom
 189                 {
 190                         if(zoomdir)
 191                                 current_viewzoom = 1 / zoomfactor;
 192                         else
 193                                 current_viewzoom = 1;
 194                 }
 195                 else
 196                 {
 197                         if(zoomdir)
 198                                 current_viewzoom = 1 / bound(1, 1 / current_viewzoom + drawframetime * zoomspeed * (zoomfactor - 1), zoomfactor);
 199                         else
 200                                 current_viewzoom = bound(1 / zoomfactor, current_viewzoom + drawframetime * zoomspeed * (1 - 1 / zoomfactor), 1);
 201                 }
 202         }
 203
 204         if(almost_equals(current_viewzoom, 1))
 205                 current_zoomfraction = 0;
 206         else if(almost_equals(current_viewzoom, 1/zoomfactor))
 207                 current_zoomfraction = 1;
 208         else
 209                 current_zoomfraction = (current_viewzoom - 1) / (1/zoomfactor - 1);
 210
 211         if(zoomsensitivity < 1)
 212                 setsensitivityscale(pow(current_viewzoom, 1 - zoomsensitivity));
 213         else
 214                 setsensitivityscale(1);
 215
 216         if(autocvar_cl_velocityzoom_enabled && autocvar_cl_velocityzoom_type) // _type = 0 disables velocity zoom too
 217         {
 218                 if(intermission) { curspeed = 0; }
 219                 else
 220                 {
 221
 222                         makevectors(view_angles);
 223                         v = pmove_vel;
 224                         if(csqcplayer)
 225                                 v = csqcplayer.velocity;
 226
 227                         switch(autocvar_cl_velocityzoom_type)
 228                         {
 229                                 case 3: curspeed = max(0, v_forward * v); break;
 230                                 case 2: curspeed = (v_forward * v); break;
 231                                 case 1: default: curspeed = vlen(v); break;
 232                         }
 233                 }
 234
 235                 velocityzoom = bound(0, drawframetime / max(0.000000001, autocvar_cl_velocityzoom_time), 1); // speed at which the zoom adapts to player velocity
 236                 avgspeed = avgspeed * (1 - velocityzoom) + (curspeed / autocvar_cl_velocityzoom_speed) * velocityzoom;
 237                 velocityzoom = exp(float2range11(avgspeed * -autocvar_cl_velocityzoom_factor / 1) * 1);
 238
 239                 //print(ftos(avgspeed), " avgspeed, ", ftos(curspeed), " curspeed, ", ftos(velocityzoom), " return\n"); // for debugging
 240         }
 241         else
 242                 velocityzoom = 1;
 243
 244         float frustumx, frustumy, fovx, fovy;
 245         frustumy = tan(fov * M_PI / 360.0) * 0.75 * current_viewzoom * velocityzoom;
 246         frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
 247         fovx = atan2(frustumx, 1) / M_PI * 360.0;
 248         fovy = atan2(frustumy, 1) / M_PI * 360.0;
 249
 250         return '1 0 0' * fovx + '0 1 0' * fovy;
 251 }
 252
 253 vector GetViewLocationFOV(float fov)
 254 {
 255         float frustumy = tan(fov * M_PI / 360.0) * 0.75;
 256         float frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
 257         float fovx = atan2(frustumx, 1) / M_PI * 360.0;
 258         float fovy = atan2(frustumy, 1) / M_PI * 360.0;
 259         return '1 0 0' * fovx + '0 1 0' * fovy;
 260 }
 261
 262 vector GetOrthoviewFOV(vector ov_worldmin, vector ov_worldmax, vector ov_mid, vector ov_org)
 263 {
 264         float fovx, fovy;
 265         float width = (ov_worldmax.x - ov_worldmin.x);
 266         float height = (ov_worldmax.y - ov_worldmin.y);
 267         float distance_to_middle_of_world = vlen(ov_mid - ov_org);
 268         fovx = atan2(width/2, distance_to_middle_of_world) / M_PI * 360.0;
 269         fovy = atan2(height/2, distance_to_middle_of_world) / M_PI * 360.0;
 270         return '1 0 0' * fovx + '0 1 0' * fovy;
 271 }
 272
 273 // this function must match W_SetupShot!
 274 float zoomscript_caught;
 275
 276 vector wcross_origin;
 277 float wcross_scale_prev, wcross_alpha_prev;
 278 vector wcross_color_prev;
 279 float wcross_scale_goal_prev, wcross_alpha_goal_prev;
 280 vector wcross_color_goal_prev;
 281 float wcross_changedonetime;
 282
 283 string wcross_name_goal_prev, wcross_name_goal_prev_prev;
 284 float wcross_resolution_goal_prev, wcross_resolution_goal_prev_prev;
 285 float wcross_name_changestarttime, wcross_name_changedonetime;
 286 float wcross_name_alpha_goal_prev, wcross_name_alpha_goal_prev_prev;
 287
 288 float wcross_ring_prev;
 289
 290 entity trueaim;
 291 entity trueaim_rifle;
 292
 293 const float SHOTTYPE_HITTEAM = 1;
 294 const float SHOTTYPE_HITOBSTRUCTION = 2;
 295 const float SHOTTYPE_HITWORLD = 3;
 296 const float SHOTTYPE_HITENEMY = 4;
 297
 298 void TrueAim_Init()
 299 {
 300         trueaim = spawn();
 301         trueaim.classname = "trueaim";
 302         trueaim.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 303         trueaim_rifle = spawn();
 304         trueaim_rifle.classname = "trueaim_rifle";
 305         trueaim_rifle.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 306 }
 307
 308 float EnemyHitCheck()
 309 {
 310         float t, n;
 311         wcross_origin = project_3d_to_2d(trace_endpos);
 312         wcross_origin.z = 0;
 313         if(trace_ent)
 314                 n = trace_ent.entnum;
 315         else
 316                 n = trace_networkentity;
 317         if(n < 1)
 318                 return SHOTTYPE_HITWORLD;
 319         if(n > maxclients)
 320                 return SHOTTYPE_HITWORLD;
 321         t = GetPlayerColor(n - 1);
 322         if(teamplay)
 323                 if(t == myteam)
 324                         return SHOTTYPE_HITTEAM;
 325         if(t == NUM_SPECTATOR)
 326                 return SHOTTYPE_HITWORLD;
 327         return SHOTTYPE_HITENEMY;
 328 }
 329
 330 float TrueAimCheck()
 331 {
 332         float nudge = 1; // added to traceline target and subtracted from result TOOD(divVerent): do we still need this? Doesn't the engine do this now for us?
 333         vector vecs, trueaimpoint, w_shotorg;
 334         vector mi, ma, dv;
 335         float shottype;
 336         entity ta;
 337         float mv;
 338
 339         mi = ma = '0 0 0';
 340         ta = trueaim;
 341         mv = MOVE_NOMONSTERS;
 342
 343         switch(activeweapon) // WEAPONTODO
 344         {
 345                 case WEP_TUBA.m_id: // no aim
 346                 case WEP_PORTO.m_id: // shoots from eye
 347                 case WEP_NEXBALL.m_id: // shoots from eye
 348                 case WEP_HOOK.m_id: // no trueaim
 349                 case WEP_MORTAR.m_id: // toss curve
 350                         return SHOTTYPE_HITWORLD;
 351                 case WEP_VORTEX.m_id:
 352                 case WEP_VAPORIZER.m_id:
 353                         mv = MOVE_NORMAL;
 354                         break;
 355                 case WEP_RIFLE.m_id:
 356                         ta = trueaim_rifle;
 357                         mv = MOVE_NORMAL;
 358                         if(zoomscript_caught)
 359                         {
 360                                 tracebox(view_origin, '0 0 0', '0 0 0', view_origin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
 361                                 return EnemyHitCheck();
 362                         }
 363                         break;
 364                 case WEP_DEVASTATOR.m_id: // projectile has a size!
 365                         mi = '-3 -3 -3';
 366                         ma = '3 3 3';
 367                         break;
 368                 case WEP_FIREBALL.m_id: // projectile has a size!
 369                         mi = '-16 -16 -16';
 370                         ma = '16 16 16';
 371                         break;
 372                 case WEP_SEEKER.m_id: // projectile has a size!
 373                         mi = '-2 -2 -2';
 374                         ma = '2 2 2';
 375                         break;
 376                 case WEP_ELECTRO.m_id: // projectile has a size!
 377                         mi = '0 0 -3';
 378                         ma = '0 0 -3';
 379                         break;
 380         }
 381
 382         vector traceorigin = getplayerorigin(player_localentnum-1) + (eZ * getstati(STAT_VIEWHEIGHT));
 383
 384         vecs = decompressShotOrigin(getstati(STAT_SHOTORG));
 385
 386         traceline(traceorigin, traceorigin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
 387         trueaimpoint = trace_endpos;
 388
 389         if(vlen(trueaimpoint - traceorigin) < g_trueaim_minrange)
 390                 trueaimpoint = traceorigin + view_forward * g_trueaim_minrange;
 391
 392         if(vecs.x > 0)
 393                 vecs.y = -vecs.y;
 394         else
 395                 vecs = '0 0 0';
 396
 397         dv = view_right * vecs.y + view_up * vecs.z;
 398         w_shotorg = traceorigin + dv;
 399
 400         // now move the vecs forward as much as requested if possible
 401         tracebox(w_shotorg, mi, ma, w_shotorg + view_forward * (vecs.x + nudge), MOVE_NORMAL, ta); // FIXME this MOVE_NORMAL part will misbehave a little in csqc
 402         w_shotorg = trace_endpos - view_forward * nudge;
 403
 404         tracebox(w_shotorg, mi, ma, trueaimpoint, MOVE_NORMAL, ta);
 405         shottype = EnemyHitCheck();
 406         if(shottype != SHOTTYPE_HITWORLD)
 407                 return shottype;
 408
 409 #if 0
 410         // FIXME WHY DOES THIS NOT WORK FOR THE ROCKET LAUNCHER?
 411         // or rather, I know why, but see no fix
 412         if(vlen(trace_endpos - trueaimpoint) > vlen(ma) + vlen(mi) + 1)
 413                 // yes, this is an ugly hack... but it seems good enough to find out whether the test hits the same place as the initial trace
 414                 return SHOTTYPE_HITOBSTRUCTION;
 415 #endif
 416
 417         return SHOTTYPE_HITWORLD;
 418 }
 419
 420 void PostInit(void);
 421 void CSQC_Demo_Camera();
 422 float HUD_WouldDrawScoreboard();
 423 float camera_mode;
 424 const float CAMERA_FREE = 1;
 425 const float CAMERA_CHASE = 2;
 426 float reticle_type;
 427 string reticle_image;
 428 string NextFrameCommand;
 429
 430 vector freeze_org, freeze_ang;
 431 entity nightvision_noise, nightvision_noise2;
 432
 433 const float MAX_TIME_DIFF = 5;
 434 float pickup_crosshair_time, pickup_crosshair_size;
 435 float hitindication_crosshair_size;
 436 float use_vortex_chargepool;
 437
 438 float myhealth, myhealth_prev;
 439 float myhealth_flash;
 440
 441 float old_blurradius, old_bluralpha;
 442 float old_sharpen_intensity;
 443
 444 vector myhealth_gentlergb;
 445
 446 float contentavgalpha, liquidalpha_prev;
 447 vector liquidcolor_prev;
 448
 449 float eventchase_current_distance;
 450 float eventchase_running;
 451 bool WantEventchase()
 452 {SELFPARAM();
 453         if(autocvar_cl_orthoview)
 454                 return false;
 455         if(intermission)
 456                 return true;
 457         if(self.viewloc)
 458                 return true;
 459         if(spectatee_status >= 0)
 460         {
 461                 if(hud != HUD_NORMAL && (autocvar_cl_eventchase_vehicle || spectatee_status > 0))
 462                         return true;
 463                 if(MUTATOR_CALLHOOK(WantEventchase, self))
 464                         return true;
 465                 if(autocvar_cl_eventchase_nexball && gametype == MAPINFO_TYPE_NEXBALL && !(WepSet_GetFromStat() & WepSet_FromWeapon(WEP_NEXBALL.m_id)))
 466                         return true;
 467                 if(autocvar_cl_eventchase_death && (getstati(STAT_HEALTH) <= 0))
 468                 {
 469                         if(autocvar_cl_eventchase_death == 2)
 470                         {
 471                                 // don't stop eventchase once it's started (even if velocity changes afterwards)
 472                                 if(self.velocity == '0 0 0' || eventchase_running)
 473                                         return true;
 474                         }
 475                         else return true;
 476                 }
 477         }
 478         return false;
 479 }
 480
 481 void HUD_Crosshair_Vehicle()
 482 {
 483         if(hud != HUD_BUMBLEBEE_GUN)
 484         {
 485                 Vehicle info = get_vehicleinfo(hud);
 486                 info.vr_crosshair(info);
 487         }
 488 }
 489
 490 vector damage_blurpostprocess, content_blurpostprocess;
 491
 492 float unaccounted_damage = 0;
 493 void UpdateDamage()
 494 {
 495         // accumulate damage with each stat update
 496         static float damage_total_prev = 0;
 497         float damage_total = getstati(STAT_DAMAGE_DEALT_TOTAL);
 498         float unaccounted_damage_new = COMPARE_INCREASING(damage_total, damage_total_prev);
 499         damage_total_prev = damage_total;
 500
 501         static float damage_dealt_time_prev = 0;
 502         float damage_dealt_time = getstatf(STAT_HIT_TIME);
 503         if (damage_dealt_time != damage_dealt_time_prev)
 504         {
 505                 unaccounted_damage += unaccounted_damage_new;
 506                 LOG_TRACE("dmg total: ", ftos(unaccounted_damage), " (+", ftos(unaccounted_damage_new), ")", "\n");
 507         }
 508         damage_dealt_time_prev = damage_dealt_time;
 509
 510         // prevent hitsound when switching spectatee
 511         static float spectatee_status_prev = 0;
 512         if (spectatee_status != spectatee_status_prev)
 513                 unaccounted_damage = 0;
 514         spectatee_status_prev = spectatee_status;
 515 }
 516
 517 void HitSound()
 518 {
 519         // varying sound pitch
 520
 521         static float hitsound_time_prev = 0;
 522         // HACK: the only way to get the arc to sound consistent with pitch shift is to ignore cl_hitsound_antispam_time
 523         float arc_hack = activeweapon == WEP_ARC.m_id && autocvar_cl_hitsound >= 2;
 524         if (arc_hack || COMPARE_INCREASING(time, hitsound_time_prev) > autocvar_cl_hitsound_antispam_time)
 525         {
 526                 if (autocvar_cl_hitsound && unaccounted_damage)
 527                 {
 528                         // customizable gradient function that crosses (0,a), (c,1) and asymptotically approaches b
 529                         float a = autocvar_cl_hitsound_max_pitch;
 530                         float b = autocvar_cl_hitsound_min_pitch;
 531                         float c = autocvar_cl_hitsound_nom_damage;
 532                         float x = unaccounted_damage;
 533                         float pitch_shift = (b*x*(a-1) + a*c*(1-b)) / (x*(a-1) + c*(1-b));
 534
 535                         // if sound variation is disabled, set pitch_shift to 1
 536                         if (autocvar_cl_hitsound == 1)
 537                                 pitch_shift = 1;
 538
 539                         // if pitch shift is reversed, mirror in (max-min)/2 + min
 540                         if (autocvar_cl_hitsound == 3)
 541                         {
 542                                 float mirror_value = (a-b)/2 + b;
 543                                 pitch_shift = mirror_value + (mirror_value - pitch_shift);
 544                         }
 545
 546                         LOG_TRACE("dmg total (dmg): ", ftos(unaccounted_damage), " , pitch shift: ", ftos(pitch_shift), "\n");
 547
 548                         // todo: avoid very long and very short sounds from wave stretching using different sound files? seems unnecessary
 549                         // todo: normalize sound pressure levels? seems unnecessary
 550
 551                         sound7(world, CH_INFO, SND(HIT), VOL_BASE, ATTN_NONE, pitch_shift * 100, 0);
 552                 }
 553                 unaccounted_damage = 0;
 554                 hitsound_time_prev = time;
 555         }
 556
 557         static float typehit_time_prev = 0;
 558         float typehit_time = getstatf(STAT_TYPEHIT_TIME);
 559         if (COMPARE_INCREASING(typehit_time, typehit_time_prev) > autocvar_cl_hitsound_antispam_time)
 560         {
 561                 sound(world, CH_INFO, SND_TYPEHIT, VOL_BASE, ATTN_NONE);
 562                 typehit_time_prev = typehit_time;
 563         }
 564 }
 565
 566 void HUD_Crosshair()
 567 {SELFPARAM();
 568         static float rainbow_last_flicker;
 569         static vector rainbow_prev_color;
 570         entity e = self;
 571         float f, i, j;
 572         vector v;
 573         if(!scoreboard_active && !camera_active && intermission != 2 &&
 574                 spectatee_status != -1 && !csqcplayer.viewloc &&
 575                 !HUD_MinigameMenu_IsOpened() )
 576         {
 577                 if (!autocvar_crosshair_enabled) // main toggle for crosshair rendering
 578                         return;
 579
 580                 if (hud != HUD_NORMAL)
 581                 {
 582                         HUD_Crosshair_Vehicle();
 583                         return;
 584                 }
 585
 586                 string wcross_style;
 587                 float wcross_alpha, wcross_resolution;
 588                 wcross_style = autocvar_crosshair;
 589                 if (wcross_style == "0")
 590                         return;
 591                 wcross_resolution = autocvar_crosshair_size;
 592                 if (wcross_resolution == 0)
 593                         return;
 594                 wcross_alpha = autocvar_crosshair_alpha;
 595                 if (wcross_alpha == 0)
 596                         return;
 597
 598                 // TrueAim check
 599                 float shottype;
 600
 601                 // wcross_origin = '0.5 0 0' * vid_conwidth + '0 0.5 0' * vid_conheight;
 602                 wcross_origin = project_3d_to_2d(view_origin + MAX_SHOT_DISTANCE * view_forward);
 603                 wcross_origin.z = 0;
 604                 if(autocvar_crosshair_hittest)
 605                 {
 606                         vector wcross_oldorigin;
 607                         wcross_oldorigin = wcross_origin;
 608                         shottype = TrueAimCheck();
 609                         if(shottype == SHOTTYPE_HITWORLD)
 610                         {
 611                                 v = wcross_origin - wcross_oldorigin;
 612                                 v.x /= vid_conwidth;
 613                                 v.y /= vid_conheight;
 614                                 if(vlen(v) > 0.01)
 615                                         shottype = SHOTTYPE_HITOBSTRUCTION;
 616                         }
 617                         if(!autocvar_crosshair_hittest_showimpact)
 618                                 wcross_origin = wcross_oldorigin;
 619                 }
 620                 else
 621                         shottype = SHOTTYPE_HITWORLD;
 622
 623                 vector wcross_color = '0 0 0', wcross_size = '0 0 0';
 624                 string wcross_name = "";
 625                 float wcross_scale, wcross_blur;
 626
 627                 if(autocvar_crosshair_per_weapon || (autocvar_crosshair_color_special == 1))
 628                 {
 629                         e = get_weaponinfo(switchingweapon);
 630                         if(e)
 631                         {
 632                                 if(autocvar_crosshair_per_weapon)
 633                                 {
 634                                         // WEAPONTODO: access these through some general settings (with non-balance config settings)
 635                                         //wcross_resolution *= cvar(strcat("crosshair_", wcross_wep, "_size"));
 636                                         //if (wcross_resolution == 0)
 637                                                 //return;
 638
 639                                         //wcross_style = cvar_string(strcat("crosshair_", wcross_wep));
 640                                         wcross_resolution *= e.w_crosshair_size;
 641                                         wcross_name = e.w_crosshair;
 642                                 }
 643                         }
 644                 }
 645
 646                 if(wcross_name == "")
 647                         wcross_name = strcat("gfx/crosshair", wcross_style);
 648
 649                 // MAIN CROSSHAIR COLOR DECISION
 650                 switch(autocvar_crosshair_color_special)
 651                 {
 652                         case 1: // crosshair_color_per_weapon
 653                         {
 654                                 if(e)
 655                                 {
 656                                         wcross_color = e.wpcolor;
 657                                         break;
 658                                 }
 659                                 else { goto normalcolor; }
 660                         }
 661
 662                         case 2: // crosshair_color_by_health
 663                         {
 664                                 float x = getstati(STAT_HEALTH);
 665
 666                                 //x = red
 667                                 //y = green
 668                                 //z = blue
 669
 670                                 wcross_color.z = 0;
 671
 672                                 if(x > 200)
 673                                 {
 674                                         wcross_color.x = 0;
 675                                         wcross_color.y = 1;
 676                                 }
 677                                 else if(x > 150)
 678                                 {
 679                                         wcross_color.x = 0.4 - (x-150)*0.02 * 0.4;
 680                                         wcross_color.y = 0.9 + (x-150)*0.02 * 0.1;
 681                                 }
 682                                 else if(x > 100)
 683                                 {
 684                                         wcross_color.x = 1 - (x-100)*0.02 * 0.6;
 685                                         wcross_color.y = 1 - (x-100)*0.02 * 0.1;
 686                                         wcross_color.z = 1 - (x-100)*0.02;
 687                                 }
 688                                 else if(x > 50)
 689                                 {
 690                                         wcross_color.x = 1;
 691                                         wcross_color.y = 1;
 692                                         wcross_color.z = 0.2 + (x-50)*0.02 * 0.8;
 693                                 }
 694                                 else if(x > 20)
 695                                 {
 696                                         wcross_color.x = 1;
 697                                         wcross_color.y = (x-20)*90/27/100;
 698                                         wcross_color.z = (x-20)*90/27/100 * 0.2;
 699                                 }
 700                                 else
 701                                 {
 702                                         wcross_color.x = 1;
 703                                         wcross_color.y = 0;
 704                                 }
 705                                 break;
 706                         }
 707
 708                         case 3: // crosshair_color_rainbow
 709                         {
 710                                 if(time >= rainbow_last_flicker)
 711                                 {
 712                                         rainbow_prev_color = randomvec() * autocvar_crosshair_color_special_rainbow_brightness;
 713                                         rainbow_last_flicker = time + autocvar_crosshair_color_special_rainbow_delay;
 714                                 }
 715                                 wcross_color = rainbow_prev_color;
 716                                 break;
 717                         }
 718                         :normalcolor
 719                         default: { wcross_color = stov(autocvar_crosshair_color); break; }
 720                 }
 721
 722                 if(autocvar_crosshair_effect_scalefade)
 723                 {
 724                         wcross_scale = wcross_resolution;
 725                         wcross_resolution = 1;
 726                 }
 727                 else
 728                 {
 729                         wcross_scale = 1;
 730                 }
 731
 732                 if(autocvar_crosshair_pickup)
 733                 {
 734                         float stat_pickup_time = getstatf(STAT_LAST_PICKUP);
 735
 736                         if(pickup_crosshair_time < stat_pickup_time)
 737                         {
 738                                 if(time - stat_pickup_time < MAX_TIME_DIFF) // don't trigger the animation if it's too old
 739                                         pickup_crosshair_size = 1;
 740
 741                                 pickup_crosshair_time = stat_pickup_time;
 742                         }
 743
 744                         if(pickup_crosshair_size > 0)
 745                                 pickup_crosshair_size -= autocvar_crosshair_pickup_speed * frametime;
 746                         else
 747                                 pickup_crosshair_size = 0;
 748
 749                         wcross_scale += sin(pickup_crosshair_size) * autocvar_crosshair_pickup;
 750                 }
 751
 752                 // todo: make crosshair hit indication dependent on damage dealt
 753                 if(autocvar_crosshair_hitindication)
 754                 {
 755                         vector hitindication_color = ((autocvar_crosshair_color_special == 1) ? stov(autocvar_crosshair_hitindication_per_weapon_color) : stov(autocvar_crosshair_hitindication_color));
 756
 757                         if(unaccounted_damage)
 758                         {
 759                                 hitindication_crosshair_size = 1;
 760                         }
 761
 762                         if(hitindication_crosshair_size > 0)
 763                                 hitindication_crosshair_size -= autocvar_crosshair_hitindication_speed * frametime;
 764                         else
 765                                 hitindication_crosshair_size = 0;
 766
 767                         wcross_scale += sin(hitindication_crosshair_size) * autocvar_crosshair_hitindication;
 768                         wcross_color.x += sin(hitindication_crosshair_size) * hitindication_color.x;
 769                         wcross_color.y += sin(hitindication_crosshair_size) * hitindication_color.y;
 770                         wcross_color.z += sin(hitindication_crosshair_size) * hitindication_color.z;
 771                 }
 772
 773                 if(shottype == SHOTTYPE_HITENEMY)
 774                         wcross_scale *= autocvar_crosshair_hittest; // is not queried if hittest is 0
 775                 if(shottype == SHOTTYPE_HITTEAM)
 776                         wcross_scale /= autocvar_crosshair_hittest; // is not queried if hittest is 0
 777
 778                 f = fabs(autocvar_crosshair_effect_time);
 779                 if(wcross_scale != wcross_scale_goal_prev || wcross_alpha != wcross_alpha_goal_prev || wcross_color != wcross_color_goal_prev)
 780                 {
 781                         wcross_changedonetime = time + f;
 782                 }
 783                 if(wcross_name != wcross_name_goal_prev || wcross_resolution != wcross_resolution_goal_prev)
 784                 {
 785                         wcross_name_changestarttime = time;
 786                         wcross_name_changedonetime = time + f;
 787                         if(wcross_name_goal_prev_prev)
 788                                 strunzone(wcross_name_goal_prev_prev);
 789                         wcross_name_goal_prev_prev = wcross_name_goal_prev;
 790                         wcross_name_goal_prev = strzone(wcross_name);
 791                         wcross_name_alpha_goal_prev_prev = wcross_name_alpha_goal_prev;
 792                         wcross_resolution_goal_prev_prev = wcross_resolution_goal_prev;
 793                         wcross_resolution_goal_prev = wcross_resolution;
 794                 }
 795
 796                 wcross_scale_goal_prev = wcross_scale;
 797                 wcross_alpha_goal_prev = wcross_alpha;
 798                 wcross_color_goal_prev = wcross_color;
 799
 800                 if(spectatee_status == -1 && shottype == SHOTTYPE_HITTEAM || (shottype == SHOTTYPE_HITOBSTRUCTION && autocvar_crosshair_hittest_blur && !autocvar_chase_active))
 801                 {
 802                         wcross_blur = 1;
 803                         wcross_alpha *= 0.75;
 804                 }
 805                 else
 806                         wcross_blur = 0;
 807                 // *_prev is at time-frametime
 808                 // * is at wcross_changedonetime+f
 809                 // what do we have at time?
 810                 if(time < wcross_changedonetime)
 811                 {
 812                         f = frametime / (wcross_changedonetime - time + frametime);
 813                         wcross_scale = f * wcross_scale + (1 - f) * wcross_scale_prev;
 814                         wcross_alpha = f * wcross_alpha + (1 - f) * wcross_alpha_prev;
 815                         wcross_color = f * wcross_color + (1 - f) * wcross_color_prev;
 816                 }
 817
 818                 wcross_scale_prev = wcross_scale;
 819                 wcross_alpha_prev = wcross_alpha;
 820                 wcross_color_prev = wcross_color;
 821
 822                 MUTATOR_CALLHOOK(UpdateCrosshair);
 823
 824                 wcross_scale *= 1 - autocvar__menu_alpha;
 825                 wcross_alpha *= 1 - autocvar__menu_alpha;
 826                 wcross_size = draw_getimagesize(wcross_name) * wcross_scale;
 827
 828                 if(wcross_scale >= 0.001 && wcross_alpha >= 0.001)
 829                 {
 830                         // crosshair rings for weapon stats
 831                         if (autocvar_crosshair_ring || autocvar_crosshair_ring_reload)
 832                         {
 833                                 // declarations and stats
 834                                 float ring_value = 0, ring_scale = 0, ring_alpha = 0, ring_inner_value = 0, ring_inner_alpha = 0;
 835                                 string ring_image = string_null, ring_inner_image = string_null;
 836                                 vector ring_rgb = '0 0 0', ring_inner_rgb = '0 0 0';
 837
 838                                 ring_scale = autocvar_crosshair_ring_size;
 839
 840                                 float weapon_clipload, weapon_clipsize;
 841                                 weapon_clipload = getstati(STAT_WEAPON_CLIPLOAD);
 842                                 weapon_clipsize = getstati(STAT_WEAPON_CLIPSIZE);
 843
 844                                 float ok_ammo_charge, ok_ammo_chargepool;
 845                                 ok_ammo_charge = getstatf(STAT_OK_AMMO_CHARGE);
 846                                 ok_ammo_chargepool = getstatf(STAT_OK_AMMO_CHARGEPOOL);
 847
 848                                 float vortex_charge, vortex_chargepool;
 849                                 vortex_charge = getstatf(STAT_VORTEX_CHARGE);
 850                                 vortex_chargepool = getstatf(STAT_VORTEX_CHARGEPOOL);
 851
 852                                 float arc_heat = getstatf(STAT_ARC_HEAT);
 853
 854                                 if(vortex_charge_movingavg == 0) // this should only happen if we have just loaded up the game
 855                                         vortex_charge_movingavg = vortex_charge;
 856
 857
 858                                 // handle the values
 859                                 if (autocvar_crosshair_ring && activeweapon == WEP_VORTEX.m_id && vortex_charge && autocvar_crosshair_ring_vortex) // ring around crosshair representing velocity-dependent damage for the vortex
 860                                 {
 861                                         if (vortex_chargepool || use_vortex_chargepool) {
 862                                                 use_vortex_chargepool = 1;
 863                                                 ring_inner_value = vortex_chargepool;
 864                                         } else {
 865                                                 vortex_charge_movingavg = (1 - autocvar_crosshair_ring_vortex_currentcharge_movingavg_rate) * vortex_charge_movingavg + autocvar_crosshair_ring_vortex_currentcharge_movingavg_rate * vortex_charge;
 866                                                 ring_inner_value = bound(0, autocvar_crosshair_ring_vortex_currentcharge_scale * (vortex_charge - vortex_charge_movingavg), 1);
 867                                         }
 868
 869                                         ring_inner_alpha = autocvar_crosshair_ring_vortex_inner_alpha;
 870                                         ring_inner_rgb = eX * autocvar_crosshair_ring_vortex_inner_color_red + eY * autocvar_crosshair_ring_vortex_inner_color_green + eZ * autocvar_crosshair_ring_vortex_inner_color_blue;
 871                                         ring_inner_image = "gfx/crosshair_ring_inner.tga";
 872
 873                                         // draw the outer ring to show the current charge of the weapon
 874                                         ring_value = vortex_charge;
 875                                         ring_alpha = autocvar_crosshair_ring_vortex_alpha;
 876                                         ring_rgb = wcross_color;
 877                                         ring_image = "gfx/crosshair_ring_nexgun.tga";
 878                                 }
 879                                 else if (autocvar_crosshair_ring && activeweapon == WEP_MINE_LAYER.m_id && minelayer_maxmines && autocvar_crosshair_ring_minelayer)
 880                                 {
 881                                         ring_value = bound(0, getstati(STAT_LAYED_MINES) / minelayer_maxmines, 1); // if you later need to use the count of bullets in another place, then add a float for it. For now, no need to.
 882                                         ring_alpha = autocvar_crosshair_ring_minelayer_alpha;
 883                                         ring_rgb = wcross_color;
 884                                         ring_image = "gfx/crosshair_ring.tga";
 885                                 }
 886                                 else if (activeweapon == WEP_HAGAR.m_id && getstati(STAT_HAGAR_LOAD) && autocvar_crosshair_ring_hagar)
 887                                 {
 888                                         ring_value = bound(0, getstati(STAT_HAGAR_LOAD) / hagar_maxrockets, 1);
 889                                         ring_alpha = autocvar_crosshair_ring_hagar_alpha;
 890                                         ring_rgb = wcross_color;
 891                                         ring_image = "gfx/crosshair_ring.tga";
 892                                 }
 893                                 else if (ok_ammo_charge)
 894                                 {
 895                                         ring_value = ok_ammo_chargepool;
 896                                         ring_alpha = autocvar_crosshair_ring_reload_alpha;
 897                                         ring_rgb = wcross_color;
 898                                         ring_image = "gfx/crosshair_ring.tga";
 899                                 }
 900                                 else if(autocvar_crosshair_ring_reload && weapon_clipsize) // forces there to be only an ammo ring
 901                                 {
 902                                         ring_value = bound(0, weapon_clipload / weapon_clipsize, 1);
 903                                         ring_scale = autocvar_crosshair_ring_reload_size;
 904                                         ring_alpha = autocvar_crosshair_ring_reload_alpha;
 905                                         ring_rgb = wcross_color;
 906
 907                                         // Note: This is to stop Taoki from complaining that the image doesn't match all potential balances.
 908                                         // if a new image for another weapon is added, add the code (and its respective file/value) here
 909                                         if ((activeweapon == WEP_RIFLE.m_id) && (weapon_clipsize == 80))
 910                                                 ring_image = "gfx/crosshair_ring_rifle.tga";
 911                                         else
 912                                                 ring_image = "gfx/crosshair_ring.tga";
 913                                 }
 914                                 else if ( autocvar_crosshair_ring && autocvar_crosshair_ring_arc && arc_heat && activeweapon == WEP_ARC.m_id )
 915                                 {
 916                                         ring_value = arc_heat;
 917                                         ring_alpha = (1-arc_heat)*autocvar_crosshair_ring_arc_cold_alpha +
 918                                                 arc_heat*autocvar_crosshair_ring_arc_hot_alpha;
 919                                         ring_rgb = (1-arc_heat)*wcross_color + arc_heat*autocvar_crosshair_ring_arc_hot_color;
 920                                         ring_image = "gfx/crosshair_ring.tga";
 921                                 }
 922
 923                                 // if in weapon switch animation, fade ring out/in
 924                                 if(autocvar_crosshair_effect_time > 0)
 925                                 {
 926                                         f = (time - wcross_name_changestarttime) / autocvar_crosshair_effect_time;
 927                                         if (f >= 1)
 928                                         {
 929                                                 wcross_ring_prev = ((ring_image) ? true : false);
 930                                         }
 931
 932                                         if(wcross_ring_prev)
 933                                         {
 934                                                 if(f < 1)
 935                                                         ring_alpha *= fabs(1 - bound(0, f, 1));
 936                                         }
 937                                         else
 938                                         {
 939                                                 if(f < 1)
 940                                                         ring_alpha *= bound(0, f, 1);
 941                                         }
 942                                 }
 943
 944                                 if (autocvar_crosshair_ring_inner && ring_inner_value) // lets draw a ring inside a ring so you can ring while you ring
 945                                         DrawCircleClippedPic(wcross_origin, wcross_size.x * ring_scale, ring_inner_image, ring_inner_value, ring_inner_rgb, wcross_alpha * ring_inner_alpha, DRAWFLAG_ADDITIVE);
 946
 947                                 if (ring_value)
 948                                         DrawCircleClippedPic(wcross_origin, wcross_size.x * ring_scale, ring_image, ring_value, ring_rgb, wcross_alpha * ring_alpha, DRAWFLAG_ADDITIVE);
 949                         }
 950
 951 #define CROSSHAIR_DO_BLUR(M,sz,wcross_name,wcross_alpha) \
 952                         do \
 953                         { \
 954                                 if(wcross_blur > 0) \
 955                                 { \
 956                                         for(i = -2; i <= 2; ++i) \
 957                                         for(j = -2; j <= 2; ++j) \
 958                                         M(i,j,sz,wcross_name,wcross_alpha*0.04); \
 959                                 } \
 960                                 else \
 961                                 { \
 962                                         M(0,0,sz,wcross_name,wcross_alpha); \
 963                                 } \
 964                         } \
 965                         while(0)
 966
 967 #define CROSSHAIR_DRAW_SINGLE(i,j,sz,wcross_name,wcross_alpha) \
 968                         drawpic(wcross_origin - ('0.5 0 0' * (sz * wcross_size.x + i * wcross_blur) + '0 0.5 0' * (sz * wcross_size.y + j * wcross_blur)), wcross_name, sz * wcross_size, wcross_color, wcross_alpha, DRAWFLAG_NORMAL)
 969
 970 #define CROSSHAIR_DRAW(sz,wcross_name,wcross_alpha) \
 971                         CROSSHAIR_DO_BLUR(CROSSHAIR_DRAW_SINGLE,sz,wcross_name,wcross_alpha)
 972
 973                         if(time < wcross_name_changedonetime && wcross_name != wcross_name_goal_prev_prev && wcross_name_goal_prev_prev)
 974                         {
 975                                 f = (wcross_name_changedonetime - time) / (wcross_name_changedonetime - wcross_name_changestarttime);
 976                                 wcross_size = draw_getimagesize(wcross_name_goal_prev_prev) * wcross_scale;
 977                                 CROSSHAIR_DRAW(wcross_resolution_goal_prev_prev, wcross_name_goal_prev_prev, wcross_alpha * f * wcross_name_alpha_goal_prev_prev);
 978                                 f = 1 - f;
 979                         }
 980                         else
 981                         {
 982                                 f = 1;
 983                         }
 984                         wcross_name_alpha_goal_prev = f;
 985
 986                         wcross_size = draw_getimagesize(wcross_name) * wcross_scale;
 987                         CROSSHAIR_DRAW(wcross_resolution, wcross_name, wcross_alpha * f);
 988
 989                         if(autocvar_crosshair_dot)
 990                         {
 991                                 vector wcross_color_old;
 992                                 wcross_color_old = wcross_color;
 993
 994                                 if((autocvar_crosshair_dot_color_custom) && (autocvar_crosshair_dot_color != "0"))
 995                                         wcross_color = stov(autocvar_crosshair_dot_color);
 996
 997                                 CROSSHAIR_DRAW(wcross_resolution * autocvar_crosshair_dot_size, "gfx/crosshairdot.tga", f * autocvar_crosshair_dot_alpha);
 998                                 // FIXME why don't we use wcross_alpha here?cl_notice_run();
 999                                 wcross_color = wcross_color_old;
1000                         }
1001                 }
1002         }
1003         else
1004         {
1005                 wcross_scale_prev = 0;
1006                 wcross_alpha_prev = 0;
1007                 wcross_scale_goal_prev = 0;
1008                 wcross_alpha_goal_prev = 0;
1009                 wcross_changedonetime = 0;
1010                 if(wcross_name_goal_prev)
1011                         strunzone(wcross_name_goal_prev);
1012                 wcross_name_goal_prev = string_null;
1013                 if(wcross_name_goal_prev_prev)
1014                         strunzone(wcross_name_goal_prev_prev);
1015                 wcross_name_goal_prev_prev = string_null;
1016                 wcross_name_changestarttime = 0;
1017                 wcross_name_changedonetime = 0;
1018                 wcross_name_alpha_goal_prev = 0;
1019                 wcross_name_alpha_goal_prev_prev = 0;
1020                 wcross_resolution_goal_prev = 0;
1021                 wcross_resolution_goal_prev_prev = 0;
1022         }
1023 }
1024
1025 void HUD_Draw()
1026 {
1027         if(getstati(STAT_FROZEN))
1028                 drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, ((getstatf(STAT_REVIVE_PROGRESS)) ? ('0.25 0.90 1' + ('1 0 0' * getstatf(STAT_REVIVE_PROGRESS)) + ('0 1 1' * getstatf(STAT_REVIVE_PROGRESS) * -1)) : '0.25 0.90 1'), autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1029         else if (getstatf(STAT_HEALING_ORB)>time)
1030                 drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, NADE_TYPE_HEAL.m_color, autocvar_hud_colorflash_alpha*getstatf(STAT_HEALING_ORB_ALPHA), DRAWFLAG_ADDITIVE);
1031         if(!intermission)
1032         if(getstatf(STAT_NADE_TIMER) && autocvar_cl_nade_timer) // give nade top priority, as it's a matter of life and death
1033         {
1034                 DrawCircleClippedPic(eX * 0.5 * vid_conwidth + eY * 0.6 * vid_conheight, 0.1 * vid_conheight, "gfx/crosshair_ring.tga", getstatf(STAT_NADE_TIMER), '0.25 0.90 1' + ('1 0 0' * getstatf(STAT_NADE_TIMER)) - ('0 1 1' * getstatf(STAT_NADE_TIMER)), autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1035                 drawstring_aspect(eY * 0.64 * vid_conheight, ((autocvar_cl_nade_timer == 2) ? _("Nade timer") : ""), eX * vid_conwidth + eY * 0.025 * vid_conheight, '1 1 1', 1, DRAWFLAG_NORMAL);
1036         }
1037         else if(getstatf(STAT_REVIVE_PROGRESS))
1038         {
1039                 DrawCircleClippedPic(eX * 0.5 * vid_conwidth + eY * 0.6 * vid_conheight, 0.1 * vid_conheight, "gfx/crosshair_ring.tga", getstatf(STAT_REVIVE_PROGRESS), '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1040                 drawstring_aspect(eY * 0.64 * vid_conheight, _("Revival progress"), eX * vid_conwidth + eY * 0.025 * vid_conheight, '1 1 1', 1, DRAWFLAG_NORMAL);
1041         }
1042
1043         if(autocvar_r_letterbox == 0)
1044                 if(autocvar_viewsize < 120)
1045                 {
1046                         if(!(gametype == MAPINFO_TYPE_RACE || gametype == MAPINFO_TYPE_CTS))
1047                                 Accuracy_LoadLevels();
1048
1049                         HUD_Main();
1050                         HUD_DrawScoreboard();
1051                 }
1052
1053         // crosshair goes VERY LAST
1054         UpdateDamage();
1055         HUD_Crosshair();
1056         HitSound();
1057 }
1058
1059 bool ov_enabled;
1060 float oldr_nearclip;
1061 float oldr_farclip_base;
1062 float oldr_farclip_world;
1063 float oldr_novis;
1064 float oldr_useportalculling;
1065 float oldr_useinfinitefarclip;
1066
1067 const int BUTTON_3 = 4;
1068 const int BUTTON_4 = 8;
1069 float cl_notice_run();
1070 float prev_myteam;
1071 int lasthud;
1072 float vh_notice_time;
1073 void WaypointSprite_Load();
1074 void CSQC_UpdateView(float w, float h)
1075 {SELFPARAM();
1076         entity e;
1077         float fov;
1078         float f;
1079         vector vf_size, vf_min;
1080         float a;
1081
1082         execute_next_frame();
1083
1084         ++framecount;
1085
1086         hud = getstati(STAT_HUD);
1087
1088         if(hud != HUD_NORMAL && lasthud == HUD_NORMAL)
1089                 vh_notice_time = time + autocvar_cl_vehicles_notify_time;
1090
1091         lasthud = hud;
1092
1093         if(autocvar__hud_showbinds_reload) // menu can set this one
1094         {
1095                 db_close(binddb);
1096                 binddb = db_create();
1097                 cvar_set("_hud_showbinds_reload", "0");
1098         }
1099
1100         if(checkextension("DP_CSQC_MINFPS_QUALITY"))
1101                 view_quality = getproperty(VF_MINFPS_QUALITY);
1102         else
1103                 view_quality = 1;
1104
1105         button_attack2 = (input_buttons & BUTTON_3);
1106         button_zoom = (input_buttons & BUTTON_4);
1107
1108         vf_size = getpropertyvec(VF_SIZE);
1109         vf_min = getpropertyvec(VF_MIN);
1110         vid_width = vf_size.x;
1111         vid_height = vf_size.y;
1112
1113         vector reticle_pos = '0 0 0', reticle_size = '0 0 0';
1114         vector splash_pos = '0 0 0', splash_size = '0 0 0';
1115
1116         WaypointSprite_Load();
1117
1118         CSQCPlayer_SetCamera();
1119
1120         if(player_localentnum <= maxclients) // is it a client?
1121                 current_player = player_localentnum - 1;
1122         else // then player_localentnum is the vehicle I'm driving
1123                 current_player = player_localnum;
1124         myteam = GetPlayerColor(current_player);
1125
1126         if(myteam != prev_myteam)
1127         {
1128                 myteamcolors = colormapPaletteColor(myteam, 1);
1129                 FOREACH(hud_panels, true, LAMBDA(it.update_time = time));
1130                 prev_myteam = myteam;
1131         }
1132
1133         ticrate = getstatf(STAT_MOVEVARS_TICRATE) * getstatf(STAT_MOVEVARS_TIMESCALE);
1134
1135         float is_dead = (getstati(STAT_HEALTH) <= 0);
1136
1137         // FIXME do we need this hack?
1138         if(isdemo())
1139         {
1140                 // in demos, input_buttons do not work
1141                 button_zoom = (autocvar__togglezoom == "-");
1142         }
1143         else if(button_zoom
1144                 && autocvar_cl_unpress_zoom_on_death
1145                 && (spectatee_status >= 0)
1146                 && (is_dead || intermission))
1147         {
1148                 // no zoom while dead or in intermission please
1149                 localcmd("-zoom\n");
1150                 button_zoom = false;
1151         }
1152
1153         // event chase camera
1154         if(autocvar_chase_active <= 0) // greater than 0 means it's enabled manually, and this code is skipped
1155         {
1156                 float vehicle_chase = (hud != HUD_NORMAL && (autocvar_cl_eventchase_vehicle || spectatee_status > 0));
1157                 float ons_roundlost = (gametype == MAPINFO_TYPE_ONSLAUGHT && getstati(STAT_ROUNDLOST));
1158                 entity gen = world;
1159
1160                 if(ons_roundlost)
1161                 {
1162                         entity e;
1163                         for(e = world; (e = find(e, classname, "onslaught_generator")); )
1164                         {
1165                                 if(e.health <= 0)
1166                                 {
1167                                         gen = e;
1168                                         break;
1169                                 }
1170                         }
1171                         if(!gen)
1172                                 ons_roundlost = FALSE; // don't enforce the 3rd person camera if there is no dead generator to show
1173                 }
1174                 if(WantEventchase() || (!autocvar_cl_orthoview && ons_roundlost))
1175                 {
1176                         eventchase_running = true;
1177
1178                         // make special vector since we can't use view_origin (It is one frame old as of this code, it gets set later with the results this code makes.)
1179                         vector current_view_origin = (csqcplayer ? csqcplayer.origin : pmove_org);
1180                         if(ons_roundlost) { current_view_origin = gen.origin; }
1181
1182                         // detect maximum viewoffset and use it
1183                         vector view_offset = autocvar_cl_eventchase_viewoffset;
1184                         if(vehicle_chase && autocvar_cl_eventchase_vehicle_viewoffset) { view_offset = autocvar_cl_eventchase_vehicle_viewoffset; }
1185                         if(ons_roundlost) { view_offset = autocvar_cl_eventchase_generator_viewoffset; }
1186
1187                         if(view_offset)
1188                         {
1189                                 WarpZone_TraceLine(current_view_origin, current_view_origin + view_offset + ('0 0 1' * autocvar_cl_eventchase_maxs.z), MOVE_WORLDONLY, self);
1190                                 if(trace_fraction == 1) { current_view_origin += view_offset; }
1191                                 else { current_view_origin.z += max(0, (trace_endpos.z - current_view_origin.z) - autocvar_cl_eventchase_maxs.z); }
1192                         }
1193
1194                         // We must enable chase_active to get a third person view (weapon viewmodel hidden and own player model showing).
1195                         // Ideally, there should be another way to enable third person cameras, such as through setproperty()
1196                         // -1 enables chase_active while marking it as set by this code, and not by the user (which would be 1)
1197                         if(!autocvar_chase_active) { cvar_set("chase_active", "-1"); }
1198
1199                         // make the camera smooth back
1200                         float chase_distance = autocvar_cl_eventchase_distance;
1201                         if(vehicle_chase && autocvar_cl_eventchase_vehicle_distance) { chase_distance = autocvar_cl_eventchase_vehicle_distance; }
1202                         if(ons_roundlost) { chase_distance = autocvar_cl_eventchase_generator_distance; }
1203
1204                         if(autocvar_cl_eventchase_speed && eventchase_current_distance < chase_distance)
1205                                 eventchase_current_distance += autocvar_cl_eventchase_speed * (chase_distance - eventchase_current_distance) * frametime; // slow down the further we get
1206                         else if(eventchase_current_distance != chase_distance)
1207                                 eventchase_current_distance = chase_distance;
1208
1209                         makevectors(view_angles);
1210
1211                         vector eventchase_target_origin = (current_view_origin - (v_forward * eventchase_current_distance));
1212                         WarpZone_TraceBox(current_view_origin, autocvar_cl_eventchase_mins, autocvar_cl_eventchase_maxs, eventchase_target_origin, MOVE_WORLDONLY, self);
1213
1214                         // If the boxtrace fails, revert back to line tracing.
1215                         if(!self.viewloc)
1216                         if(trace_startsolid)
1217                         {
1218                                 eventchase_target_origin = (current_view_origin - (v_forward * eventchase_current_distance));
1219                                 WarpZone_TraceLine(current_view_origin, eventchase_target_origin, MOVE_WORLDONLY, self);
1220                                 setproperty(VF_ORIGIN, (trace_endpos - (v_forward * autocvar_cl_eventchase_mins.z)));
1221                         }
1222                         else { setproperty(VF_ORIGIN, trace_endpos); }
1223
1224                         if(!self.viewloc)
1225                                 setproperty(VF_ANGLES, WarpZone_TransformVAngles(WarpZone_trace_transform, view_angles));
1226                 }
1227                 else if(autocvar_chase_active < 0) // time to disable chase_active if it was set by this code
1228                 {
1229                         eventchase_running = false;
1230                         cvar_set("chase_active", "0");
1231                         eventchase_current_distance = 0; // start from 0 next time
1232                 }
1233         }
1234         // workaround for camera stuck between player's legs when using chase_active 1
1235         // because the engine stops updating the chase_active camera when the game ends
1236         else if(intermission)
1237         {
1238                 cvar_settemp("chase_active", "-1");
1239                 eventchase_current_distance = 0;
1240         }
1241
1242         // do lockview after event chase camera so that it still applies whenever necessary.
1243         if(autocvar_cl_lockview || (!autocvar_hud_cursormode && (autocvar__hud_configure && spectatee_status <= 0 || intermission > 1 || QuickMenu_IsOpened())))
1244         {
1245                 setproperty(VF_ORIGIN, freeze_org);
1246                 setproperty(VF_ANGLES, freeze_ang);
1247         }
1248         else
1249         {
1250                 freeze_org = getpropertyvec(VF_ORIGIN);
1251                 freeze_ang = getpropertyvec(VF_ANGLES);
1252         }
1253
1254         WarpZone_FixView();
1255         //WarpZone_FixPMove();
1256         {
1257                 static string name_last;
1258                 string name = get_weaponinfo(switchingweapon).mdl;
1259                 if (name != name_last)
1260                 {
1261                         CL_WeaponEntity_SetModel(viewmodel, name_last = name);
1262                         updateanim(viewmodel);
1263                         if (!viewmodel.animstate_override)
1264                                 setanim(viewmodel, viewmodel.anim_idle, true, false, false);
1265                 }
1266         }
1267
1268         vector ov_org = '0 0 0';
1269         vector ov_mid = '0 0 0';
1270         vector ov_worldmin = '0 0 0';
1271         vector ov_worldmax = '0 0 0';
1272         if(autocvar_cl_orthoview)
1273         {
1274                 ov_worldmin = mi_picmin;
1275                 ov_worldmax = mi_picmax;
1276
1277                 float ov_width = (ov_worldmax.x - ov_worldmin.x);
1278                 float ov_height = (ov_worldmax.y - ov_worldmin.y);
1279                 float ov_distance = (max(vid_width, vid_height) * max(ov_width, ov_height));
1280
1281                 ov_mid = ((ov_worldmax + ov_worldmin) * 0.5);
1282                 ov_org = vec3(ov_mid.x, ov_mid.y, (ov_mid.z + ov_distance));
1283
1284                 float ov_nearest = vlen(ov_org - vec3(
1285                         bound(ov_worldmin.x, ov_org.x, ov_worldmax.x),
1286                         bound(ov_worldmin.y, ov_org.y, ov_worldmax.y),
1287                         bound(ov_worldmin.z, ov_org.z, ov_worldmax.z)
1288                 ));
1289
1290                 float ov_furthest = 0;
1291                 float dist = 0;
1292
1293                 if((dist = vlen(vec3(ov_worldmin.x, ov_worldmin.y, ov_worldmin.z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
1294                 if((dist = vlen(vec3(ov_worldmax.x, ov_worldmin.y, ov_worldmin.z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
1295                 if((dist = vlen(vec3(ov_worldmin.x, ov_worldmax.y, ov_worldmin.z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
1296                 if((dist = vlen(vec3(ov_worldmin.x, ov_worldmin.y, ov_worldmax.z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
1297                 if((dist = vlen(vec3(ov_worldmax.x, ov_worldmax.y, ov_worldmin.z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
1298                 if((dist = vlen(vec3(ov_worldmin.x, ov_worldmax.y, ov_worldmax.z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
1299                 if((dist = vlen(vec3(ov_worldmax.x, ov_worldmin.y, ov_worldmax.z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
1300                 if((dist = vlen(vec3(ov_worldmax.x, ov_worldmax.y, ov_worldmax.z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
1301
1302                 if(!ov_enabled)
1303                 {
1304                         oldr_nearclip = cvar("r_nearclip");
1305                         oldr_farclip_base = cvar("r_farclip_base");
1306                         oldr_farclip_world = cvar("r_farclip_world");
1307                         oldr_novis = cvar("r_novis");
1308                         oldr_useportalculling = cvar("r_useportalculling");
1309                         oldr_useinfinitefarclip = cvar("r_useinfinitefarclip");
1310                 }
1311
1312                 cvar_settemp("r_nearclip", ftos(ov_nearest));
1313                 cvar_settemp("r_farclip_base", ftos(ov_furthest));
1314                 cvar_settemp("r_farclip_world", "0");
1315                 cvar_settemp("r_novis", "1");
1316                 cvar_settemp("r_useportalculling", "0");
1317                 cvar_settemp("r_useinfinitefarclip", "0");
1318
1319                 setproperty(VF_ORIGIN, ov_org);
1320                 setproperty(VF_ANGLES, '90 0 0');
1321
1322                 ov_enabled = true;
1323
1324                 #if 0
1325                 LOG_INFOF("OrthoView: org = %s, angles = %s, distance = %f, nearest = %f, furthest = %f\n",
1326                         vtos(ov_org),
1327                         vtos(getpropertyvec(VF_ANGLES)),
1328                         ov_distance,
1329                         ov_nearest,
1330                         ov_furthest);
1331                 #endif
1332         }
1333         else
1334         {
1335                 if(ov_enabled)
1336                 {
1337                         cvar_set("r_nearclip", ftos(oldr_nearclip));
1338                         cvar_set("r_farclip_base", ftos(oldr_farclip_base));
1339                         cvar_set("r_farclip_world", ftos(oldr_farclip_world));
1340                         cvar_set("r_novis", ftos(oldr_novis));
1341                         cvar_set("r_useportalculling", ftos(oldr_useportalculling));
1342                         cvar_set("r_useinfinitefarclip", ftos(oldr_useinfinitefarclip));
1343                 }
1344                 ov_enabled = false;
1345         }
1346
1347         // Render the Scene
1348         view_origin = getpropertyvec(VF_ORIGIN);
1349         view_angles = getpropertyvec(VF_ANGLES);
1350         makevectors(view_angles);
1351         view_forward = v_forward;
1352         view_right = v_right;
1353         view_up = v_up;
1354
1355 #ifdef BLURTEST
1356         if(time > blurtest_time0 && time < blurtest_time1)
1357         {
1358                 float r, t;
1359
1360                 t = (time - blurtest_time0) / (blurtest_time1 - blurtest_time0);
1361                 r = t * blurtest_radius;
1362                 f = 1 / pow(t, blurtest_power) - 1;
1363
1364                 cvar_set("r_glsl_postprocess", "1");
1365                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(r), " ", ftos(f), " 0 0"));
1366         }
1367         else
1368         {
1369                 cvar_set("r_glsl_postprocess", "0");
1370                 cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
1371         }
1372 #endif
1373
1374         TargetMusic_Advance();
1375         Fog_Force();
1376
1377         if(drawtime == 0)
1378                 drawframetime = 0.01666667; // when we don't know fps yet, we assume 60fps
1379         else
1380                 drawframetime = bound(0.000001, time - drawtime, 1);
1381         drawtime = time;
1382
1383         // watch for gametype changes here...
1384         // in ParseStuffCMD the cmd isn't executed yet :/
1385         // might even be better to add the gametype to TE_CSQC_INIT...?
1386         if(!postinit)
1387                 PostInit();
1388
1389         if(intermission && !isdemo() && !(calledhooks & HOOK_END))
1390         {
1391                 if(calledhooks & HOOK_START)
1392                 {
1393                         localcmd("\ncl_hook_gameend\n");
1394                         calledhooks |= HOOK_END;
1395                 }
1396         }
1397
1398         Announcer();
1399
1400         fov = autocvar_fov;
1401         if(fov <= 59.5)
1402         {
1403                 if(!zoomscript_caught)
1404                 {
1405                         localcmd("+button9\n");
1406                         zoomscript_caught = 1;
1407                 }
1408         }
1409         else
1410         {
1411                 if(zoomscript_caught)
1412                 {
1413                         localcmd("-button9\n");
1414                         zoomscript_caught = 0;
1415                 }
1416         }
1417
1418         ColorTranslateMode = autocvar_cl_stripcolorcodes;
1419
1420         // next WANTED weapon (for HUD)
1421         switchweapon = getstati(STAT_SWITCHWEAPON);
1422
1423         // currently switching-to weapon (for crosshair)
1424         switchingweapon = getstati(STAT_SWITCHINGWEAPON);
1425
1426         // actually active weapon (for zoom)
1427         activeweapon = getstati(STAT_ACTIVEWEAPON);
1428
1429         f = (serverflags & SERVERFLAG_TEAMPLAY);
1430         if(f != teamplay)
1431         {
1432                 teamplay = f;
1433                 HUD_InitScores();
1434         }
1435
1436         if(last_switchweapon != switchweapon)
1437         {
1438                 weapontime = time;
1439                 last_switchweapon = switchweapon;
1440                 if(button_zoom && autocvar_cl_unpress_zoom_on_weapon_switch)
1441                 {
1442                         localcmd("-zoom\n");
1443                         button_zoom = false;
1444                 }
1445                 if(autocvar_cl_unpress_attack_on_weapon_switch)
1446                 {
1447                         localcmd("-fire\n");
1448                         localcmd("-fire2\n");
1449                         button_attack2 = false;
1450                 }
1451         }
1452         if(last_activeweapon != activeweapon)
1453         {
1454                 last_activeweapon = activeweapon;
1455
1456                 e = get_weaponinfo(activeweapon);
1457                 if(e.netname != "")
1458                         localcmd(strcat("\ncl_hook_activeweapon ", e.netname), "\n");
1459                 else
1460                         localcmd("\ncl_hook_activeweapon none\n");
1461         }
1462
1463         // ALWAYS Clear Current Scene First
1464         clearscene();
1465
1466         setproperty(VF_ORIGIN, view_origin);
1467         setproperty(VF_ANGLES, view_angles);
1468
1469         // FIXME engine bug? VF_SIZE and VF_MIN are not restored to sensible values by this
1470         setproperty(VF_SIZE, vf_size);
1471         setproperty(VF_MIN, vf_min);
1472
1473         // Assign Standard Viewflags
1474         // Draw the World (and sky)
1475         setproperty(VF_DRAWWORLD, 1);
1476
1477         // Set the console size vars
1478         vid_conwidth = autocvar_vid_conwidth;
1479         vid_conheight = autocvar_vid_conheight;
1480         vid_pixelheight = autocvar_vid_pixelheight;
1481
1482         if(autocvar_cl_orthoview) { setproperty(VF_FOV, GetOrthoviewFOV(ov_worldmin, ov_worldmax, ov_mid, ov_org)); }
1483         else if(csqcplayer.viewloc) { setproperty(VF_FOV, GetViewLocationFOV(110)); } // enforce 110 fov, so things dont look odd
1484         else { setproperty(VF_FOV, GetCurrentFov(fov)); }
1485
1486         // Camera for demo playback
1487         if(camera_active)
1488         {
1489                 if(autocvar_camera_enable)
1490                         CSQC_Demo_Camera();
1491                 else
1492                 {
1493                         cvar_set("chase_active", ftos(chase_active_backup));
1494                         cvar_set("cl_demo_mousegrab", "0");
1495                         camera_active = false;
1496                 }
1497         }
1498         else
1499         {
1500 #ifdef CAMERATEST
1501                 if(autocvar_camera_enable)
1502 #else
1503                 if(autocvar_camera_enable && isdemo())
1504 #endif
1505                 {
1506                         // Enable required Darkplaces cvars
1507                         chase_active_backup = autocvar_chase_active;
1508                         cvar_set("chase_active", "2");
1509                         cvar_set("cl_demo_mousegrab", "1");
1510                         camera_active = true;
1511                         camera_mode = false;
1512                 }
1513         }
1514
1515         // Draw the Crosshair
1516         setproperty(VF_DRAWCROSSHAIR, 0); //Make sure engine crosshairs are always hidden
1517
1518         // Draw the Engine Status Bar (the default Quake HUD)
1519         setproperty(VF_DRAWENGINESBAR, 0);
1520
1521         // Update the mouse position
1522         /*
1523            mousepos_x = vid_conwidth;
1524            mousepos_y = vid_conheight;
1525            mousepos = mousepos*0.5 + getmousepos();
1526          */
1527
1528         for(entity e = NULL; (e = nextent(e)); ) if (e.draw) {
1529                 WITH(entity, self, e, e.draw(e));
1530         }
1531
1532         addentities(MASK_NORMAL | MASK_ENGINE | MASK_ENGINEVIEWMODELS);
1533         renderscene();
1534
1535         // now switch to 2D drawing mode by calling a 2D drawing function
1536         // then polygon drawing will draw as 2D stuff, and NOT get queued until the
1537         // next R_RenderScene call
1538         drawstring('0 0 0', "", '1 1 0', '1 1 1', 0, 0);
1539
1540         if(autocvar_r_fakelight >= 2 || autocvar_r_fullbright)
1541         if (!(serverflags & SERVERFLAG_ALLOW_FULLBRIGHT))
1542         {
1543                 // apply night vision effect
1544                 vector tc_00, tc_01, tc_10, tc_11;
1545                 vector rgb = '0 0 0';
1546
1547                 if(!nightvision_noise)
1548                 {
1549                         nightvision_noise = spawn();
1550                         nightvision_noise.classname = "nightvision_noise";
1551                 }
1552                 if(!nightvision_noise2)
1553                 {
1554                         nightvision_noise2 = spawn();
1555                         nightvision_noise2.classname = "nightvision_noise2";
1556                 }
1557
1558                 // color tint in yellow
1559                 drawfill('0 0 0', autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', '0.5 1 0.3', 1, DRAWFLAG_MODULATE);
1560
1561                 // draw BG
1562                 a = Noise_Pink(nightvision_noise, frametime * 1.5) * 0.05 + 0.15;
1563                 rgb = '1 1 1';
1564                 tc_00 = '0 0 0' + '0.2 0 0' * sin(time * 0.3) + '0 0.3 0' * cos(time * 0.7);
1565                 tc_01 = '0 2.25 0' + '0.6 0 0' * cos(time * 1.2) - '0 0.3 0' * sin(time * 2.2);
1566                 tc_10 = '1.5 0 0' - '0.2 0 0' * sin(time * 0.5) + '0 0.5 0' * cos(time * 1.7);
1567                 //tc_11 = '1 1 0' + '0.6 0 0' * sin(time * 0.6) + '0 0.3 0' * cos(time * 0.1);
1568                 tc_11 = tc_01 + tc_10 - tc_00;
1569                 R_BeginPolygon("gfx/nightvision-bg.tga", DRAWFLAG_ADDITIVE);
1570                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
1571                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
1572                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
1573                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
1574                 R_EndPolygon();
1575
1576                 // draw FG
1577                 a = Noise_Pink(nightvision_noise2, frametime * 0.1) * 0.05 + 0.12;
1578                 rgb = '0.3 0.6 0.4' + '0.1 0.4 0.2' * Noise_White(nightvision_noise2, frametime);
1579                 tc_00 = '0 0 0' + '1 0 0' * Noise_White(nightvision_noise2, frametime) + '0 1 0' * Noise_White(nightvision_noise2, frametime);
1580                 tc_01 = tc_00 + '0 3 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.2);
1581                 tc_10 = tc_00 + '2 0 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.3);
1582                 tc_11 = tc_01 + tc_10 - tc_00;
1583                 R_BeginPolygon("gfx/nightvision-fg.tga", DRAWFLAG_ADDITIVE);
1584                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
1585                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
1586                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
1587                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
1588                 R_EndPolygon();
1589         }
1590
1591         if(autocvar_cl_reticle)
1592         {
1593                 Weapon wep = get_weaponinfo(activeweapon);
1594                 // Draw the aiming reticle for weapons that use it
1595                 // reticle_type is changed to the item we are zooming / aiming with, to decide which reticle to use
1596                 // It must be a persisted float for fading out to work properly (you let go of the zoom button for
1597                 // the view to go back to normal, so reticle_type would become 0 as we fade out)
1598                 if(spectatee_status || is_dead || hud != HUD_NORMAL)
1599                 {
1600                         // no zoom reticle while dead
1601                         reticle_type = 0;
1602                 }
1603                 else if(wep.wr_zoomreticle(wep) && autocvar_cl_reticle_weapon)
1604                 {
1605                         if(reticle_image != "") { reticle_type = 2; }
1606                         else { reticle_type = 0; }
1607                 }
1608                 else if(button_zoom || zoomscript_caught)
1609                 {
1610                         // normal zoom
1611                         reticle_type = 1;
1612                 }
1613
1614                 if(reticle_type)
1615                 {
1616                         if(autocvar_cl_reticle_stretch)
1617                         {
1618                                 reticle_size.x = vid_conwidth;
1619                                 reticle_size.y = vid_conheight;
1620                                 reticle_pos.x = 0;
1621                                 reticle_pos.y = 0;
1622                         }
1623                         else
1624                         {
1625                                 reticle_size.x = max(vid_conwidth, vid_conheight);
1626                                 reticle_size.y = max(vid_conwidth, vid_conheight);
1627                                 reticle_pos.x = (vid_conwidth - reticle_size.x) / 2;
1628                                 reticle_pos.y = (vid_conheight - reticle_size.y) / 2;
1629                         }
1630
1631                         if(zoomscript_caught)
1632                                 f = 1;
1633                         else
1634                                 f = current_zoomfraction;
1635
1636                         if(f)
1637                         {
1638                                 switch(reticle_type)
1639                                 {
1640                                         case 1: drawpic(reticle_pos, "gfx/reticle_normal", reticle_size, '1 1 1', f * autocvar_cl_reticle_normal_alpha, DRAWFLAG_NORMAL); break;
1641                                         case 2: drawpic(reticle_pos, reticle_image, reticle_size, '1 1 1', f * autocvar_cl_reticle_weapon_alpha, DRAWFLAG_NORMAL); break;
1642                                 }
1643                         }
1644                 }
1645         }
1646         else
1647         {
1648                 if(reticle_type != 0) { reticle_type = 0; }
1649         }
1650
1651
1652         // improved polyblend
1653         if(autocvar_hud_contents)
1654         {
1655                 float contentalpha_temp, incontent, liquidalpha, contentfadetime;
1656                 vector liquidcolor;
1657
1658                 switch(pointcontents(view_origin))
1659                 {
1660                         case CONTENT_WATER:
1661                                 liquidalpha = autocvar_hud_contents_water_alpha;
1662                                 liquidcolor = stov(autocvar_hud_contents_water_color);
1663                                 incontent = 1;
1664                                 break;
1665
1666                         case CONTENT_LAVA:
1667                                 liquidalpha = autocvar_hud_contents_lava_alpha;
1668                                 liquidcolor = stov(autocvar_hud_contents_lava_color);
1669                                 incontent = 1;
1670                                 break;
1671
1672                         case CONTENT_SLIME:
1673                                 liquidalpha = autocvar_hud_contents_slime_alpha;
1674                                 liquidcolor = stov(autocvar_hud_contents_slime_color);
1675                                 incontent = 1;
1676                                 break;
1677
1678                         default:
1679                                 liquidalpha = 0;
1680                                 liquidcolor = '0 0 0';
1681                                 incontent = 0;
1682                                 break;
1683                 }
1684
1685                 if(incontent) // fade in/out at different speeds so you can do e.g. instant fade when entering water and slow when leaving it.
1686                 { // also lets delcare previous values for blending properties, this way it isn't reset until after you have entered a different content
1687                         contentfadetime = autocvar_hud_contents_fadeintime;
1688                         liquidalpha_prev = liquidalpha;
1689                         liquidcolor_prev = liquidcolor;
1690                 }
1691                 else
1692                         contentfadetime = autocvar_hud_contents_fadeouttime;
1693
1694                 contentalpha_temp = bound(0, drawframetime / max(0.0001, contentfadetime), 1);
1695                 contentavgalpha = contentavgalpha * (1 - contentalpha_temp) + incontent * contentalpha_temp;
1696
1697                 if(contentavgalpha)
1698                         drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, liquidcolor_prev, contentavgalpha * liquidalpha_prev, DRAWFLAG_NORMAL);
1699
1700                 if(autocvar_hud_postprocessing)
1701                 {
1702                         if(autocvar_hud_contents_blur && contentavgalpha)
1703                         {
1704                                 content_blurpostprocess.x = 1;
1705                                 content_blurpostprocess.y = contentavgalpha * autocvar_hud_contents_blur;
1706                                 content_blurpostprocess.z = contentavgalpha * autocvar_hud_contents_blur_alpha;
1707                         }
1708                         else
1709                         {
1710                                 content_blurpostprocess.x = 0;
1711                                 content_blurpostprocess.y = 0;
1712                                 content_blurpostprocess.z = 0;
1713                         }
1714                 }
1715         }
1716
1717         if(autocvar_hud_damage && !getstati(STAT_FROZEN))
1718         {
1719                 splash_size.x = max(vid_conwidth, vid_conheight);
1720                 splash_size.y = max(vid_conwidth, vid_conheight);
1721                 splash_pos.x = (vid_conwidth - splash_size.x) / 2;
1722                 splash_pos.y = (vid_conheight - splash_size.y) / 2;
1723
1724                 float myhealth_flash_temp;
1725                 myhealth = getstati(STAT_HEALTH);
1726
1727                 // fade out
1728                 myhealth_flash = max(0, myhealth_flash - autocvar_hud_damage_fade_rate * frametime);
1729                 // add new damage
1730                 myhealth_flash = bound(0, myhealth_flash + dmg_take * autocvar_hud_damage_factor, autocvar_hud_damage_maxalpha);
1731
1732                 float pain_threshold, pain_threshold_lower, pain_threshold_lower_health;
1733                 pain_threshold = autocvar_hud_damage_pain_threshold;
1734                 pain_threshold_lower = autocvar_hud_damage_pain_threshold_lower;
1735                 pain_threshold_lower_health = autocvar_hud_damage_pain_threshold_lower_health;
1736
1737                 if(pain_threshold_lower && myhealth < pain_threshold_lower_health)
1738                 {
1739                         pain_threshold = pain_threshold - max(autocvar_hud_damage_pain_threshold_pulsating_min, fabs(sin(M_PI * time / autocvar_hud_damage_pain_threshold_pulsating_period))) * pain_threshold_lower * (1 - max(0, myhealth)/pain_threshold_lower_health);
1740                 }
1741
1742                 myhealth_flash_temp = bound(0, myhealth_flash - pain_threshold, 1);
1743
1744                 if(myhealth_prev < 1)
1745                 {
1746                         if(myhealth >= 1)
1747                         {
1748                                 myhealth_flash = 0; // just spawned, clear the flash immediately
1749                                 myhealth_flash_temp = 0;
1750                         }
1751                         else
1752                         {
1753                                 myhealth_flash += autocvar_hud_damage_fade_rate * frametime; // dead
1754                         }
1755                 }
1756
1757                 if(spectatee_status == -1 || intermission)
1758                 {
1759                         myhealth_flash = 0; // observing, or match ended
1760                         myhealth_flash_temp = 0;
1761                 }
1762
1763                 myhealth_prev = myhealth;
1764
1765                 // IDEA: change damage color/picture based on player model for robot/alien species?
1766                 // pro: matches model better
1767                 // contra: it's not red because blood is red, but because red is an alarming color, so red should stay
1768                 // maybe different reddish pics?
1769                 if(autocvar_cl_gentle_damage || autocvar_cl_gentle)
1770                 {
1771                         if(autocvar_cl_gentle_damage == 2)
1772                         {
1773                                 if(myhealth_flash < pain_threshold) // only randomize when the flash is gone
1774                                         myhealth_gentlergb = eX * random() + eY * random() + eZ * random();
1775                         }
1776                         else
1777                                 myhealth_gentlergb = stov(autocvar_hud_damage_gentle_color);
1778
1779                         if(myhealth_flash_temp > 0)
1780                                 drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, myhealth_gentlergb, autocvar_hud_damage_gentle_alpha_multiplier * bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
1781                 }
1782                 else if(myhealth_flash_temp > 0)
1783                         drawpic(splash_pos, "gfx/blood", splash_size, stov(autocvar_hud_damage_color), bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
1784
1785                 if(autocvar_hud_postprocessing) // we still need to set this anyway even when chase_active is set, this way it doesn't get stuck on.
1786                 {
1787                         if(autocvar_hud_damage_blur && myhealth_flash_temp)
1788                         {
1789                                 damage_blurpostprocess.x = 1;
1790                                 damage_blurpostprocess.y = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur;
1791                                 damage_blurpostprocess.z = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur_alpha;
1792                         }
1793                         else
1794                         {
1795                                 damage_blurpostprocess.x = 0;
1796                                 damage_blurpostprocess.y = 0;
1797                                 damage_blurpostprocess.z = 0;
1798                         }
1799                 }
1800         }
1801
1802         float e1 = (autocvar_hud_postprocessing_maxbluralpha != 0);
1803         float e2 = (autocvar_hud_powerup != 0);
1804         if(autocvar_hud_postprocessing && (e1 || e2)) // TODO: Remove this code and re-do the postprocess handling in the engine, where it properly belongs.
1805         {
1806                 // enable or disable rendering types if they are used or not
1807                 if(cvar("r_glsl_postprocess_uservec1_enable") != e1) { cvar_set("r_glsl_postprocess_uservec1_enable", ftos(e1)); }
1808                 if(cvar("r_glsl_postprocess_uservec2_enable") != e2) { cvar_set("r_glsl_postprocess_uservec2_enable", ftos(e2)); }
1809
1810                 // blur postprocess handling done first (used by hud_damage and hud_contents)
1811                 if((damage_blurpostprocess.x || content_blurpostprocess.x))
1812                 {
1813                         float blurradius = bound(0, damage_blurpostprocess.y + content_blurpostprocess.y, autocvar_hud_postprocessing_maxblurradius);
1814                         float bluralpha = bound(0, damage_blurpostprocess.z + content_blurpostprocess.z, autocvar_hud_postprocessing_maxbluralpha);
1815                         if(blurradius != old_blurradius || bluralpha != old_bluralpha) // reduce cvar_set spam as much as possible
1816                         {
1817                                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(blurradius), " ", ftos(bluralpha), " 0 0"));
1818                                 old_blurradius = blurradius;
1819                                 old_bluralpha = bluralpha;
1820                         }
1821                 }
1822                 else if(cvar_string("r_glsl_postprocess_uservec1") != "0 0 0 0") // reduce cvar_set spam as much as possible
1823                 {
1824                         cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
1825                         old_blurradius = 0;
1826                         old_bluralpha = 0;
1827                 }
1828
1829                 // edge detection postprocess handling done second (used by hud_powerup)
1830                 float sharpen_intensity = 0, strength_finished = getstatf(STAT_STRENGTH_FINISHED), invincible_finished = getstatf(STAT_INVINCIBLE_FINISHED);
1831                 if (strength_finished - time > 0) { sharpen_intensity += (strength_finished - time); }
1832                 if (invincible_finished - time > 0) { sharpen_intensity += (invincible_finished - time); }
1833
1834                 sharpen_intensity = bound(0, ((getstati(STAT_HEALTH) > 0) ? sharpen_intensity : 0), 5); // Check to see if player is alive (if not, set 0) - also bound to fade out starting at 5 seconds.
1835
1836                 if(autocvar_hud_powerup && sharpen_intensity > 0)
1837                 {
1838                         if(sharpen_intensity != old_sharpen_intensity) // reduce cvar_set spam as much as possible
1839                         {
1840                                 cvar_set("r_glsl_postprocess_uservec2", strcat(ftos((sharpen_intensity / 5) * autocvar_hud_powerup), " ", ftos(-sharpen_intensity * autocvar_hud_powerup), " 0 0"));
1841                                 old_sharpen_intensity = sharpen_intensity;
1842                         }
1843                 }
1844                 else if(cvar_string("r_glsl_postprocess_uservec2") != "0 0 0 0") // reduce cvar_set spam as much as possible
1845                 {
1846                         cvar_set("r_glsl_postprocess_uservec2", "0 0 0 0");
1847                         old_sharpen_intensity = 0;
1848                 }
1849
1850                 if(cvar("r_glsl_postprocess") == 0)
1851                         cvar_set("r_glsl_postprocess", "2");
1852         }
1853         else if(cvar("r_glsl_postprocess") == 2)
1854                 cvar_set("r_glsl_postprocess", "0");
1855
1856         if(menu_visible)
1857                 menu_show();
1858
1859         /*if(gametype == MAPINFO_TYPE_CTF)
1860           {
1861           ctf_view();
1862           } else */
1863
1864         // draw 2D entities
1865         for (entity e = NULL; (e = nextent(e)); ) if (e.draw2d) {
1866                 WITH(entity, self, e, e.draw2d(e));
1867         }
1868         Draw_ShowNames_All();
1869
1870         scoreboard_active = HUD_WouldDrawScoreboard();
1871
1872         HUD_Draw();
1873
1874         if(NextFrameCommand)
1875         {
1876                 localcmd("\n", NextFrameCommand, "\n");
1877                 NextFrameCommand = string_null;
1878         }
1879
1880         // we must do this check AFTER a frame was rendered, or it won't work
1881         if(cs_project_is_b0rked == 0)
1882         {
1883                 string w0, h0;
1884                 w0 = ftos(autocvar_vid_conwidth);
1885                 h0 = ftos(autocvar_vid_conheight);
1886                 //setproperty(VF_VIEWPORT, '0 0 0', '640 480 0');
1887                 //setproperty(VF_FOV, '90 90 0');
1888                 setproperty(VF_ORIGIN, '0 0 0');
1889                 setproperty(VF_ANGLES, '0 0 0');
1890                 setproperty(VF_PERSPECTIVE, 1);
1891                 makevectors('0 0 0');
1892                 vector v1, v2;
1893                 cvar_set("vid_conwidth", "800");
1894                 cvar_set("vid_conheight", "600");
1895                 v1 = cs_project(v_forward);
1896                 cvar_set("vid_conwidth", "640");
1897                 cvar_set("vid_conheight", "480");
1898                 v2 = cs_project(v_forward);
1899                 if(v1 == v2)
1900                         cs_project_is_b0rked = 1;
1901                 else
1902                         cs_project_is_b0rked = -1;
1903                 cvar_set("vid_conwidth", w0);
1904                 cvar_set("vid_conheight", h0);
1905         }
1906
1907         if(autocvar__hud_configure)
1908                 HUD_Panel_Mouse();
1909         else if ( HUD_MinigameMenu_IsOpened() || minigame_isactive() )
1910                 HUD_Minigame_Mouse();
1911         else if(QuickMenu_IsOpened())
1912                 QuickMenu_Mouse();
1913         else
1914                 HUD_Radar_Mouse();
1915
1916         cl_notice_run();
1917
1918         // let's reset the view back to normal for the end
1919         setproperty(VF_MIN, '0 0 0');
1920         setproperty(VF_SIZE, '1 0 0' * w + '0 1 0' * h);
1921 }
1922
1923
1924 // following vectors must be global to allow seamless switching between camera modes
1925 vector camera_offset, current_camera_offset, mouse_angles, current_angles, current_origin, current_position;
1926 void CSQC_Demo_Camera()
1927 {
1928         float speed, attenuation, dimensions;
1929         vector tmp, delta;
1930
1931         if( autocvar_camera_reset || !camera_mode )
1932         {
1933                 camera_offset = '0 0 0';
1934                 current_angles = '0 0 0';
1935                 camera_direction = '0 0 0';
1936                 camera_offset.z += 30;
1937                 camera_offset.x += 30 * -cos(current_angles.y * DEG2RAD);
1938                 camera_offset.y += 30 * -sin(current_angles.y * DEG2RAD);
1939                 current_origin = view_origin;
1940                 current_camera_offset  = camera_offset;
1941                 cvar_set("camera_reset", "0");
1942                 camera_mode = CAMERA_CHASE;
1943         }
1944
1945         // Camera angles
1946         if( camera_roll )
1947                 mouse_angles.z += camera_roll * autocvar_camera_speed_roll;
1948
1949         if(autocvar_camera_look_player)
1950         {
1951                 vector dir;
1952                 float n;
1953
1954                 dir = normalize(view_origin - current_position);
1955                 n = mouse_angles.z;
1956                 mouse_angles = vectoangles(dir);
1957                 mouse_angles.x = mouse_angles.x * -1;
1958                 mouse_angles.z = n;
1959         }
1960         else
1961         {
1962                 tmp = getmousepos() * 0.1;
1963                 if(vlen(tmp)>autocvar_camera_mouse_threshold)
1964                 {
1965                         mouse_angles.x += tmp.y * cos(mouse_angles.z * DEG2RAD) + (tmp.x * sin(mouse_angles.z * DEG2RAD));
1966                         mouse_angles.y -= tmp.x * cos(mouse_angles.z * DEG2RAD) + (tmp.y * -sin(mouse_angles.z * DEG2RAD));
1967                 }
1968         }
1969
1970         while (mouse_angles.x < -180) mouse_angles.x = mouse_angles.x + 360;
1971         while (mouse_angles.x > 180) mouse_angles.x = mouse_angles.x - 360;
1972         while (mouse_angles.y < -180) mouse_angles.y = mouse_angles.y + 360;
1973         while (mouse_angles.y > 180) mouse_angles.y = mouse_angles.y - 360;
1974
1975         // Fix difference when angles don't have the same sign
1976         delta = '0 0 0';
1977         if(mouse_angles.y < -60 && current_angles.y > 60)
1978                 delta = '0 360 0';
1979         if(mouse_angles.y > 60 && current_angles.y < -60)
1980                 delta = '0 -360 0';
1981
1982         if(autocvar_camera_look_player)
1983                 attenuation = autocvar_camera_look_attenuation;
1984         else
1985                 attenuation = autocvar_camera_speed_attenuation;
1986
1987         attenuation = 1 / max(1, attenuation);
1988         current_angles += (mouse_angles - current_angles + delta) * attenuation;
1989
1990         while (current_angles.x < -180) current_angles.x = current_angles.x + 360;
1991         while (current_angles.x > 180) current_angles.x = current_angles.x - 360;
1992         while (current_angles.y < -180) current_angles.y = current_angles.y + 360;
1993         while (current_angles.y > 180) current_angles.y = current_angles.y - 360;
1994
1995         // Camera position
1996         tmp = '0 0 0';
1997         dimensions = 0;
1998
1999         if( camera_direction.x )
2000         {
2001                 tmp.x = camera_direction.x * cos(current_angles.y * DEG2RAD);
2002                 tmp.y = camera_direction.x * sin(current_angles.y * DEG2RAD);
2003                 if( autocvar_camera_forward_follows && !autocvar_camera_look_player )
2004                         tmp.z = camera_direction.x * -sin(current_angles.x * DEG2RAD);
2005                 ++dimensions;
2006         }
2007
2008         if( camera_direction.y )
2009         {
2010                 tmp.x += camera_direction.y * -sin(current_angles.y * DEG2RAD);
2011                 tmp.y += camera_direction.y * cos(current_angles.y * DEG2RAD) * cos(current_angles.z * DEG2RAD);
2012                 tmp.z += camera_direction.y * sin(current_angles.z * DEG2RAD);
2013                 ++dimensions;
2014         }
2015
2016         if( camera_direction.z )
2017         {
2018                 tmp.z += camera_direction.z * cos(current_angles.z * DEG2RAD);
2019                 ++dimensions;
2020         }
2021
2022         if(autocvar_camera_free)
2023                 speed = autocvar_camera_speed_free;
2024         else
2025                 speed = autocvar_camera_speed_chase;
2026
2027         if(dimensions)
2028         {
2029                 speed = speed * sqrt(1 / dimensions);
2030                 camera_offset += tmp * speed;
2031         }
2032
2033         current_camera_offset += (camera_offset - current_camera_offset) * attenuation;
2034
2035         // Camera modes
2036         if( autocvar_camera_free )
2037         {
2038                 if ( camera_mode == CAMERA_CHASE )
2039                 {
2040                         current_camera_offset = current_origin + current_camera_offset;
2041                         camera_offset = current_origin + camera_offset;
2042                 }
2043
2044                 camera_mode = CAMERA_FREE;
2045                 current_position = current_camera_offset;
2046         }
2047         else
2048         {
2049                 if ( camera_mode == CAMERA_FREE )
2050                 {
2051                         current_origin = view_origin;
2052                         camera_offset = camera_offset - current_origin;
2053                         current_camera_offset = current_camera_offset - current_origin;
2054                 }
2055
2056                 camera_mode = CAMERA_CHASE;
2057
2058                 if(autocvar_camera_chase_smoothly)
2059                         current_origin += (view_origin - current_origin) * attenuation;
2060                 else
2061                         current_origin = view_origin;
2062
2063                 current_position = current_origin + current_camera_offset;
2064         }
2065
2066         setproperty(VF_ANGLES, current_angles);
2067         setproperty(VF_ORIGIN, current_position);
2068 }