qcsrc/common/gamemodes/gamemode/lms/sv_lms.qc

   1 #include "sv_lms.qh"
   2
   3 #include <common/mutators/mutator/instagib/items.qh>
   4 #include <server/campaign.qh>
   5 #include <server/command/_mod.qh>
   6
   7 int autocvar_g_lms_extra_lives;
   8 bool autocvar_g_lms_join_anytime;
   9 int autocvar_g_lms_last_join;
  10 bool autocvar_g_lms_regenerate;
  11
  12 // main functions
  13 float LMS_NewPlayerLives()
  14 {
  15         float fl;
  16         fl = autocvar_fraglimit;
  17         if(fl == 0)
  18                 fl = 999;
  19
  20         // first player has left the game for dying too much? Nobody else can get in.
  21         if(lms_lowest_lives < 1)
  22                 return 0;
  23
  24         if(!autocvar_g_lms_join_anytime)
  25                 if(lms_lowest_lives < fl - autocvar_g_lms_last_join)
  26                         return 0;
  27
  28         return bound(1, lms_lowest_lives, fl);
  29 }
  30
  31 void ClearWinners();
  32
  33 // LMS winning condition: game terminates if and only if there's at most one
  34 // one player who's living lives. Top two scores being equal cancels the time
  35 // limit.
  36 int WinningCondition_LMS()
  37 {
  38         entity first_player = NULL;
  39         int totalplayers = 0;
  40         FOREACH_CLIENT(IS_PLAYER(it), {
  41                 if (!totalplayers)
  42                         first_player = it;
  43                 ++totalplayers;
  44         });
  45
  46         if (totalplayers)
  47         {
  48                 if (totalplayers > 1)
  49                 {
  50                         // two or more active players - continue with the game
  51
  52                         if (autocvar_g_campaign)
  53                         {
  54                                 FOREACH_CLIENT(IS_REAL_CLIENT(it), {
  55                                         float pl_lives = GameRules_scoring_add(it, LMS_LIVES, 0);
  56                                         if (!pl_lives)
  57                                                 return WINNING_YES; // human player lost, game over
  58                                         break;
  59                                 });
  60                         }
  61                 }
  62                 else
  63                 {
  64                         // exactly one player?
  65
  66                         ClearWinners();
  67                         SetWinners(winning, 0); // NOTE: exactly one player is still "player", so this works out
  68
  69                         if (LMS_NewPlayerLives())
  70                         {
  71                                 // game still running (that is, nobody got removed from the game by a frag yet)? then continue
  72                                 return WINNING_NO;
  73                         }
  74                         else
  75                         {
  76                                 // a winner!
  77                                 // and assign him his first place
  78                                 GameRules_scoring_add(first_player, LMS_RANK, 1);
  79                                 if(warmup_stage)
  80                                         return WINNING_NO;
  81                                 else
  82                                         return WINNING_YES;
  83                         }
  84                 }
  85         }
  86         else
  87         {
  88                 // nobody is playing at all...
  89                 if (LMS_NewPlayerLives())
  90                 {
  91                         // wait for players...
  92                 }
  93                 else
  94                 {
  95                         // SNAFU (maybe a draw game?)
  96                         ClearWinners();
  97                         LOG_TRACE("No players, ending game.");
  98                         return WINNING_YES;
  99                 }
 100         }
 101
 102         // When we get here, we have at least two players who are actually LIVING,
 103         // now check if the top two players have equal score.
 104         WinningConditionHelper(NULL);
 105
 106         ClearWinners();
 107         if(WinningConditionHelper_winner)
 108                 WinningConditionHelper_winner.winning = true;
 109         if(WinningConditionHelper_topscore == WinningConditionHelper_secondscore)
 110                 return WINNING_NEVER;
 111
 112         // Top two have different scores? Way to go for our beloved TIMELIMIT!
 113         return WINNING_NO;
 114 }
 115
 116 // mutator hooks
 117 MUTATOR_HOOKFUNCTION(lms, reset_map_global)
 118 {
 119         lms_lowest_lives = 999;
 120 }
 121
 122 MUTATOR_HOOKFUNCTION(lms, reset_map_players)
 123 {
 124         FOREACH_CLIENT(true, {
 125                 TRANSMUTE(Player, it);
 126                 it.frags = FRAGS_PLAYER;
 127                 GameRules_scoring_add(it, LMS_LIVES, LMS_NewPlayerLives());
 128                 PutClientInServer(it);
 129         });
 130 }
 131
 132 // FIXME add support for sv_ready_restart_after_countdown
 133 // that is find a way to respawn/reset players IN GAME without setting lives to 0
 134 MUTATOR_HOOKFUNCTION(lms, ReadLevelCvars)
 135 {
 136         // incompatible
 137         sv_ready_restart_after_countdown = 0;
 138 }
 139
 140 MUTATOR_HOOKFUNCTION(lms, PutClientInServer)
 141 {
 142         entity player = M_ARGV(0, entity);
 143
 144         if(player.frags == FRAGS_SPECTATOR)
 145                 TRANSMUTE(Observer, player);
 146         else
 147         {
 148                 float tl = GameRules_scoring_add(player, LMS_LIVES, 0);
 149                 if(tl < lms_lowest_lives)
 150                         lms_lowest_lives = tl;
 151                 if(tl <= 0)
 152                         TRANSMUTE(Observer, player);
 153                 if(warmup_stage)
 154                         GameRules_scoring_add(player, LMS_RANK, -GameRules_scoring_add(player, LMS_RANK, 0));
 155         }
 156 }
 157
 158 MUTATOR_HOOKFUNCTION(lms, ForbidSpawn)
 159 {
 160         entity player = M_ARGV(0, entity);
 161
 162         if(warmup_stage)
 163                 return false;
 164         if(player.frags == FRAGS_SPECTATOR)
 165                 return true;
 166         if(GameRules_scoring_add(player, LMS_LIVES, 0) <= 0)
 167         {
 168                 Send_Notification(NOTIF_ONE, player, MSG_CENTER, CENTER_LMS_NOLIVES);
 169                 return true;
 170         }
 171         return false;
 172 }
 173
 174 MUTATOR_HOOKFUNCTION(lms, PlayerDies)
 175 {
 176         entity frag_target = M_ARGV(2, entity);
 177
 178         frag_target.respawn_flags |= RESPAWN_FORCE;
 179 }
 180
 181 void lms_RemovePlayer(entity player)
 182 {
 183         static int quitters = 0;
 184         float player_rank = GameRules_scoring_add(player, LMS_RANK, 0);
 185         if (!player_rank)
 186         {
 187                 int pl_cnt = 0;
 188                 FOREACH_CLIENT(IS_PLAYER(it), { pl_cnt++; });
 189                 if (player.lms_spectate_warning != 2)
 190                 {
 191                         if(IS_BOT_CLIENT(player))
 192                                 bot_clear(player);
 193                         player.frags = FRAGS_LMS_LOSER;
 194                         GameRules_scoring_add(player, LMS_RANK, pl_cnt + 1);
 195                 }
 196                 else
 197                 {
 198                         lms_lowest_lives = 999;
 199                         FOREACH_CLIENT(true, {
 200                                 if (it.frags == FRAGS_LMS_LOSER)
 201                                 {
 202                                         float it_rank = GameRules_scoring_add(it, LMS_RANK, 0);
 203                                         if (it_rank > player_rank && it_rank <= 256)
 204                                                 GameRules_scoring_add(it, LMS_RANK, -1);
 205                                         lms_lowest_lives = 0;
 206                                 }
 207                                 else if (it.frags != FRAGS_SPECTATOR)
 208                                 {
 209                                         float tl = GameRules_scoring_add(it, LMS_LIVES, 0);
 210                                         if(tl < lms_lowest_lives)
 211                                                 lms_lowest_lives = tl;
 212                                 }
 213                         });
 214                         GameRules_scoring_add(player, LMS_RANK, 665 - quitters); // different from 666
 215                         if(!warmup_stage)
 216                         {
 217                                 GameRules_scoring_add(player, LMS_LIVES, -GameRules_scoring_add(player, LMS_LIVES, 0));
 218                                 ++quitters;
 219                         }
 220                         player.frags = FRAGS_LMS_LOSER;
 221                         TRANSMUTE(Observer, player);
 222                 }
 223                 if (pl_cnt == 2 && !warmup_stage) // a player is forfeiting leaving only one player
 224                         lms_lowest_lives = 0; // end the game now!
 225         }
 226
 227         if(CS(player).killcount != FRAGS_SPECTATOR)
 228                 if(GameRules_scoring_add(player, LMS_RANK, 0) > 0 && player.lms_spectate_warning != 2)
 229                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_LMS_NOLIVES, player.netname);
 230                 else
 231                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_LMS_FORFEIT, player.netname);
 232 }
 233
 234 MUTATOR_HOOKFUNCTION(lms, ClientDisconnect)
 235 {
 236         entity player = M_ARGV(0, entity);
 237
 238         lms_RemovePlayer(player);
 239 }
 240
 241 MUTATOR_HOOKFUNCTION(lms, MakePlayerObserver)
 242 {
 243         entity player = M_ARGV(0, entity);
 244
 245         if (!IS_PLAYER(player))
 246                 return true;
 247
 248         lms_RemovePlayer(player);
 249         return true;  // prevent team reset
 250 }
 251
 252 MUTATOR_HOOKFUNCTION(lms, ClientConnect)
 253 {
 254         entity player = M_ARGV(0, entity);
 255
 256         if(GameRules_scoring_add(player, LMS_LIVES, LMS_NewPlayerLives()) <= 0)
 257         {
 258                 GameRules_scoring_add(player, LMS_RANK, 666); // mark as forced spectator for the hud code
 259                 player.frags = FRAGS_SPECTATOR;
 260         }
 261 }
 262
 263 // FIXME LMS doesn't allow clients to spectate due to its particular implementation
 264 MUTATOR_HOOKFUNCTION(lms, AutoJoinOnConnection)
 265 {
 266         if(autocvar_g_campaign)
 267                 return false;
 268         return true;
 269 }
 270
 271 MUTATOR_HOOKFUNCTION(lms, PlayerPreThink)
 272 {
 273         entity player = M_ARGV(0, entity);
 274
 275         if(player.deadflag == DEAD_DYING)
 276                 player.deadflag = DEAD_RESPAWNING;
 277 }
 278
 279 MUTATOR_HOOKFUNCTION(lms, PlayerRegen)
 280 {
 281         if(autocvar_g_lms_regenerate)
 282                 return false;
 283         return true;
 284 }
 285
 286 MUTATOR_HOOKFUNCTION(lms, ForbidThrowCurrentWeapon)
 287 {
 288         // forbode!
 289         return true;
 290 }
 291
 292 MUTATOR_HOOKFUNCTION(lms, GiveFragsForKill)
 293 {
 294         entity frag_target = M_ARGV(1, entity);
 295
 296         if (!warmup_stage)
 297         {
 298                 // remove a life
 299                 int tl = GameRules_scoring_add(frag_target, LMS_LIVES, -1);
 300                 if(tl < lms_lowest_lives)
 301                         lms_lowest_lives = tl;
 302                 if(tl <= 0)
 303                 {
 304                         int pl_cnt = 0;
 305                         FOREACH_CLIENT(IS_PLAYER(it), { pl_cnt++; });
 306                         if(IS_BOT_CLIENT(frag_target))
 307                                 bot_clear(frag_target);
 308                         frag_target.frags = FRAGS_LMS_LOSER;
 309                         GameRules_scoring_add(frag_target, LMS_RANK, pl_cnt);
 310                 }
 311         }
 312         M_ARGV(2, float) = 0; // frag score
 313
 314         return true;
 315 }
 316
 317 MUTATOR_HOOKFUNCTION(lms, SetStartItems)
 318 {
 319         start_items &= ~IT_UNLIMITED_AMMO;
 320         start_health       = warmup_start_health       = cvar("g_lms_start_health");
 321         start_armorvalue   = warmup_start_armorvalue   = cvar("g_lms_start_armor");
 322         start_ammo_shells  = warmup_start_ammo_shells  = cvar("g_lms_start_ammo_shells");
 323         start_ammo_nails   = warmup_start_ammo_nails   = cvar("g_lms_start_ammo_nails");
 324         start_ammo_rockets = warmup_start_ammo_rockets = cvar("g_lms_start_ammo_rockets");
 325         start_ammo_cells   = warmup_start_ammo_cells   = cvar("g_lms_start_ammo_cells");
 326         start_ammo_plasma  = warmup_start_ammo_plasma  = cvar("g_lms_start_ammo_plasma");
 327         start_ammo_fuel    = warmup_start_ammo_fuel    = cvar("g_lms_start_ammo_fuel");
 328 }
 329
 330 MUTATOR_HOOKFUNCTION(lms, ForbidPlayerScore_Clear)
 331 {
 332         // don't clear player score
 333         return true;
 334 }
 335
 336 MUTATOR_HOOKFUNCTION(lms, FilterItemDefinition)
 337 {
 338         entity definition = M_ARGV(0, entity);
 339
 340         if (autocvar_g_lms_extra_lives && definition == ITEM_ExtraLife)
 341         {
 342                 return false;
 343         }
 344         return true;
 345 }
 346
 347 void lms_extralife(entity this)
 348 {
 349         StartItem(this, ITEM_ExtraLife);
 350 }
 351
 352 MUTATOR_HOOKFUNCTION(lms, OnEntityPreSpawn)
 353 {
 354         if (!autocvar_g_powerups) return false;
 355         if (!autocvar_g_lms_extra_lives) return false;
 356
 357         entity ent = M_ARGV(0, entity);
 358
 359         // Can't use .itemdef here
 360         if (ent.classname != "item_health_mega") return false;
 361
 362         entity e = spawn();
 363         setthink(e, lms_extralife);
 364
 365         e.nextthink = time + 0.1;
 366         e.spawnflags = ent.spawnflags;
 367         e.noalign = ent.noalign;
 368         setorigin(e, ent.origin);
 369
 370         return true;
 371 }
 372
 373 MUTATOR_HOOKFUNCTION(lms, ItemTouch)
 374 {
 375         entity item = M_ARGV(0, entity);
 376         entity toucher = M_ARGV(1, entity);
 377
 378         if(item.itemdef == ITEM_ExtraLife)
 379         {
 380                 Send_Notification(NOTIF_ONE, toucher, MSG_CENTER, CENTER_EXTRALIVES);
 381                 GameRules_scoring_add(toucher, LMS_LIVES, autocvar_g_lms_extra_lives);
 382                 return MUT_ITEMTOUCH_PICKUP;
 383         }
 384
 385         return MUT_ITEMTOUCH_CONTINUE;
 386 }
 387
 388 MUTATOR_HOOKFUNCTION(lms, Bot_FixCount, CBC_ORDER_EXCLUSIVE)
 389 {
 390         FOREACH_CLIENT(IS_REAL_CLIENT(it), {
 391                 ++M_ARGV(0, int); // activerealplayers
 392                 ++M_ARGV(1, int); // realplayers
 393         });
 394
 395         return true;
 396 }
 397
 398 MUTATOR_HOOKFUNCTION(lms, ClientCommand_Spectate)
 399 {
 400         entity player = M_ARGV(0, entity);
 401
 402         if(warmup_stage || player.lms_spectate_warning)
 403         {
 404                 // for the forfeit message...
 405                 player.lms_spectate_warning = 2;
 406         }
 407         else
 408         {
 409                 if(player.frags != FRAGS_SPECTATOR && player.frags != FRAGS_LMS_LOSER)
 410                 {
 411                         player.lms_spectate_warning = 1;
 412                         sprint(player, "WARNING: you won't be able to enter the game again after spectating in LMS. Use the same command again to spectate anyway.\n");
 413                 }
 414                 return MUT_SPECCMD_RETURN;
 415         }
 416         return MUT_SPECCMD_CONTINUE;
 417 }
 418
 419 MUTATOR_HOOKFUNCTION(lms, CheckRules_World)
 420 {
 421         M_ARGV(0, float) = WinningCondition_LMS();
 422         return true;
 423 }
 424
 425 MUTATOR_HOOKFUNCTION(lms, WantWeapon)
 426 {
 427         M_ARGV(2, bool) = true; // all weapons
 428 }
 429
 430 MUTATOR_HOOKFUNCTION(lms, GetPlayerStatus)
 431 {
 432         return true;
 433 }
 434
 435 MUTATOR_HOOKFUNCTION(lms, AddPlayerScore)
 436 {
 437         if(game_stopped)
 438         if(M_ARGV(0, entity) == SP_LMS_RANK) // score field
 439                 return true; // allow writing to this field in intermission as it is needed for newly joining players
 440 }
 441
 442 void lms_Initialize()
 443 {
 444         lms_lowest_lives = 9999;
 445 }