qcsrc/common/gamemodes/gamemode/freezetag/sv_freezetag.qc

   1 #include "sv_freezetag.qh"
   2
   3 #include <common/resources/sv_resources.qh>
   4 #include <server/elimination.qh>
   5
   6 float autocvar_g_freezetag_frozen_maxtime;
   7 float autocvar_g_freezetag_revive_clearspeed;
   8 float autocvar_g_freezetag_round_timelimit;
   9 //int autocvar_g_freezetag_teams;
  10 int autocvar_g_freezetag_teams_override;
  11 float autocvar_g_freezetag_warmup;
  12
  13 float autocvar_g_ft_start_health = 100;
  14 float autocvar_g_ft_start_armor = 100;
  15 float autocvar_g_ft_start_ammo_shells = 60;
  16 float autocvar_g_ft_start_ammo_nails = 320;
  17 float autocvar_g_ft_start_ammo_rockets = 160;
  18 float autocvar_g_ft_start_ammo_cells = 180;
  19 float autocvar_g_ft_start_ammo_plasma = 180;
  20 float autocvar_g_ft_start_ammo_fuel = 0;
  21
  22 void freezetag_count_alive_players()
  23 {
  24         total_players = 0;
  25         for (int i = 1; i <= NUM_TEAMS; ++i)
  26         {
  27                 Team_SetNumberOfAlivePlayers(Team_GetTeamFromIndex(i), 0);
  28         }
  29         FOREACH_CLIENT(IS_PLAYER(it) && Entity_HasValidTeam(it),
  30         {
  31                 ++total_players;
  32                 if (GetResource(it, RES_HEALTH) < 1 || STAT(FROZEN, it) == FROZEN_NORMAL)
  33                 {
  34                         continue;
  35                 }
  36                 entity team_ = Entity_GetTeam(it);
  37                 int num_alive = Team_GetNumberOfAlivePlayers(team_);
  38                 ++num_alive;
  39                 Team_SetNumberOfAlivePlayers(team_, num_alive);
  40         });
  41         FOREACH_CLIENT(IS_REAL_CLIENT(it),
  42         {
  43                 STAT(REDALIVE, it) = Team_GetNumberOfAlivePlayers(Team_GetTeamFromIndex(1));
  44                 STAT(BLUEALIVE, it) = Team_GetNumberOfAlivePlayers(Team_GetTeamFromIndex(2));
  45                 STAT(YELLOWALIVE, it) = Team_GetNumberOfAlivePlayers(Team_GetTeamFromIndex(3));
  46                 STAT(PINKALIVE, it) = Team_GetNumberOfAlivePlayers(Team_GetTeamFromIndex(4));
  47         });
  48
  49         eliminatedPlayers.SendFlags |= 1;
  50 }
  51
  52 bool freezetag_CheckTeams()
  53 {
  54         static float prev_missing_teams_mask;
  55         if (Team_GetNumberOfAliveTeams() == NumTeams(freezetag_teams))
  56         {
  57                 if(prev_missing_teams_mask > 0)
  58                         Kill_Notification(NOTIF_ALL, NULL, MSG_CENTER, CPID_MISSING_TEAMS);
  59                 prev_missing_teams_mask = -1;
  60                 return true;
  61         }
  62         if(total_players == 0)
  63         {
  64                 if(prev_missing_teams_mask > 0)
  65                         Kill_Notification(NOTIF_ALL, NULL, MSG_CENTER, CPID_MISSING_TEAMS);
  66                 prev_missing_teams_mask = -1;
  67                 return false;
  68         }
  69         int missing_teams_mask = 0;
  70         for (int i = 1; i <= NUM_TEAMS; ++i)
  71         {
  72                 if ((freezetag_teams & Team_IndexToBit(i)) &&
  73                         (Team_GetNumberOfAlivePlayers(Team_GetTeamFromIndex(i)) == 0))
  74                 {
  75                         missing_teams_mask |= Team_IndexToBit(i);
  76                 }
  77         }
  78         if(prev_missing_teams_mask != missing_teams_mask)
  79         {
  80                 Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, CENTER_MISSING_TEAMS, missing_teams_mask);
  81                 prev_missing_teams_mask = missing_teams_mask;
  82         }
  83         return false;
  84 }
  85
  86 void nades_Clear(entity);
  87 void nades_GiveBonus(entity player, float score);
  88
  89 bool freezetag_CheckWinner()
  90 {
  91         if(round_handler_GetEndTime() > 0 && round_handler_GetEndTime() - time <= 0)
  92         {
  93                 Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, CENTER_ROUND_OVER);
  94                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_ROUND_OVER);
  95                 FOREACH_CLIENT(IS_PLAYER(it), {
  96                         it.freezetag_frozen_timeout = 0;
  97                         it.freezetag_revive_time = 0;
  98                         nades_Clear(it);
  99                 });
 100                 game_stopped = true;
 101                 round_handler_Init(5, autocvar_g_freezetag_warmup, autocvar_g_freezetag_round_timelimit);
 102                 return true;
 103         }
 104
 105         int winner_team = Team_GetWinnerAliveTeam();
 106         if (!winner_team)
 107                 return false;
 108
 109         if(winner_team > 0)
 110         {
 111                 Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, APP_TEAM_NUM(winner_team, CENTER_ROUND_TEAM_WIN));
 112                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, APP_TEAM_NUM(winner_team, INFO_ROUND_TEAM_WIN));
 113                 TeamScore_AddToTeam(winner_team, ST_FT_ROUNDS, +1);
 114         }
 115         else if(winner_team == -1)
 116         {
 117                 Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, CENTER_ROUND_TIED);
 118                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_ROUND_TIED);
 119         }
 120
 121         FOREACH_CLIENT(IS_PLAYER(it), {
 122                 it.freezetag_frozen_timeout = 0;
 123                 it.freezetag_revive_time = 0;
 124                 nades_Clear(it);
 125         });
 126
 127         game_stopped = true;
 128         round_handler_Init(5, autocvar_g_freezetag_warmup, autocvar_g_freezetag_round_timelimit);
 129         return true;
 130 }
 131
 132 entity freezetag_LastPlayerForTeam(entity this)
 133 {
 134         entity last_pl = NULL;
 135         FOREACH_CLIENT(IS_PLAYER(it) && it != this && SAME_TEAM(it, this), {
 136                 if (STAT(FROZEN, it) != FROZEN_NORMAL && GetResource(it, RES_HEALTH) >= 1)
 137                 {
 138                         if (!last_pl)
 139                                 last_pl = it;
 140                         else
 141                                 return NULL;
 142                 }
 143         });
 144         return last_pl;
 145 }
 146
 147 void freezetag_LastPlayerForTeam_Notify(entity this)
 148 {
 149         if(round_handler_IsActive())
 150         if(round_handler_IsRoundStarted())
 151         {
 152                 entity pl = freezetag_LastPlayerForTeam(this);
 153                 if(pl)
 154                         Send_Notification(NOTIF_ONE, pl, MSG_CENTER, CENTER_ALONE);
 155         }
 156 }
 157
 158 void freezetag_Add_Score(entity targ, entity attacker)
 159 {
 160         if(attacker == targ)
 161         {
 162                 // you froze your own dumb self
 163                 // counted as "suicide" already
 164                 GameRules_scoring_add(targ, SCORE, -1);
 165         }
 166         else if(IS_PLAYER(attacker))
 167         {
 168                 // got frozen by an enemy
 169                 // counted as "kill" and "death" already
 170                 GameRules_scoring_add(targ, SCORE, -1);
 171                 GameRules_scoring_add(attacker, SCORE, +1);
 172         }
 173         // else nothing - got frozen by the game type rules themselves
 174 }
 175
 176 // to be called when the player is frozen by freezetag (on death, spectator join etc), gives the score
 177 void freezetag_Freeze(entity targ, entity attacker)
 178 {
 179         if(STAT(FROZEN, targ))
 180                 return;
 181
 182         targ.freezetag_frozen_time = time;
 183         if (autocvar_g_freezetag_revive_auto && autocvar_g_freezetag_frozen_maxtime > 0)
 184                 targ.freezetag_frozen_timeout = time + autocvar_g_freezetag_frozen_maxtime;
 185
 186         Freeze(targ, 0, FROZEN_NORMAL, true);
 187
 188         freezetag_count_alive_players();
 189
 190         freezetag_Add_Score(targ, attacker);
 191 }
 192
 193 bool freezetag_isEliminated(entity e)
 194 {
 195         if(IS_PLAYER(e) && (STAT(FROZEN, e) == FROZEN_NORMAL || IS_DEAD(e)))
 196                 return true;
 197         return false;
 198 }
 199
 200
 201 // ================
 202 // Bot player logic
 203 // ================
 204
 205 void(entity this) havocbot_role_ft_freeing;
 206 void(entity this) havocbot_role_ft_offense;
 207
 208 void havocbot_goalrating_ft_freeplayers(entity this, float ratingscale, vector org, float sradius)
 209 {
 210         entity best_pl = NULL;
 211         float best_dist2 = FLOAT_MAX;
 212         FOREACH_CLIENT(IS_PLAYER(it) && it != this && SAME_TEAM(it, this), {
 213                 if (STAT(FROZEN, it) == FROZEN_NORMAL)
 214                 {
 215                         if(vdist(it.origin - org, >, sradius))
 216                                 continue;
 217                         navigation_routerating(this, it, ratingscale, 2000);
 218                 }
 219                 else if (best_dist2
 220                         && GetResource(it, RES_HEALTH) < GetResource(this, RES_HEALTH) + 30
 221                         && vlen2(it.origin - org) < best_dist2)
 222                 {
 223                         // If teamate is not frozen still seek them out as fight better
 224                         // in a group.
 225                         best_dist2 = vlen2(it.origin - org);
 226                         if (best_dist2 < 700 ** 2)
 227                         {
 228                                 best_pl = NULL;
 229                                 best_dist2 = 0; // already close to a teammate
 230                         }
 231                         else
 232                                 best_pl = it;
 233                 }
 234         });
 235         if (best_pl)
 236                 navigation_routerating(this, best_pl, ratingscale / 2, 2000);
 237 }
 238
 239 void havocbot_role_ft_offense(entity this)
 240 {
 241         if(IS_DEAD(this))
 242                 return;
 243
 244         if (!this.havocbot_role_timeout)
 245                 this.havocbot_role_timeout = time + random() * 10 + 20;
 246
 247         // Count how many players on team are unfrozen.
 248         int unfrozen = 0;
 249         FOREACH_CLIENT(IS_PLAYER(it) && SAME_TEAM(it, this) && STAT(FROZEN, it) != FROZEN_NORMAL, {
 250                 unfrozen++;
 251         });
 252
 253         // If only one left on team or if role has timed out then start trying to free players.
 254         if ((!unfrozen && STAT(FROZEN, this) != FROZEN_NORMAL) || time > this.havocbot_role_timeout)
 255         {
 256                 LOG_TRACE("changing role to freeing");
 257                 this.havocbot_role = havocbot_role_ft_freeing;
 258                 this.havocbot_role_timeout = 0;
 259                 return;
 260         }
 261
 262         if (navigation_goalrating_timeout(this))
 263         {
 264                 navigation_goalrating_start(this);
 265                 havocbot_goalrating_items(this, 12000, this.origin, 10000);
 266                 havocbot_goalrating_enemyplayers(this, 10000, this.origin, 10000);
 267                 havocbot_goalrating_ft_freeplayers(this, 9000, this.origin, 10000);
 268                 havocbot_goalrating_waypoints(this, 1, this.origin, 3000);
 269                 navigation_goalrating_end(this);
 270
 271                 navigation_goalrating_timeout_set(this);
 272         }
 273 }
 274
 275 void havocbot_role_ft_freeing(entity this)
 276 {
 277         if(IS_DEAD(this))
 278                 return;
 279
 280         if (!this.havocbot_role_timeout)
 281                 this.havocbot_role_timeout = time + random() * 10 + 20;
 282
 283         if (time > this.havocbot_role_timeout)
 284         {
 285                 LOG_TRACE("changing role to offense");
 286                 this.havocbot_role = havocbot_role_ft_offense;
 287                 this.havocbot_role_timeout = 0;
 288                 return;
 289         }
 290
 291         if (navigation_goalrating_timeout(this))
 292         {
 293                 navigation_goalrating_start(this);
 294                 havocbot_goalrating_items(this, 10000, this.origin, 10000);
 295                 havocbot_goalrating_enemyplayers(this, 5000, this.origin, 10000);
 296                 havocbot_goalrating_ft_freeplayers(this, 20000, this.origin, 10000);
 297                 havocbot_goalrating_waypoints(this, 1, this.origin, 3000);
 298                 navigation_goalrating_end(this);
 299
 300                 navigation_goalrating_timeout_set(this);
 301         }
 302 }
 303
 304
 305 // ==============
 306 // Hook Functions
 307 // ==============
 308
 309 void ft_RemovePlayer(entity this)
 310 {
 311         if (STAT(FROZEN, this) != FROZEN_NORMAL)
 312                 freezetag_LastPlayerForTeam_Notify(this);
 313         Unfreeze(this, false);
 314
 315         SetResourceExplicit(this, RES_HEALTH, 0); // neccessary to correctly count alive players
 316         freezetag_count_alive_players();
 317 }
 318
 319 MUTATOR_HOOKFUNCTION(ft, ClientDisconnect)
 320 {
 321         entity player = M_ARGV(0, entity);
 322
 323         ft_RemovePlayer(player);
 324         return true;
 325 }
 326
 327 MUTATOR_HOOKFUNCTION(ft, MakePlayerObserver)
 328 {
 329         entity player = M_ARGV(0, entity);
 330
 331         ft_RemovePlayer(player);
 332 }
 333
 334 MUTATOR_HOOKFUNCTION(ft, PlayerDies)
 335 {
 336         entity frag_attacker = M_ARGV(1, entity);
 337         entity frag_target = M_ARGV(2, entity);
 338         float frag_deathtype = M_ARGV(3, float);
 339
 340         if(round_handler_IsActive())
 341         if(round_handler_CountdownRunning())
 342         {
 343                 if (STAT(FROZEN, frag_target) == FROZEN_NORMAL)
 344                         Unfreeze(frag_target, true);
 345                 freezetag_count_alive_players();
 346                 frag_target.respawn_time = time;
 347                 frag_target.respawn_flags |= RESPAWN_FORCE;
 348                 return true;
 349         }
 350
 351         frag_target.respawn_time = time + 1;
 352         frag_target.respawn_flags |= RESPAWN_FORCE;
 353
 354         // Cases DEATH_TEAMCHANGE and DEATH_AUTOTEAMCHANGE are needed to fix a bug whe
 355         // you succeed changing team through the menu: you both really die (gibbing) and get frozen
 356         if(ITEM_DAMAGE_NEEDKILL(frag_deathtype)
 357                 || frag_deathtype == DEATH_TEAMCHANGE.m_id || frag_deathtype == DEATH_AUTOTEAMCHANGE.m_id)
 358         {
 359                 // let the player die, they will be automatically frozen when they respawn
 360                 if (STAT(FROZEN, frag_target) != FROZEN_NORMAL)
 361                 {
 362                         freezetag_Add_Score(frag_target, frag_attacker);
 363                         freezetag_count_alive_players();
 364                         freezetag_LastPlayerForTeam_Notify(frag_target);
 365                         frag_target.freezetag_frozen_timeout = -2; // freeze on respawn
 366                 }
 367                 else
 368                 {
 369                         float t = frag_target.freezetag_frozen_timeout;
 370                         float t2 = frag_target.freezetag_frozen_time;
 371                         Unfreeze(frag_target, false); // remove ice
 372                         // keep timeout value so it can be restored when player will be refrozen on respawn
 373                         // NOTE this can't be exactly -2 since game starts from time 2
 374                         frag_target.freezetag_frozen_timeout = -t;
 375                         frag_target.freezetag_frozen_time = t2;
 376                 }
 377                 return true;
 378         }
 379
 380         if (STAT(FROZEN, frag_target) == FROZEN_NORMAL)
 381                 return true;
 382
 383         freezetag_Freeze(frag_target, frag_attacker);
 384         freezetag_LastPlayerForTeam_Notify(frag_target);
 385
 386         if(frag_attacker == frag_target || frag_attacker == NULL)
 387         {
 388                 if(IS_PLAYER(frag_target))
 389                         Send_Notification(NOTIF_ONE, frag_target, MSG_CENTER, CENTER_FREEZETAG_SELF);
 390                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_FREEZETAG_SELF, frag_target.netname);
 391         }
 392         else
 393         {
 394                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_FREEZETAG_FREEZE, frag_target.netname, frag_attacker.netname);
 395         }
 396
 397         return true;
 398 }
 399
 400 MUTATOR_HOOKFUNCTION(ft, PlayerSpawn)
 401 {
 402         entity player = M_ARGV(0, entity);
 403
 404         if(player.freezetag_frozen_timeout == -1) // if PlayerSpawn is called by reset_map_players
 405                 return true; // do nothing, round is starting right now
 406
 407         if(player.freezetag_frozen_timeout <= -2) // player was dead
 408         {
 409                 float t = player.freezetag_frozen_timeout;
 410                 float t2 = player.freezetag_frozen_time;
 411                 freezetag_Freeze(player, NULL);
 412                 if (t < -2)
 413                 {
 414                         player.freezetag_frozen_timeout = -t;
 415                         player.freezetag_frozen_time = t2;
 416                 }
 417                 return true;
 418         }
 419
 420         freezetag_count_alive_players();
 421
 422         if(round_handler_IsActive())
 423         if(round_handler_IsRoundStarted())
 424         {
 425                 Send_Notification(NOTIF_ONE, player, MSG_CENTER, CENTER_FREEZETAG_SPAWN_LATE);
 426                 freezetag_Freeze(player, NULL);
 427         }
 428
 429         return true;
 430 }
 431
 432 MUTATOR_HOOKFUNCTION(ft, reset_map_players)
 433 {
 434         FOREACH_CLIENT(IS_PLAYER(it), {
 435                 CS(it).killcount = 0;
 436                 it.freezetag_revive_time = 0;
 437                 it.freezetag_frozen_timeout = -1;
 438                 PutClientInServer(it);
 439                 it.freezetag_frozen_timeout = 0;
 440         });
 441         freezetag_count_alive_players();
 442         return true;
 443 }
 444
 445 MUTATOR_HOOKFUNCTION(ft, GiveFragsForKill, CBC_ORDER_FIRST)
 446 {
 447         M_ARGV(2, float) = 0; // no frags counted in Freeze Tag
 448         return true;
 449 }
 450
 451 MUTATOR_HOOKFUNCTION(ft, Unfreeze)
 452 {
 453         entity targ = M_ARGV(0, entity);
 454         targ.freezetag_frozen_time = 0;
 455         targ.freezetag_frozen_timeout = 0;
 456 }
 457
 458 MUTATOR_HOOKFUNCTION(ft, Damage_Calculate)
 459 {
 460         entity frag_attacker = M_ARGV(1, entity);
 461         entity frag_target = M_ARGV(2, entity);
 462         //float frag_deathtype = M_ARGV(3, float);
 463         //float frag_damage = M_ARGV(4, float);
 464         vector frag_force = M_ARGV(6, vector);
 465
 466         if (STAT(FROZEN, frag_target) == FROZEN_NORMAL && autocvar_g_freezetag_revive_auto_reducible
 467                 && autocvar_g_freezetag_frozen_maxtime > 0 && autocvar_g_freezetag_revive_auto)
 468         {
 469                 float t = 0;
 470                 if ((autocvar_g_freezetag_revive_auto_reducible < 0 || DIFF_TEAM(frag_attacker, frag_target))
 471                         && frag_target.freezetag_frozen_timeout > time)
 472                 {
 473                         if (fabs(autocvar_g_freezetag_revive_auto_reducible) == 1)
 474                         {
 475                                 float maxforce = autocvar_g_freezetag_revive_auto_reducible_maxforce;
 476                                 t = vlen(frag_force);
 477                                 // limit hit force considered at once, e.g when you have the Strength
 478                                 // powerup but also with weapons that fire multiple projectiles at once (crylink)
 479                                 if (frag_target.freezetag_frozen_force + t > maxforce)
 480                                 {
 481                                         t = max(0, maxforce - frag_target.freezetag_frozen_force);
 482                                         frag_target.freezetag_frozen_force = maxforce;
 483                                 }
 484                                 else
 485                                         frag_target.freezetag_frozen_force += t;
 486                                 t *= autocvar_g_freezetag_revive_auto_reducible_forcefactor;
 487                         }
 488                         frag_target.freezetag_frozen_timeout -= t;
 489                         if (frag_target.freezetag_frozen_timeout < time)
 490                                 frag_target.freezetag_frozen_timeout = time;
 491                 }
 492         }
 493 }
 494
 495 #ifdef IN_REVIVING_RANGE
 496         #undef IN_REVIVING_RANGE
 497 #endif
 498
 499 #define IN_REVIVING_RANGE(player, it, revive_extra_size) \
 500         (it != player && !IS_DEAD(it) && SAME_TEAM(it, player) \
 501         && boxesoverlap(player.absmin - revive_extra_size, player.absmax + revive_extra_size, it.absmin, it.absmax))
 502
 503 MUTATOR_HOOKFUNCTION(ft, PlayerPreThink, CBC_ORDER_FIRST)
 504 {
 505         if(game_stopped)
 506                 return true;
 507
 508         if(round_handler_IsActive())
 509         if(!round_handler_IsRoundStarted())
 510                 return true;
 511
 512         entity player = M_ARGV(0, entity);
 513         //if (STAT(FROZEN, player) == FROZEN_NORMAL)
 514         //if(player.freezetag_frozen_timeout > 0 && time < player.freezetag_frozen_timeout)
 515                 //player.iceblock.alpha = ICE_MIN_ALPHA + (ICE_MAX_ALPHA - ICE_MIN_ALPHA) * (player.freezetag_frozen_timeout - time) / (player.freezetag_frozen_timeout - player.freezetag_frozen_time);
 516
 517         player.freezetag_frozen_force = 0;
 518
 519         if (!(frametime && IS_PLAYER(player)))
 520                 return true;
 521
 522         entity revivers_last = NULL;
 523         entity revivers_first = NULL;
 524
 525         bool player_is_reviving = false;
 526         int n = 0;
 527         vector revive_extra_size = '1 1 1' * autocvar_g_freezetag_revive_extra_size;
 528         FOREACH_CLIENT(IS_PLAYER(it), {
 529                 // check if player is reviving anyone
 530                 if (STAT(FROZEN, it) == FROZEN_NORMAL)
 531                 {
 532                         if ((STAT(FROZEN, player) == FROZEN_NORMAL))
 533                                 continue;
 534                         if (!IN_REVIVING_RANGE(player, it, revive_extra_size))
 535                                 continue;
 536                         player_is_reviving = true;
 537                         break;
 538                 }
 539
 540                 if (!(STAT(FROZEN, player) == FROZEN_NORMAL))
 541                         continue; // both player and it are NOT frozen
 542                 if (!IN_REVIVING_RANGE(player, it, revive_extra_size))
 543                         continue;
 544
 545                 // found a teammate that is reviving player
 546                 if (autocvar_g_freezetag_revive_time_to_score > 0 && STAT(FROZEN, player) == FROZEN_NORMAL)
 547                 {
 548                         it.freezetag_revive_time += frametime / autocvar_g_freezetag_revive_time_to_score;
 549                         while (it.freezetag_revive_time > 1)
 550                         {
 551                                 GameRules_scoring_add(it, SCORE, +1);
 552                                 it.freezetag_revive_time -= 1;
 553                         }
 554                 }
 555                 if (revivers_last)
 556                         revivers_last.chain = it;
 557                 revivers_last = it;
 558                 if (!revivers_first)
 559                         revivers_first = it;
 560                 ++n;
 561         });
 562         if (revivers_last)
 563                 revivers_last.chain = NULL;
 564
 565         // allow normal revival during automatic revival
 566         // (if we wouldn't allow it then freezetag_frozen_timeout should be checked too in the previous loop)
 567         //if (STAT(FROZEN, player) == FROZEN_NORMAL) // redundant check
 568         if (!n && player.freezetag_frozen_timeout > 0 && time >= player.freezetag_frozen_timeout)
 569                 n = -1;
 570
 571         float base_progress = 0;
 572         if  (STAT(FROZEN, player) == FROZEN_NORMAL && autocvar_g_freezetag_revive_auto
 573                 && autocvar_g_freezetag_frozen_maxtime > 0 && autocvar_g_freezetag_revive_auto_progress)
 574         {
 575                 // NOTE if auto-revival is in progress, manual revive speed is reduced so that it always takes the same amount of time
 576                 base_progress = bound(0, (1 - (player.freezetag_frozen_timeout - time) / autocvar_g_freezetag_frozen_maxtime), 1);
 577         }
 578
 579         if (!n) // no teammate nearby
 580         {
 581                 float clearspeed = autocvar_g_freezetag_revive_clearspeed;
 582                 if (STAT(FROZEN, player) == FROZEN_NORMAL)
 583                 {
 584                         if (autocvar_g_freezetag_revive_time_to_score > 0)
 585                         {
 586                                 if (STAT(REVIVE_PROGRESS, player) > base_progress)
 587                                 {
 588                                         // reduce auto-revival time based on manual revival progress
 589                                         base_progress = STAT(REVIVE_PROGRESS, player);
 590                                         player.freezetag_frozen_timeout = time + autocvar_g_freezetag_frozen_maxtime * (1 - STAT(REVIVE_PROGRESS, player));
 591                                 }
 592                                 // don't clear revive progress, it would allow stacking points
 593                                 // by entering and exiting the revival zone many times
 594                                 STAT(REVIVE_PROGRESS, player) = base_progress;
 595                         }
 596                         else
 597                                 STAT(REVIVE_PROGRESS, player) = bound(base_progress, STAT(REVIVE_PROGRESS, player) - frametime * clearspeed * (1 - base_progress), 1);
 598                 }
 599                 else if (!STAT(FROZEN, player) && !player_is_reviving)
 600                         STAT(REVIVE_PROGRESS, player) = base_progress; // thawing nobody
 601         }
 602         else if (STAT(FROZEN, player) == FROZEN_NORMAL) // OK, there is at least one teammate reviving us
 603         {
 604                 float spd = autocvar_g_freezetag_revive_speed_t2s;
 605                 if (autocvar_g_freezetag_revive_time_to_score <= 0)
 606                         spd = autocvar_g_freezetag_revive_speed * (1 - base_progress);
 607                 STAT(REVIVE_PROGRESS, player) = bound(base_progress, STAT(REVIVE_PROGRESS, player) + frametime * max(1/60, spd), 1);
 608
 609                 if(STAT(REVIVE_PROGRESS, player) >= 1)
 610                 {
 611                         float frozen_time = time - player.freezetag_frozen_time;
 612                         Unfreeze(player, false);
 613                         SetResourceExplicit(player, RES_HEALTH, ((warmup_stage) ? warmup_start_health : start_health));
 614                         player.spawnshieldtime = time + autocvar_g_freezetag_revive_spawnshield;
 615                         freezetag_count_alive_players();
 616
 617                         if(n == -1)
 618                         {
 619                                 if(autocvar_sv_eventlog)
 620                                         GameLogEcho(strcat(":ft:autorevival:", ftos(player.playerid)));
 621                                 Send_Notification(NOTIF_ONE, player, MSG_CENTER, CENTER_FREEZETAG_AUTO_REVIVED, frozen_time);
 622                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_FREEZETAG_AUTO_REVIVED, player.netname, frozen_time);
 623                                 return true;
 624                         }
 625
 626                         // EVERY team mate nearby gets a point (even if multiple!)
 627                         for(entity it = revivers_first; it; it = it.chain)
 628                         {
 629                                 GameRules_scoring_add(it, FREEZETAG_REVIVALS, +1);
 630                                 if (autocvar_g_freezetag_revive_time_to_score <= 0)
 631                                         GameRules_scoring_add(it, SCORE, +1);
 632                                 nades_GiveBonus(it, autocvar_g_nades_bonus_score_low);
 633                         }
 634
 635                         Send_Notification(NOTIF_ONE, player, MSG_CENTER, CENTER_FREEZETAG_REVIVED, revivers_first.netname);
 636                         Send_Notification(NOTIF_ONE, revivers_first, MSG_CENTER, CENTER_FREEZETAG_REVIVE, player.netname);
 637                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_FREEZETAG_REVIVED, player.netname, revivers_first.netname);
 638                         if(autocvar_sv_eventlog)
 639                         {
 640                                 string revivers = "";
 641                                 for(entity it = revivers_first; it; it = it.chain)
 642                                         revivers = strcat(revivers, ftos(it.playerid), ",");
 643                                 revivers = substring(revivers, 0, strlen(revivers) - 1);
 644                                 GameLogEcho(strcat(":ft:revival:", ftos(player.playerid), ":", revivers));
 645                         }
 646                 }
 647
 648                 for(entity it = revivers_first; it; it = it.chain)
 649                         STAT(REVIVE_PROGRESS, it) = STAT(REVIVE_PROGRESS, player);
 650         }
 651
 652         if (STAT(FROZEN, player) == FROZEN_NORMAL)
 653         {
 654                 entity player_wp = player.waypointsprite_attached;
 655                 if (n > 0 || (n == 0 && STAT(REVIVE_PROGRESS, player) > 0.95))
 656                 {
 657                         WaypointSprite_UpdateSprites(player_wp, WP_Reviving, WP_Null, WP_Null);
 658                         WaypointSprite_UpdateTeamRadar(player_wp, RADARICON_WAYPOINT, WP_REVIVING_COLOR);
 659                 }
 660                 else
 661                 {
 662                         WaypointSprite_UpdateSprites(player_wp, WP_Frozen, WP_Null, WP_Null);
 663                         WaypointSprite_UpdateTeamRadar(player_wp, RADARICON_WAYPOINT, WP_FROZEN_COLOR);
 664                 }
 665
 666                 WaypointSprite_UpdateMaxHealth(player_wp, 1);
 667                 WaypointSprite_UpdateHealth(player_wp, STAT(REVIVE_PROGRESS, player));
 668         }
 669
 670         return true;
 671 }
 672
 673 MUTATOR_HOOKFUNCTION(ft, SetStartItems)
 674 {
 675         start_items &= ~(IT_UNLIMITED_AMMO | IT_UNLIMITED_SUPERWEAPONS);
 676         if(!cvar("g_use_ammunition"))
 677                 start_items |= IT_UNLIMITED_AMMO;
 678
 679         start_health       = warmup_start_health       = autocvar_g_ft_start_health;
 680         start_armorvalue   = warmup_start_armorvalue   = autocvar_g_ft_start_armor;
 681         start_ammo_shells  = warmup_start_ammo_shells  = autocvar_g_ft_start_ammo_shells;
 682         start_ammo_nails   = warmup_start_ammo_nails   = autocvar_g_ft_start_ammo_nails;
 683         start_ammo_rockets = warmup_start_ammo_rockets = autocvar_g_ft_start_ammo_rockets;
 684         start_ammo_cells   = warmup_start_ammo_cells   = autocvar_g_ft_start_ammo_cells;
 685         start_ammo_plasma  = warmup_start_ammo_plasma  = autocvar_g_ft_start_ammo_plasma;
 686         start_ammo_fuel    = warmup_start_ammo_fuel    = autocvar_g_ft_start_ammo_fuel;
 687 }
 688
 689 MUTATOR_HOOKFUNCTION(ft, HavocBot_ChooseRole)
 690 {
 691         entity bot = M_ARGV(0, entity);
 692
 693         if (!IS_DEAD(bot))
 694         {
 695                 if (random() < 0.5)
 696                         bot.havocbot_role = havocbot_role_ft_freeing;
 697                 else
 698                         bot.havocbot_role = havocbot_role_ft_offense;
 699         }
 700
 701         // if bots spawn all at once assign them a more appropriated role after a while
 702         if (time < CS(bot).jointime + 1)
 703                 bot.havocbot_role_timeout = time + 10 + random() * 10;
 704
 705         return true;
 706 }
 707
 708 MUTATOR_HOOKFUNCTION(ft, TeamBalance_CheckAllowedTeams, CBC_ORDER_EXCLUSIVE)
 709 {
 710         M_ARGV(0, float) = freezetag_teams;
 711         return true;
 712 }
 713
 714 MUTATOR_HOOKFUNCTION(ft, SetWeaponArena)
 715 {
 716         if(M_ARGV(0, string) == "0" || M_ARGV(0, string) == "")
 717                 M_ARGV(0, string) = autocvar_g_freezetag_weaponarena;
 718 }
 719
 720 MUTATOR_HOOKFUNCTION(ft, FragCenterMessage)
 721 {
 722         entity frag_attacker = M_ARGV(0, entity);
 723         entity frag_target = M_ARGV(1, entity);
 724         //float frag_deathtype = M_ARGV(2, float);
 725         int kill_count_to_attacker = M_ARGV(3, int);
 726         int kill_count_to_target = M_ARGV(4, int);
 727
 728         if(STAT(FROZEN, frag_target) == FROZEN_NORMAL)
 729                 return; // target was already frozen, so this is just pushing them off the cliff
 730
 731         Send_Notification(NOTIF_ONE, frag_attacker, MSG_CHOICE, CHOICE_FRAG_FREEZE, frag_target.netname, kill_count_to_attacker, (IS_BOT_CLIENT(frag_target) ? -1 : CS(frag_target).ping));
 732         Send_Notification(NOTIF_ONE, frag_target, MSG_CHOICE, CHOICE_FRAGGED_FREEZE, frag_attacker.netname, kill_count_to_target,
 733                 GetResource(frag_attacker, RES_HEALTH), GetResource(frag_attacker, RES_ARMOR), (IS_BOT_CLIENT(frag_attacker) ? -1 : CS(frag_attacker).ping));
 734
 735         return true;
 736 }
 737
 738 MUTATOR_HOOKFUNCTION(ft, SV_ParseServerCommand)
 739 {
 740         string cmd_name = M_ARGV(0, string);
 741         if (cmd_name == "shuffleteams")
 742                 shuffleteams_on_reset_map = !(round_handler_IsActive() && !round_handler_IsRoundStarted());
 743         return false;
 744 }
 745
 746 MUTATOR_HOOKFUNCTION(ft, Scores_CountFragsRemaining)
 747 {
 748         // announce remaining frags
 749         return true;
 750 }
 751
 752 void freezetag_Initialize()
 753 {
 754         freezetag_teams = autocvar_g_freezetag_teams_override;
 755         if(freezetag_teams < 2)
 756                 freezetag_teams = cvar("g_freezetag_teams"); // read the cvar directly as it gets written earlier in the same frame
 757
 758         freezetag_teams = BITS(bound(2, freezetag_teams, 4));
 759         GameRules_scoring(freezetag_teams, SFL_SORT_PRIO_PRIMARY, 0, {
 760                 field_team(ST_FT_ROUNDS, "rounds", SFL_SORT_PRIO_PRIMARY);
 761                 field(SP_FREEZETAG_REVIVALS, "revivals", 0);
 762         });
 763
 764         round_handler_Spawn(freezetag_CheckTeams, freezetag_CheckWinner, func_null);
 765         round_handler_Init(5, autocvar_g_freezetag_warmup, autocvar_g_freezetag_round_timelimit);
 766
 767         EliminatedPlayers_Init(freezetag_isEliminated);
 768 }